gnu/dist/gettext/gettext-tools/examples/hello-python/configure.ac

   1 dnl Example for use of GNU gettext.
   2 dnl Copyright (C) 2003 Free Software Foundation, Inc.
   3 dnl This file is in the public domain.
   4 dnl
   5 dnl Configuration file - processed by autoconf.
   6
   7 AC_INIT
   8 AC_CONFIG_SRCDIR(hello.py.in)
   9 AM_INIT_AUTOMAKE(hello-python, 0)
  10
  11 dnl Check for availability of the Python interpreter.
  12 AM_PATH_PYTHON
  13 if test -z "$PYTHON"; then
  14   echo "*** Essential program python not found" 1>&2
  15   exit 1
  16 fi
  17
  18 dnl The installed program must know where to find its message catalogs.
  19 dnl Unfortunately, prefix gets only finally determined at the end of configure.
  20 if test "X$prefix" = "XNONE"; then
  21   final_prefix="$ac_default_prefix"
  22 else
  23   final_prefix="$prefix"
  24 fi
  25 save_prefix="$prefix"
  26 prefix="$final_prefix"
  27 eval "localedir=\"${datadir}/locale\""
  28 prefix="$save_prefix"
  29 AC_SUBST(localedir)
  30
  31 dnl Support for the po directory.
  32 AM_PO_SUBDIRS
  33
  34 AC_CONFIG_FILES([Makefile hello.py])
  35 AC_CONFIG_FILES([m4/Makefile])
  36 AC_CONFIG_FILES([po/Makefile], [AM_POSTPROCESS_PO_MAKEFILE])
  37 AC_OUTPUT