gnu/dist/gettext/gettext-tools/configure.ac

   1 dnl Configuration for the gettext-tools directory of GNU gettext
   2 dnl Copyright (C) 1995-1999, 2000-2005 Free Software Foundation, Inc.
   3 dnl
   4 dnl This program is free software; you can redistribute it and/or modify
   5 dnl it under the terms of the GNU General Public License as published by
   6 dnl the Free Software Foundation; either version 2, or (at your option)
   7 dnl any later version.
   8 dnl
   9 dnl This program is distributed in the hope that it will be useful,
  10 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 dnl GNU General Public License for more details.
  13 dnl
  14 dnl You should have received a copy of the GNU General Public License
  15 dnl along with this program; if not, write to the Free Software
  16 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  17
  18 dnl Process this file with autoconf to produce a configure script.
  19
  20 AC_PREREQ(2.57)
  21 AC_INIT
  22 AC_CONFIG_SRCDIR(src/msgfmt.c)
  23 AC_CONFIG_AUX_DIR(../build-aux)
  24 . $srcdir/../version.sh
  25 AM_INIT_AUTOMAKE(gettext-tools, $VERSION_NUMBER)
  26 AM_CONFIG_HEADER(config.h)
  27
  28 dnl Installation directories.
  29 AC_SUBST([localedir], ['${datadir}/locale'])
  30 AC_SUBST([docdir], ['${datadir}/doc/gettext'])
  31 dnl Prefer modern Filesystem Hierarchy Standard over antiquated GNU standards.
  32 test "$mandir" != '${prefix}/man' || mandir='${datadir}/man'
  33
  34 dnl Checks for programs.
  35 AC_PROG_CC
  36 AC_PROG_INSTALL
  37 AC_PROG_YACC
  38
  39 gt_GCJ
  40 if test -n "$HAVE_GCJ"; then
  41   BUILDJAVAEXE=yes
  42 else
  43   BUILDJAVAEXE=no
  44 fi
  45 AC_SUBST(BUILDJAVAEXE)
  46
  47 gt_JAVACOMP
  48 AC_CHECK_PROG(JAR, jar, jar)
  49 if test -n "$HAVE_JAVACOMP" && test -n "$JAR"; then
  50   BUILDJAVA=yes
  51 else
  52   BUILDJAVA=no
  53 fi
  54 AC_SUBST(BUILDJAVA)
  55
  56 gt_JAVAEXEC
  57 if test -n "$HAVE_JAVAEXEC" && test $BUILDJAVA = yes; then
  58   TESTJAVA=yes
  59 else
  60   TESTJAVA=no
  61 fi
  62 AC_SUBST(TESTJAVA)
  63
  64 gt_CSHARPCOMP
  65 if test -n "$HAVE_CSHARPCOMP" && test "$CSHARP_CHOICE" != no; then
  66   BUILDCSHARP=yes
  67 else
  68   BUILDCSHARP=no
  69 fi
  70 AC_SUBST(BUILDCSHARP)
  71
  72 gt_CSHARPEXEC
  73 if test -n "$HAVE_CSHARPEXEC" && test $BUILDCSHARP = yes; then
  74   TESTCSHARP=yes
  75 else
  76   TESTCSHARP=no
  77 fi
  78 AC_SUBST(TESTCSHARP)
  79
  80 dnl Check for host type.
  81 AC_CANONICAL_HOST
  82
  83 dnl Checks for UNIX variants that set DEFS,
  84 AC_ISC_POSIX
  85
  86 dnl Checks for compiler output filename suffixes.
  87 AC_OBJEXT
  88 AC_EXEEXT
  89
  90 dnl Make sure we see all GNU and Solaris extensions.
  91 AC_GNU_SOURCE
  92 gl_USE_SYSTEM_EXTENSIONS
  93
  94 dnl Check for build configuration.
  95 AC_LIBTOOL_WIN32_DLL
  96 AC_PROG_LIBTOOL
  97
  98 AC_RELOCATABLE
  99
 100 dnl Checks for libraries.
 101
 102 dnl Checks for header files.
 103 AC_HEADER_STDC
 104 AC_CHECK_HEADERS(limits.h malloc.h pwd.h string.h unistd.h utime.h values.h)
 105 AM_STDBOOL_H
 106
 107 dnl Checks for typedefs, structures, and compiler characteristics.
 108 AC_C_INLINE
 109 bh_C_SIGNED
 110 gl_AC_TYPE_UNSIGNED_LONG_LONG
 111 AC_TYPE_SIZE_T
 112 AC_CHECK_TYPES(ptrdiff_t)
 113 gl_AC_TYPE_UINTMAX_T
 114 gt_TYPE_SSIZE_T
 115 AC_TYPE_PID_T
 116 AC_TYPE_MODE_T
 117 gt_TYPE_SIG_ATOMIC_T
 118
 119 dnl Checks for library functions.
 120 gl_ALLOCSA
 121 AC_FUNC_VPRINTF
 122 AC_CHECK_FUNCS([chown getcwd posix_spawn raise select strerror strtoul uname \
 123 utime utimes waitid])
 124 AC_REPLACE_FUNCS([atexit memmove memset stpcpy strcspn \
 125 strpbrk strstr vasprintf])
 126 AM_FUNC_GETLINE
 127 if test $am_cv_func_working_getline != yes; then
 128   AC_CHECK_FUNCS(getdelim)
 129 fi
 130 gl_EXITFAIL
 131 gl_FUNC_FNMATCH_POSIX
 132 gl_GETOPT
 133 gl_FUNC_EACCESS
 134 gl_FUNC_STPNCPY
 135 gl_STRCASE
 136 gl_FUNC_STRTOUL
 137 gl_MBSWIDTH
 138 gt_PREREQ_BACKUPFILE
 139 AC_FUNC_VFORK
 140 gt_UNION_WAIT
 141 gt_TMPDIR
 142 gt_FUNC_MKDTEMP
 143 gt_SIGNALBLOCKING
 144 gt_SIGINFO
 145 gt_FUNC_SETENV
 146 gl_FUNC_STRERROR
 147 gl_FUNC_GLIBC_UNLOCKED_IO
 148 gl_ERROR
 149 gl_QUOTEARG
 150 gl_QUOTE
 151 gl_PATHMAX
 152 gl_FUNC_READLINK
 153 gl_XREADLINK
 154 gl_CANONICALIZE
 155 gt_SETLOCALE
 156 gl_XSIZE
 157 gt_LIBGREP
 158
 159 gt_PREREQ_HOSTNAME
 160
 161 dnl These are the only lines required to internationalize the package.
 162 dnl (OK, not quite, the AC_CONFIG_FILES has also some parts.)
 163 AM_GNU_GETTEXT(use-libtool, need-ngettext)
 164
 165 dnl Put some default definitions into config.h.
 166 AH_TOP([
 167 /* Default value for alignment of strings in .mo file.  */
 168 #define DEFAULT_OUTPUT_ALIGNMENT 1
 169 ])
 170 AH_BOTTOM([
 171 /* A file name cannot consist of any character possible.  INVALID_PATH_CHAR
 172    contains the characters not allowed.  */
 173 #if defined _MSC_VER || defined __MINGW32__
 174 /* Woe32.  This string is valid for Windows NT/2000.  On Windows 95/98/ME some
 175    few characters in the range 0x80..0xff are invalid as well, but this doesn't
 176    matter much for our purposes.  */
 177 # define INVALID_PATH_CHAR "\001\002\003\004\005\006\007\010\011\012\013\014\015\016\017\020\021\022\023\024\025\026\027\030\031\032\033\034\035\036\037\"*/:<>?\\|"
 178 #elif defined MSDOS
 179 /* Something like this for MSDOG.  */
 180 # define INVALID_PATH_CHAR "\001\002\003\004\005\006\007\010\011\012\013\014\015\016\017\020\021\022\023\024\025\026\027\030\031\032\033\034\035\036\037 \177\\:."
 181 #else
 182 /* Unix.  */
 183 # define INVALID_PATH_CHAR "\001\002\003\004\005\006\007\010\011\012\013\014\015\016\017\020\021\022\023\024\025\026\027\030\031\032\033\034\035\036\037 \177/"
 184 #endif
 185
 186 /* This is the page width for the message_print function.  It should
 187    not be set to more than 79 characters (Emacs users will appreciate
 188    it).  It is used to wrap the msgid and msgstr strings, and also to
 189    wrap the file position (#:) comments.  */
 190 #define PAGE_WIDTH 79
 191
 192 /* On Windows, variables that may be in a DLL must be marked specially.  */
 193 #if defined _MSC_VER && defined _DLL
 194 # define DLL_VARIABLE __declspec (dllimport)
 195 #else
 196 # define DLL_VARIABLE
 197 #endif
 198
 199 /* Extra OS/2 (emx+gcc) defines.  */
 200 #ifdef __EMX__
 201 # include "intl/os2compat.h"
 202 #endif
 203 ])
 204
 205 dnl Check for the expat XML parser.
 206 dnl On operating systems where binary distribution vendors are likely to
 207 dnl ship both gettext and expat, we use dynamic loading to avoid a hard
 208 dnl dependency from gettext to expat.
 209 case "$host_os" in
 210   linux*)
 211     AC_DEFINE([DYNLOAD_LIBEXPAT], 1,
 212       [Define to 1 if libexpat shall be dynamically loaded via dlopen().])
 213     LIBEXPAT="-ldl"
 214     LTLIBEXPAT="-ldl"
 215     AC_SUBST(LIBEXPAT)
 216     AC_SUBST(LTLIBEXPAT)
 217     ;;
 218   *)
 219     AC_LIB_HAVE_LINKFLAGS([expat], [],
 220       [#include <expat.h>], [XML_ExpatVersion();])
 221     ;;
 222 esac
 223
 224 dnl Check for Emacs and where to install .elc files.
 225 AM_PATH_LISPDIR
 226
 227 aclocaldir='${datadir}/aclocal'
 228 AC_SUBST(aclocaldir)
 229
 230 dnl Check for tools needed for formatting the documentation.
 231 ac_aux_dir_abs=`cd $ac_aux_dir && pwd`
 232 AC_PATH_PROG(DVIPS, dvips, $ac_aux_dir_abs/missing dvips)
 233 AC_PATH_PROG(TEXI2PDF, texi2pdf, $ac_aux_dir_abs/missing texi2pdf)
 234 AC_PATH_PROG(PERL, perl, $ac_aux_dir_abs/missing perl)
 235
 236 dnl Check for tools needed for formatting man pages.
 237 CROSS_COMPILING=$cross_compiling
 238 AC_SUBST(CROSS_COMPILING)
 239
 240 dnl Checks for optional programs for the tests/lang-* tests.
 241 gt_PROG_ANSI_CXX
 242 gt_LOCALE_FR
 243 gt_LOCALE_FR_UTF8
 244
 245 dnl Check whether to execute tests that rely on libasprintf.
 246 dnl This test must be consistent with gettext-runtime/configure.ac.
 247 if test "${enable_libasprintf+set}" = set; then
 248   if test "$enable_libasprintf" != no; then
 249     TESTLIBASPRINTF=yes
 250   else
 251     TESTLIBASPRINTF=no
 252   fi
 253 else
 254   TESTLIBASPRINTF=yes
 255 fi
 256 if test "$CXX" = ":"; then
 257   TESTLIBASPRINTF=no
 258 fi
 259 AC_SUBST(TESTLIBASPRINTF)
 260
 261 dnl Generate the version information file in the intl/ directory.
 262 test -d intl || mkdir intl
 263 echo "GNU gettext library from gettext-$VERSION" > intl/VERSION
 264 cat > intl/ChangeLog.inst <<EOF
 265 $RELEASE_DATE  GNU  <bug-gnu-gettext@gnu.org>
 266
 267         * Version $VERSION released.
 268
 269 EOF
 270
 271 AC_CONFIG_FILES([Makefile])
 272
 273 AC_CONFIG_FILES([doc/Makefile],
 274                 [FIX_MAKEFILE_COMPILE
 275                  FIX_MAKEFILE_DISTRIB
 276                  FIX_MAKEFILE_INFO])
 277
 278 AC_CONFIG_FILES([intl/Makefile:../gettext-runtime/intl/Makefile.in], [
 279   # Change srcdir variable so that it points to ../gettext-runtime/intl.
 280   sed -e 's|^srcdir =.*$|srcdir = $(top_srcdir)/../gettext-runtime/intl|' \
 281     < intl/Makefile > intl/Makefile.tmp
 282   mv intl/Makefile.tmp intl/Makefile
 283   ])
 284
 285 AC_CONFIG_FILES([lib/Makefile],
 286                 [FIX_MAKEFILE_COMPILE])
 287 AC_CONFIG_FILES([lib/javacomp.sh lib/javaexec.sh])
 288 AC_CONFIG_FILES([lib/csharpcomp.sh lib/csharpexec.sh])
 289
 290 AC_CONFIG_FILES([libgrep/Makefile],
 291                 [FIX_MAKEFILE_COMPILE])
 292
 293 AC_CONFIG_FILES([libuniname/Makefile],
 294                 [FIX_MAKEFILE_COMPILE])
 295
 296 AC_CONFIG_FILES([src/Makefile],
 297                 [FIX_MAKEFILE_COMPILE])
 298 AC_CONFIG_FILES([src/user-email:src/user-email.sh.in])
 299
 300 AC_CONFIG_FILES([po/Makefile.in])
 301
 302 AC_CONFIG_FILES([projects/Makefile])
 303
 304 AC_CONFIG_FILES([misc/Makefile])
 305 AC_CONFIG_FILES([misc/gettextize], [chmod a+x misc/gettextize])
 306 AC_CONFIG_FILES([misc/autopoint], [chmod a+x misc/autopoint])
 307
 308 AC_CONFIG_FILES([man/Makefile],
 309                 [FIX_MAKEFILE_DISTRIB])
 310 AC_CONFIG_FILES([man/x-to-1])
 311
 312 AC_CONFIG_FILES([m4/Makefile])
 313
 314 AC_CONFIG_FILES([tests/Makefile],
 315                 [FIX_MAKEFILE_COMPILE])
 316
 317 AC_CONFIG_FILES([examples/Makefile],
 318                 [FIX_MAKEFILE_DISTRIB])
 319 AC_CONFIG_FILES([examples/installpaths])
 320 AC_CONFIG_FILES([examples/po/Makefile], [AM_POSTPROCESS_PO_MAKEFILE])
 321
 322 AC_OUTPUT