vcl/aqua/source/dtrans/aqua_clipboard.cxx

   1 /*************************************************************************
   2  *
   3  * DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
   4  *
   5  * Copyright 2008 by Sun Microsystems, Inc.
   6  *
   7  * OpenOffice.org - a multi-platform office productivity suite
   8  *
   9  * $RCSfile: aqua_clipboard.cxx,v $
  10  * $Revision: 1.8 $
  11  *
  12  * This file is part of OpenOffice.org.
  13  *
  14  * OpenOffice.org is free software: you can redistribute it and/or modify
  15  * it under the terms of the GNU Lesser General Public License version 3
  16  * only, as published by the Free Software Foundation.
  17  *
  18  * OpenOffice.org is distributed in the hope that it will be useful,
  19  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  20  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21  * GNU Lesser General Public License version 3 for more details
  22  * (a copy is included in the LICENSE file that accompanied this code).
  23  *
  24  * You should have received a copy of the GNU Lesser General Public License
  25  * version 3 along with OpenOffice.org.  If not, see
  26  * <http://www.openoffice.org/license.html>
  27  * for a copy of the LGPLv3 License.
  28  *
  29  ************************************************************************/
  30
  31 // MARKER(update_precomp.py): autogen include statement, do not remove
  32 #include "precompiled_vcl.hxx"
  33 #include "aqua_clipboard.hxx"
  34
  35 #include "DataFlavorMapping.hxx"
  36 #include "OSXTransferable.hxx"
  37
  38 #include "vcl/unohelp.hxx"
  39
  40 #include "comphelper/makesequence.hxx"
  41
  42 #include <boost/assert.hpp>
  43
  44 using namespace com::sun::star::datatransfer;
  45 using namespace com::sun::star::datatransfer::clipboard;
  46 using namespace com::sun::star::lang;
  47 using namespace com::sun::star::uno;
  48 using namespace cppu;
  49 using namespace osl;
  50 using namespace rtl;
  51 using namespace std;
  52 using namespace comphelper;
  53
  54
  55 @implementation EventListener;
  56
  57 -(EventListener*)initWithAquaClipboard: (AquaClipboard*) pcb
  58 {
  59     self = [super init];
  60
  61     if (self)
  62         pAquaClipboard = pcb;
  63
  64     return self;
  65 }
  66
  67 -(void)pasteboard:(NSPasteboard*)sender provideDataForType:(NSString*)type
  68 {
  69     if( pAquaClipboard )
  70         pAquaClipboard->provideDataForType(sender, type);
  71 }
  72
  73 -(void)applicationDidBecomeActive:(NSNotification*)aNotification
  74 {
  75     if( pAquaClipboard )
  76         pAquaClipboard->applicationDidBecomeActive(aNotification);
  77 }
  78
  79 -(void)disposing
  80 {
  81     pAquaClipboard = NULL;
  82 }
  83
  84 @end
  85
  86
  87 OUString clipboard_getImplementationName()
  88 {
  89   return OUString(RTL_CONSTASCII_USTRINGPARAM("com.sun.star.datatransfer.clipboard.AquaClipboard"));
  90 }
  91
  92 Sequence<OUString> clipboard_getSupportedServiceNames()
  93 {
  94   return makeSequence(OUString(RTL_CONSTASCII_USTRINGPARAM("com.sun.star.datatransfer.clipboard.SystemClipboard")));
  95 }
  96
  97
  98 AquaClipboard::AquaClipboard(NSPasteboard* pasteboard, bool bUseSystemPasteboard) :
  99   WeakComponentImplHelper4<XClipboardEx, XClipboardNotifier, XFlushableClipboard, XServiceInfo>(m_aMutex),
 100   mIsSystemPasteboard(bUseSystemPasteboard)
 101 {
 102     Reference<XMultiServiceFactory> mrServiceMgr = vcl::unohelper::GetMultiServiceFactory();
 103
 104     mrXMimeCntFactory = Reference<XMimeContentTypeFactory>(mrServiceMgr->createInstance(
 105      OUString(RTL_CONSTASCII_USTRINGPARAM("com.sun.star.datatransfer.MimeContentTypeFactory"))), UNO_QUERY);
 106
 107   if (!mrXMimeCntFactory.is())
 108     {
 109       throw RuntimeException(OUString(
 110             RTL_CONSTASCII_USTRINGPARAM("AquaClipboard: Cannot create com.sun.star.datatransfer.MimeContentTypeFactory")),
 111             static_cast<XClipboardEx*>(this));
 112     }
 113
 114   mpDataFlavorMapper = DataFlavorMapperPtr_t(new DataFlavorMapper());
 115
 116   if (pasteboard != NULL)
 117     {
 118       mPasteboard = pasteboard;
 119       mIsSystemPasteboard = false;
 120     }
 121   else
 122     {
 123       mPasteboard = bUseSystemPasteboard ? [NSPasteboard generalPasteboard] :
 124         [NSPasteboard pasteboardWithName: NSDragPboard];
 125
 126       if (mPasteboard == nil)
 127         {
 128           throw RuntimeException(OUString(
 129                 RTL_CONSTASCII_USTRINGPARAM("AquaClipboard: Cannot create Cocoa pasteboard")),
 130                 static_cast<XClipboardEx*>(this));
 131         }
 132     }
 133
 134   [mPasteboard retain];
 135
 136   mEventListener = [[EventListener alloc] initWithAquaClipboard: this];
 137
 138   if (mEventListener == nil)
 139     {
 140       [mPasteboard release];
 141
 142       throw RuntimeException(
 143             OUString(RTL_CONSTASCII_USTRINGPARAM("AquaClipboard: Cannot create pasteboard change listener")),
 144             static_cast<XClipboardEx*>(this));
 145     }
 146
 147   if (mIsSystemPasteboard)
 148     {
 149       NSNotificationCenter* notificationCenter = [NSNotificationCenter defaultCenter];
 150
 151       [notificationCenter addObserver: mEventListener
 152        selector: @selector(applicationDidBecomeActive:)
 153        name: @"NSApplicationDidBecomeActiveNotification"
 154        object: [NSApplication sharedApplication]];
 155     }
 156
 157   mPasteboardChangeCount = [mPasteboard changeCount];
 158 }
 159
 160
 161 AquaClipboard::~AquaClipboard()
 162 {
 163   if (mIsSystemPasteboard)
 164     {
 165       [[NSNotificationCenter defaultCenter] removeObserver: mEventListener];
 166     }
 167
 168   [mEventListener disposing];
 169   [mEventListener release];
 170   [mPasteboard release];
 171 }
 172
 173
 174 Reference<XTransferable> SAL_CALL AquaClipboard::getContents() throw(RuntimeException)
 175 {
 176   MutexGuard aGuard(m_aMutex);
 177
 178   // Shortcut: If we are clipboard owner already we don't need
 179   // to drag the data through the system clipboard
 180   if (mXClipboardContent.is())
 181     {
 182       return mXClipboardContent;
 183     }
 184
 185   return Reference<XTransferable>(new OSXTransferable(mrXMimeCntFactory,
 186                                                       mpDataFlavorMapper,
 187                                                       mPasteboard));
 188 }
 189
 190
 191 void SAL_CALL AquaClipboard::setContents(const Reference<XTransferable>& xTransferable,
 192     const Reference<XClipboardOwner>& xClipboardOwner)
 193         throw( RuntimeException )
 194 {
 195     ClearableMutexGuard aGuard(m_aMutex);
 196
 197     Reference<XClipboardOwner> oldOwner(mXClipboardOwner);
 198     mXClipboardOwner = xClipboardOwner;
 199
 200     Reference<XTransferable> oldContent(mXClipboardContent);
 201     mXClipboardContent = xTransferable;
 202
 203     NSArray* types = mXClipboardContent.is() ?
 204         mpDataFlavorMapper->flavorSequenceToTypesArray(mXClipboardContent->getTransferDataFlavors()) :
 205         [NSArray array];
 206     mPasteboardChangeCount = [mPasteboard declareTypes: types owner: mEventListener];
 207
 208     // if we are already the owner of the clipboard
 209     // then fire lost ownership event
 210     if (oldOwner.is())
 211     {
 212         fireLostClipboardOwnershipEvent(oldOwner, oldContent);
 213     }
 214
 215     fireClipboardChangedEvent();
 216 }
 217
 218
 219 OUString SAL_CALL AquaClipboard::getName() throw( RuntimeException )
 220 {
 221   return OUString();
 222 }
 223
 224
 225 sal_Int8 SAL_CALL AquaClipboard::getRenderingCapabilities() throw( RuntimeException )
 226 {
 227     return 0;
 228 }
 229
 230
 231 void SAL_CALL AquaClipboard::addClipboardListener(const Reference< XClipboardListener >& listener)
 232   throw( RuntimeException )
 233 {
 234   MutexGuard aGuard(m_aMutex);
 235
 236   if (!listener.is())
 237      throw IllegalArgumentException(OUString(RTL_CONSTASCII_USTRINGPARAM("empty reference")),
 238                                    static_cast<XClipboardEx*>(this), 1);
 239
 240   mClipboardListeners.push_back(listener);
 241 }
 242
 243
 244 void SAL_CALL AquaClipboard::removeClipboardListener(const Reference< XClipboardListener >& listener)
 245   throw( RuntimeException )
 246 {
 247   MutexGuard aGuard(m_aMutex);
 248
 249   if (!listener.is())
 250      throw IllegalArgumentException(OUString(RTL_CONSTASCII_USTRINGPARAM("empty reference")),
 251                                    static_cast<XClipboardEx*>(this), 1);
 252
 253   mClipboardListeners.remove(listener);
 254 }
 255
 256
 257 void AquaClipboard::applicationDidBecomeActive(NSNotification* aNotification)
 258 {
 259   MutexGuard aGuard(m_aMutex);
 260
 261   int currentPboardChgCount = [mPasteboard changeCount];
 262
 263   if (currentPboardChgCount != mPasteboardChangeCount)
 264     {
 265       mPasteboardChangeCount = currentPboardChgCount;
 266
 267       // Clear clipboard content and owner and send lostOwnership
 268       // notification to the old clipboard owner as well as
 269       // ClipboardChanged notification to any clipboard listener
 270       Reference<XClipboardOwner> oldOwner(mXClipboardOwner);
 271       mXClipboardOwner = Reference<XClipboardOwner>();
 272
 273       Reference<XTransferable> oldContent(mXClipboardContent);
 274       mXClipboardContent = Reference<XTransferable>();
 275
 276       if (oldOwner.is())
 277         {
 278           fireLostClipboardOwnershipEvent(oldOwner, oldContent);
 279         }
 280
 281       fireClipboardChangedEvent();
 282     }
 283 }
 284
 285
 286 void AquaClipboard::fireClipboardChangedEvent()
 287 {
 288     ClearableMutexGuard aGuard(m_aMutex);
 289
 290     list<Reference< XClipboardListener > > listeners(mClipboardListeners);
 291     ClipboardEvent aEvent;
 292
 293     if (listeners.begin() != listeners.end())
 294       {
 295         aEvent = ClipboardEvent(static_cast<OWeakObject*>(this), getContents());
 296       }
 297
 298     aGuard.clear();
 299
 300     while (listeners.begin() != listeners.end())
 301     {
 302         if (listeners.front().is())
 303           {
 304             try { listeners.front()->changedContents(aEvent); }
 305             catch (RuntimeException&) { }
 306           }
 307         listeners.pop_front();
 308     }
 309 }
 310
 311
 312 void AquaClipboard::fireLostClipboardOwnershipEvent(Reference<XClipboardOwner> oldOwner, Reference<XTransferable> oldContent)
 313 {
 314   BOOST_ASSERT(oldOwner.is());
 315
 316   try { oldOwner->lostOwnership(static_cast<XClipboardEx*>(this), oldContent); }
 317   catch(RuntimeException&) { }
 318 }
 319
 320
 321 void AquaClipboard::provideDataForType(NSPasteboard* sender, NSString* type)
 322 {
 323   DataProviderPtr_t dp = mpDataFlavorMapper->getDataProvider(type, mXClipboardContent);
 324   NSData* pBoardData = NULL;
 325
 326   if (dp.get() != NULL)
 327   {
 328       pBoardData = (NSData*)dp->getSystemData();
 329       [sender setData: pBoardData forType: type];
 330   }
 331 }
 332
 333
 334 //------------------------------------------------
 335 // XFlushableClipboard
 336 //------------------------------------------------
 337
 338 void SAL_CALL AquaClipboard::flushClipboard()
 339   throw(RuntimeException)
 340 {
 341   if (mXClipboardContent.is())
 342     {
 343           Sequence<DataFlavor> flavorList = mXClipboardContent->getTransferDataFlavors();
 344         sal_uInt32 nFlavors = flavorList.getLength();
 345
 346         for (sal_uInt32 i = 0; i < nFlavors; i++)
 347           {
 348             NSString* sysType = mpDataFlavorMapper->openOfficeToSystemFlavor(flavorList[i]);
 349
 350             if (sysType != NULL)
 351               {
 352                 provideDataForType(mPasteboard, sysType);
 353               }
 354           }
 355     }
 356 }
 357
 358
 359 NSPasteboard* AquaClipboard::getPasteboard() const
 360 {
 361   return mPasteboard;
 362 }
 363
 364
 365 //-------------------------------------------------
 366 // XServiceInfo
 367 //-------------------------------------------------
 368
 369 OUString SAL_CALL AquaClipboard::getImplementationName() throw( RuntimeException )
 370 {
 371   return clipboard_getImplementationName();
 372 }
 373
 374
 375 sal_Bool SAL_CALL AquaClipboard::supportsService( const OUString& ServiceName ) throw( RuntimeException )
 376 {
 377     return sal_False;
 378 }
 379
 380
 381 Sequence< OUString > SAL_CALL AquaClipboard::getSupportedServiceNames() throw( RuntimeException )
 382 {
 383   return clipboard_getSupportedServiceNames();
 384 }
 385