newlib/libc/machine/arc/strncpy.S

   1 /*
   2    Copyright (c) 2015-2024, Synopsys, Inc. All rights reserved.
   3
   4    Redistribution and use in source and binary forms, with or without
   5    modification, are permitted provided that the following conditions are met:
   6
   7    1) Redistributions of source code must retain the above copyright notice,
   8    this list of conditions and the following disclaimer.
   9
  10    2) Redistributions in binary form must reproduce the above copyright notice,
  11    this list of conditions and the following disclaimer in the documentation
  12    and/or other materials provided with the distribution.
  13
  14    3) Neither the name of the Synopsys, Inc., nor the names of its contributors
  15    may be used to endorse or promote products derived from this software
  16    without specific prior written permission.
  17
  18    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
  19    AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  20    IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  21    ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
  22    LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
  23    CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
  24    SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
  25    INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
  26    CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
  27    ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  28    POSSIBILITY OF SUCH DAMAGE.
  29 */
  30
  31 /* This implementation is optimized for performance.  For code size a generic
  32    implementation of this function from newlib/libc/string/strncpy.c will be
  33    used.  */
  34 #if !defined (__OPTIMIZE_SIZE__) && !defined (PREFER_SIZE_OVER_SPEED) \
  35     && !defined (__ARC_RF16__)
  36
  37 #include "asm.h"
  38
  39 /* If dst and src are 4 byte aligned, copy 8 bytes at a time.
  40    If the src is 4, but not 8 byte aligned, we first read 4 bytes to get
  41    it 8 byte aligned.  Thus, we can do a little read-ahead, without
  42    dereferencing a cache line that we should not touch.  */
  43
  44 #if defined (__ARC601__) || !defined (__ARC_BARREL_SHIFTER__)
  45
  46 #define BRand(a,b,l)    and     a,a,b ` brne_s a,0,l
  47
  48 ENTRY (strncpy)
  49         cmp_s   r2,8
  50         or      r12,r0,r1
  51         bmsk.cc.f r12,r12,1
  52         brne.d  r12,0,.Lbytewise
  53         mov_s   r10,r0
  54         ld_s    r3,[r1,0]
  55         mov     r8,0x01010101
  56         add     r6,r0,r2
  57         sub     r6,r6,8
  58         bbit0.d r1,2,.Loop_start
  59         ror     r11,r8
  60         sub     r12,r3,r8
  61         bic_l   r12,r12,r3
  62         BRand   (r12,r11,.Lr3z)
  63         mov_s   r4,r3
  64         ld.a    r3,[r1,4]
  65         st.ab   r4,[r10,4]
  66         .balign 4
  67 .Loop_start:
  68         brhs    r10,r6,.Loop_end
  69 1:
  70         ld.a    r4,[r1,4]
  71         sub     r12,r3,r8
  72         bic_s   r12,r12,r3
  73         BRand   (r12,r11,.Lr3z2)
  74         st.ab   r3,[r10,8]
  75         sub     r12,r4,r8
  76         bic     r12,r12,r4
  77         BRand   (r12,r11,.Lr4z)
  78         ld.a    r3,[r1,4]
  79         brlo.d  r10,r6,1b
  80         st      r4,[r10,-4]
  81 .Loop_end:
  82         add     r6,r6,4
  83         brhs    r10,r6,.Lastword
  84         sub     r12,r3,r8
  85         bic_s   r12,r12,r3
  86         BRand   (r12,r11,.Lr3z)
  87         add_s   r1,r1,4
  88         st.ab   r3,[r10,4]
  89 .Lastword:
  90         sub_s   r2,r2,1
  91         b.d .Lstart_charloop
  92         bmsk.f  r2,r2,1
  93
  94         .balign 4
  95         nop_s
  96 .Lr3z2: sub_s   r1,r1,4
  97 .Lr4z:
  98 .Lr3z:
  99         .balign 4
 100 .Lr3z_loop:
 101         ldb.ab  r3,[r1,1]
 102         brne.d  r3,0,.Lr3z_loop
 103         stb.ab  r3,[r10,1]
 104
 105 .Lzero_rest:
 106         ; __strncpy_bzero requires:
 107         ; return value in r0
 108         ; zeroing length in r2
 109         ; zeroing start address in r3
 110         mov_s   r3,r10
 111         add_s   r2,r2,r0
 112         b.d     __strncpy_bzero
 113         sub_s   r2,r2,r3
 114
 115         .balign 4
 116 .Lbytewise:
 117         sub.f   r2,r2,1
 118         jcs     [blink]
 119 .Lstart_charloop:
 120         mov_s   r3,r10
 121 .Lcharloop:
 122         ldb.ab  r12,[r1,1]
 123         beq.d   .Last_byte
 124         sub.f   r2,r2,1
 125         brne.d  r12,0,.Lcharloop
 126         stb.ab  r12,[r3,1]
 127         b.d     __strncpy_bzero
 128         stb.ab  r12,[r3,1]
 129 .Last_byte:
 130         j_s.d   [blink]
 131         stb_s   r12,[r3]
 132 ENDFUNC (strncpy)
 133 #endif /* __ARC601__ || !__ARC_BARREL_SHIFTER__ */
 134
 135 #endif /* !__OPTIMIZE_SIZE__ && !PREFER_SIZE_OVER_SPEED */