components/openindiana/illumos-gate/overlay/etc/.login

   1 # CDDL HEADER START
   2 #
   3 # The contents of this file are subject to the terms of the
   4 # Common Development and Distribution License, Version 1.0 only
   5 # (the "License").  You may not use this file except in compliance
   6 # with the License.
   7 #
   8 # You can obtain a copy of the license at usr/src/OPENSOLARIS.LICENSE
   9 # or http://www.opensolaris.org/os/licensing.
  10 # See the License for the specific language governing permissions
  11 # and limitations under the License.
  12 #
  13 # When distributing Covered Code, include this CDDL HEADER in each
  14 # file and include the License file at usr/src/OPENSOLARIS.LICENSE.
  15 # If applicable, add the following below this CDDL HEADER, with the
  16 # fields enclosed by brackets "[]" replaced with your own identifying
  17 # information: Portions Copyright [yyyy] [name of copyright owner]
  18 #
  19 # CDDL HEADER END
  20 #
  21 # Copyright 1998 Sun Microsystems, Inc.  All rights reserved.
  22 # Use is subject to license terms.
  23 # Copyright 2015 Nexenta Systems, Inc. All rights reserved.
  24
  25 # The initial machine wide defaults for csh.
  26
  27 if ( $?TERM == 0 ) then
  28         if ( `uname -p` == "i386" ) then
  29                 setenv TERM sun-color
  30         else
  31                 setenv TERM sun
  32         endif
  33 else
  34         if ( $TERM == "" ) then
  35                 if ( `uname -p` == "i386" ) then
  36                         setenv TERM sun-color
  37                 else
  38                         setenv TERM sun
  39                 endif
  40         endif
  41 endif
  42
  43 #
  44 # use less(1) as the default pager for the man(1) command.
  45 #
  46 setenv PAGER "/usr/bin/less -ins"
  47
  48 if (! -e .hushlogin ) then
  49         /usr/sbin/quota
  50         /bin/cat -s /etc/motd
  51         /bin/mail -E
  52         switch ( $status )
  53         case 0:
  54                 echo "You have new mail."
  55                 breaksw;
  56         case 2:
  57                 echo "You have mail."
  58                 breaksw;
  59         endsw
  60 endif
  61
  62 if ( -d /etc/profile.d && ! -f "${HOME}/.limited_profile" ) then
  63         if ($?nonomatch) then
  64                 set old=$nonomatch
  65         else
  66                 unset old
  67         endif
  68         set nonomatch=1
  69         foreach file ( /etc/profile.d/*.csh )
  70                 if ( "$file" == "/etc/profile.d/*.csh" ) then
  71                         break
  72                 endif
  73                 if ( -f "$file" && -r "$file" ) then
  74                         source "$file"
  75                 endif
  76         end
  77         if ($?old) then
  78                 set nonomatch="$old"
  79                 unset old
  80         else
  81                 unset nonomatch
  82         endif
  83         unset file
  84 endif