gnu/dist/autoconf/tests/foreign.at

   1 #                                                       -*- autoconf -*-
   2
   3 AT_BANNER([Compatibility with other tools.])
   4
   5 ## -------------------- ##
   6 ## Autoconf & Libtool.  ##
   7 ## -------------------- ##
   8
   9 AT_SETUP([[Libtool]])
  10
  11 # Skip this test if there is no libtoolize.
  12 AT_CHECK([libtoolize --version || exit 77],
  13          ignore, ignore, ignore)
  14 # CVS Autoconf probably does not work with too old Libtools.
  15 AT_CHECK([[
  16 case `libtoolize --version |
  17       sed -n '/^.* \([0-9][0-9.a-z]*\)$/{s//\1/;p;q;}'` in
  18   0.*          ) exit 77;;
  19   1.[012]*     ) exit 77;;
  20   1.3.[01234]* ) exit 77;;
  21 esac]],
  22          ignore, ignore, ignore)
  23
  24 # FIXME: Once Libtool `configure.ac' aware, change this.
  25 # Using a configure.in, have libtoolize confess where libtool.m4 is.
  26 AT_DATA([configure.in],
  27 [[AC_INIT
  28 # The other tests are relying on Autoconf's own copy of install-sh
  29 # etc. via AC_CONFIG_AUX_DIR(..).  Don't do that here, since we don't
  30 # want libtoolize to pollute Autoconf's srcdir.
  31 AC_CONFIG_AUX_DIR(.)
  32 AC_PROG_LIBTOOL
  33 ]])
  34 AT_CHECK([libtoolize | sed -n ["s,^.*\`\(/[^']*\)'.*,\1,p"]],
  35          0, [stdout], ignore)
  36
  37 # Make sure at-path contains something valid, and let the test suite
  38 # display it when verbose.  And fail, skipping would too easily hide
  39 # problems.
  40 AT_CHECK([grep . stdout], 0, [ignore])
  41 AT_CHECK([test -f "`cat stdout`"])
  42
  43 # libtoolize installed everything but install-sh...
  44 touch install-sh
  45
  46 # Build the concatenation of libtool.m4 and configure.ac.
  47 cp `cat stdout` configure.in
  48 cat >>configure.in <<_EOF
  49 AC_INIT
  50 AC_CONFIG_AUX_DIR(.)
  51 AC_CANONICAL_SYSTEM
  52 AC_PROG_LIBTOOL
  53 _EOF
  54
  55 AT_CHECK_AUTOCONF
  56
  57 # Ignore stderr, because ltconfig always loads the cache, which is
  58 # /dev/null, and some shells choke on this.  For instance with Bash
  59 # 2.05, you get:
  60 #
  61 #   loading cache /dev/null within ltconfig
  62 #   ./ltconfig: .: /dev/null: not a regular file
  63 #
  64 # But the script executes properly.
  65 AT_CHECK_CONFIGURE([], [], [], [ignore])
  66
  67 AT_CLEANUP(install-sh ltconfig libtool at-path ltmain.sh config.guess config.sub)