gnu/dist/gettext/gettext-tools/examples/hello-java-awt/configure.ac

   1 dnl Example for use of GNU gettext.
   2 dnl Copyright (C) 2003 Free Software Foundation, Inc.
   3 dnl This file is in the public domain.
   4 dnl
   5 dnl Configuration file - processed by autoconf.
   6
   7 AC_INIT
   8 AC_CONFIG_SRCDIR(Hello.java)
   9 AM_INIT_AUTOMAKE(hello-java-awt, 0)
  10
  11 dnl Check whether we can build native executable.
  12 AC_ARG_ENABLE(java-exe,
  13   [  --enable-java-exe       compile Java to native code, not to bytecode],
  14   :, enable_java_exe=no)
  15 gt_GCJ
  16 if test "$enable_java_exe" != no && test -n "$HAVE_GCJ"; then
  17   BUILDJAVAEXE=yes
  18 else
  19   BUILDJAVAEXE=no
  20 fi
  21 AC_SUBST(BUILDJAVAEXE)
  22 AM_CONDITIONAL([USEJEXE], [test $BUILDJAVAEXE = yes])
  23 AC_PROG_RANLIB
  24
  25 dnl Check whether we can build Java programs at all.
  26 gt_JAVACOMP
  27 AC_CHECK_PROG(JAR, jar, jar)
  28 if test -n "$HAVE_JAVACOMP" && test -n "$JAR"; then
  29   BUILDJAVA=yes
  30 else
  31   BUILDJAVA=no
  32 fi
  33 AC_SUBST(BUILDJAVA)
  34
  35 dnl Check whether we can execute Java programs.
  36 gt_JAVAEXEC([TestAWT], [$srcdir/m4])
  37 if test -n "$HAVE_JAVAEXEC" && test $BUILDJAVA = yes; then
  38   TESTJAVA=yes
  39 else
  40   TESTJAVA=no
  41 fi
  42 AC_SUBST(TESTJAVA)
  43
  44 dnl Checks for compiler output filename suffixes.
  45 AC_OBJEXT
  46 AC_EXEEXT
  47
  48 dnl Checks for needed libraries.
  49 AM_PATH_PROG_WITH_TEST([GETTEXT_WITH_LIBINTL_JAR], [gettext],
  50   [{ basedir=`echo "$ac_dir" | sed -e 's,/bin$,,'`; test -r "$basedir"/share/gettext/libintl.jar; }])
  51 if test -z "$GETTEXT_WITH_LIBINTL_JAR"; then
  52   echo "Required library libintl.jar not found." 1>&2
  53   exit 1
  54 fi
  55 changequote(,)dnl
  56 basedir=`echo "$GETTEXT_WITH_LIBINTL_JAR" | sed -e 's,/[^/]*$,,' | sed -e 's,/bin$,,'`
  57 changequote([, ])dnl
  58 LIBINTL_JAR="$basedir"/share/gettext/libintl.jar
  59 AC_SUBST([LIBINTL_JAR])
  60
  61 dnl Support for the po directory.
  62 AM_PO_SUBDIRS
  63
  64 AC_CONFIG_FILES([Makefile])
  65 AC_CONFIG_FILES([javacomp.sh])
  66 AC_CONFIG_FILES([javaexec.sh])
  67 AC_CONFIG_FILES([m4/Makefile])
  68 AC_CONFIG_FILES([po/Makefile], [AM_POSTPROCESS_PO_MAKEFILE])
  69 AC_OUTPUT