usr.bin/menuc/scan.l

   1 /*      $NetBSD: scan.l,v 1.14 2004/08/02 21:29:07 dsl Exp $    */
   2
   3 /*
   4  * Copyright 1997 Piermont Information Systems Inc.
   5  * All rights reserved.
   6  *
   7  * Written by Philip A. Nelson for Piermont Information Systems Inc.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software develooped for the NetBSD Project by
  20  *      Piermont Information Systems Inc.
  21  * 4. The name of Piermont Information Systems Inc. may not be used to endorse
  22  *    or promote products derived from this software without specific prior
  23  *    written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY PIERMONT INFORMATION SYSTEMS INC. ``AS IS''
  26  * AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  27  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  28  * ARE DISCLAIMED. IN NO EVENT SHALL PIERMONT INFORMATION SYSTEMS INC. BE
  29  * LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  30  * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  31  * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  32  * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  33  * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  34  * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF
  35  * THE POSSIBILITY OF SUCH DAMAGE.
  36  *
  37  */
  38
  39 %{
  40 /* scan.l: scanner description for menu compiler. */
  41
  42 #include <stdio.h>
  43 #include <string.h>
  44 #include "defs.h"
  45 #include "parse.h"
  46
  47 static int level;       /* For nested comments. */
  48 static int comstart;    /* line number of comment start. */
  49
  50 %}
  51
  52 %x COMMENT
  53 %x BRACE
  54
  55 %option noinput
  56
  57 %%
  58
  59 [ \t]+  { /* ignore spaces and tabs */ }
  60
  61 [\n]    { line_no++; }
  62
  63 "="|";"|","|"("|")"     { return (int)yytext[0]; }
  64
  65 x       { return X; }
  66
  67 y       { return Y; }
  68
  69 w       { return W; }
  70
  71 h       { return H; }
  72
  73 no      { return NO; }
  74
  75 box     { return BOX; }
  76
  77 sub     { return SUB; }
  78
  79 help    { return HELP; }
  80
  81 menu    { return MENU; }
  82
  83 menus   { return MENUS; }
  84
  85 next    { return NEXT; }
  86
  87 exit    { return  EXIT; }
  88
  89 exitstring { return  EXITSTRING; }
  90
  91 title   { return TITLE; }
  92
  93 action  { return ACTION; }
  94
  95 endwin  { return ENDWIN; }
  96
  97 option  { return OPTION; }
  98
  99 default { return DEFAULT; }
 100
 101 display { return DISPLAY; }
 102
 103 error { return ERROR; }
 104
 105 allow { return ALLOW; }
 106
 107 dynamic { return DYNAMIC; }
 108
 109 messages { return MESSAGES; }
 110
 111 scrollable { return SCROLLABLE; }
 112
 113 shortcut { return SHORTCUT; }
 114
 115 clear { return CLEAR; }
 116
 117 always { return ALWAYS; }
 118
 119 scroll { return SCROLL; }
 120
 121 \"([^\"\n]*(\\\")?)*\"  {
 122           yylval.s_value = strdup (yytext);
 123           max_strlen = max_strlen > strlen(yytext)
 124                        ? max_strlen : strlen(yytext) + 1;
 125           return STRING;
 126         }
 127
 128 [a-zA-Z][a-zA-Z0-9_]* {
 129           yylval.s_value = strdup(yytext);
 130           return(NAME);
 131         }
 132
 133 0|[-1-9][0-9]* {
 134           yylval.s_value = strdup(yytext);
 135           return(INT_CONST);
 136         }
 137
 138 "'"[^'\\]|(\\[athrn])|(\\[0-9][0-9]?[0-9]?)"'" {
 139           yylval.s_value = strdup(yytext);
 140           return(CHAR_CONST);
 141         }
 142
 143 "/*"  { level = 1; comstart = line_no; BEGIN COMMENT; }
 144
 145 <COMMENT>"/*" { level++; }
 146
 147 <COMMENT>"*/" { if (level-- == 1) BEGIN 0; }
 148
 149 <COMMENT>"\n" { line_no++; }
 150
 151 <COMMENT><<EOF>> {
 152                 yyerror ("EOF inside a comment that started at line %d",
 153                          comstart);
 154                 exit (1);
 155         }
 156
 157 <COMMENT>.  {/* eat character */}
 158
 159 "{"     { level = 1; BEGIN BRACE; }
 160
 161 <BRACE>"{"      { buff_add_ch(yytext[0]); level++; }
 162
 163 <BRACE>"}"      { if (level-- == 1)  {
 164                         BEGIN 0;
 165                         yylval.s_value = buff_copy();
 166                         return CODE;
 167                   } else
 168                         buff_add_ch (yytext[0]);
 169                 }
 170
 171 <BRACE>"\n"     { buff_add_ch (yytext[0]); line_no++; }
 172
 173 <BRACE>.        { buff_add_ch (yytext[0]); }
 174
 175 .       {
 176           if (yytext[0] < ' ')
 177             yyerror ("illegal character: ^%c",yytext[0] + '@');
 178           else
 179             if (yytext[0] > '~')
 180               yyerror ("illegal character: \\%3d", (int) yytext[0]);
 181             else
 182               yyerror ("illegal character: %s",yytext);
 183
 184           /* To quiet the compiler */
 185           if (0) unput(0);
 186         }
 187 %%
 188
 189 #ifdef SCAN
 190 YYSTYPE yylval;
 191
 192 main()
 193 {
 194   int val;
 195
 196   line_no = 1;
 197   while ( (val = yylex()) != 0 )
 198     printf ("val = %d\n yytext = %s\n", val, yytext);
 199 }
 200 #endif