newlib/libc/machine/arc/strcpy-bs-arc600.S

   1 /*
   2    Copyright (c) 2015-2024, Synopsys, Inc. All rights reserved.
   3
   4    Redistribution and use in source and binary forms, with or without
   5    modification, are permitted provided that the following conditions are met:
   6
   7    1) Redistributions of source code must retain the above copyright notice,
   8    this list of conditions and the following disclaimer.
   9
  10    2) Redistributions in binary form must reproduce the above copyright notice,
  11    this list of conditions and the following disclaimer in the documentation
  12    and/or other materials provided with the distribution.
  13
  14    3) Neither the name of the Synopsys, Inc., nor the names of its contributors
  15    may be used to endorse or promote products derived from this software
  16    without specific prior written permission.
  17
  18    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  19    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
  22    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  23    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  24    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  26    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  27    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  28    POSSIBILITY OF SUCH DAMAGE.
  29 */
  30
  31 /* This implementation is optimized for performance.  For code size a generic
  32    implementation of this function from newlib/libc/string/strcpy.c will be
  33    used.  */
  34 #if !defined (__OPTIMIZE_SIZE__) && !defined (PREFER_SIZE_OVER_SPEED) \
  35     && !defined (__ARC_RF16__)
  36
  37 #include "asm.h"
  38
  39 #if defined (__ARC600__) && defined (__ARC_BARREL_SHIFTER__)
  40 /* If dst and src are 4 byte aligned, copy 8 bytes at a time.
  41    If the src is 4, but not 8 byte aligned, we first read 4 bytes to get
  42    it 8 byte aligned.  Thus, we can do a little read-ahead, without
  43    dereferencing a cache line that we should not touch.
  44    Note that short and long instructions have been scheduled to avoid
  45    branch stalls.
  46    This version is optimized for the ARC600 pipeline.  */
  47
  48 ENTRY (strcpy)
  49         or      r2,r0,r1
  50         bmsk.f  0,r2,1
  51         mov     r8,0x01010101
  52         bne.d   .Lcharloop
  53         mov_s   r10,r0
  54         ld_l    r3,[r1,0]
  55         bbit0.d r1,2,.Loop_setup
  56         ror     r12,r8
  57         sub     r2,r3,r8
  58         bic_s   r2,r2,r3
  59         and_s   r2,r2,r12
  60         brne_s  r2,0,.Lr3z
  61         st.ab   r3,[r10,4]
  62         ld.a    r3,[r1,4]
  63 .Loop_setup:
  64         ld.a    r4,[r1,4]
  65
  66         sub     r2,r3,r8
  67         and.f   r2,r2,r12
  68         sub     r5,r4,r8
  69         and.eq.f r5,r5,r12
  70         b.d     .Loop_start
  71         mov_s   r6,r3
  72         .balign 4
  73 .Loop:
  74         ld.a    r3,[r1,4]
  75         st      r4,[r10,4]
  76         ld.a    r4,[r1,4]
  77         sub     r2,r3,r8
  78         and.f   r2,r2,r12
  79         sub     r5,r4,r8
  80         and.eq.f r5,r5,r12
  81         st.ab   r6,[r10,8]
  82         mov     r6,r3
  83 .Loop_start:
  84         beq.d   .Loop
  85         bic_s   r2,r2,r3
  86         brne.d  r2,0,.Lr3z
  87         and     r5,r5,r12
  88         bic     r5,r5,r4
  89         breq.d  r5,0,.Loop
  90         mov_s   r3,r4
  91         st.ab   r6,[r10,4]
  92 #ifdef __LITTLE_ENDIAN__
  93 .Lr3z:  bmsk.f  r1,r3,7
  94 .Lr3z_loop:
  95         lsr_s   r3,r3,8
  96         stb.ab  r1,[r10,1]
  97         bne.d   .Lr3z_loop
  98         bmsk.f  r1,r3,7
  99         j_s     [blink]
 100 #else
 101 .Lr3z:  lsr.f   r1,r3,24
 102 .Lr3z_loop:
 103         asl_s   r3,r3,8
 104         stb.ab  r1,[r10,1]
 105         bne.d   .Lr3z_loop
 106         lsr.f   r1,r3,24
 107         j_s     [blink]
 108 #endif
 109
 110         .balign 4
 111 .Lcharloop:
 112         ldb.ab  r3,[r1,1]
 113
 114
 115         brne.d  r3,0,.Lcharloop
 116         stb.ab  r3,[r10,1]
 117         j       [blink]
 118 ENDFUNC (strcpy)
 119 #endif /* __ARC600__ && __ARC_BARREL_SHIFTER__ */
 120
 121 #endif /* !__OPTIMIZE_SIZE__ && !PREFER_SIZE_OVER_SPEED */