gnu/dist/autoconf/tests/base.at

   1 #                                                       -*- autoconf -*-
   2
   3 AT_BANNER([Autoconf base layer.])
   4
   5
   6 ## ------------------------------- ##
   7 ## AC_REQUIRE: topological sort..  ##
   8 ## ------------------------------- ##
   9
  10 # Check that dependencies are always properly honored.
  11
  12 AT_SETUP([AC_REQUIRE: topological sort])
  13
  14 AT_DATA(configure.ac,
  15 [[define([REQUIRE_AND_CHECK],
  16 [AC_REQUIRE([$1])dnl
  17 test -z "$m4_translit([$1], [A-Z], [a-z])" && AS_EXIT(1)])
  18
  19 AC_DEFUN([TEST1],
  20 [REQUIRE_AND_CHECK([TEST2a])
  21 REQUIRE_AND_CHECK([TEST2b])
  22 test1=set])
  23
  24 AC_DEFUN([TEST2a],
  25 [test2a=set])
  26
  27 AC_DEFUN([TEST2b],
  28 [REQUIRE_AND_CHECK([TEST3])
  29 test2b=set])
  30
  31 AC_DEFUN([TEST3],
  32 [REQUIRE_AND_CHECK([TEST2a])
  33 test3=set])
  34
  35 AC_PLAIN_SCRIPT()dnl
  36 #! /bin/sh
  37
  38 TEST1
  39 test -z "$test1" &&
  40   AC_MSG_ERROR([\$test1 is empty])
  41 AS_EXIT(0)
  42 ]])
  43
  44 AT_CHECK_AUTOCONF
  45 AT_CHECK_CONFIGURE
  46
  47 AT_CLEANUP
  48
  49
  50
  51 ## ----------------------------------------------- ##
  52 ## AC_REQUIRE and AC_DEFUN_ONCE: Require, expand.  ##
  53 ## ----------------------------------------------- ##
  54
  55 AT_SETUP([AC_REQUIRE & AC_DEFUN_ONCE: Require, expand])
  56
  57 AT_DATA([configure.ac],
  58 [[AC_DEFUN([TEST],
  59 [AC_REQUIRE([MULTI_TEST])
  60 AC_REQUIRE([SINGLE_TEST])])
  61
  62 AC_DEFUN([MULTI_TEST],
  63 [multi_test=".$multi_test"])
  64
  65 AC_DEFUN_ONCE([SINGLE_TEST],
  66 [single_test=".$single_test"])
  67
  68 AC_PLAIN_SCRIPT()dnl
  69 #! /bin/sh
  70
  71 TEST
  72 TEST
  73 MULTI_TEST
  74 MULTI_TEST
  75 SINGLE_TEST
  76 SINGLE_TEST
  77
  78 case $multi_test:$single_test in
  79   ...:. ) AS_EXIT(0);;
  80   ...:* ) AC_MSG_ERROR([DEFUN_ONCE is broken]);;
  81   *:.   ) AC_MSG_ERROR([DEFUN is broken (Wow, congrats!)]);;
  82 esac
  83 ]])
  84
  85 AT_CHECK_AUTOCONF([], 0, [],
  86 [configure.ac:18: warning: SINGLE_TEST invoked multiple times
  87 configure.ac:19: warning: SINGLE_TEST invoked multiple times
  88 ])
  89
  90 AT_CHECK_CONFIGURE
  91
  92 AT_CLEANUP
  93
  94
  95
  96 ## ----------------------------------------------- ##
  97 ## AC_REQUIRE and AC_DEFUN_ONCE: Expand, require.  ##
  98 ## ----------------------------------------------- ##
  99
 100 AT_SETUP([AC_REQUIRE & AC_DEFUN_ONCE: Expand, require])
 101
 102 AT_DATA([configure.ac],
 103 [[AC_DEFUN([TEST],
 104 [AC_REQUIRE([MULTI_TEST])
 105 AC_REQUIRE([SINGLE_TEST])])
 106
 107 AC_DEFUN([MULTI_TEST],
 108 [multi_test=".$multi_test"])
 109
 110 AC_DEFUN_ONCE([SINGLE_TEST],
 111 [single_test=".$single_test"])
 112
 113 AC_PLAIN_SCRIPT()dnl
 114 #! /bin/sh
 115
 116 MULTI_TEST
 117 MULTI_TEST
 118 SINGLE_TEST
 119 SINGLE_TEST
 120 TEST
 121 TEST
 122
 123 case $multi_test:$single_test in
 124   ..:. ) AS_EXIT(0);;
 125   ..:* ) AC_MSG_ERROR([DEFUN_ONCE is broken]);;
 126   *:.  ) AC_MSG_ERROR([DEFUN is broken (Wow, congrats!)]);;
 127      * ) AC_MSG_ERROR([received `$multi_test:$single_test']);;
 128 esac
 129 ]])
 130
 131 AT_CHECK_AUTOCONF([], 0, [],
 132 [configure.ac:17: warning: SINGLE_TEST invoked multiple times
 133 ])
 134 AT_CHECK_CONFIGURE
 135
 136 AT_CLEANUP
 137
 138
 139
 140 ## ------------------------- ##
 141 ## AC_REQUIRE & AC_PROVIDE.  ##
 142 ## ------------------------- ##
 143
 144 AT_SETUP([AC_REQUIRE & AC_PROVIDE])
 145
 146 AT_DATA([configure.ac],
 147 [[AC_DEFUN([TEST],
 148 [AC_REQUIRE([INNER_TEST])])
 149
 150 AC_DEFUN([INNER_TEST],
 151 [inner_test=".$inner_test"])
 152
 153 AC_PLAIN_SCRIPT()dnl
 154 #! /bin/sh
 155
 156 AC_PROVIDE([INNER_TEST])
 157 TEST
 158
 159 case $inner_test in
 160   "" ) AS_EXIT(0);;
 161   *  ) AC_MSG_ERROR([received `$inner_test']);;
 162 esac
 163 ]])
 164
 165 AT_CHECK_AUTOCONF
 166 AT_CHECK_CONFIGURE
 167
 168 AT_CLEANUP
 169
 170
 171 ## ---------------------- ##
 172 ## AC_REQUIRE & AC_LANG.  ##
 173 ## ---------------------- ##
 174
 175 AT_SETUP([AC_REQUIRE & AC_LANG])
 176
 177 AT_DATA([configure.ac],
 178 [[AC_DEFUN([AC_F77_1],
 179 [AC_LANG_PUSH([Fortran 77])
 180 if test $ac_ext != f; then
 181   AC_MSG_ERROR([F77_1: current shell language is $ac_ext, expected Fortran])
 182 fi
 183 AC_LANG_POP
 184 ])
 185
 186
 187 AC_DEFUN([AC_F77_2],
 188 [AC_LANG_PUSH([Fortran 77])
 189 AC_REQUIRE([AC_F77_1])
 190 if test $ac_ext != f; then
 191   AC_MSG_ERROR([F77_2: current shell language is $ac_ext, expected Fortran])
 192 fi
 193 AC_LANG_POP
 194 ])
 195
 196 AC_INIT
 197 AC_F77_2
 198 AS_EXIT(0)
 199 ]])
 200
 201 AT_CHECK_AUTOCONF
 202 AT_CHECK_CONFIGURE
 203
 204 AT_CLEANUP
 205
 206
 207 ## ---------------- ##
 208 ## AC_CACHE_CHECK.  ##
 209 ## ---------------- ##
 210
 211 # Make sure AC_CACHE_CHECK is silent with -q.
 212
 213 AT_SETUP([AC_CACHE_CHECK])
 214
 215 AT_DATA([configure.ac],
 216 [[AC_INIT
 217 AC_CACHE_CHECK([for nothing],
 218                [ac_nothing],
 219                [ac_nothing=found])
 220 ]])
 221
 222 AT_CHECK_AUTOCONF
 223 AT_CHECK_CONFIGURE([-q])
 224
 225 AT_CLEANUP
 226
 227
 228 ## ---------- ##
 229 ## AC_TRY_*.  ##
 230 ## ---------- ##
 231
 232 AT_SETUP([AC_TRY_*])
 233
 234 AT_DATA([configure.ac],
 235 [[AC_INIT
 236
 237 if AC_TRY_COMMAND([(echo "The Cat in the Hat";
 238                     echo "The Hat in the Cat" >&2)
 239                   | grep \^The\ Cat\ in\ the\ Hat\$ >/dev/null]); then
 240   :
 241 else
 242   AC_MSG_ERROR([Didn't see the Cat in the Hat!])
 243 fi
 244
 245 if AC_TRY_COMMAND([(echo "The Cat in the Hat";
 246                     echo "The Hat in the Cat" >&2)
 247                   | grep \^The\ Hat\ in\ the\ Cat\$ >/dev/null]); then
 248   AC_MSG_ERROR([Saw the Hat in the Cat!])
 249 fi
 250 ]])
 251
 252 AT_CHECK_AUTOCONF
 253 AT_CHECK_CONFIGURE([-q])
 254
 255 AT_CLEANUP