newlib/libc/machine/arc/memcpy-bs.S

   1 /*
   2    Copyright (c) 2015-2024, Synopsys, Inc. All rights reserved.
   3
   4    Redistribution and use in source and binary forms, with or without
   5    modification, are permitted provided that the following conditions are met:
   6
   7    1) Redistributions of source code must retain the above copyright notice,
   8    this list of conditions and the following disclaimer.
   9
  10    2) Redistributions in binary form must reproduce the above copyright notice,
  11    this list of conditions and the following disclaimer in the documentation
  12    and/or other materials provided with the distribution.
  13
  14    3) Neither the name of the Synopsys, Inc., nor the names of its contributors
  15    may be used to endorse or promote products derived from this software
  16    without specific prior written permission.
  17
  18    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  19    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
  22    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  23    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  24    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  26    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  27    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  28    POSSIBILITY OF SUCH DAMAGE.
  29 */
  30
  31 /* This implementation is optimized for performance.  For code size a generic
  32    implementation of this function from newlib/libc/string/memcpy.c will be
  33    used.  */
  34 #if !defined (__OPTIMIZE_SIZE__) && !defined (PREFER_SIZE_OVER_SPEED) \
  35     && !defined (__ARC_RF16__)
  36
  37 #include "asm.h"
  38
  39 #if !defined (__ARC601__) && !defined (__ARCHS__) \
  40     && defined (__ARC_BARREL_SHIFTER__)
  41
  42 /* Mostly optimized for ARC700, but not bad for ARC600 either.  */
  43 /* This memcpy implementation does not support objects of 1GB or larger -
  44    the check for alignment does not work then.  */
  45 /* We assume that most sources and destinations are aligned, and
  46    that also lengths are mostly a multiple of four, although to a lesser
  47    extent.  */
  48 ENTRY (memcpy)
  49         or      r3,r0,r1
  50         asl_s   r3,r3,30
  51         mov_s   r5,r0
  52         brls.d  r2,r3,.Lcopy_bytewise
  53         sub.f   r3,r2,1
  54         ld_s    r12,[r1,0]
  55         asr.f   lp_count,r3,3
  56         bbit0.d r3,2,.Lnox4
  57         bmsk_s  r2,r2,1
  58         st.ab   r12,[r5,4]
  59         ld.a    r12,[r1,4]
  60 .Lnox4:
  61         lppnz   .Lendloop
  62         ld_s    r3,[r1,4]
  63         st.ab   r12,[r5,4]
  64         ld.a    r12,[r1,8]
  65         st.ab   r3,[r5,4]
  66 .Lendloop:
  67         breq_l  r2,0,.Last_store
  68         ld      r3,[r5,0]
  69 #ifdef __LITTLE_ENDIAN__
  70         add3    r2,-1,r2
  71         ; uses long immediate
  72         xor_s   r12,r12,r3
  73         bmsk    r12,r12,r2
  74         xor_s   r12,r12,r3
  75 #else /* BIG ENDIAN */
  76         sub3    r2,31,r2
  77         ; uses long immediate
  78         xor_s   r3,r3,r12
  79         bmsk    r3,r3,r2
  80         xor_s   r12,r12,r3
  81 #endif /* ENDIAN */
  82 .Last_store:
  83         j_s.d   [blink]
  84         st      r12,[r5,0]
  85
  86         .balign 4
  87 .Lcopy_bytewise:
  88         jcs     [blink]
  89         ldb_s   r12,[r1,0]
  90         lsr.f   lp_count,r3
  91         bcc_s   .Lnox1
  92         stb.ab  r12,[r5,1]
  93         ldb.a   r12,[r1,1]
  94 .Lnox1:
  95         lppnz   .Lendbloop
  96         ldb_s   r3,[r1,1]
  97         stb.ab  r12,[r5,1]
  98         ldb.a   r12,[r1,2]
  99         stb.ab  r3,[r5,1]
 100 .Lendbloop:
 101         j_s.d   [blink]
 102         stb     r12,[r5,0]
 103 ENDFUNC (memcpy)
 104 #endif /* !__ARC601__ && !__ARCHS__ && __ARC_BARREL_SHIFTER__ */
 105
 106 #endif /* !__OPTIMIZE_SIZE__ && !PREFER_SIZE_OVER_SPEED */