libgloss/m68k/sim.ld

   1 STARTUP(sim-crt0.o)
   2 OUTPUT_ARCH(m68k)
   3
   4 SEARCH_DIR(.)
   5 GROUP(-lsim -lc -lgcc -lsim)
   6 __DYNAMIC  =  0;
   7
   8
   9 MEMORY
  10 {
  11   ram (rwx) : ORIGIN = 0x80000000, LENGTH = 1M
  12 }
  13
  14 PROVIDE (__stack = 0);
  15
  16 SECTIONS
  17 {
  18   .text :
  19   {
  20     CREATE_OBJECT_SYMBOLS
  21     *(.text .text.*)
  22
  23     . = ALIGN(0x4);
  24     /* These are for running static constructors and destructors under ELF.  */
  25     KEEP (*crtbegin.o(.ctors))
  26     KEEP (*(EXCLUDE_FILE (*crtend.o) .ctors))
  27     KEEP (*(SORT(.ctors.*)))
  28     KEEP (*(.ctors))
  29     KEEP (*crtbegin.o(.dtors))
  30     KEEP (*(EXCLUDE_FILE (*crtend.o) .dtors))
  31     KEEP (*(SORT(.dtors.*)))
  32     KEEP (*(.dtors))
  33
  34     *(.rodata .rodata.*)
  35
  36     . = ALIGN(0x4);
  37     *(.gcc_except_table)
  38
  39     . = ALIGN(0x4);
  40     *(.eh_frame)
  41
  42     . = ALIGN(0x4);
  43     __INIT_SECTION__ = . ;
  44     LONG (0x4e560000)   /* linkw %fp,#0 */
  45     *(.init)
  46     SHORT (0x4e5e)      /* unlk %fp */
  47     SHORT (0x4e75)      /* rts */
  48
  49     . = ALIGN(0x4);
  50     __FINI_SECTION__ = . ;
  51     LONG (0x4e560000)   /* linkw %fp,#0 */
  52     *(.fini)
  53     SHORT (0x4e5e)      /* unlk %fp */
  54     SHORT (0x4e75)      /* rts */
  55
  56     _etext = .;
  57     *(.lit)
  58   } > ram
  59
  60   .data :
  61   {
  62     *(.got.plt) *(.got)
  63     *(.shdata)
  64     *(.data .data.*)
  65     _edata = .;
  66   } > ram
  67
  68   .bss :
  69   {
  70     . = ALIGN(0x4);
  71     __bss_start = . ;
  72     *(.shbss)
  73     *(.bss .bss.*)
  74     *(COMMON)
  75     _end =  ALIGN (0x8);
  76     __end = _end;
  77   } > ram
  78
  79   .stab 0 (NOLOAD) :
  80   {
  81     *(.stab)
  82   }
  83
  84   .stabstr 0 (NOLOAD) :
  85   {
  86     *(.stabstr)
  87   }
  88 }