libgloss/mn10300/sim.ld

   1 /* Linker script for the MN10300 simulator.  */
   2
   3 OUTPUT_FORMAT("elf32-mn10300", "elf32-mn10300", "elf32-mn10300")
   4 OUTPUT_ARCH(mn10300)
   5 ENTRY(_start)
   6 GROUP(-lc -leval -lgcc)
   7 SEARCH_DIR(.);
   8
   9 SECTIONS
  10 {
  11   /* Read-only sections, merged into text segment: */
  12   /* Start of RAM (leaving room for Cygmon data) */
  13   . = 4;
  14
  15   .interp        : { *(.interp)         }
  16   .hash          : { *(.hash)           }
  17   .dynsym        : { *(.dynsym)         }
  18   .dynstr        : { *(.dynstr)         }
  19   .gnu.version   : { *(.gnu.version)    }
  20   .gnu.version_d : { *(.gnu.version_d)  }
  21   .gnu.version_r : { *(.gnu.version_r)  }
  22   .rel.text      : { *(.rel.text    .rel.text.*    .rel.gnu.linkonce.t*)  }
  23   .rela.text     : { *(.rela.text   .rela.text.*   .rela.gnu.linkonce.t*) }
  24   .rel.data      : { *(.rel.data    .rel.data.*    .rel.gnu.linkonce.d*)  }
  25   .rela.data     : { *(.rela.data   .rela.data.*   .rela.gnu.linkonce.d*) }
  26   .rel.rodata    : { *(.rel.rodata  .rel.rodata.*  .rel.gnu.linkonce.r*)  }
  27   .rela.rodata   : { *(.rela.rodata .rela.rodata.* .rela.gnu.linkonce.r*) }
  28   .rel.got       : { *(.rel.got)        }
  29   .rela.got      : { *(.rela.got)       }
  30   .rel.ctors     : { *(.rel.ctors)      }
  31   .rela.ctors    : { *(.rela.ctors)     }
  32   .rel.dtors     : { *(.rel.dtors)      }
  33   .rela.dtors    : { *(.rela.dtors)     }
  34   .rel.init      : { *(.rel.init)       }
  35   .rela.init     : { *(.rela.init)      }
  36   .rel.fini      : { *(.rel.fini)       }
  37   .rela.fini     : { *(.rela.fini)      }
  38   .rel.bss       : { *(.rel.bss  .rel.bss.*  .rel.gnu.linkonce.b.*)     }
  39   .rela.bss      : { *(.rela.bss .rela.bss.* .rela.gnu.linkonce.b.*)    }
  40   .rel.plt       : { *(.rel.plt)        }
  41   .rela.plt      : { *(.rela.plt)       }
  42   .init          : { KEEP (*(.init))    } =0
  43   .plt           : { *(.plt)            }
  44   .text      :
  45   {
  46     *(.text .stub .text.*)
  47     KEEP (*(.text.*personality*))
  48     /* .gnu.warning sections are handled specially by elf32.em.  */
  49     *(.gnu.warning)
  50     *(.gnu.linkonce.t*)
  51     *(.gcc_except_table)
  52   } =0
  53   _etext = .;
  54   PROVIDE (etext = .);
  55   .fini      : { KEEP (*(.fini))    } =0
  56   .rodata    : { *(.rodata .rodata.* .gnu.linkonce.r*) }
  57   .rodata1   : { *(.rodata1) }
  58   /* Adjust the address for the data segment.  We want to adjust up to
  59      the same address within the page on the next page up.  */
  60   . = ALIGN(1) + (. & (1 - 1));
  61   .data    :
  62   {
  63     *(.data .data.* .gnu.linkonce.d.*)
  64     KEEP (*(.gnu.linkonce.d.*personality*))
  65     CONSTRUCTORS
  66   }
  67   .data1   : { *(.data1) }
  68   .ctors         :
  69   {
  70     ___ctors = .;
  71     KEEP(*crtbegin.o(.ctors))
  72     KEEP(*(SORT(.ctors.*)))
  73     KEEP(*(.ctors))
  74     ___ctors_end = .;
  75   }
  76   .dtors         :
  77   {
  78     ___dtors = .;
  79     KEEP(*crtbegin.o(.dtors))
  80     KEEP(*(SORT(.dtors.*)))
  81     KEEP(*(.dtors))
  82     ___dtors_end = .;
  83   }
  84   .got           : { *(.got.plt) *(.got) }
  85   .dynamic       : { *(.dynamic) }
  86   /* We want the small data sections together, so single-instruction offsets
  87      can access them all, and initialized data all before uninitialized, so
  88      we can shorten the on-disk segment size.  */
  89   .sdata     : { *(.sdata .sdata.* .gnu.linkonce.s.*) }
  90   _edata  =  .;
  91   PROVIDE (edata = .);
  92   __bss_start = .;
  93   .sbss      : { *(.dynsbss) *(.sbss .sbss.* .gnu.linkonce.sb.*) *(.scommon) }
  94   .bss       :
  95   {
  96    *(.dynbss)
  97    *(.bss .bss.* .gnu.linkonce.b.*)
  98    *(COMMON)
  99   }
 100   _end = . ;
 101   PROVIDE (end = .);
 102   /* Stabs debugging sections.  */
 103   .stab 0 : { *(.stab) }
 104   .stabstr 0 : { *(.stabstr) }
 105   .stab.excl 0 : { *(.stab.excl) }
 106   .stab.exclstr 0 : { *(.stab.exclstr) }
 107   .stab.index 0 : { *(.stab.index) }
 108   .stab.indexstr 0 : { *(.stab.indexstr) }
 109   .comment 0 : { *(.comment) }
 110   /* DWARF debug sections.
 111      Symbols in the DWARF debugging sections are relative to the beginning
 112      of the section so we begin them at 0.  */
 113   /* DWARF 1 */
 114   .debug          0 : { *(.debug) }
 115   .line           0 : { *(.line) }
 116   /* GNU DWARF 1 extensions */
 117   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 118   .debug_sfnames  0 : { *(.debug_sfnames) }
 119   /* DWARF 1.1 and DWARF 2 */
 120   .debug_aranges  0 : { *(.debug_aranges) }
 121   .debug_pubnames 0 : { *(.debug_pubnames) }
 122   /* DWARF 2 */
 123   .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
 124   .debug_abbrev   0 : { *(.debug_abbrev) }
 125   .debug_line     0 : { *(.debug_line) }
 126   .debug_frame    0 : { *(.debug_frame) }
 127   .debug_str      0 : { *(.debug_str) }
 128   .debug_loc      0 : { *(.debug_loc) }
 129   .debug_macinfo  0 : { *(.debug_macinfo) }
 130   .debug_ranges   0 : { *(.debug_ranges) }
 131   /* SGI/MIPS DWARF 2 extensions */
 132   .debug_weaknames 0 : { *(.debug_weaknames) }
 133   .debug_funcnames 0 : { *(.debug_funcnames) }
 134   .debug_typenames 0 : { *(.debug_typenames) }
 135   .debug_varnames  0 : { *(.debug_varnames) }
 136
 137   .stack 0x80000 : { _stack = .; *(.stack) *(._stack) }
 138 }