sys/arch/evbppc/walnut/walnut_start.S

   1 /*      $NetBSD: walnut_start.S,v 1.16 2009/02/13 22:41:01 apb Exp $    */
   2 /*      $OpenBSD: locore.S,v 1.4 1997/01/26 09:06:38 rahnds Exp $       */
   3
   4 /*
   5  * Copyright 2001 Wasabi Systems, Inc.
   6  * All rights reserved.
   7  *
   8  * Written by Eduardo Horvath and Simon Burge for Wasabi Systems, Inc.
   9  *
  10  * Redistribution and use in source and binary forms, with or without
  11  * modification, are permitted provided that the following conditions
  12  * are met:
  13  * 1. Redistributions of source code must retain the above copyright
  14  *    notice, this list of conditions and the following disclaimer.
  15  * 2. Redistributions in binary form must reproduce the above copyright
  16  *    notice, this list of conditions and the following disclaimer in the
  17  *    documentation and/or other materials provided with the distribution.
  18  * 3. All advertising materials mentioning features or use of this software
  19  *    must display the following acknowledgement:
  20  *      This product includes software developed for the NetBSD Project by
  21  *      Wasabi Systems, Inc.
  22  * 4. The name of Wasabi Systems, Inc. may not be used to endorse
  23  *    or promote products derived from this software without specific prior
  24  *    written permission.
  25  *
  26  * THIS SOFTWARE IS PROVIDED BY WASABI SYSTEMS, INC. ``AS IS'' AND
  27  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  28  * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
  29  * PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL WASABI SYSTEMS, INC
  30  * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  31  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  32  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  33  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  34  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  35  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  36  * POSSIBILITY OF SUCH DAMAGE.
  37  */
  38
  39 /*
  40  * Copyright (C) 1995, 1996 Wolfgang Solfrank.
  41  * Copyright (C) 1995, 1996 TooLs GmbH.
  42  * All rights reserved.
  43  *
  44  * Redistribution and use in source and binary forms, with or without
  45  * modification, are permitted provided that the following conditions
  46  * are met:
  47  * 1. Redistributions of source code must retain the above copyright
  48  *    notice, this list of conditions and the following disclaimer.
  49  * 2. Redistributions in binary form must reproduce the above copyright
  50  *    notice, this list of conditions and the following disclaimer in the
  51  *    documentation and/or other materials provided with the distribution.
  52  * 3. All advertising materials mentioning features or use of this software
  53  *    must display the following acknowledgement:
  54  *      This product includes software developed by TooLs GmbH.
  55  * 4. The name of TooLs GmbH may not be used to endorse or promote products
  56  *    derived from this software without specific prior written permission.
  57  *
  58  * THIS SOFTWARE IS PROVIDED BY TOOLS GMBH ``AS IS'' AND ANY EXPRESS OR
  59  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  60  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  61  * IN NO EVENT SHALL TOOLS GMBH BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  62  * SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  63  * PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS;
  64  * OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY,
  65  * WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR
  66  * OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF
  67  * ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  68  */
  69
  70 #undef PPC_4XX_NOCACHE
  71 #define _NOREGNAMES
  72
  73 #include "opt_ddb.h"
  74 #include "opt_ipkdb.h"
  75 #include "opt_lockdebug.h"
  76 #include "opt_modular.h"
  77 #include "opt_multiprocessor.h"
  78 #include "opt_ppcarch.h"
  79 #include "opt_ppcparam.h"
  80 #include "assym.h"
  81 #include "ksyms.h"
  82
  83 #include <sys/syscall.h>
  84
  85 #include <machine/param.h>
  86 #include <machine/psl.h>
  87 #include <machine/trap.h>
  88 #include <machine/asm.h>
  89
  90 #include <powerpc/spr.h>
  91 #include <powerpc/ibm4xx/dcr405gp.h>
  92 #include <powerpc/ibm4xx/pmap.h>
  93
  94 /* Function pointer for requesting board_config_data from openbios*/
  95 #define BOARD_CFG_FP       0xFFFE0B50
  96
  97 /*
  98  * Some instructions gas doesn't understand (yet?)
  99  */
 100 #define bdneq   bdnzf 2,
 101
 102 /*
 103  * This symbol is here for the benefit of kvm_mkdb, and is supposed to
 104  * mark the start of kernel text.
 105  */
 106         .text
 107         .globl  _C_LABEL(kernel_text)
 108 _C_LABEL(kernel_text):
 109
 110 /*
 111  * Startup entry.  Note, this must be the first thing in the text
 112  * segment!
 113  */
 114         .text
 115         .globl  __start
 116 __start:
 117         b       1f
 118         /* Reserve some space for info_block required for IBM eval board bootloader */
 119         nop
 120         nop
 121         nop
 122         nop
 123         nop
 124         nop
 125         nop
 126         nop
 127         nop
 128         nop
 129
 130 1:
 131         /* Get the board_config_data from openbios */
 132         lis     %r3,BOARD_CFG_FP@h
 133         ori     %r3,%r3,BOARD_CFG_FP@l
 134         lwz     %r0,0x0(%r3)
 135         mtctr   %r0
 136         bctrl                           /* call the xcoff function */
 137         mr      %r31,%r3                /* Save value in r31 */
 138
 139         li      %r0,0
 140         mtmsr   %r0                     /* Disable FPU/MMU/exceptions */
 141         isync
 142
 143         /* PPC405GP errata, item #58.
 144          * Load string instructions may write incorrect data into the last GPR
 145          * targeted in the operation.
 146          * Workaround: set OCM0_DSCNTL[DSEN]=0 and OCM0_DSCNTL[DOF]=0 */
 147         mtdcr   DCR_OCM0_DSCNTL, %r0    /* Disable Data access to OCM */
 148         mtdcr   DCR_OCM0_ISCNTL, %r0    /* Disable Instruction access to OCM. Just in case */
 149 /*
 150  * CPU detect.
 151  *
 152  */
 153 __start_cpu0:
 154 #ifdef PPC_4XX_NOCACHE
 155         /* Disable all caches for physical addresses */
 156         li      %r0,0
 157 #else
 158         /* Allow cacheing for only the first 2GB of RAM */
 159         lis     %r0,0xffff
 160 #endif
 161         mtdccr  %r0
 162         mticcr  %r0
 163
 164         /* Invalidate all TLB entries */
 165         tlbia
 166         sync
 167         isync
 168 /* get start of bss */
 169         lis     %r3,_C_LABEL(_edata)-4@ha
 170         addi    %r3,%r3,_C_LABEL(_edata)-4@l
 171 /* get end of kernel memory */
 172         lis     %r8,_C_LABEL(end)@ha
 173         addi    %r8,%r8,_C_LABEL(end)@l
 174 /* zero bss */
 175         li      %r4,0
 176 2:      stwu    %r4,%r4(3)
 177         cmpw    %r3,%r8
 178         bne+    2b
 179
 180 #if NKSYMS || defined(DDB) || defined(MODULAR)
 181         /* If we had symbol table location we'd store it here and would've adjusted r8 here */
 182         lis     %r7,_C_LABEL(startsym)@ha
 183         addi    %r7,%r7,_C_LABEL(startsym)@l
 184         stw     %r8,0(%r7)
 185         lis     %r7,_C_LABEL(endsym)@ha
 186         addi    %r7,%r7,_C_LABEL(endsym)@l
 187         stw     %r8,0(%r7)
 188 #endif
 189
 190         /* Set kernel MMU context. */
 191         li      %r0,KERNEL_PID
 192         mtpid   %r0
 193         sync
 194
 195         INIT_CPUINFO(8,1,9,0)
 196         mr      %r4,%r8
 197
 198         lis     %r3,__start@ha
 199         addi    %r3,%r3,__start@l
 200
 201         mr      %r6,%r31                /* info_block address */
 202         bl      _C_LABEL(initppc)
 203         bl      _C_LABEL(main)
 204
 205 loop:   b       loop                    /* XXX not reached */
 206
 207 #include <powerpc/ibm4xx/4xx_locore.S>