configure.ac

   1 dnl If not 1, append datestamp to the version number
   2 m4_define(empathy_released, 0)
   3
   4 m4_define([empathy_major_version], [3])
   5 m4_define([empathy_minor_version], [25])
   6 m4_define([empathy_micro_version], [90])
   7 m4_define([empathy_nano_version], [0])
   8
   9 dnl Display the nano_version only if it's not '0'
  10 m4_define([empathy_base_version],
  11           [empathy_major_version.empathy_minor_version.empathy_micro_version])
  12 m4_define([empathy_full_version],
  13           [m4_if(empathy_nano_version, 0, [empathy_base_version],
  14               [empathy_base_version].[empathy_nano_version])])
  15
  16 m4_define(empathy_maybe_datestamp,
  17           m4_esyscmd([if test x]empathy_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  18
  19 m4_define(empathy_version, empathy_full_version[]empathy_maybe_datestamp)
  20
  21
  22 AC_INIT([Empathy],
  23         [empathy_version],
  24         [http://bugzilla.gnome.org/browse.cgi?product=empathy],
  25         [empathy],
  26         [https://live.gnome.org/Empathy])
  27
  28 AC_PREREQ([2.64])
  29 AC_COPYRIGHT([
  30   Copyright (C) 2003-2007 Imendio AB
  31   Copyright (C) 2007-2010 Collabora Ltd.
  32 ])
  33
  34 # Minimal version required
  35
  36 # Hardp deps
  37 FOLKS_REQUIRED=0.9.5
  38
  39 GLIB_REQUIRED=2.48.0
  40 AC_DEFINE(GLIB_VERSION_MIN_REQUIRED, GLIB_VERSION_2_48, [Ignore post 2.48 deprecations])
  41 AC_DEFINE(GLIB_VERSION_MAX_ALLOWED, GLIB_VERSION_2_48, [Prevent post 2.48 APIs])
  42
  43 GTK_REQUIRED=3.9.4
  44 AC_DEFINE(GDK_VERSION_MIN_REQUIRED, GDK_VERSION_3_8, [Ignore post 3.8 deprecations])
  45 AC_DEFINE(GDK_VERSION_MAX_ALLOWED, GDK_VERSION_3_10, [Prevent post 3.10 APIs])
  46
  47 CLUTTER_REQUIRED=1.10.0
  48 AC_DEFINE(CLUTTER_VERSION_MIN_REQUIRED, CLUTTER_VERSION_1_8, [Ignore post 1.8 deprecations])
  49 AC_DEFINE(CLUTTER_VERSION_MAX_ALLOWED, CLUTTER_VERSION_1_10, [Prevent post 1.10 APIs])
  50
  51 CLUTTER_GTK_REQUIRED=1.1.2
  52
  53 TELEPATHY_GLIB_REQUIRED=0.23.2
  54 AC_DEFINE(TP_VERSION_MIN_REQUIRED, TP_VERSION_0_20, [Ignore post 0.20 deprecations])
  55 AC_DEFINE(TP_VERSION_MAX_ALLOWED, TP_VERSION_0_24, [Prevent post 0.24 APIs])
  56 AC_DEFINE(TP_SEAL_ENABLE, 1, [Prevent to use sealed variables])
  57 AC_DEFINE(TP_DISABLE_SINGLE_INCLUDE, 1, [Disable single include header])
  58
  59 COGL_REQUIRED=1.14
  60 AC_DEFINE(COGL_VERSION_MIN_REQUIRED, COGL_VERSION_1_8, [Ignore post 1.8 deprecations])
  61 AC_DEFINE(COGL_VERSION_MAX_ALLOWED, COGL_VERSION_1_14, [Prevent post 1.14 APIs])
  62
  63 GSTREAMER_REQUIRED=0.10.32
  64 TP_FS_REQUIRED=0.6.0
  65 LIBSECRET_REQUIRED=0.5
  66 GCR_REQUIRED=2.91.4
  67 LIBCANBERRA_GTK_REQUIRED=0.25
  68 LIBNOTIFY_REQUIRED=0.7.0
  69 LIBSOUP_REQUIRED=2.42.0
  70 TELEPATHY_LOGGER=0.8.0
  71 WEBKIT_REQUIRED=2.10.0
  72 GOA_REQUIRED=3.5.1
  73
  74 # Optional deps
  75 ENCHANT_REQUIRED=1.2.0
  76 GEOCLUE_REQUIRED=2.1.0
  77 GEOCODE_GLIB_REQUIRED=0.99.1
  78 ISO_CODES_REQUIRED=0.35
  79 NAUTILUS_SENDTO_REQUIRED=2.90.0
  80 NETWORK_MANAGER_REQUIRED=0.7.0
  81 CHAMPLAIN_REQUIRED=0.12.1
  82 CHEESE_GTK_REQUIRED=3.4.0
  83 LIBACCOUNTS_REQUIRED=1.4
  84 LIBSIGNON_REQUIRED=1.8
  85 MC_PLUGINS_REQUIRED=5.13.1
  86
  87 # Use --enable-maintainer-mode to disable deprecated symbols,
  88 # disable single include and enable GSEAL. If this is not a released empathy,
  89 # maintainer mode is forced
  90 # FIXME: don't disable deprecated symbols until bgo #636654 has been fixed
  91 #ifelse(empathy_released, 1, [], [enable_maintainer_mode="yes"])
  92 #GNOME_MAINTAINER_MODE_DEFINES
  93
  94 PKG_PROG_PKG_CONFIG([0.25])
  95
  96 # tp-account-widgets
  97 prev_top_build_prefix=$ac_top_build_prefix
  98 prev_ac_configure_args=$ac_configure_args
  99 ac_configure_args="$ac_configure_args --with-pkgdatadir=${datadir}/empathy"
 100 ac_configure_args="$ac_configure_args --with-gettext-package=empathy-tpaw"
 101 ifelse(empathy_released, 1, [],
 102     [
 103         ac_configure_args="$ac_configure_args --enable-unreleased-checks"
 104     ])
 105 AX_CONFIG_DIR([telepathy-account-widgets])
 106 ac_top_build_prefix=$prev_top_build_prefix
 107 ac_configure_args=$prev_ac_configure_args
 108
 109 export PKG_CONFIG_PATH=$PKG_CONFIG_PATH:"$ac_top_build_prefix"telepathy-account-widgets/
 110 PKG_CHECK_MODULES(TPAW, telepathy-account-widgets)
 111
 112 EMPATHY_UOA_PROVIDER=`$PKG_CONFIG --variable=uoa_provider telepathy-account-widgets`
 113 AC_DEFINE_UNQUOTED(EMPATHY_UOA_PROVIDER, "$EMPATHY_UOA_PROVIDER",
 114    [Name of provider for accounts imported from libaccounts])
 115
 116 AC_CONFIG_MACRO_DIR([m4])
 117 AC_CONFIG_HEADERS([config.h])
 118 AC_CONFIG_SRCDIR([configure.ac])
 119 AC_CONFIG_AUX_DIR(.)
 120
 121 AM_INIT_AUTOMAKE([1.11 no-define -Wno-portability tar-ustar no-dist-gzip dist-xz])
 122
 123 # Support silent build rules. Disable
 124 # by either passing --disable-silent-rules to configure or passing V=1
 125 # to make
 126 AM_SILENT_RULES([yes])
 127
 128 # Check for programs
 129 AC_PROG_CC
 130 AC_HEADER_STDC
 131 AC_PROG_MKDIR_P
 132 AM_PATH_GLIB_2_0
 133 AC_PATH_XTRA
 134
 135 # Initialize libtool
 136 LT_PREREQ([2.2])
 137 LT_INIT
 138
 139 AC_PATH_PROG(DBUS_BINDING_TOOL, dbus-binding-tool)
 140 GLIB_GSETTINGS
 141
 142 GLIB_COMPILE_RESOURCES=`$PKG_CONFIG gio-2.0 --variable=glib_compile_resources`
 143 AC_SUBST(GLIB_COMPILE_RESOURCES)
 144 GLIB_GENMARSHAL=`$PKG_CONFIG glib-2.0 --variable=glib_genmarshal`
 145 AC_SUBST(GLIB_GENMARSHAL)
 146
 147 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
 148 if test -z "$XSLTPROC"; then
 149   AC_MSG_ERROR([xsltproc (from libxslt) is required])
 150 fi
 151 AM_PATH_PYTHON([2.3])
 152
 153 EMPATHY_ARG_VALGRIND
 154
 155
 156 # -----------------------------------------------------------
 157 # Error flags
 158 # -----------------------------------------------------------
 159 AS_COMPILER_FLAG(-Wall, ERROR_CFLAGS="-Wall", ERROR_CFLAGS="")
 160
 161 AS_COMPILER_FLAG(-Wextra, wextra=yes, wextra=no)
 162 AS_COMPILER_FLAG(-Wno-missing-field-initializers,
 163         wno_missing_field_initializers=yes,
 164         wno_missing_field_initializers=no)
 165 AS_COMPILER_FLAG(-Wno-unused-parameter,
 166         wno_unused_parameter=yes,
 167         wno_unused_parameter=no)
 168
 169 ifelse(empathy_released, 1, [],
 170     [
 171         if test x$wextra = xyes -a \
 172             x$wno_missing_field_initializers = xyes -a \
 173             x$wno_unused_parameter = xyes; then
 174             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra -Wno-missing-field-initializers -Wno-unused-parameter"
 175         fi
 176     ])
 177
 178 AS_COMPILER_FLAG(-Wdeclaration-after-statement, ERROR_CFLAGS="$ERROR_CFLAGS -Wdeclaration-after-statement")
 179 AS_COMPILER_FLAG(-Wshadow, ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow")
 180 AS_COMPILER_FLAG(-Wmissing-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-prototypes")
 181 AS_COMPILER_FLAG(-Wmissing-declarations, ERROR_CFLAGS="$ERROR_CFLAGS -Wmissing-declarations")
 182 AS_COMPILER_FLAG(-Wstrict-prototypes, ERROR_CFLAGS="$ERROR_CFLAGS -Wstrict-prototypes")
 183
 184 AC_SUBST(ERROR_CFLAGS)
 185
 186 AC_ARG_ENABLE(gprof,
 187             AS_HELP_STRING([--enable-gprof=@<:@no/yes@:>@],
 188             [build with support for gprof]),,
 189             [enable_gprof=no])
 190 if test "x$enable_gprof" != "xno" ; then
 191     CFLAGS="$CFLAGS -pg"
 192     LDFLAGS="$LDFLAGS -pg"
 193 fi
 194
 195 AC_SUBST(LDFLAGS)
 196
 197 # -----------------------------------------------------------
 198 # Pkg-Config dependency checks
 199 # -----------------------------------------------------------
 200
 201 AC_CHECK_LIBM
 202 AC_SUBST(LIBM)
 203
 204 PKG_CHECK_MODULES(EMPATHY,
 205 [
 206    dbus-glib-1
 207    folks >= $FOLKS_REQUIRED
 208    folks-telepathy >= $FOLKS_REQUIRED
 209    glib-2.0 >= $GLIB_REQUIRED
 210    gio-2.0 >= $GLIB_REQUIRED
 211    gio-unix-2.0 >= $GLIB_REQUIRED
 212    libsecret-1 >= $LIBSECRET_REQUIRED
 213    gmodule-export-2.0
 214    gobject-2.0
 215    gsettings-desktop-schemas
 216    libxml-2.0
 217    telepathy-glib >= $TELEPATHY_GLIB_REQUIRED
 218    telepathy-logger-0.2 >= $TELEPATHY_LOGGER
 219    x11
 220    gtk+-3.0 >= $GTK_REQUIRED
 221    libcanberra-gtk3 >= $LIBCANBERRA_GTK_REQUIRED
 222    libnotify >= $LIBNOTIFY_REQUIRED
 223    gcr-3 >= $GCR_REQUIRED
 224    libpulse
 225    libpulse-mainloop-glib
 226    webkit2gtk-4.0 >= $WEBKIT_REQUIRED
 227    libsoup-2.4 >= $LIBSOUP_REQUIRED
 228    gee-0.8
 229 ])
 230
 231 # -----------------------------------------------------------
 232 # GStreamer
 233 # -----------------------------------------------------------
 234 PKG_CHECK_MODULES(EMPATHY_CALL,
 235 [
 236    farstream-0.2
 237    telepathy-farstream >= $TP_FS_REQUIRED
 238    clutter-1.0 >= $CLUTTER_REQUIRED
 239    clutter-gtk-1.0 >= $CLUTTER_GTK_REQUIRED
 240    clutter-gst-3.0
 241    gstreamer-1.0
 242    gstreamer-audio-1.0
 243    gstreamer-video-1.0
 244    cogl-1.0 >= $COGL_REQUIRED
 245 ])
 246
 247 AC_DEFINE(EMPATHY_GOA_PROVIDER, "org.gnome.OnlineAccounts",
 248    [Name of provider for accounts imported from GOA])
 249
 250 # -----------------------------------------------------------
 251 # Enable debug
 252 # -----------------------------------------------------------
 253
 254 AC_ARG_ENABLE(debug,
 255   AS_HELP_STRING([--disable-debug],
 256                  [compile without debug code]),
 257     enable_debug=$enableval, enable_debug=yes )
 258
 259 if test x$enable_debug = xyes; then
 260   AC_DEFINE(ENABLE_DEBUG, [], [Enable debug code])
 261 fi
 262
 263 # -----------------------------------------------------------
 264 # Language Support
 265 # -----------------------------------------------------------
 266 IT_PROG_INTLTOOL([0.50.0])
 267
 268 GETTEXT_PACKAGE=empathy
 269 AC_SUBST(GETTEXT_PACKAGE)
 270 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Gettext package name])
 271
 272 # -----------------------------------------------------------
 273 # gudev
 274 # -----------------------------------------------------------
 275 AC_ARG_ENABLE(gudev,
 276               AS_HELP_STRING([--enable-gudev=@<:@no/yes/auto@:>@],
 277                              [build with gudev support]), ,
 278                              enable_gudev=auto)
 279
 280 if test "x$enable_gudev" != "xno"; then
 281
 282    PKG_CHECK_MODULES(UDEV, [gudev-1.0],
 283         have_gudev="yes", have_gudev="no")
 284
 285    if test "x$have_gudev" = "xyes"; then
 286       AC_DEFINE(HAVE_UDEV, 1, [Define if you have gudev])
 287    fi
 288 else
 289    have_gudev=no
 290 fi
 291
 292 if test "x$enable_gudev" = "xyes" -a "x$have_gudev" != "xyes"; then
 293    AC_MSG_ERROR([Could not find gudev dependencies:
 294
 295 $UDEV_PKG_ERRORS])
 296 fi
 297 AM_CONDITIONAL(HAVE_UDEV, test "x$have_gudev" = "xyes")
 298
 299 # -----------------------------------------------------------
 300 # spellchecking checks: enchant and iso-codes
 301 # -----------------------------------------------------------
 302 AC_ARG_ENABLE(spell,
 303               AS_HELP_STRING([--enable-spell=@<:@no/yes/auto@:>@],
 304                              [Enable spell checking]), ,
 305                              enable_spell=auto)
 306
 307 if test "x$enable_spell" != "xno"; then
 308    PKG_CHECK_MODULES(ENCHANT,
 309    [
 310       enchant >= $ENCHANT_REQUIRED,
 311       iso-codes >= $ISO_CODES_REQUIRED
 312    ], have_enchant="yes", have_enchant="no")
 313
 314    if test "x$have_enchant" = "xyes"; then
 315       AC_MSG_CHECKING([whether iso-codes has iso-639 and iso-3166 domains])
 316       if $PKG_CONFIG --variable=domains iso-codes | grep 639 > /dev/null && \
 317          $PKG_CONFIG --variable=domains iso-codes | grep 3166 > /dev/null ; then
 318             AC_DEFINE_UNQUOTED(ISO_CODES_PREFIX, ["`$PKG_CONFIG --variable=prefix iso-codes`"], [ISO codes prefix])
 319             AC_DEFINE(HAVE_ENCHANT, [], [Define if you have libenchant])
 320             result=yes
 321       else
 322             result=no
 323             have_enchant="no"
 324       fi
 325       AC_MSG_RESULT([$result])
 326    fi
 327 else
 328    have_enchant=no
 329 fi
 330
 331 if test "x$enable_spell" = "xyes" -a "x$have_enchant" != "xyes"; then
 332    AC_MSG_ERROR([Could not find spell-checking dependencies:
 333
 334 $ENCHANT_PKG_ERRORS])
 335 fi
 336
 337 AM_CONDITIONAL(HAVE_ENCHANT, test "x$have_enchant" = "xyes")
 338
 339 # -----------------------------------------------------------
 340 # Map view checks: libchamplain
 341 # -----------------------------------------------------------
 342 AC_ARG_ENABLE(map,
 343               AS_HELP_STRING([--enable-map=@<:@no/yes/auto@:>@],
 344                              [Enable map view]), ,
 345                              enable_map=auto)
 346
 347 if test "x$enable_map" != "xno"; then
 348
 349    PKG_CHECK_MODULES(LIBCHAMPLAIN,
 350     [
 351        clutter-gtk-1.0
 352        champlain-gtk-0.12
 353        champlain-0.12 >= $CHAMPLAIN_REQUIRED
 354     ], have_libchamplain="yes", have_libchamplain="no")
 355
 356    if test "x$have_libchamplain" = "xyes"; then
 357       AC_DEFINE(HAVE_LIBCHAMPLAIN, 1, [Define if you have libchamplain])
 358    fi
 359 else
 360    have_libchamplain=no
 361 fi
 362
 363 if test "x$enable_map" = "xyes" -a "x$have_libchamplain" != "xyes"; then
 364    AC_MSG_ERROR([Could not find map view dependencies:
 365
 366 $LIBCHAMPLAIN_PKG_ERRORS])
 367 fi
 368
 369 AM_CONDITIONAL(HAVE_LIBCHAMPLAIN, test "x$have_libchamplain" = "xyes")
 370
 371 # -----------------------------------------------------------
 372 # location checks: geoclue
 373 # -----------------------------------------------------------
 374 AC_ARG_ENABLE(location,
 375               AS_HELP_STRING([--enable-location=@<:@no/yes/auto@:>@],
 376                              [Enable location awareness]), ,
 377                              enable_location=auto)
 378
 379 if test "x$enable_location" != "xno"; then
 380    PKG_CHECK_MODULES(GEOCLUE,
 381    [
 382       geoclue-2.0 >= $GEOCLUE_REQUIRED
 383    ], have_geoclue="yes", have_geoclue="no")
 384
 385    if test "x$have_geoclue" = "xyes"; then
 386       GEOCLUE_XML_FILE=`$PKG_CONFIG --variable=dbus_interface geoclue-2.0`
 387       if test "x$GEOCLUE_XML_FILE" = "x"; then
 388         echo "Can't find dbus_interface variable in geoclue-2.0.pc"
 389         have_geoclue="no"
 390       else
 391         AC_DEFINE(HAVE_GEOCLUE, 1, [Define if you have geoclue-2])
 392         AC_SUBST(GEOCLUE_XML_FILE)
 393       fi
 394    fi
 395 else
 396    have_geoclue="no"
 397 fi
 398
 399 if test "x$enable_location" = "xyes" -a "x$have_geoclue" != "xyes"; then
 400    AC_MSG_ERROR([Could not find location dependencies:
 401
 402 $GEOCLUE_PKG_ERRORS])
 403 fi
 404
 405 AM_CONDITIONAL(HAVE_GEOCLUE, test "x$have_geoclue" = "xyes")
 406 AC_SUBST(GEOCLUE_CFLAGS)
 407 AC_SUBST(GEOCLUE_LIBS)
 408
 409 # -----------------------------------------------------------
 410 # location checks: geocode-glib
 411 # -----------------------------------------------------------
 412 AC_ARG_ENABLE(geocode,
 413               AS_HELP_STRING([--enable-geocode=@<:@no/yes/auto@:>@],
 414                              [Enable geocode support]), ,
 415                              enable_geocode=auto)
 416
 417 if test "x$enable_geocode" != "xno"; then
 418    PKG_CHECK_MODULES(GEOCODE,
 419    [
 420       geocode-glib-1.0 >= $GEOCODE_GLIB_REQUIRED
 421    ], have_geocode="yes", have_geocode="no")
 422
 423    if test "x$have_geocode" = "xyes"; then
 424       AC_DEFINE(HAVE_GEOCODE, 1, [Define if you have geocode])
 425    fi
 426 else
 427    have_geocode="no"
 428 fi
 429
 430 if test "x$enable_geocode" = "xyes" -a "x$have_geocode" != "xyes"; then
 431    AC_MSG_ERROR([Could not find geocode dependencies:
 432
 433 $GEOCODE_PKG_ERRORS])
 434 fi
 435
 436 AM_CONDITIONAL(HAVE_GEOCODE, test "x$have_geocode" = "xyes")
 437 AC_SUBST(GEOCODE_CFLAGS)
 438 AC_SUBST(GEOCODE_LIBS)
 439
 440 # -----------------------------------------------------------
 441 # goa-mc-plugin
 442 # -----------------------------------------------------------
 443 AC_ARG_ENABLE(goa,
 444               AS_HELP_STRING([--enable-goa=@<:@no/yes/auto@:>@],
 445                              [build GOA MC plugin]), ,
 446                              enable_goa=auto)
 447
 448 if test "x$enable_goa" != "xno"; then
 449    PKG_CHECK_MODULES(GOA,
 450     [
 451        mission-control-plugins
 452        goa-1.0 >= $GOA_REQUIRED
 453     ], have_goa="yes", have_goa="no")
 454 else
 455    have_goa=no
 456 fi
 457
 458 if test "x$enable_goa" = "xyes" -a "x$have_goa" != "xyes"; then
 459    AC_MSG_ERROR([Could not find GOA dependencies:
 460
 461 $GOA_PKG_ERRORS])
 462 fi
 463
 464 if test "x$have_goa" = "xyes"; then
 465    AC_DEFINE(HAVE_GOA, 1, [Define to 1 to enable GNOME Online Accounts])
 466 fi
 467
 468 AM_CONDITIONAL(HAVE_GOA, test "x$have_goa" = "xyes")
 469
 470 # Optional dependency for avatar selection
 471 AC_ARG_WITH([cheese],
 472             AS_HELP_STRING([--with-cheese],
 473                            [enable cheese webcam support]),,
 474             with_cheese=auto)
 475
 476 if test x"$with_cheese" != x"no" ; then
 477    PKG_CHECK_MODULES(CHEESE, cheese-gtk >= CHEESE_GTK_REQUIRED, [have_cheese=yes], [have_cheese=no])
 478    if test x${have_cheese} = xyes; then
 479      AC_DEFINE(HAVE_CHEESE, 1, [Define to 1 to enable cheese webcam support])
 480    fi
 481    if test x${with_cheese} = xyes && test x${have_cheese} = xno; then
 482      AC_MSG_ERROR([Cheese configured but not found:
 483
 484 $CHEESE_PKG_ERRORS])
 485    fi
 486 else
 487    have_cheese=no
 488 fi
 489 AM_CONDITIONAL(BUILD_CHEESE, test x${have_cheese} = xyes)
 490
 491 # -----------------------------------------------------------
 492 # ubuntu-online-accounts support
 493 # -----------------------------------------------------------
 494 AC_ARG_ENABLE(ubuntu-online-accounts,
 495               AS_HELP_STRING([--enable-ubuntu-online-accounts=@<:@no/yes/auto@:>@],
 496                              [build Ubuntu Online Accounts plugins]), ,
 497                              enable_ubuntu_online_accounts=auto)
 498
 499 if test "x$enable_ubuntu_online_accounts" != "xno"; then
 500    PKG_CHECK_MODULES(UOA,
 501     [
 502        account-plugin
 503        mission-control-plugins >= $MC_PLUGINS_REQUIRED
 504        libaccounts-glib >= $LIBACCOUNTS_REQUIRED
 505        libsignon-glib >= $LIBSIGNON_REQUIRED
 506     ], have_uoa="yes", have_uoa="no")
 507
 508    # provider plugin dir
 509    AC_MSG_CHECKING([Accounts provider plugin dir])
 510    ACCOUNTS_PROVIDER_PLUGIN_DIR=`$PKG_CONFIG --variable=provider_plugindir account-plugin`
 511
 512    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_PLUGIN_DIR])
 513    AC_SUBST(ACCOUNTS_PROVIDER_PLUGIN_DIR)
 514
 515    # app plugin dir
 516    AC_MSG_CHECKING([Accounts provider app plugin dir])
 517    ACCOUNTS_APP_PLUGIN_DIR=`$PKG_CONFIG --variable=application_plugindir account-plugin`
 518
 519    AC_MSG_RESULT([$ACCOUNTS_APP_PLUGIN_DIR])
 520    AC_SUBST(ACCOUNTS_APP_PLUGIN_DIR)
 521
 522    # provider files dir
 523    AC_MSG_CHECKING([Accounts provider files dir])
 524    ACCOUNTS_PROVIDER_FILES_DIR=`$PKG_CONFIG --variable=providerfilesdir libaccounts-glib`
 525
 526    AC_MSG_RESULT([$ACCOUNTS_PROVIDER_FILES_DIR])
 527    AC_SUBST(ACCOUNTS_PROVIDER_FILES_DIR)
 528
 529    # service files dir
 530    AC_MSG_CHECKING([Accounts service files dir])
 531    ACCOUNTS_SERVICE_FILES_DIR=`$PKG_CONFIG --variable=servicefilesdir libaccounts-glib`
 532
 533    AC_MSG_RESULT([$ACCOUNTS_SERVICE_FILES_DIR])
 534    AC_SUBST(ACCOUNTS_SERVICE_FILES_DIR)
 535
 536    # application files dir
 537    AC_MSG_CHECKING([Accounts applications files dir])
 538    ACCOUNTS_APPLICATION_FILES_DIR=`$PKG_CONFIG --variable=applicationfilesdir libaccounts-glib`
 539
 540    AC_MSG_RESULT([$ACCOUNTS_APPLICATION_FILES_DIR])
 541    AC_SUBST(ACCOUNTS_APPLICATION_FILES_DIR)
 542
 543 else
 544    have_uoa=no
 545 fi
 546
 547 if test "x$enable_ubuntu_online_accounts" = "xyes" -a "x$have_uoa" != "xyes"; then
 548    AC_MSG_ERROR([Could not find Ubuntu Online Accounts dependencies:
 549
 550 $UOA_PKG_ERRORS])
 551 fi
 552
 553 if test "x$have_uoa" = "xyes"; then
 554    AC_DEFINE(HAVE_UOA, 1, [Define to 1 to build Ubuntu Online Accounts plugins])
 555 fi
 556
 557 AM_CONDITIONAL(HAVE_UOA, test "x$have_uoa" = "xyes")
 558
 559 if test "x$have_uoa" = "xyes" -o "x$have_goa" = "xyes"; then
 560    AC_MSG_CHECKING([Mission Control plugins dir])
 561    MISSION_CONTROL_PLUGINS_DIR=`$PKG_CONFIG --define-variable=libdir='${libdir}' --variable=plugindir mission-control-plugins`
 562
 563    AC_MSG_RESULT([$MISSION_CONTROL_PLUGINS_DIR])
 564    AC_SUBST(MISSION_CONTROL_PLUGINS_DIR)
 565 fi
 566
 567
 568 # Help documentation
 569 YELP_HELP_INIT
 570
 571 # -----------------------------------------------------------
 572 # Coding style checks
 573 # -----------------------------------------------------------
 574 AC_ARG_ENABLE(coding-style-checks,
 575   AS_HELP_STRING([--disable-coding-style-checks],
 576                  [do not check coding style using grep]),
 577     [ENABLE_CODING_STYLE_CHECKS=$enableval],
 578     [ENABLE_CODING_STYLE_CHECKS=yes])
 579
 580 AC_SUBST([ENABLE_CODING_STYLE_CHECKS])
 581 # -----------------------------------------------------------
 582
 583 AC_CONFIG_FILES([
 584    Makefile
 585    data/Makefile
 586    data/org.gnome.Empathy.desktop.in
 587    data/icons/Makefile
 588    data/themes/Makefile
 589    extensions/Makefile
 590    po/Makefile.in
 591    libempathy/Makefile
 592    libempathy-gtk/Makefile
 593    src/Makefile
 594    goa-mc-plugin/Makefile
 595    ubuntu-online-accounts/Makefile
 596    ubuntu-online-accounts/mc-plugin/Makefile
 597    ubuntu-online-accounts/cc-plugins/Makefile
 598    ubuntu-online-accounts/cc-plugins/account-plugins/Makefile
 599    ubuntu-online-accounts/cc-plugins/providers/Makefile
 600    ubuntu-online-accounts/cc-plugins/services/Makefile
 601    ubuntu-online-accounts/cc-plugins/app-plugin/Makefile
 602    help/Makefile
 603    tests/Makefile
 604    tests/interactive/Makefile
 605    tests/xml/Makefile
 606    tests/certificates/Makefile
 607    tools/Makefile
 608 ])
 609 AC_OUTPUT
 610
 611 echo "
 612 Configure summary:
 613
 614         Compiler....................:  ${CC}
 615         Compiler Flags..............:  ${CFLAGS} ${ERROR_CFLAGS}
 616         Linker Flags................:  ${LDFLAGS}
 617         Prefix......................:  ${prefix}
 618         Coding style checks.........:  ${ENABLE_CODING_STYLE_CHECKS}
 619
 620     Features:
 621         Spell checking (enchant)....:  ${have_enchant}
 622         Display maps (libchamplain).:  ${have_libchamplain}
 623         Location awareness (Geoclue):  ${have_geoclue}
 624         Geocode support (Geocode)...:  ${have_geocode}
 625         Cheese webcam support ......:  ${have_cheese}
 626         Camera monitoring...........:  ${have_gudev}
 627
 628     Extras:
 629         GOA MC plugin...............:  ${have_goa}
 630         Ubuntu Online plugins.......:  ${have_uoa}
 631 "