configure.ac

   1 dnl AC_INIT does not take a macro as a version nr: set it separately! - Bram
   2 AC_INIT([ODE],[0.16],[ode@ode.org])
   3 ODE_VERSION=0.16
   4 AC_SUBST(ODE_VERSION)
   5
   6 # Those are instructions from the Libtool manual:
   7 #  1. Start with version information of `0:0:0' for each libtool library.
   8 #
   9 #  2. Update the version information only immediately before a public
  10 #     release of your software.  More frequent updates are unnecessary,
  11 #     and only guarantee that the current interface number gets larger
  12 #     faster.
  13 #
  14 #  3. If the library source code has changed at all since the last
  15 #     update, then increment REVISION (`C:R:A' becomes `C:r+1:A').
  16 #
  17 #  4. If any interfaces have been added, removed, or changed since the
  18 #     last update, increment CURRENT, and set REVISION to 0.
  19 #
  20 #  5. If any interfaces have been added since the last public release,
  21 #     then increment AGE.
  22 #
  23 #  6. If any interfaces have been removed since the last public release,
  24 #     then set AGE to 0.
  25 CURRENT=8
  26 REVISION=0
  27 AGE=0
  28
  29 AC_ARG_ENABLE(version-info,
  30         AS_HELP_STRING([--disable-version-info],
  31                 [don't encode version information in the generated library]),
  32         version_info=$enableval,
  33         version_info=yes)
  34 if test x$version_info = xyes
  35 then
  36     ODE_VERSION_INFO="-version-info $CURRENT:$REVISION:$AGE"
  37 else
  38     ODE_VERSION_INFO="-avoid-version"
  39 fi
  40 AC_SUBST(ODE_VERSION_INFO)
  41
  42
  43 AC_CONFIG_SRCDIR([ode/src/ode.cpp])
  44 AC_CONFIG_MACRO_DIR([m4])
  45
  46 AC_CANONICAL_HOST
  47
  48 AM_INIT_AUTOMAKE([1.10 foreign])
  49 AC_CONFIG_HEADERS([ode/src/config.h])
  50
  51 dnl This is needed because we have subdirectories
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CXX
  54 AC_PROG_CC
  55 AM_PROG_CC_C_O
  56 AC_PROG_CPP
  57 AC_PROG_AWK
  58 AC_PROG_INSTALL
  59 AC_PROG_LN_S
  60 AC_PROG_MKDIR_P
  61 LT_INIT([disable-shared win32-dll])
  62 AC_CHECK_TOOLS([WINDRES], [windres])
  63
  64 AC_C_BIGENDIAN
  65 AC_C_INLINE
  66 AC_C_VOLATILE
  67 PKG_PROG_PKG_CONFIG
  68
  69 AC_ARG_VAR([DOXYGEN], [set to doxygen binary to generate doxygen docs])
  70 AC_CHECK_PROGS([DOXYGEN], [doxygen])
  71 AM_CONDITIONAL([HAVE_DOXYGEN], [test x$DOXYGEN = xdoxygen])
  72
  73
  74 dnl this may NOT be the machine on which the code is going to run in,
  75 dnl so allow users to compile programs for their target machine.
  76 pentium=no
  77 cpu64=no
  78 case "$host_cpu" in
  79   i586 | i686 | i786 )
  80         pentium=yes
  81         AC_DEFINE(PENTIUM,1,[compiling for a pentium on a gcc-based platform?])
  82     ;;
  83   x86_64* )
  84         pentium=yes
  85         cpu64=yes
  86         AC_DEFINE(X86_64_SYSTEM,1,[compiling for a X86_64 system on a gcc-based platform?])
  87     ;;
  88 esac
  89
  90 AM_CONDITIONAL(X86_64_SYSTEM, test x$cpu64 = xyes)
  91
  92
  93
  94
  95
  96
  97 dnl check for required headers
  98 AC_CHECK_HEADERS( [alloca.h stdio.h inttypes.h stdint.h stdlib.h math.h \
  99                   string.h stdarg.h malloc.h float.h time.h sys/time.h \
 100                   limits.h stddef.h])
 101
 102
 103 opcode=no
 104 gimpact=no
 105 AC_ARG_WITH(trimesh, AS_HELP_STRING([--with-trimesh=@<:@opcode|gimpact|none@:>@],
 106         [use the specified system for trimesh support @<:@default=opcode@:>@]),
 107         trimesh=$withval,trimesh=opcode
 108 )
 109 if test "$trimesh" = opcode
 110 then
 111   opcode=yes
 112 fi
 113 if test "$trimesh" = gimpact
 114 then
 115   gimpact=yes
 116 fi
 117
 118 AM_CONDITIONAL(OPCODE,  test $opcode  = yes)
 119 AM_CONDITIONAL(GIMPACT, test $gimpact = yes)
 120 AM_CONDITIONAL(TRIMESH, test $opcode = yes -o $gimpact = yes)
 121
 122
 123 AC_MSG_CHECKING(if double precision is requested)
 124 AC_ARG_ENABLE(double-precision,
 125         AS_HELP_STRING([--enable-double-precision],
 126         [Configure ODE to work with double precision, if not specified, single precision is used @<:@default=no@:>@]),
 127         usedouble=$enableval,usedouble=no)
 128 AC_MSG_RESULT([$usedouble])
 129 if test "$usedouble" = yes;
 130 then
 131         ODE_PRECISION=dDOUBLE
 132 else
 133         ODE_PRECISION=dSINGLE
 134 fi
 135 AC_SUBST(ODE_PRECISION)
 136
 137
 138 AC_ARG_WITH([drawstuff],
 139     AS_HELP_STRING([--with-drawstuff=X11|Win32|OSX|none],
 140         [force a particular drawstuff implementation or disable it.[default=autodetect]]),
 141     [drawstuff=$withval],[drawstuff=])
 142
 143 dnl Set some Platform Specific Variables
 144 EXTRA_LIBTOOL_LDFLAGS=
 145 case "$host_os" in
 146   cygwin* | mingw*)
 147     if test "x$drawstuff" = x
 148     then
 149        drawstuff="Win32" # if in a Windows enviroment
 150     fi
 151     EXTRA_LIBTOOL_LDFLAGS="-no-undefined"
 152     ;;
 153   *apple* | *darwin*) # For Mac OS X
 154     if test "x$drawstuff" = x
 155     then
 156        drawstuff="OSX"
 157     fi
 158     dnl We need to use C++ compilation and linking for ode on Mac
 159     dnl Might as well do it for all code.
 160     CC="$CXX"
 161     LINK="$CXXLINK"
 162     ;;
 163   *)
 164     if test "x$drawstuff" = x
 165     then
 166        drawstuff="X11" # if anything else default to X11
 167     fi
 168     ;;
 169 esac
 170 AC_SUBST(EXTRA_LIBTOOL_LDFLAGS)
 171
 172
 173 dnl Set Drawstuff variables
 174 AC_MSG_CHECKING([which drawstuff lib to build])
 175 AC_MSG_RESULT($drawstuff)
 176
 177 if test "x$drawstuff" = "xX11"
 178 then
 179     # The built-in macro, X_PATH, causes too many problems, these days everyone uses Xorg,
 180     # so we can ask pkg-config to find it for us.
 181     PKG_CHECK_MODULES(X11, x11, [], [drawstuff="none"])
 182 fi
 183
 184 dnl Check for OpenGL
 185 if test "x$drawstuff" = "xOSX"; then
 186   AC_DEFINE([HAVE_APPLE_OPENGL_FRAMEWORK], [1],
 187             [Use the Apple OpenGL framework.])
 188   GL_LIBS="-framework OpenGL -framework GLUT"
 189 elif test "x$drawstuff" != "xnone"; then
 190   have_gl_headers=yes
 191   AC_CHECK_HEADERS(GL/gl.h GL/glu.h GL/glext.h, ,
 192         [have_gl_headers=no],
 193        [[#ifdef WIN32
 194          #include <windows.h>
 195          #endif
 196          #if HAVE_GL_GL_H
 197          #include <GL/gl.h>
 198          #endif
 199              #if HAVE_GL_GLU_H
 200          #include <GL/glu.h>
 201          #endif
 202        ]])
 203   have_gl=no
 204   have_glu=no
 205   TEMP_LDFLAGS="$LDFLAGS"
 206   AC_CHECK_LIB(GL, main, [GL_LIBS="-lGL"; have_gl=yes])
 207   AC_CHECK_LIB(GLU, main, [GL_LIBS="-lGLU $GL_LIBS"; have_glu=yes], , -lGL)
 208   AC_CHECK_LIB(opengl32, main, [GL_LIBS="-lopengl32"; have_gl=yes])
 209   AC_CHECK_LIB(glu32, main, [GL_LIBS="-lglu32 $GL_LIBS"; have_glu=yes], , -lopengl32)
 210   LDFLAGS="$TEMP_LDFLAGS"
 211   if test $have_gl = no -o $have_glu = no -o $have_gl_headers = no; then
 212     drawstuff="none"
 213   fi
 214 fi
 215 AC_SUBST(GL_LIBS)
 216
 217 dnl Set Conditionals
 218 AM_CONDITIONAL(WIN32, test x$drawstuff = xWin32)
 219 AM_CONDITIONAL(X11, test x$drawstuff = xX11)
 220 AM_CONDITIONAL(OSX, test x$drawstuff = xOSX)
 221 AM_CONDITIONAL(ENABLE_DRAWSTUFF, test x$drawstuff != xnone)
 222
 223 dnl Check if we want to build demos
 224 AC_MSG_CHECKING(if demos should be built)
 225 AC_ARG_ENABLE(demos,
 226         AS_HELP_STRING([--disable-demos], [don't build demos]),
 227         enable_demos=$enableval,enable_demos=yes)
 228 if test x$drawstuff = xnone -a x$enable_demos = xyes ; then
 229     enable_demos=no
 230     AC_MSG_RESULT($enable_demos)
 231     AC_MSG_WARN([Demos will not be built because OpenGL doesn't seem to work. See `config.log' for details.])
 232 else
 233     AC_MSG_RESULT($enable_demos)
 234 fi
 235
 236
 237 dnl stdc++ is required when linking C programs against ode
 238 AC_CHECK_LIB(stdc++,main,[LIBSTDCXX="-lstdc++"],[LIBSTDCXX=])
 239 AC_SUBST(LIBSTDCXX)
 240 AC_CHECK_LIB(pthread,main,[LIBS="$LIBS -lpthread"])
 241
 242
 243 dnl test if we will build demos
 244 AM_CONDITIONAL(ENABLE_DEMOS, test x$enable_demos = xyes)
 245
 246
 247 dnl Check if the user wants the old timesh collider
 248 old_trimesh=no
 249 AC_ARG_ENABLE([old-trimesh], AS_HELP_STRING([--enable-old-trimesh],[enable use of the old trimesh collider]),
 250         [old_trimesh=$enableval]
 251         )
 252 if test x$old_trimesh = xyes -a $trimesh = opcode; then
 253         AC_DEFINE(dTRIMESH_OPCODE_USE_OLD_TRIMESH_TRIMESH_COLLIDER, 1,
 254                 [Use the old trimesh-trimesh collider])
 255 else
 256         old_trimesh=no
 257 fi
 258
 259
 260 dnl Check if the user wants to profile ODE using gprof
 261 AC_MSG_CHECKING(for gprof)
 262 AC_ARG_ENABLE([gprof],
 263         AS_HELP_STRING([--enable-gprof],[enable profiling with gprof]),
 264         gprof=$enableval,
 265         gprof=no)
 266 if test "$gprof" != no
 267 then
 268     CFLAGS="-pg $CFLAGS"
 269     CXXFLAGS="-pg $CXXFLAGS"
 270     AC_MSG_RESULT(enabled)
 271     AC_CHECK_LIB(gmon, main,[LIBS="$LIBS -lgmon"])
 272 else
 273     AC_MSG_RESULT(no)
 274 fi
 275
 276 AC_ARG_ENABLE([sse2],
 277         AS_HELP_STRING([--disable-sse2],
 278             [disable generating SSE2 code on x86 in favor of FPU]
 279         ),
 280         sse2=$enableval,sse2=yes)
 281 fpuarch_flags=
 282 if test x$pentium = xyes -a x$cpu64 = xno
 283 then
 284     if test x$sse2 = xyes
 285     then
 286         fpuarch_flags="-mmmx -msse -msse2 -mfpmath=sse -mstackrealign"
 287     fi
 288 else
 289     sse2=
 290 fi
 291 CFLAGS="$fpuarch_flags $CFLAGS"
 292 CXXFLAGS="$fpuarch_flags $CXXFLAGS"
 293
 294 # Checks for typedefs, structures, and compiler characteristics.
 295 AC_HEADER_STDBOOL
 296 AC_C_INLINE
 297 AC_TYPE_INT32_T
 298 AC_FUNC_OBSTACK
 299 AC_TYPE_SIZE_T
 300 AC_TYPE_UINT32_T
 301
 302 dnl Check for autoscan sugested functions
 303 AC_CHECK_LIB(m, [main])
 304 AC_CHECK_LIB(sunmath, [main])
 305 AC_CHECK_LIB(rt, [main])
 306 AC_CHECK_FUNCS([atan2f clock_gettime copysign copysignf cosf fabsf floor fmodf gettimeofday isnan _isnan __isnan isnanf _isnanf __isnanf memmove memset pthread_attr_setstacklazy pthread_attr_setinheritsched pthread_condattr_setclock sinf snprintf sqrt sqrtf strchr strstr vsnprintf])
 307 AC_FUNC_ALLOCA
 308
 309 dnl This trick allows having additional define in case if a function is not found.
 310 dnl It fakes cached value for an inexistent function which is then used to fool function check to produce desired result.
 311 AC_CHECK_FUNC(pthread_condattr_setclock,,ac_cv_func_no_pthread_condattr_setclock=yes)
 312 AC_CHECK_FUNCS(no_pthread_condattr_setclock)
 313
 314
 315 AC_ARG_ENABLE([threading-intf],
 316         AS_HELP_STRING([--disable-threading-intf],
 317             [disable threading interface support (external implementations cannot be assigned)]
 318         ),
 319         threading_intf=$enableval,threading_intf=yes)
 320 AC_ARG_ENABLE([ou],
 321         AS_HELP_STRING([--enable-ou],
 322             [use TLS for global caches (allows threaded collision checks for isolated spaces)]
 323         ),
 324         use_ou_tls=$enableval,use_ou_tls=no)
 325 use_ou="no"
 326 if test x$use_ou_tls = xyes -o x$threading_intf = xyes
 327 then
 328     use_ou="yes"
 329 fi
 330
 331 OU_NAMESPACE=odeou
 332 AC_CONFIG_COMMANDS_POST([export OU_NAMESPACE=$OU_NAMESPACE])
 333 AC_DEFINE([_OU_NAMESPACE],[odeou],[libou namespace for ODE])
 334 AC_DEFINE([dOU_ENABLED],[1],[Generic OU features are enabled])
 335
 336 if test x$use_ou_tls = xyes
 337 then
 338     OU_FEATURE_SET=_OU_FEATURE_SET_TLS
 339     AC_DEFINE([_OU_FEATURE_SET],[_OU_FEATURE_SET_TLS],[OU features enabled])
 340 elif test x$use_ou = xyes
 341 then
 342     OU_FEATURE_SET=_OU_FEATURE_SET_ATOMICS
 343     AC_DEFINE([_OU_FEATURE_SET],[_OU_FEATURE_SET_ATOMICS],[OU features enabled])
 344 else
 345     OU_FEATURE_SET=_OU_FEATURE_SET_BASICS
 346     AC_DEFINE([_OU_FEATURE_SET],[_OU_FEATURE_SET_BASICS],[OU features enabled])
 347 fi
 348 AC_CONFIG_COMMANDS_POST([export OU_FEATURE_SET=$OU_FEATURE_SET])
 349
 350 if test x$use_ou = xyes
 351 then
 352     AC_DEFINE([dATOMICS_ENABLED],[1],[Atomic API of OU is enabled])
 353     if test x$use_ou_tls = xyes
 354     then
 355       AC_DEFINE([dTLS_ENABLED],[1],[Thread Local Storage API of OU is enabled])
 356     fi
 357 fi
 358
 359 case "$host_os" in
 360   cygwin* | mingw*)
 361     targetos=_OU_TARGET_OS_WINDOWS
 362     ;;
 363   *qnx*)
 364     targetos=_OU_TARGET_OS_QNX
 365     ;;
 366   *apple* | *darwin*)
 367     targetos=_OU_TARGET_OS_MAC
 368     ;;
 369   *sunos*)
 370     targetos=_OU_TARGET_OS_SUNOS
 371     ;;
 372   *aix*)
 373     targetos=_OU_TARGET_OS_AIX
 374     ;;
 375   *)
 376     targetos=_OU_TARGET_OS_GENUNIX
 377     ;;
 378 esac
 379
 380 if test $targetos = _OU_TARGET_OS_MAC
 381 then
 382     MAC_OS_X_VERSION=1000
 383     AC_CHECK_FUNC([OSAtomicAdd32Barrier], [MAC_OS_X_VERSION=1040])
 384     AC_CHECK_FUNC([OSAtomicAnd32OrigBarrier], [MAC_OS_X_VERSION=1050])
 385     AC_DEFINE_UNQUOTED(MAC_OS_X_VERSION, $MAC_OS_X_VERSION, [Mac OS X version setting for OU Library])
 386 fi
 387
 388 if test $targetos = _OU_TARGET_OS_SUNOS
 389 then
 390     AC_CHECK_FUNC(atomic_inc_32_nv, [],
 391         [targetos=_OU_TARGET_OS_GENUNIX])
 392 fi
 393
 394 AC_DEFINE_UNQUOTED(_OU_TARGET_OS, $targetos, [Target OS setting for OU Library])
 395
 396 AC_CONFIG_SUBDIRS([ou])
 397 AM_CONDITIONAL(ENABLE_OU, true)
 398
 399 if test x$threading_intf = xyes
 400 then
 401     AC_ARG_ENABLE([builtin-threading-impl],
 402         AS_HELP_STRING([--disable-builtin-threading-impl],
 403             [disable built-in multithreaded threading implementation]
 404         ),
 405         use_builtin_threading_impl=$enableval,use_builtin_threading_impl=yes)
 406     if test x$use_builtin_threading_impl = xyes
 407     then
 408         AC_DEFINE([dBUILTIN_THREADING_IMPL_ENABLED],[1],[Built-in multithreaded threading implementation is included])
 409     fi
 410 else
 411     AC_DEFINE([dTHREADING_INTF_DISABLED],[1],[Threading interface is disabled])
 412     use_builtin_threading_impl=no
 413 fi
 414
 415 col_cylinder_cylinder=none
 416 col_box_cylinder=default
 417 col_capsule_cylinder=none
 418 col_convex_box=none
 419 col_convex_capsule=none
 420 col_convex_cylinder=none
 421 col_convex_sphere=default
 422 col_convex_convex=default
 423
 424
 425 use_libccd=no
 426 libccd_all=no
 427 AC_ARG_ENABLE(libccd, AS_HELP_STRING([--enable-libccd],
 428             [enable all libccd colliders (except box-cylinder)]),
 429             libccd_all=$enableval)
 430 if test x$libccd_all = xyes
 431 then
 432     col_cylinder_cylinder=libccd
 433     col_capsule_cylinder=libccd
 434     col_convex_box=libccd
 435     col_convex_capsule=libccd
 436     col_convex_cylinder=libccd
 437     col_convex_sphere=libccd
 438     col_convex_convex=libccd
 439     use_libccd=yes
 440 fi
 441
 442
 443 AC_ARG_WITH([cylinder-cylinder], AS_HELP_STRING([--with-cylinder-cylinder=@<:@none,libccd@:>@], [use specific collider for cylinder-cylinder]),
 444             col_cylinder_cylinder=$withval)
 445
 446 AC_ARG_WITH([box-cylinder],
 447         AS_HELP_STRING([--with-box-cylinder=@<:@default,libccd@:>@], [use specific collider for box-cylinder]),
 448             col_box_cylinder=$withval)
 449
 450 AC_ARG_WITH([capsule-cylinder], AS_HELP_STRING([--with-capsule-cylinder=@<:@none,libccd@:>@], [use specific collider for capsule-cylinder]),
 451             col_capsule_cylinder=$withval)
 452
 453 AC_ARG_WITH([convex-box], AS_HELP_STRING([--with-convex-box=@<:@none,libccd@:>@], [use specific collider for convex-box]),
 454             col_convex_box=$withval)
 455
 456 AC_ARG_WITH([convex-capsule], AS_HELP_STRING([--with-convex-capsule=@<:@none,libccd@:>@], [use specific collider for convex-capsule]),
 457             col_convex_capsule=$withval)
 458
 459 AC_ARG_WITH([convex-cylinder], AS_HELP_STRING([--with-convex-cylinder=@<:@none,libccd@:>@], [use specific collider for convex-cylinder]),
 460             col_convex_cylinder=$withval)
 461
 462 AC_ARG_WITH([convex-sphere], AS_HELP_STRING([--with-convex-sphere=@<:@default,libccd@:>@], [use specific collider for convex-sphere]),
 463             col_convex_sphere=$withval)
 464
 465 AC_ARG_WITH([convex-convex], AS_HELP_STRING([--with-convex-convex=@<:@default,libccd@:>@], [use specific collider for convex-convex]),
 466             col_convex_convex=$withval)
 467
 468 if test x$col_cylinder_cylinder = xlibccd -o \
 469     x$col_box_cylinder = xlibccd -o \
 470     x$col_capsule_cylinder = xlibccd -o \
 471     x$col_convex_box = xlibccd -o \
 472     x$col_convex_capsule = libccd -o \
 473     x$col_convex_cylinder = xlibccd -o \
 474     x$col_convex_sphere = libccd -o \
 475     x$col_convex_convex = libccd
 476 then
 477     use_libccd=yes
 478 fi
 479
 480
 481 libccd_source=internal
 482
 483 AC_ARG_WITH(libccd,
 484         [AS_HELP_STRING([--with-libccd=@<:@internal|system@:>@],
 485                 [use the specified libccd @<:@default=system@:>@])],
 486         [libccd_source=$withval],
 487         [libccd_source=system])
 488
 489 if test x$use_libccd = xyes
 490 then
 491     if test x$libccd_source = xsystem
 492     then
 493         PKG_CHECK_MODULES(CCD, ccd, ,[libccd_source=internal])
 494     fi
 495 fi
 496
 497 CCD_FPUARCH_FLAGS="$fpuarch_flags"
 498 AC_CONFIG_COMMANDS_POST([export CCD_FPUARCH_FLAGS="$CCD_FPUARCH_FLAGS"])
 499
 500 # Configure libccd unconditionally as that may be needed for special make targets
 501 AC_CONFIG_SUBDIRS([libccd])
 502
 503 AM_CONDITIONAL(LIBCCD, test x$use_libccd != xno)
 504 AM_CONDITIONAL(LIBCCD_INTERNAL, test x$libccd_source = xinternal)
 505 AM_CONDITIONAL(LIBCCD_BOX_CYL,          test x$col_box_cylinder = xlibccd)
 506 AM_CONDITIONAL(LIBCCD_CYL_CYL,          test x$col_cylinder_cylinder = xlibccd)
 507 AM_CONDITIONAL(LIBCCD_CAP_CYL,          test x$col_capsule_cylinder = xlibccd)
 508 AM_CONDITIONAL(LIBCCD_CONVEX_BOX,       test x$col_convex_box = xlibccd)
 509 AM_CONDITIONAL(LIBCCD_CONVEX_CAP,       test x$col_convex_capsule = xlibccd)
 510 AM_CONDITIONAL(LIBCCD_CONVEX_CYL,       test x$col_convex_cylinder = xlibccd)
 511 AM_CONDITIONAL(LIBCCD_CONVEX_SPHERE,    test x$col_convex_sphere = xlibccd)
 512 AM_CONDITIONAL(LIBCCD_CONVEX_CONVEX,    test x$col_convex_convex = xlibccd)
 513
 514
 515
 516 AC_ARG_ENABLE([asserts],
 517         AS_HELP_STRING([--disable-asserts],
 518             [disables debug error checking]),
 519         asserts=$enableval,asserts=yes)
 520 if test x$asserts = xno
 521 then
 522     CPPFLAGS="$CPPFLAGS -DdNODEBUG -DNDEBUG"
 523 fi
 524
 525
 526 dnl include found system headers into config.h
 527 AH_TOP([
 528 #ifndef ODE_CONFIG_H
 529 #define ODE_CONFIG_H
 530 ])
 531 AH_BOTTOM([
 532
 533 #ifdef HAVE_ALLOCA_H
 534 #include <alloca.h>
 535 #endif
 536 #ifdef HAVE_MALLOC_H
 537 #include <malloc.h>
 538 #endif
 539 #ifdef HAVE_STDINT_H
 540 #include <stdint.h>
 541 #endif
 542 #ifdef HAVE_INTTYPES_H
 543 #include <inttypes.h>
 544 #endif
 545
 546
 547 #include "typedefs.h"
 548
 549
 550 #endif /* #define ODE_CONFIG_H */
 551 ])
 552
 553 dnl Finally write our Makefiles
 554 AC_CONFIG_FILES([
 555  Makefile
 556  drawstuff/Makefile
 557  drawstuff/src/Makefile
 558  drawstuff/dstest/Makefile
 559  include/Makefile
 560  include/drawstuff/Makefile
 561  include/ode/Makefile
 562  include/ode/version.h
 563  include/ode/precision.h
 564  ode/Makefile
 565  ode/doc/Doxyfile
 566  ode/doc/Makefile
 567  ode/src/Makefile
 568  ode/src/joints/Makefile
 569  ode/demo/Makefile
 570  OPCODE/Makefile
 571  OPCODE/Ice/Makefile
 572  GIMPACT/Makefile
 573  GIMPACT/include/Makefile
 574  GIMPACT/include/GIMPACT/Makefile
 575  GIMPACT/src/Makefile
 576  tests/Makefile
 577  tests/joints/Makefile
 578  tests/UnitTest++/Makefile
 579  tests/UnitTest++/src/Makefile
 580  tests/UnitTest++/src/Posix/Makefile
 581  tests/UnitTest++/src/Win32/Makefile
 582  ode-config
 583  ode.pc
 584  ])
 585 AC_OUTPUT
 586
 587 chmod +x ode-config
 588
 589 BUILDDIR=`pwd`
 590
 591 dnl Print some useful information
 592 echo "Configuration:"
 593 echo "  Build  system type:      $build"
 594 echo "  Host   system type:      $host"
 595 echo "  Use double precision:    $usedouble"
 596 echo "  Use drawstuff:           $drawstuff"
 597 echo "  Demos enabled:           $enable_demos"
 598 echo "  Use OPCODE:              $opcode"
 599 echo "  Use GIMPACT:             $gimpact"
 600 echo "  Use libccd:              $use_libccd"
 601
 602 if test x$use_libccd = xyes
 603 then
 604 echo "  libccd source:           $libccd_source"
 605 fi
 606
 607 echo "  Custom colliders:"
 608 echo "        cylinder-cylinder: $col_cylinder_cylinder"
 609 echo "        box-cylinder:      $col_box_cylinder"
 610 echo "        capsule-cylinder:  $col_capsule_cylinder"
 611 echo "        convex-box:        $col_convex_box"
 612 echo "        convex-capsule:    $col_convex_capsule"
 613 echo "        convex-cylinder:   $col_convex_cylinder"
 614 echo "        convex-sphere:     $col_convex_sphere"
 615 echo "        convex-convex:     $col_convex_convex"
 616 echo "  Is target a Pentium:     $pentium"
 617 echo "  Is target x86-64:        $cpu64"
 618 if test x$sse2 != x
 619 then
 620 echo "  Is SSE2 code generated:  $sse2"
 621 fi
 622 echo "  Use old opcode trimesh collider: $old_trimesh"
 623 echo "  TLS for global caches:   $use_ou_tls"
 624 echo "  Threading intf enabled:  $threading_intf"
 625 echo "  Built-in threading included: $use_builtin_threading_impl"
 626 echo "  Enable debug error check: $asserts"
 627 echo "  Headers will be installed in $includedir/ode"
 628 echo "  Libraries will be installed in $libdir"
 629 echo "  Building in directory    $BUILDDIR"
 630