newlib/libc/machine/arc/strcmp.S

   1 /*
   2    Copyright (c) 2015-2024, Synopsys, Inc. All rights reserved.
   3
   4    Redistribution and use in source and binary forms, with or without
   5    modification, are permitted provided that the following conditions are met:
   6
   7    1) Redistributions of source code must retain the above copyright notice,
   8    this list of conditions and the following disclaimer.
   9
  10    2) Redistributions in binary form must reproduce the above copyright notice,
  11    this list of conditions and the following disclaimer in the documentation
  12    and/or other materials provided with the distribution.
  13
  14    3) Neither the name of the Synopsys, Inc., nor the names of its contributors
  15    may be used to endorse or promote products derived from this software
  16    without specific prior written permission.
  17
  18    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  19    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
  22    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  23    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  24    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  26    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  27    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  28    POSSIBILITY OF SUCH DAMAGE.
  29 */
  30
  31 /* This implementation is optimized for performance.  For code size a generic
  32    implementation of this function from newlib/libc/string/strcmp.c will be
  33    used.  */
  34 #if !defined (__OPTIMIZE_SIZE__) && !defined (PREFER_SIZE_OVER_SPEED) \
  35     && !defined (__ARC_RF16__)
  36
  37 #include "asm.h"
  38
  39 /* This is optimized primarily for the ARC700.
  40    It would be possible to speed up the loops by one cycle / word
  41    respective one cycle / byte by forcing double source 1 alignment, unrolling
  42    by a factor of two, and speculatively loading the second word / byte of
  43    source 1; however, that would increase the overhead for loop setup / finish,
  44    and strcmp might often terminate early.  */
  45 #ifndef __ARCHS__
  46
  47 ENTRY (strcmp)
  48         or      r2,r0,r1
  49         bmsk_s  r2,r2,1
  50         brne_l  r2,0,.Lcharloop
  51         mov_s   r12,0x01010101
  52         ror     r5,r12
  53 .Lwordloop:
  54         ld.ab   r2,[r0,4]
  55         ld.ab   r3,[r1,4]
  56         nop_s
  57         sub     r4,r2,r12
  58         bic     r4,r4,r2
  59         and     r4,r4,r5
  60         brne_l  r4,0,.Lfound0
  61         breq    r2,r3,.Lwordloop
  62 #ifdef  __LITTLE_ENDIAN__
  63         xor     r0,r2,r3        ; mask for difference
  64         sub_s   r1,r0,1
  65         bic_s   r0,r0,r1        ; mask for least significant difference bit
  66         sub     r1,r5,r0
  67         xor     r0,r5,r1        ; mask for least significant difference byte
  68         and_s   r2,r2,r0
  69         and_s   r3,r3,r0
  70 #endif /* LITTLE ENDIAN */
  71         cmp_s   r2,r3
  72         mov_s   r0,1
  73         j_s.d   [blink]
  74         bset.lo r0,r0,31
  75
  76         .balign 4
  77 #ifdef __LITTLE_ENDIAN__
  78 .Lfound0:
  79         xor     r0,r2,r3        ; mask for difference
  80         or      r0,r0,r4        ; or in zero indicator
  81         sub_s   r1,r0,1
  82         bic_s   r0,r0,r1        ; mask for least significant difference bit
  83         sub     r1,r5,r0
  84         xor     r0,r5,r1        ; mask for least significant difference byte
  85         and_s   r2,r2,r0
  86         and_s   r3,r3,r0
  87         sub.f   r0,r2,r3
  88         mov.hi  r0,1
  89         j_s.d   [blink]
  90         bset.lo r0,r0,31
  91 #else /* BIG ENDIAN */
  92         /* The zero-detection above can mis-detect 0x01 bytes as zeroes
  93            because of carry-propagateion from a lower significant zero byte.
  94            We can compensate for this by checking that bit0 is zero.
  95            This compensation is not necessary in the step where we
  96            get a low estimate for r2, because in any affected bytes
  97            we already have 0x00 or 0x01, which will remain unchanged
  98            when bit 7 is cleared.  */
  99         .balign 4
 100 .Lfound0:
 101 #ifdef __ARC_BARREL_SHIFTER__
 102         lsr     r0,r4,8
 103         lsr_s   r1,r2
 104         bic_s   r2,r2,r0        ; get low estimate for r2 and get ...
 105         bic_s   r0,r0,r1        ; <this is the adjusted mask for zeros>
 106         or_s    r3,r3,r0        ; ... high estimate r3 so that r2 > r3 will ...
 107         cmp_s   r3,r2           ; ... be independent of trailing garbage
 108         or_s    r2,r2,r0        ; likewise for r3 > r2
 109         bic_s   r3,r3,r0
 110         rlc     r0,0            ; r0 := r2 > r3 ? 1 : 0
 111         cmp_s   r2,r3
 112         j_s.d   [blink]
 113         bset.lo r0,r0,31
 114 #else /* __ARC_BARREL_SHIFTER__ */
 115         /* Fall through to .Lcharloop.  */
 116         sub_s   r0,r0,4
 117         sub_s   r1,r1,4
 118 #endif /* __ARC_BARREL_SHIFTER__ */
 119 #endif /* ENDIAN */
 120
 121         .balign 4
 122 .Lcharloop:
 123         ldb.ab  r2,[r0,1]
 124         ldb.ab  r3,[r1,1]
 125         nop_s
 126         breq_l  r2,0,.Lcmpend
 127         breq    r2,r3,.Lcharloop
 128 .Lcmpend:
 129         j_s.d   [blink]
 130         sub     r0,r2,r3
 131 ENDFUNC (strcmp)
 132 #endif /* !__ARCHS__ */
 133
 134 #endif /* !__OPTIMIZE_SIZE__ && !PREFER_SIZE_OVER_SPEED */