libgloss/rs6000/yellowknife.ld

   1 OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc",
   2               "elf32-powerpc")
   3 OUTPUT_ARCH(powerpc)
   4 ENTRY(_start)
   5 /* Do we need any of these for elf?
   6    __DYNAMIC = 0;    */
   7 PROVIDE (__stack = 0);
   8 SECTIONS
   9 {
  10   /* Read-only sections, merged into text segment: */
  11   . = 0x50000 + SIZEOF_HEADERS;
  12   .interp   : { *(.interp) }
  13   .hash           : { *(.hash)          }
  14   .dynsym         : { *(.dynsym)                }
  15   .dynstr         : { *(.dynstr)                }
  16   .rela.text     :
  17     { *(.rela.text) *(.rela.gnu.linkonce.t*) }
  18   .rela.data     :
  19     { *(.rela.data) *(.rela.gnu.linkonce.d*) }
  20   .rela.rodata   :
  21     { *(.rela.rodata) *(.rela.gnu.linkonce.r*) }
  22   .rela.got       : { *(.rela.got)      }
  23   .rela.got1      : { *(.rela.got1)     }
  24   .rela.got2      : { *(.rela.got2)     }
  25   .rela.ctors     : { *(.rela.ctors)    }
  26   .rela.dtors     : { *(.rela.dtors)    }
  27   .rela.init      : { *(.rela.init)     }
  28   .rela.fini      : { *(.rela.fini)     }
  29   .rela.bss       : { *(.rela.bss)      }
  30   .rela.plt       : { *(.rela.plt)      }
  31   .rela.sdata     : { *(.rela.sdata2)   }
  32   .rela.sbss      : { *(.rela.sbss2)    }
  33   .rela.sdata2    : { *(.rela.sdata2)   }
  34   .rela.sbss2     : { *(.rela.sbss2)    }
  35   .plt   : { *(.plt) }
  36   .text      :
  37   {
  38     *(.text)
  39     /* .gnu.warning sections are handled specially by elf32.em.  */
  40     *(.gnu.warning)
  41     *(.gnu.linkonce.t*)
  42   } =0
  43   .init           : { *(.init)          } =0
  44   .fini           : { *(.fini)          } =0
  45   .rodata         : { *(.rodata) *(.gnu.linkonce.r*) }
  46   .rodata1        : { *(.rodata1) }
  47   _etext = .;
  48   PROVIDE (etext = .);
  49   .sdata2   : { *(.sdata2) }
  50   .sbss2   : { *(.sbss2) }
  51   /* Adjust the address for the data segment.  We want to adjust up to
  52      the same address within the page on the next page up.  It would
  53      be more correct to do this:
  54        . = ALIGN(0x50000) + (ALIGN(8) & (0x50000 - 1));
  55      The current expression does not correctly handle the case of a
  56      text segment ending precisely at the end of a page; it causes the
  57      data segment to skip a page.  The above expression does not have
  58      this problem, but it will currently (2/95) cause BFD to allocate
  59      a single segment, combining both text and data, for this case.
  60      This will prevent the text segment from being shared among
  61      multiple executions of the program; I think that is more
  62      important than losing a page of the virtual address space (note
  63      that no actual memory is lost; the page which is skipped can not
  64      be referenced).  */
  65   . =  ALIGN(8) + 0x50000;
  66   .data    :
  67   {
  68     *(.data)
  69     *(.gnu.linkonce.d*)
  70     CONSTRUCTORS
  71   }
  72   .data1   : { *(.data1) }
  73   .got1           : { *(.got1) }
  74   .dynamic        : { *(.dynamic) }
  75   /* Put .ctors and .dtors next to the .got2 section, so that the pointers
  76      get relocated with -mrelocatable. Also put in the .fixup pointers.
  77      The current compiler no longer needs this, but keep it around for 2.7.2  */
  78                 PROVIDE (_GOT2_START_ = .);
  79   .got2           :  { *(.got2) }
  80                 PROVIDE (__CTOR_LIST__ = .);
  81   .ctors          : { *(.ctors) }
  82                 PROVIDE (__CTOR_END__ = .);
  83                 PROVIDE (__DTOR_LIST__ = .);
  84   .dtors          : { *(.dtors) }
  85                 PROVIDE (__DTOR_END__ = .);
  86                 PROVIDE (_FIXUP_START_ = .);
  87   .fixup          : { *(.fixup) }
  88                 PROVIDE (_FIXUP_END_ = .);
  89                 PROVIDE (_GOT2_END_ = .);
  90                 PROVIDE (_GOT_START_ = .);
  91   .got            : { *(.got) }
  92   .got.plt        : { *(.got.plt) }
  93                 PROVIDE (_GOT_END_ = .);
  94   /* We want the small data sections together, so single-instruction offsets
  95      can access them all, and initialized data all before uninitialized, so
  96      we can shorten the on-disk segment size.  */
  97   .sdata          : { *(.sdata) }
  98   _edata  =  .;
  99   PROVIDE (edata = .);
 100   .sbss      :
 101   {
 102     PROVIDE (__sbss_start = .);
 103     *(.sbss)
 104     *(.scommon)
 105     PROVIDE (__sbss_end = .);
 106   }
 107   .bss       :
 108   {
 109    PROVIDE (__bss_start = .);
 110    *(.dynbss)
 111    *(.bss)
 112    *(COMMON)
 113   }
 114   _end = . ;
 115   PROVIDE (end = .);
 116   /* These are needed for ELF backends which have not yet been
 117      converted to the new style linker.  */
 118   .stab 0 : { *(.stab) }
 119   .stabstr 0 : { *(.stabstr) }
 120   /* DWARF debug sections.
 121      Symbols in the DWARF debugging sections are relative to the beginning
 122      of the section so we begin them at 0.  */
 123   /* DWARF 1 */
 124   .debug          0 : { *(.debug) }
 125   .line           0 : { *(.line) }
 126   /* GNU DWARF 1 extensions */
 127   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 128   .debug_sfnames  0 : { *(.debug_sfnames) }
 129   /* DWARF 1.1 and DWARF 2 */
 130   .debug_aranges  0 : { *(.debug_aranges) }
 131   .debug_pubnames 0 : { *(.debug_pubnames) }
 132   /* DWARF 2 */
 133   .debug_info     0 : { *(.debug_info) }
 134   .debug_abbrev   0 : { *(.debug_abbrev) }
 135   .debug_line     0 : { *(.debug_line) }
 136   .debug_frame    0 : { *(.debug_frame) }
 137   .debug_str      0 : { *(.debug_str) }
 138   .debug_loc      0 : { *(.debug_loc) }
 139   .debug_macinfo  0 : { *(.debug_macinfo) }
 140   .debug_ranges   0 : { *(.debug_ranges) }
 141   /* SGI/MIPS DWARF 2 extensions */
 142   .debug_weaknames 0 : { *(.debug_weaknames) }
 143   .debug_funcnames 0 : { *(.debug_funcnames) }
 144   .debug_typenames 0 : { *(.debug_typenames) }
 145   .debug_varnames  0 : { *(.debug_varnames) }
 146   /* These must appear regardless of  .  */
 147 }