newlib/libc/machine/arc/strncpy-bs.S

   1 /*
   2    Copyright (c) 2015-2024, Synopsys, Inc. All rights reserved.
   3
   4    Redistribution and use in source and binary forms, with or without
   5    modification, are permitted provided that the following conditions are met:
   6
   7    1) Redistributions of source code must retain the above copyright notice,
   8    this list of conditions and the following disclaimer.
   9
  10    2) Redistributions in binary form must reproduce the above copyright notice,
  11    this list of conditions and the following disclaimer in the documentation
  12    and/or other materials provided with the distribution.
  13
  14    3) Neither the name of the Synopsys, Inc., nor the names of its contributors
  15    may be used to endorse or promote products derived from this software
  16    without specific prior written permission.
  17
  18    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  19    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
  22    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  23    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  24    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  26    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  27    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  28    POSSIBILITY OF SUCH DAMAGE.
  29 */
  30
  31 /* This implementation is optimized for performance.  For code size a generic
  32    implementation of this function from newlib/libc/string/strncpy.c will be
  33    used.  */
  34 #if !defined (__OPTIMIZE_SIZE__) && !defined (PREFER_SIZE_OVER_SPEED) \
  35     && !defined (__ARC_RF16__)
  36
  37 #include "asm.h"
  38
  39 /* If dst and src are 4 byte aligned, copy 8 bytes at a time.
  40    If the src is 4, but not 8 byte aligned, we first read 4 bytes to get
  41    it 8 byte aligned.  Thus, we can do a little read-ahead, without
  42    dereferencing a cache line that we should not touch.
  43    Note that short and long instructions have been scheduled to avoid
  44    branch stalls.
  45    The beq_s to r3z could be made unaligned & long to avoid a stall
  46    there, but the it is not likely to be taken often, and it
  47    would also be likey to cost an unaligned mispredict at the next call.  */
  48
  49 #if !defined (__ARC601__) && defined (__ARC_BARREL_SHIFTER__)
  50
  51 #if defined (__ARC700___) || defined (__ARCEM__) || defined (__ARCHS__)
  52 #define BRand(a,b,l)    tst     a,b ` bne_l l
  53 #else
  54 #define BRand(a,b,l)    and     a,a,b ` brne_s a,0,l
  55 #endif
  56
  57 ENTRY (strncpy)
  58         cmp_s   r2,8
  59         or      r12,r0,r1
  60         bmsk.cc.f r12,r12,1
  61         brne.d  r12,0,.Lbytewise
  62         mov_s   r10,r0
  63         ld_s    r3,[r1,0]
  64         mov     r8,0x01010101
  65         sub     lp_count,r2,1
  66         bbit0.d r1,2,.Loop_start
  67         ror     r11,r8
  68         sub     r12,r3,r8
  69         bic_l   r12,r12,r3
  70         BRand   (r12,r11,.Lr3z)
  71         mov_s   r4,r3
  72         ld.a    r3,[r1,4]
  73         sub     lp_count,lp_count,4
  74         st.ab   r4,[r10,4]
  75         .balign 4
  76 .Loop_start:
  77         lsr.f   lp_count,lp_count,3
  78         lpne    .Loop_end
  79         ld.a    r4,[r1,4]
  80         sub     r12,r3,r8
  81         bic_s   r12,r12,r3
  82         BRand   (r12,r11,.Lr3z)
  83         st.ab   r3,[r10,4]
  84         sub     r12,r4,r8
  85         bic     r12,r12,r4
  86         BRand   (r12,r11,.Lr4z)
  87         ld.a    r3,[r1,4]
  88         st.ab   r4,[r10,4]
  89 .Loop_end:
  90         bcc_s   .Lastword
  91         ld.a    r4,[r1,4]
  92         sub     r12,r3,r8
  93         bic_s   r12,r12,r3
  94         BRand   (r12,r11,.Lr3z)
  95         st.ab   r3,[r10,4]
  96         mov_s   r3,r4
  97 .Lastword:
  98         and.f   lp_count,r2,3
  99         mov.eq  lp_count,4
 100         lp      .Last_byte_end
 101 #ifdef __LITTLE_ENDIAN__
 102         bmsk.f  r1,r3,7
 103         lsr.ne  r3,r3,8
 104 #else
 105         lsr.f   r1,r3,24
 106         asl.ne  r3,r3,8
 107 #endif
 108         stb.ab  r1,[r10,1]
 109 .Last_byte_end:
 110         j_s     [blink]
 111
 112         .balign 4
 113 .Lr4z:
 114         mov_l   r3,r4
 115 .Lr3z:
 116 #if defined (__ARC700__) || defined (__ARCEM__) || defined (__ARCHS__)
 117 #ifdef __LITTLE_ENDIAN__
 118         bmsk.f  r1,r3,7
 119         lsr_s   r3,r3,8
 120 #else
 121         lsr.f   r1,r3,24
 122         asl_s   r3,r3,8
 123 #endif
 124         bne.d   .Lr3z
 125         stb.ab  r1,[r10,1]
 126 #else /* ! __ARC700__ */
 127 #ifdef __LITTLE_ENDIAN__
 128         bmsk.f  r1,r3,7
 129 .Lr3z_loop:
 130         lsr_s   r3,r3,8
 131         stb.ab  r1,[r10,1]
 132         bne.d   .Lr3z_loop
 133         bmsk.f  r1,r3,7
 134 #else
 135         lsr.f   r1,r3,24
 136 .Lr3z_loop:
 137         asl_s   r3,r3,8
 138         stb.ab  r1,[r10,1]
 139         bne.d   .Lr3z_loop
 140         lsr.f   r1,r3,24
 141 #endif /* ENDIAN */
 142 #endif /* ! __ARC700__ */
 143 .Lzero_rest:
 144         ; __strncpy_bzero requires:
 145         ; return value in r0
 146         ; zeroing length in r2
 147         ; zeroing start address in r3
 148         mov_s   r3,r10
 149         add_s   r2,r2,r0
 150         b.d     __strncpy_bzero
 151         sub_s   r2,r2,r3
 152
 153         .balign 4
 154 .Lbytewise:
 155         sub.f   r2,r2,1
 156         mov_l   r3,r0
 157         jcs     [blink]
 158 .Lcharloop:
 159         ldb.ab  r12,[r1,1]
 160         beq.d   .Last_byte
 161         sub.f   r2,r2,1
 162         brne.d  r12,0,.Lcharloop
 163         stb.ab  r12,[r3,1]
 164         b.d     __strncpy_bzero
 165         stb.ab  r12,[r3,1]
 166 .Last_byte:
 167         j_s.d   [blink]
 168         stb_l   r12,[r3]
 169 ENDFUNC (strncpy)
 170 #endif /* !__ARC601__ && __ARC_BARREL_SHIFTER__ */
 171
 172 #endif /* !__OPTIMIZE_SIZE__ && !PREFER_SIZE_OVER_SPEED */