gnu/dist/gettext/gettext-tools/examples/hello-csharp/configure.ac

   1 dnl Example for use of GNU gettext.
   2 dnl Copyright (C) 2003 Free Software Foundation, Inc.
   3 dnl This file is in the public domain.
   4 dnl
   5 dnl Configuration file - processed by autoconf.
   6
   7 AC_INIT
   8 AC_CONFIG_SRCDIR(hello.cs)
   9 AM_INIT_AUTOMAKE(hello-csharp, 0)
  10
  11 dnl Check whether we can build C# programs at all.
  12 gt_CSHARPCOMP
  13 if test -n "$HAVE_CSHARPCOMP"; then
  14   BUILDCSHARP=yes
  15 else
  16   BUILDCSHARP=no
  17 fi
  18 AC_SUBST(BUILDCSHARP)
  19
  20 dnl Check whether we can execute C# programs.
  21 gt_CSHARPEXEC
  22 if test -n "$HAVE_CSHARPEXEC" && test $BUILDCSHARP = yes; then
  23   TESTCSHARP=yes
  24 else
  25   TESTCSHARP=no
  26 fi
  27 AC_SUBST(TESTCSHARP)
  28
  29 dnl Checks for needed libraries.
  30 AM_PATH_PROG_WITH_TEST([GETTEXT_WITH_GNU_GETTEXT_DLL], [gettext],
  31   [{ basedir=`echo "$ac_dir" | sed -e 's,/bin$,,'`; test -r "$basedir"/lib/GNU.Gettext.dll; }])
  32 if test -z "$GETTEXT_WITH_GNU_GETTEXT_DLL"; then
  33   echo "Required library GNU.Gettext.dll not found." 1>&2
  34   exit 1
  35 fi
  36 changequote(,)dnl
  37 basedir=`echo "$GETTEXT_WITH_GNU_GETTEXT_DLL" | sed -e 's,/[^/]*$,,' | sed -e 's,/bin$,,'`
  38 changequote([, ])dnl
  39 GNU_GETTEXT_DLL="$basedir"/lib/GNU.Gettext.dll
  40 GNU_GETTEXT_LDADD="-L $basedir/lib"
  41 GNU_GETTEXT_LIBS="-l GNU.Gettext"
  42 AC_SUBST([GNU_GETTEXT_LDADD])
  43 AC_SUBST([GNU_GETTEXT_LIBS])
  44
  45 dnl Support for the po directory.
  46 AM_PO_SUBDIRS
  47
  48 AC_CONFIG_FILES([Makefile])
  49 AC_CONFIG_FILES([csharpcomp.sh])
  50 AC_CONFIG_FILES([csharpexec.sh])
  51 AC_CONFIG_FILES([m4/Makefile])
  52 AC_CONFIG_FILES([po/Makefile], [AM_POSTPROCESS_PO_MAKEFILE])
  53 AC_OUTPUT