newlib/libc/machine/arc/strlen-bs.S

   1 /*
   2    Copyright (c) 2015-2024, Synopsys, Inc. All rights reserved.
   3
   4    Redistribution and use in source and binary forms, with or without
   5    modification, are permitted provided that the following conditions are met:
   6
   7    1) Redistributions of source code must retain the above copyright notice,
   8    this list of conditions and the following disclaimer.
   9
  10    2) Redistributions in binary form must reproduce the above copyright notice,
  11    this list of conditions and the following disclaimer in the documentation
  12    and/or other materials provided with the distribution.
  13
  14    3) Neither the name of the Synopsys, Inc., nor the names of its contributors
  15    may be used to endorse or promote products derived from this software
  16    without specific prior written permission.
  17
  18    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  19    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
  22    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  23    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  24    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  26    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  27    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  28    POSSIBILITY OF SUCH DAMAGE.
  29 */
  30
  31 /* This implementation is optimized for performance.  For code size a generic
  32    implementation of this function from newlib/libc/string/strlen.c will be
  33    used.  */
  34 #if !defined (__OPTIMIZE_SIZE__) && !defined (PREFER_SIZE_OVER_SPEED) \
  35     && !defined (__ARC_RF16__)
  36
  37 #include "asm.h"
  38
  39 #if (defined (__ARC600__) || !defined (__ARC_NORM__)) && !defined (__ARC601__) \
  40     && defined (__ARC_BARREL_SHIFTER__)
  41 /* This code is optimized for the ARC600 pipeline.  */
  42
  43 ENTRY (strlen)
  44         or      r3,r0,7
  45         ld      r2,[r3,-7]
  46         ld.a    r6,[r3,-3]
  47         mov     r4,0x01010101
  48         ; uses long immediate
  49 #ifdef __LITTLE_ENDIAN__
  50         asl_s   r1,r0,3
  51         btst_s  r0,2
  52         asl     r7,r4,r1
  53         ror     r5,r4
  54         sub     r1,r2,r7
  55         bic_l   r1,r1,r2
  56         mov.eq  r7,r4
  57         sub     r12,r6,r7
  58         bic     r12,r12,r6
  59         or.eq   r12,r12,r1
  60         and     r12,r12,r5
  61         brne    r12,0,.Learly_end
  62 #else /* BIG ENDIAN */
  63         ror     r5,r4
  64         btst_s  r0,2
  65         mov_s   r1,31
  66         sub3    r7,r1,r0
  67         sub     r1,r2,r4
  68         bic_l   r1,r1,r2
  69         bmsk    r1,r1,r7
  70         sub     r12,r6,r4
  71         bic     r12,r12,r6
  72         bmsk.ne r12,r12,r7
  73         or.eq   r12,r12,r1
  74         and     r12,r12,r5
  75         brne    r12,0,.Learly_end
  76 #endif /* ENDIAN */
  77
  78 .Loop:
  79         ld_s    r2,[r3,4]
  80         ld.a    r6,[r3,8]
  81         ; stall for load result
  82         sub     r1,r2,r4
  83         bic_s   r1,r1,r2
  84         sub     r12,r6,r4
  85         bic     r12,r12,r6
  86         or_s    r12,r12,r1
  87         and     r12,r12,r5
  88         breq_s  r12,0,.Loop
  89 .Lend:
  90         and.f   r1,r1,r5
  91         sub.ne  r3,r3,4
  92 #ifdef __LITTLE_ENDIAN__
  93         mov.eq  r1,r12
  94         asr.f   0,r1,8
  95         bmsk.f  0,r1,15
  96         sub     r0,r3,r0
  97         add.cc  r0,r0,1
  98         jne.d   [blink]
  99         asl.f   0,r1,9
 100         j_s.d   [blink]
 101         sbc     r0,r0,-2
 102 #else /* BIG ENDIAN */
 103         mov.eq  r2,r6
 104         asl_s   r2,r2,7
 105         mov.eq  r1,r12
 106         bic_s   r1,r1,r2
 107         asr.f   0,r1,16
 108         sub     r0,r3,r0
 109         add.pl  r0,r0,1
 110         jne.d   [blink]
 111         add.eq  r0,r0,1
 112         j_s.d   [blink]
 113         add.cc  r0,r0,1
 114 #endif /* ENDIAN */
 115
 116         .balign 4
 117 .Learly_end:
 118         b.d     .Lend
 119         sub_s.ne r1,r1,r1
 120 ENDFUNC (strlen)
 121 #endif /* (__ARC600__ || !__ARC_NORM__) && !__ARC601__ && __ARC_BARREL_SHIFTER__ */
 122
 123 #endif /* !__OPTIMIZE_SIZE__ && !PREFER_SIZE_OVER_SPEED */