newlib/libc/machine/arc/strcpy.S

   1 /*
   2    Copyright (c) 2015-2024, Synopsys, Inc. All rights reserved.
   3
   4    Redistribution and use in source and binary forms, with or without
   5    modification, are permitted provided that the following conditions are met:
   6
   7    1) Redistributions of source code must retain the above copyright notice,
   8    this list of conditions and the following disclaimer.
   9
  10    2) Redistributions in binary form must reproduce the above copyright notice,
  11    this list of conditions and the following disclaimer in the documentation
  12    and/or other materials provided with the distribution.
  13
  14    3) Neither the name of the Synopsys, Inc., nor the names of its contributors
  15    may be used to endorse or promote products derived from this software
  16    without specific prior written permission.
  17
  18    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  19    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
  22    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  23    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  24    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  26    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  27    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  28    POSSIBILITY OF SUCH DAMAGE.
  29 */
  30
  31 /* This implementation is optimized for performance.  For code size a generic
  32    implementation of this function from newlib/libc/string/strcpy.c will be
  33    used.  */
  34 #if !defined (__OPTIMIZE_SIZE__) && !defined (PREFER_SIZE_OVER_SPEED) \
  35     && !defined (__ARC_RF16__)
  36
  37 #include "asm.h"
  38
  39 #if defined (__ARC601__) || !defined (__ARC_BARREL_SHIFTER__)
  40 /* If dst and src are 4 byte aligned, copy 8 bytes at a time.
  41    If the src is 4, but not 8 byte aligned, we first read 4 bytes to get
  42    it 8 byte aligned.  Thus, we can do a little read-ahead, without
  43    dereferencing a cache line that we should not touch.
  44    This version is a compromise between speed for the 601 pipeline and code
  45    size.  */
  46
  47 ENTRY (strcpy)
  48         or      r2,r0,r1
  49         bmsk.f  0,r2,1
  50         mov     r8,0x01010101
  51         bne.d   .Lcharloop
  52         mov_s   r10,r0
  53         ld_s    r3,[r1]
  54         bbit0.d r1,2,.Loop_start
  55         ror     r12,r8
  56         sub     r2,r3,r8
  57         bic_s   r2,r2,r3
  58         and_s   r2,r2,r12
  59         brne_s  r2,0,.Lr3z
  60         mov     r4,r3
  61         sub_s   r1,r1,4
  62         .balign 4
  63 .Loop:
  64         ld.a    r3,[r1,8]
  65         st.ab   r4,[r10,4]
  66 .Loop_start:
  67         ld      r4,[r1,4]
  68         sub     r2,r3,r8
  69         bic_s   r2,r2,r3
  70         tst_s   r2,r12
  71         sub     r5,r4,r8
  72         bic     r5,r5,r4
  73         bne_s   .Lr3z
  74         and     r5,r5,r12
  75         breq.d  r5,0,.Loop
  76         st.ab   r3,[r10,4]
  77
  78         ;mov_s  r3,r4
  79         add_s   r1,r1,4
  80
  81         .balign 4
  82 .Lr3z:
  83 .Lcharloop:
  84         ldb.ab  r3,[r1,1]
  85         brne.d  r3,0,.Lcharloop
  86         stb.ab  r3,[r10,1]
  87         j_s     [blink]
  88 ENDFUNC (strcpy)
  89 #endif /* __ARC601__ || !__ARC_BARREL_SHIFTER__ */
  90
  91 #endif /* !__OPTIMIZE_SIZE__ && !PREFER_SIZE_OVER_SPEED */