solenv/bin/modules/installer/windows/registry.pm

   1 #*************************************************************************
   2 #
   3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4 #
   5 # Copyright 2008 by Sun Microsystems, Inc.
   6 #
   7 # OpenOffice.org - a multi-platform office productivity suite
   8 #
   9 # $RCSfile: registry.pm,v $
  10 #
  11 # $Revision: 1.18 $
  12 #
  13 # This file is part of OpenOffice.org.
  14 #
  15 # OpenOffice.org is free software: you can redistribute it and/or modify
  16 # it under the terms of the GNU Lesser General Public License version 3
  17 # only, as published by the Free Software Foundation.
  18 #
  19 # OpenOffice.org is distributed in the hope that it will be useful,
  20 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  21 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  22 # GNU Lesser General Public License version 3 for more details
  23 # (a copy is included in the LICENSE file that accompanied this code).
  24 #
  25 # You should have received a copy of the GNU Lesser General Public License
  26 # version 3 along with OpenOffice.org.  If not, see
  27 # <http://www.openoffice.org/license.html>
  28 # for a copy of the LGPLv3 License.
  29 #
  30 #*************************************************************************
  31
  32 package installer::windows::registry;
  33
  34 use installer::files;
  35 use installer::globals;
  36 use installer::worker;
  37 use installer::windows::idtglobal;
  38
  39 #####################################################
  40 # Generating the component name from a registryitem
  41 #####################################################
  42
  43 sub get_registry_component_name
  44 {
  45     my ($registryref, $allvariables) = @_;
  46
  47     # In this function exists the rule to create components from registryitems
  48     # Rule:
  49     # The componentname can be directly taken from the ModuleID.
  50     # All registryitems belonging to one module can get the same component.
  51
  52     my $componentname = "";
  53     my $isrootmodule = 0;
  54
  55     if ( $registryref->{'ModuleID'} ) { $componentname = $registryref->{'ModuleID'}; }
  56
  57     $componentname =~ s/\\/\_/g;
  58     $componentname =~ s/\//\_/g;
  59     $componentname =~ s/\-/\_/g;
  60     $componentname =~ s/\_\s*$//g;
  61
  62     $componentname = lc($componentname);        # componentnames always lowercase
  63
  64     if ( $componentname eq "gid_module_root" ) { $isrootmodule = 1; }
  65
  66     # Attention: Maximum length for the componentname is 72
  67
  68     $componentname =~ s/gid_module_/g_m_/g;
  69     $componentname =~ s/_optional_/_o_/g;
  70     $componentname =~ s/_javafilter_/_jf_/g;
  71
  72     $componentname = $componentname . "_registry";      # identifying this component as registryitem component
  73
  74     # This componentname must be more specific
  75     my $addon = "_";
  76     if ( $allvariables->{'PRODUCTNAME'} ) { $addon = $addon . $allvariables->{'PRODUCTNAME'}; }
  77     if ( $allvariables->{'PRODUCTVERSION'} ) { $addon = $addon . $allvariables->{'PRODUCTVERSION'}; }
  78     $addon = lc($addon);
  79     $addon =~ s/ //g;
  80     $addon =~ s/-//g;
  81     $addon =~ s/\.//g;
  82
  83     my $styles = "";
  84     if ( $registryref->{'Styles'} ) { $styles = $registryref->{'Styles'}; }
  85
  86     # Layer links must have unique Component GUID for all products. This is necessary, because only the
  87     # uninstallation of the last product has to delete registry keys.
  88     if ( $styles =~ /\bLAYER_REGISTRY\b/ )
  89     {
  90         $componentname = "g_m_root_registry_layer_ooo_reglayer";
  91         # Styles USE_URELAYERVERSION, USE_OOOBASEVERSION
  92         if ( $styles =~ /\bUSE_URELAYERVERSION\b/ ) { $addon = "_ure_" . $allvariables->{'URELAYERVERSION'}; }
  93         if ( $styles =~ /\bUSE_OOOBASEVERSION\b/ ) { $addon = "_basis_" . $allvariables->{'OOOBASEVERSION'}; }
  94         $addon =~ s/\.//g;
  95     }
  96
  97     $componentname = $componentname . $addon;
  98
  99     if (( $styles =~ /\bLANGUAGEPACK\b/ ) && ( $installer::globals::languagepack )) { $componentname = $componentname . "_lang"; }
 100     if ( $styles =~ /\bALWAYS_REQUIRED\b/ ) { $componentname = $componentname . "_forced"; }
 101
 102     if ( $isrootmodule ) { $installer::globals::registryrootcomponent = $componentname; }
 103
 104     return $componentname;
 105 }
 106
 107 ##############################################################
 108 # Returning identifier for registry table.
 109 ##############################################################
 110
 111 sub get_registry_identifier
 112 {
 113     my ($registry) = @_;
 114
 115     my $identifier = "";
 116
 117     if ( $registry->{'gid'} ) { $identifier = $registry->{'gid'}; }
 118
 119     $identifier = lc($identifier);      # always lower case
 120
 121     # Attention: Maximum length is 72
 122
 123     $identifier =~ s/gid_regitem_/g_r_/;
 124     $identifier =~ s/_soffice_/_s_/;
 125     $identifier =~ s/_clsid_/_c_/;
 126     $identifier =~ s/_currentversion_/_cv_/;
 127     $identifier =~ s/_microsoft_/_ms_/;
 128     $identifier =~ s/_staroffice_/_so_/;
 129     $identifier =~ s/_classpath_/_cp_/;
 130     $identifier =~ s/__/_/g;
 131
 132     # Saving this in the registry collector
 133
 134     $registry->{'uniquename'} = $identifier;
 135
 136     return $identifier;
 137 }
 138
 139 ##################################################################
 140 # Returning root value for registry table.
 141 ##################################################################
 142
 143 sub get_registry_root
 144 {
 145     my ($registry) = @_;
 146
 147     my $rootvalue = 0;  # Default: Parent is KKEY_CLASSES_ROOT
 148     my $scproot = "";
 149
 150     if ( $registry->{'ParentID'} ) { $scproot = $registry->{'ParentID'}; }
 151
 152     if ( $scproot eq "PREDEFINED_HKEY_LOCAL_MACHINE" ) { $rootvalue = -1; }
 153
 154     if ( $scproot eq "PREDEFINED_HKEY_CLASSES_ROOT" ) { $rootvalue = 0; }
 155
 156     if ( $scproot eq "PREDEFINED_HKEY_CURRENT_USER_ONLY" ) { $rootvalue = 1; }
 157
 158     if ( $scproot eq "PREDEFINED_HKEY_LOCAL_MACHINE_ONLY" ) { $rootvalue = 2; }
 159
 160     return $rootvalue;
 161 }
 162
 163 ##############################################################
 164 # Returning key for registry table.
 165 ##############################################################
 166
 167 sub get_registry_key
 168 {
 169     my ($registry, $allvariableshashref) = @_;
 170
 171     my $key = "";
 172
 173     if ( $registry->{'Subkey'} ) { $key = $registry->{'Subkey'}; }
 174
 175     if ( $key =~ /\%/ ) { $key = installer::worker::replace_variables_in_string($key, $allvariableshashref); }
 176
 177     return $key;
 178 }
 179
 180 ##############################################################
 181 # Returning name for registry table.
 182 ##############################################################
 183
 184 sub get_registry_name
 185 {
 186     my ($registry, $allvariableshashref) = @_;
 187
 188     my $name = "";
 189
 190     if ( $registry->{'Name'} ) { $name = $registry->{'Name'}; }
 191
 192     if ( $name =~ /\%/ ) { $name = installer::worker::replace_variables_in_string($name, $allvariableshashref); }
 193
 194     return $name;
 195 }
 196
 197 ##############################################################
 198 # Returning value for registry table.
 199 ##############################################################
 200
 201 sub get_registry_value
 202 {
 203     my ($registry, $allvariableshashref) = @_;
 204
 205     my $value = "";
 206
 207     if ( $registry->{'Value'} ) { $value = $registry->{'Value'}; }
 208
 209     $value =~ s/\\\"/\"/g;      # no more masquerading of '"'
 210     $value =~ s/\<progpath\>/\[OFFICEINSTALLLOCATION\]/;
 211     $value =~ s/\[OFFICEINSTALLLOCATION\]\\/\[OFFICEINSTALLLOCATION\]/; # removing "\" after "[OFFICEINSTALLLOCATION]"
 212
 213     if ( $value =~ /\%/ ) { $value = installer::worker::replace_variables_in_string($value, $allvariableshashref); }
 214
 215     return $value;
 216 }
 217
 218 ##############################################################
 219 # Returning component for registry table.
 220 ##############################################################
 221
 222 sub get_registry_component
 223 {
 224     my ($registry, $allvariables) = @_;
 225
 226     # All registry items belonging to one module can
 227     # be included into one component
 228
 229     my $componentname = get_registry_component_name($registry, $allvariables);
 230
 231     # saving componentname in the registryitem collector
 232
 233     $registry->{'componentname'} = $componentname;
 234
 235     return $componentname;
 236 }
 237
 238 ######################################################
 239 # Adding the content of
 240 # @installer::globals::userregistrycollector
 241 # to the registry table. The content was collected
 242 # in create_files_table() in file.pm.
 243 ######################################################
 244
 245 sub add_userregs_to_registry_table
 246 {
 247     my ( $registrytable, $allvariables ) = @_;
 248
 249     for ( my $i = 0; $i <= $#installer::globals::userregistrycollector; $i++ )
 250     {
 251         my $onefile = $installer::globals::userregistrycollector[$i];
 252
 253         my $styles = "";
 254         if ( $onefile->{'Styles'} ) { $styles = $onefile->{'Styles'}; }
 255
 256         my %registry = ();
 257
 258         $registry{'Registry'} = $onefile->{'userregkeypath'};
 259         $registry{'Root'} = "1";  # always HKCU
 260         $registry{'Key'} = "Software\\$allvariables->{'MANUFACTURER'}\\$allvariables->{'PRODUCTNAME'} $allvariables->{'PRODUCTVERSION'}\\";
 261         if ( $onefile->{'needs_user_registry_key'} ) { $registry{'Key'} = $registry{'Key'} . "StartMenu"; }
 262         else { $registry{'Key'} = $registry{'Key'} . "ShellNew"; }
 263         $registry{'Name'} = $onefile->{'Name'};
 264         $registry{'Value'} = "1";
 265         $registry{'Component_'} = $onefile->{'componentname'};
 266
 267         my $oneline = $registry{'Registry'} . "\t" . $registry{'Root'} . "\t" . $registry{'Key'} . "\t"
 268                     . $registry{'Name'} . "\t" . $registry{'Value'} . "\t" . $registry{'Component_'} . "\n";
 269
 270         push(@{$registrytable}, $oneline);
 271     }
 272 }
 273
 274 ######################################################
 275 # Creating the file Registry.idt dynamically
 276 # Content:
 277 # Registry Root Key Name Value Component_
 278 ######################################################
 279
 280 sub create_registry_table
 281 {
 282     my ($registryref, $allregistrycomponentsref, $basedir, $languagesarrayref, $allvariableshashref) = @_;
 283
 284     for ( my $m = 0; $m <= $#{$languagesarrayref}; $m++ )
 285     {
 286         my $onelanguage = ${$languagesarrayref}[$m];
 287
 288         my @registrytable = ();
 289
 290         installer::windows::idtglobal::write_idt_header(\@registrytable, "registry");
 291
 292         for ( my $i = 0; $i <= $#{$registryref}; $i++ )
 293         {
 294             my $oneregistry = ${$registryref}[$i];
 295
 296             # Controlling the language!
 297             # Only language independent folderitems or folderitems with the correct language
 298             # will be included into the table
 299
 300             if (! (!(( $oneregistry->{'ismultilingual'} )) || ( $oneregistry->{'specificlanguage'} eq $onelanguage )) )  { next; }
 301
 302             my %registry = ();
 303
 304             $registry{'Registry'} = get_registry_identifier($oneregistry);
 305             $registry{'Root'} = get_registry_root($oneregistry);
 306             $registry{'Key'} = get_registry_key($oneregistry, $allvariableshashref);
 307             $registry{'Name'} = get_registry_name($oneregistry, $allvariableshashref);
 308             $registry{'Value'} = get_registry_value($oneregistry, $allvariableshashref);
 309             $registry{'Component_'} = get_registry_component($oneregistry, $allvariableshashref);
 310
 311             # Collecting all components
 312             if (!(installer::existence::exists_in_array($registry{'Component_'}, $allregistrycomponentsref)))
 313             {
 314                 push(@{$allregistrycomponentsref}, $registry{'Component_'});
 315             }
 316
 317             # Collecting all components with DONT_DELETE style
 318             my $style = "";
 319             if ( $oneregistry->{'Styles'} ) { $style = $oneregistry->{'Styles'}; }
 320             if ( $style =~ /\bDONT_DELETE\b/ ) { $installer::globals::dontdeletecomponents{$registry{'Component_'}} = 1; }
 321
 322             # Saving upgradekey to write this into setup.ini for minor upgrades
 323             if ( $style =~ /\bUPGRADEKEY\b/ ) { $installer::globals::minorupgradekey = $registry{'Key'}; }
 324
 325             # Collecting all registry components with ALWAYS_REQUIRED style
 326             if ( ! ( $style =~ /\bALWAYS_REQUIRED\b/ ))
 327             {
 328                 # Setting a component condition for unforced registry components!
 329                 # Only write into registry, if WRITE_REGISTRY is set.
 330                 if ( $oneregistry->{'ComponentCondition'} ) { $oneregistry->{'ComponentCondition'} = "(" . $oneregistry->{'ComponentCondition'} . ") AND (WRITE_REGISTRY=1)"; }
 331                 else { $oneregistry->{'ComponentCondition'} = "WRITE_REGISTRY=1"; }
 332             }
 333
 334             # Collecting all component conditions
 335             if ( $oneregistry->{'ComponentCondition'} )
 336             {
 337                 if ( ! exists($installer::globals::componentcondition{$registry{'Component_'}}))
 338                 {
 339                     $installer::globals::componentcondition{$registry{'Component_'}} = $oneregistry->{'ComponentCondition'};
 340                 }
 341             }
 342
 343             my $oneline = $registry{'Registry'} . "\t" . $registry{'Root'} . "\t" . $registry{'Key'} . "\t"
 344                         . $registry{'Name'} . "\t" . $registry{'Value'} . "\t" . $registry{'Component_'} . "\n";
 345
 346             push(@registrytable, $oneline);
 347         }
 348
 349         # If there are added user registry keys for files collected in
 350         # @installer::globals::userregistrycollector (file.pm), then
 351         # this registry keys have to be added now. This is necessary for
 352         # files in PREDEFINED_OSSHELLNEWDIR, because their component
 353         # needs as KeyPath a RegistryItem in HKCU.
 354
 355         if ( $installer::globals::addeduserregitrykeys ) { add_userregs_to_registry_table(\@registrytable, $allvariableshashref); }
 356
 357         # Saving the file
 358
 359         my $registrytablename = $basedir . $installer::globals::separator . "Registry.idt" . "." . $onelanguage;
 360         installer::files::save_file($registrytablename ,\@registrytable);
 361         my $infoline = "Created idt file: $registrytablename\n";
 362         push(@installer::globals::logfileinfo, $infoline);
 363     }
 364 }
 365
 366 1;