libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_INIT([GNU Offloading and Multi Processing Runtime Library], 1.0,,[libgomp])
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # -------
   8 # Options
   9 # -------
  10
  11 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  12 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  13    [Specify that runtime libraries should be installed in a compiler-specific directory],
  14    permit yes|no)
  15 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  16
  17 # We would like our source tree to be readonly. However when releases or
  18 # pre-releases are generated, the flex/bison generated files as well as the
  19 # various formats of manuals need to be included along with the rest of the
  20 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  21 # just that.
  22 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  23 LIBGOMP_ENABLE(generated-files-in-srcdir, no, ,
  24    [put copies of generated files in source dir intended for creating source
  25     tarballs for users without texinfo bison or flex.],
  26    permit yes|no)
  27 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  28 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  29
  30
  31 # -------
  32 # -------
  33
  34 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  35 #
  36 # You will slowly go insane if you do not grok the following fact:  when
  37 # building this library, the top-level /target/ becomes the library's /host/.
  38 #
  39 # configure then causes --target to default to --host, exactly like any
  40 # other package using autoconf.  Therefore, 'target' and 'host' will
  41 # always be the same.  This makes sense both for native and cross compilers
  42 # just think about it for a little while.  :-)
  43 #
  44 # Also, if this library is being configured as part of a cross compiler, the
  45 # top-level configure script will pass the "real" host as $with_cross_host.
  46 #
  47 # Do not delete or change the following two lines.  For why, see
  48 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  49 AC_CANONICAL_SYSTEM
  50 target_alias=${target_alias-$host_alias}
  51
  52 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  53 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  54 #  1.9.0:  minimum required version
  55 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  56 #              of other PACKAGE_* variables will, however, and there's nothing
  57 #              we can do about that; they come from AC_INIT).
  58 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  59 #            file in the top srcdir, etc, etc), so stop complaining.
  60 #  no-dist:  we don't want 'dist' and related rules.
  61 #  -Wall:  turns on all automake warnings...
  62 #  -Wno-portability:  ...except this one, since GNU make is required.
  63 #  -Wno-override: ... and this one, since we do want this in testsuite.
  64 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  65 AM_ENABLE_MULTILIB(, ..)
  66
  67 GCC_WITH_TOOLEXECLIBDIR
  68
  69 # Calculate toolexeclibdir
  70 # Also toolexecdir, though it's only used in toolexeclibdir
  71 case ${enable_version_specific_runtime_libs} in
  72   yes)
  73     # Need the gcc compiler version to know where to install libraries
  74     # and header files if --enable-version-specific-runtime-libs option
  75     # is selected.
  76     toolexecdir='$(libdir)/gcc/$(target_alias)'
  77     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  78     ;;
  79   no)
  80     if test -n "$with_cross_host" &&
  81        test x"$with_cross_host" != x"no"; then
  82       # Install a library built with a cross compiler in tooldir, not libdir.
  83       toolexecdir='$(exec_prefix)/$(target_alias)'
  84       case ${with_toolexeclibdir} in
  85         no)
  86           toolexeclibdir='$(toolexecdir)/lib'
  87           ;;
  88         *)
  89           toolexeclibdir=${with_toolexeclibdir}
  90           ;;
  91       esac
  92     else
  93       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  94       toolexeclibdir='$(libdir)'
  95     fi
  96     multi_os_directory=`$CC -print-multi-os-directory`
  97     case $multi_os_directory in
  98       .) ;; # Avoid trailing /.
  99       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 100     esac
 101     ;;
 102 esac
 103 AC_SUBST(toolexecdir)
 104 AC_SUBST(toolexeclibdir)
 105
 106 # Check the compiler.
 107 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 108 # We must force CC to /not/ be precious variables; otherwise
 109 # the wrong, non-multilib-adjusted value will be used in multilibs.
 110 # As a side effect, we have to subst CFLAGS ourselves.
 111
 112 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 113 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 114 AC_PROG_CC
 115 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 116
 117 AC_SUBST(CFLAGS)
 118
 119 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 120 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 121 # in both places for now and restore CFLAGS at the end of config.
 122 save_CFLAGS="$CFLAGS"
 123
 124 AC_ARG_ENABLE([werror],
 125   [AS_HELP_STRING([--disable-werror], [disable building with -Werror])])
 126 # Add -Wall -Werror if we are using GCC.
 127 AS_IF([test "x$GCC" = "xyes"],
 128   [XCFLAGS="$XCFLAGS -Wall"])
 129 AS_IF([test "x$enable_werror" != "xno" && test "x$GCC" = "xyes"],
 130   [XCFLAGS="$XCFLAGS -Werror"])
 131
 132 # Find other programs we need.
 133 AC_CHECK_TOOL(AR, ar)
 134 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 135 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 136 AC_PROG_MAKE_SET
 137 AC_PROG_INSTALL
 138
 139 # See if makeinfo has been installed and is modern enough
 140 # that we can use it.
 141 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 142                    [GNU texinfo.* \([0-9][0-9.]*\)],
 143                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 144 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 145
 146
 147 # Configure libtool
 148 AM_PROG_LIBTOOL
 149 ACX_LT_HOST_FLAGS
 150 AC_SUBST(enable_shared)
 151 AC_SUBST(enable_static)
 152
 153 AM_MAINTAINER_MODE
 154
 155 # We optionally test libgomp C++ support, and for that want to use the proper
 156 # C++ driver, 'g++' (or 'xg++' for build-tree testing).  Given that build of
 157 # target libstdc++-v3 depends on target libgomp (see '../Makefile.def'), we
 158 # cannot make build of target libgomp depend on target libstdc++-v3: circular
 159 # dependency.  We thus cannot instantiate 'AC_PROG_CXX' here: we'd get
 160 # '-funconfigured-libstdc++-v3' (see '../configure.ac').  Therefore, just
 161 # capture 'CXX', and we'll fix this up at 'make check' time (see
 162 # 'testsuite/lib/libgomp.exp:libgomp_init').
 163 AC_SUBST(CXX)
 164
 165 # Create a spec file, so that compile/link tests don't fail
 166 test -f libgfortran.spec || touch libgfortran.spec
 167 FCFLAGS="$FCFLAGS -L."
 168
 169 # We need 'gfortran' to compile parts of the library, and test libgomp Fortran
 170 # support.
 171 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 172 #AC_PROG_FC(gfortran)
 173 case `echo $GFORTRAN` in
 174   -* | no* )
 175     FC=no ;;
 176   *)
 177     set dummy $GFORTRAN; ac_word=$2
 178     if test -x "$ac_word"; then
 179       FC="$GFORTRAN"
 180     else
 181       FC=no
 182     fi ;;
 183 esac
 184 AC_PROG_FC(gfortran)
 185 FCFLAGS="$FCFLAGS -Wall -L../libgfortran"
 186
 187 # For libtool versioning info, format is CURRENT:REVISION:AGE
 188 libtool_VERSION=1:0:0
 189 AC_SUBST(libtool_VERSION)
 190
 191 # Check header files.
 192 AC_STDC_HEADERS
 193 AC_HEADER_TIME
 194 ACX_HEADER_STRING
 195 AC_CHECK_HEADERS(pthread.h unistd.h semaphore.h sys/loadavg.h sys/sysctl.h sys/time.h)
 196
 197 XPCFLAGS=""
 198 case "$host" in
 199   *-*-rtems*)
 200     # RTEMS supports Pthreads, but the library is not available at GCC build time.
 201     ;;
 202   nvptx*-*-* | amdgcn*-*-*)
 203     # NVPTX does not support Pthreads, has its own code replacement.
 204     libgomp_use_pthreads=no
 205     # NVPTX is an accelerator-only target
 206     libgomp_offloaded_only=yes
 207     ;;
 208   *)
 209     # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 210     # In case the pthread.h system header is not found, this test will fail.
 211     CFLAGS="$CFLAGS -pthread"
 212     AC_LINK_IFELSE(
 213      [AC_LANG_PROGRAM(
 214       [#include <pthread.h>
 215        void *g(void *d) { return NULL; }],
 216       [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 217      [XPCFLAGS=" -Wc,-pthread"],
 218      [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 219       AC_LINK_IFELSE(
 220        [AC_LANG_PROGRAM(
 221         [#include <pthread.h>
 222          void *g(void *d) { return NULL; }],
 223         [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 224        [],
 225        [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 226 esac
 227
 228 if test x$libgomp_use_pthreads != xno; then
 229   AC_DEFINE(LIBGOMP_USE_PTHREADS, 1,
 230             [Define to 1 if libgomp should use POSIX threads.])
 231 fi
 232
 233 if test x$libgomp_offloaded_only = xyes; then
 234   AC_DEFINE(LIBGOMP_OFFLOADED_ONLY, 1,
 235             [Define to 1 if building libgomp for an accelerator-only target.])
 236 fi
 237
 238 if test "x$enable_offload_defaulted" = xyes; then
 239   AC_DEFINE(OFFLOAD_DEFAULTED, 1,
 240     [Define to 1 to if -foffload is defaulted])
 241 fi
 242
 243 AC_CHECK_SIZEOF([void *])
 244
 245 m4_include([plugin/configfrag.ac])
 246
 247 # Check for functions needed.
 248 AC_CHECK_FUNCS(getloadavg clock_gettime strtoull)
 249 AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 250
 251 # Check for broken semaphore implementation on darwin.
 252 # sem_init returns: sem_init error: Function not implemented.
 253 case "$host" in
 254   *-darwin*)
 255     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 256         Define if the POSIX Semaphores do not work on your system.)
 257     ;;
 258 esac
 259
 260 # RTEMS specific checks
 261 case "$host" in
 262   *-*-rtems*)
 263     AC_CHECK_TYPES([struct _Mutex_Control],[],[],[#include <sys/lock.h>])
 264     ;;
 265 esac
 266
 267 GCC_LINUX_FUTEX(:)
 268
 269 # Check for pthread_{,attr_}[sg]etaffinity_np.
 270 AC_LINK_IFELSE(
 271  [AC_LANG_PROGRAM(
 272   [#define _GNU_SOURCE
 273    #include <pthread.h>],
 274   [cpu_set_t cpuset;
 275    pthread_attr_t attr;
 276    pthread_getaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 277    if (CPU_ISSET (0, &cpuset))
 278      CPU_SET (1, &cpuset);
 279    else
 280      CPU_ZERO (&cpuset);
 281    pthread_setaffinity_np (pthread_self (), sizeof (cpu_set_t), &cpuset);
 282    pthread_attr_init (&attr);
 283    pthread_attr_getaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);
 284    pthread_attr_setaffinity_np (&attr, sizeof (cpu_set_t), &cpuset);])],
 285   AC_DEFINE(HAVE_PTHREAD_AFFINITY_NP, 1,
 286 [       Define if pthread_{,attr_}{g,s}etaffinity_np is supported.]))
 287
 288 # At least for glibc, clock_gettime is in librt.  But don't pull that
 289 # in if it still doesn't give us the function we want.
 290 if test $ac_cv_func_clock_gettime = no; then
 291   AC_CHECK_LIB(rt, clock_gettime,
 292     [LIBS="-lrt $LIBS"
 293      AC_DEFINE(HAVE_CLOCK_GETTIME, 1,
 294                [Define to 1 if you have the `clock_gettime' function.])])
 295 fi
 296
 297 # Check for uname.
 298 AC_COMPILE_IFELSE(
 299  [AC_LANG_PROGRAM(
 300   [#include <string.h>
 301    #include <stdlib.h>
 302    #include <sys/utsname.h>],
 303   [struct utsname buf;
 304    volatile size_t len = 0;
 305    if (!uname (buf))
 306      len = strlen (buf.nodename);])],
 307   AC_DEFINE(HAVE_UNAME, 1,
 308 [       Define if uname is supported and struct utsname has nodename field.]))
 309
 310 # Check for gethostname.
 311 AC_COMPILE_IFELSE(
 312  [AC_LANG_PROGRAM(
 313   [#include <unistd.h>],
 314   [
 315 changequote(,)dnl
 316    char buf[256];
 317    if (gethostname (buf, sizeof (buf) - 1) == 0)
 318      buf[255] = '\0';
 319 changequote([,])dnl
 320   ])],
 321   AC_DEFINE(HAVE_GETHOSTNAME, 1,
 322 [       Define if gethostname is supported.]))
 323
 324 # Check for getpid.
 325 AC_COMPILE_IFELSE(
 326  [AC_LANG_PROGRAM(
 327   [#include <unistd.h>],
 328   [int pid = getpid ();])],
 329   AC_DEFINE(HAVE_GETPID, 1,
 330 [       Define if getpid is supported.]))
 331
 332 # See if we support thread-local storage.
 333 GCC_CHECK_TLS
 334
 335 # See if we have emulated thread-local storage.
 336 GCC_CHECK_EMUTLS
 337
 338 # See what sort of export controls are available.
 339 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 340 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 341 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 342 LIBGOMP_ENABLE_SYMVERS
 343
 344 if test $enable_symvers = gnu; then
 345   AC_DEFINE(LIBGOMP_GNU_SYMBOL_VERSIONING, 1,
 346             [Define to 1 if GNU symbol versioning is used for libgomp.])
 347 fi
 348
 349 # Determine cpu count to limit testsuite parallelism.
 350 AX_COUNT_CPUS
 351 AC_SUBST(CPU_COUNT)
 352
 353 AC_CHECK_PROGS(FLOCK, flock)
 354
 355 # Get target configury.
 356 . ${srcdir}/configure.tgt
 357 CFLAGS="$save_CFLAGS $XCFLAGS"
 358
 359 # Check for __sync_val_compare_and_swap, but only after the target has
 360 # had a chance to set XCFLAGS.
 361 LIBGOMP_CHECK_SYNC_BUILTINS
 362
 363 XCFLAGS="$XCFLAGS$XPCFLAGS"
 364
 365 # Add CET specific flags if CET is enabled
 366 GCC_CET_FLAGS(CET_FLAGS)
 367 XCFLAGS="$XCFLAGS $CET_FLAGS"
 368 FCFLAGS="$FCFLAGS $CET_FLAGS"
 369
 370 AC_SUBST(config_path)
 371 AC_SUBST(XCFLAGS)
 372 AC_SUBST(XLDFLAGS)
 373
 374 # Conditionalize the makefile for this target machine.
 375 tmake_file_=
 376 for f in ${tmake_file}
 377 do
 378         if test -f ${srcdir}/config/$f
 379         then
 380                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 381         fi
 382 done
 383 tmake_file="${tmake_file_}"
 384 AC_SUBST(tmake_file)
 385
 386 # Cleanup and exit.
 387 CFLAGS="$save_CFLAGS"
 388 AC_CACHE_SAVE
 389
 390 if test ${multilib} = yes; then
 391   multilib_arg="--enable-multilib"
 392 else
 393   multilib_arg=
 394 fi
 395
 396 # Set up the set of libraries that we need to link against for libgomp.
 397 # Note that the GOMP_SELF_SPEC in gcc.c may force -pthread,
 398 # which will force linkage against -lpthread (or equivalent for the system).
 399 # That's not 100% ideal, but about the best we can do easily.
 400 if test $enable_shared = yes; then
 401   link_gomp="-lgomp %{static: $LIBS}"
 402 else
 403   link_gomp="-lgomp $LIBS"
 404 fi
 405 AC_SUBST(link_gomp)
 406
 407 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 408
 409 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 410 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 411 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 412 # need to copy this macro to our acinclude.m4.
 413 save_CFLAGS="$CFLAGS"
 414 for i in $config_path; do
 415   if test -f $srcdir/config/$i/omp-lock.h; then
 416     CFLAGS="$CFLAGS -include confdefs.h -include $srcdir/config/$i/omp-lock.h"
 417     break
 418   fi
 419 done
 420
 421 _AC_COMPUTE_INT([sizeof (__INTPTR_TYPE__)], [INTPTR_T_KIND])
 422 _AC_COMPUTE_INT([sizeof (__int128)], [OMP_INT128_SIZE],,[OMP_INT128_SIZE=0])
 423 _AC_COMPUTE_INT([2*sizeof (__INTPTR_TYPE__)], [OMP_DEPEND_KIND],,
 424                 [OMP_DEPEND_KIND=0])
 425 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 426   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 427 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 428 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 429 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 430 _AC_COMPUTE_INT([sizeof (omp_lock_25_t)], [OMP_LOCK_25_SIZE],,
 431   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_25_t)])])
 432 _AC_COMPUTE_INT([__alignof (omp_lock_25_t)], [OMP_LOCK_25_ALIGN])
 433 _AC_COMPUTE_INT([sizeof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_SIZE])
 434 _AC_COMPUTE_INT([__alignof (omp_nest_lock_25_t)], [OMP_NEST_LOCK_25_ALIGN])
 435
 436 # If the lock fits in an integer, then arrange for Fortran to use that
 437 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 438 # Except that we don't have a way at present to multi-lib the installed
 439 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 440 # actual target.
 441 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 442 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 443 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 444   OMP_LOCK_KIND=8
 445 fi
 446 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 447   OMP_NEST_LOCK_KIND=8
 448 fi
 449 OMP_LOCK_25_KIND=$OMP_LOCK_25_SIZE
 450 OMP_NEST_LOCK_25_KIND=$OMP_NEST_LOCK_25_SIZE
 451 if test $OMP_LOCK_25_SIZE -gt 8 || test $OMP_LOCK_25_ALIGN -gt $OMP_LOCK_25_SIZE; then
 452   OMP_LOCK_25_KIND=8
 453 fi
 454 if test $OMP_NEST_LOCK_25_SIZE -gt 8 || test $OMP_NEST_LOCK_25_ALIGN -gt $OMP_NEST_LOCK_25_SIZE; then
 455   OMP_NEST_LOCK_25_KIND=8
 456 fi
 457 if test "$ac_cv_fc_compiler_gnu" = yes; then
 458   if test $OMP_DEPEND_KIND -eq 16; then
 459     if test $OMP_INT128_SIZE -ne 16; then
 460       AC_MSG_ERROR([unsupported system, cannot find Fortran int kind=16, needed for omp_depend_kind])
 461     fi
 462   else
 463     if test $OMP_DEPEND_KIND -ne 8; then
 464       AC_MSG_ERROR([unsupported system, cannot find Fortran integer kind for omp_depend_kind])
 465     fi
 466   fi
 467 fi
 468
 469 AC_SUBST(INTPTR_T_KIND)
 470 AC_SUBST(OMP_LOCK_SIZE)
 471 AC_SUBST(OMP_LOCK_ALIGN)
 472 AC_SUBST(OMP_NEST_LOCK_SIZE)
 473 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 474 AC_SUBST(OMP_LOCK_KIND)
 475 AC_SUBST(OMP_NEST_LOCK_KIND)
 476 AC_SUBST(OMP_LOCK_25_SIZE)
 477 AC_SUBST(OMP_LOCK_25_ALIGN)
 478 AC_SUBST(OMP_NEST_LOCK_25_SIZE)
 479 AC_SUBST(OMP_NEST_LOCK_25_ALIGN)
 480 AC_SUBST(OMP_LOCK_25_KIND)
 481 AC_SUBST(OMP_NEST_LOCK_25_KIND)
 482 AC_SUBST(OMP_DEPEND_KIND)
 483 CFLAGS="$save_CFLAGS"
 484
 485 # Determine what GCC version number to use in filesystem paths.
 486 GCC_BASE_VER
 487
 488 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 489 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 490 AC_CONFIG_FILES([testsuite/libgomp-test-support.pt.exp:testsuite/libgomp-test-support.exp.in])
 491 AC_CONFIG_FILES([testsuite/libgomp-site-extra.exp])
 492 AC_OUTPUT