CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 cmake_minimum_required(VERSION 3.0.2)
   4
   5 if(APPLE)
   6     # The workaround for try_compile failing with code signing
   7     # since cmake-3.18.2, not required
   8     set(CMAKE_TRY_COMPILE_PLATFORM_VARIABLES
   9         ${CMAKE_TRY_COMPILE_PLATFORM_VARIABLES}
  10         "CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED"
  11         "CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED")
  12     set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED NO)
  13     set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED NO)
  14 endif()
  15
  16 if(CMAKE_SYSTEM_NAME STREQUAL "iOS")
  17     # Fix compile failure with armv7 deployment target >= 11.0, xcode clang
  18     # will report:
  19     # error: invalid iOS deployment version '--target=armv7-apple-ios13.6',
  20     # iOS 10 is the maximum deployment target for 32-bit targets
  21     # If CMAKE_OSX_DEPLOYMENT_TARGET is not defined, cmake will choose latest
  22     # deployment target
  23     if("${CMAKE_OSX_ARCHITECTURES}" MATCHES ".*armv7.*")
  24         if(NOT DEFINED CMAKE_OSX_DEPLOYMENT_TARGET
  25             OR NOT CMAKE_OSX_DEPLOYMENT_TARGET VERSION_LESS "11.0")
  26             message(STATUS "Forcing iOS deployment target to 10.0 for armv7")
  27             set(CMAKE_OSX_DEPLOYMENT_TARGET "10.0" CACHE STRING "Minimum OS X deployment version"
  28                 FORCE)
  29         endif()
  30     endif()
  31 endif()
  32
  33 project(OpenAL)
  34
  35 if(COMMAND CMAKE_POLICY)
  36     cmake_policy(SET CMP0003 NEW)
  37     cmake_policy(SET CMP0005 NEW)
  38     if(POLICY CMP0020)
  39         cmake_policy(SET CMP0020 NEW)
  40     endif(POLICY CMP0020)
  41     if(POLICY CMP0042)
  42         cmake_policy(SET CMP0042 NEW)
  43     endif(POLICY CMP0042)
  44     if(POLICY CMP0054)
  45         cmake_policy(SET CMP0054 NEW)
  46     endif(POLICY CMP0054)
  47     if(POLICY CMP0075)
  48         cmake_policy(SET CMP0075 NEW)
  49     endif(POLICY CMP0075)
  50 endif(COMMAND CMAKE_POLICY)
  51
  52 if(NOT CMAKE_BUILD_TYPE)
  53     set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  54         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
  55         FORCE)
  56 endif()
  57 if(NOT CMAKE_DEBUG_POSTFIX)
  58     set(CMAKE_DEBUG_POSTFIX "" CACHE STRING
  59         "Library postfix for debug builds. Normally left blank."
  60         FORCE)
  61 endif()
  62
  63 set(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  64
  65 include(CheckFunctionExists)
  66 include(CheckLibraryExists)
  67 include(CheckIncludeFile)
  68 include(CheckIncludeFiles)
  69 include(CheckSymbolExists)
  70 include(CheckCCompilerFlag)
  71 include(CheckCXXCompilerFlag)
  72 include(CheckCSourceCompiles)
  73 include(CheckCXXSourceCompiles)
  74 include(CheckStructHasMember)
  75 include(CMakePackageConfigHelpers)
  76 include(GNUInstallDirs)
  77
  78 find_package(PkgConfig)
  79
  80
  81 option(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  82
  83 option(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  84
  85 option(ALSOFT_UTILS "Build utility programs"  ON)
  86 option(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  87
  88 option(ALSOFT_EXAMPLES  "Build example programs"  ON)
  89
  90 option(ALSOFT_INSTALL "Install main library" ON)
  91 option(ALSOFT_INSTALL_CONFIG "Install alsoft.conf sample configuration file" ON)
  92 option(ALSOFT_INSTALL_HRTF_DATA "Install HRTF data files" ON)
  93 option(ALSOFT_INSTALL_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  94 option(ALSOFT_INSTALL_EXAMPLES "Install example programs (alplay, alstream, ...)" ON)
  95 option(ALSOFT_INSTALL_UTILS "Install utility programs (openal-info, alsoft-config, ...)" ON)
  96 option(ALSOFT_UPDATE_BUILD_VERSION "Update git build version info" ON)
  97
  98 option(ALSOFT_EAX "Enable legacy EAX extensions" ${WIN32})
  99
 100 if(DEFINED SHARE_INSTALL_DIR)
 101     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
 102     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
 103 endif()
 104
 105 if(DEFINED LIB_SUFFIX)
 106     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
 107 endif()
 108 if(DEFINED ALSOFT_CONFIG)
 109     message(WARNING "ALSOFT_CONFIG is deprecated. Use ALSOFT_INSTALL_CONFIG instead")
 110 endif()
 111 if(DEFINED ALSOFT_HRTF_DEFS)
 112     message(WARNING "ALSOFT_HRTF_DEFS is deprecated. Use ALSOFT_INSTALL_HRTF_DATA instead")
 113 endif()
 114 if(DEFINED ALSOFT_AMBDEC_PRESETS)
 115     message(WARNING "ALSOFT_AMBDEC_PRESETS is deprecated. Use ALSOFT_INSTALL_AMBDEC_PRESETS instead")
 116 endif()
 117
 118
 119 set(CPP_DEFS ) # C pre-processor, not C++
 120 set(INC_PATHS )
 121 set(C_FLAGS )
 122 set(LINKER_FLAGS )
 123 set(EXTRA_LIBS )
 124
 125 if(WIN32)
 126     set(CPP_DEFS ${CPP_DEFS} _WIN32 NOMINMAX)
 127     if(MINGW)
 128         set(CPP_DEFS ${CPP_DEFS} __USE_MINGW_ANSI_STDIO)
 129     endif()
 130
 131     option(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
 132     if(MINGW)
 133         option(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
 134     endif()
 135 elseif(APPLE)
 136     option(ALSOFT_OSX_FRAMEWORK "Build as macOS framework" OFF)
 137 endif()
 138
 139
 140 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
 141 if("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 142     set(INC_PATHS ${INC_PATHS} /usr/include)
 143     set(LINKER_FLAGS ${LINKER_FLAGS} -L/usr/lib)
 144 endif()
 145
 146 # When the library is built for static linking, apps should define
 147 # AL_LIBTYPE_STATIC when including the AL headers.
 148 if(NOT LIBTYPE)
 149     set(LIBTYPE SHARED)
 150 endif()
 151
 152 set(LIB_MAJOR_VERSION "1")
 153 set(LIB_MINOR_VERSION "22")
 154 set(LIB_REVISION "0")
 155 set(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 156 set(LIB_VERSION_NUM ${LIB_MAJOR_VERSION},${LIB_MINOR_VERSION},${LIB_REVISION},0)
 157
 158 set(EXPORT_DECL "")
 159
 160
 161 # Require C++14
 162 set(CMAKE_CXX_STANDARD 14)
 163 set(CMAKE_CXX_STANDARD_REQUIRED TRUE)
 164
 165 # Prefer C11, but support C99 and C90 too.
 166 set(CMAKE_C_STANDARD 11)
 167
 168 if(NOT WIN32)
 169     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 170     check_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 171     if(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 172         set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 173         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 174         check_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 175         if(NOT HAVE_POSIX_MEMALIGN_POSIX)
 176             set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 177         else()
 178             set(CPP_DEFS ${CPP_DEFS} _POSIX_C_SOURCE=200112L _XOPEN_SOURCE=600)
 179         endif()
 180     endif()
 181     unset(OLD_REQUIRED_FLAGS)
 182 endif()
 183
 184 # C99 has restrict, but C++ does not, so we can only utilize __restrict.
 185 check_cxx_source_compiles("int *__restrict foo;
 186 int main() { return 0; }" HAVE___RESTRICT)
 187 if(HAVE___RESTRICT)
 188     set(CPP_DEFS ${CPP_DEFS} RESTRICT=__restrict)
 189 else()
 190     set(CPP_DEFS ${CPP_DEFS} "RESTRICT=")
 191 endif()
 192
 193 # Some systems may need libatomic for atomic functions to work
 194 set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 195 set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 196 check_cxx_source_compiles("#include <atomic>
 197 std::atomic<int> foo{0};
 198 int main() { return foo.fetch_add(2); }"
 199 HAVE_LIBATOMIC)
 200 if(NOT HAVE_LIBATOMIC)
 201     set(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 202 else()
 203     set(EXTRA_LIBS atomic ${EXTRA_LIBS})
 204 endif()
 205 unset(OLD_REQUIRED_LIBRARIES)
 206
 207 if(ANDROID)
 208     # Include liblog for Android logging
 209     check_library_exists(log __android_log_print "" HAVE_LIBLOG)
 210     if(HAVE_LIBLOG)
 211         set(EXTRA_LIBS log ${EXTRA_LIBS})
 212         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 213     endif()
 214 endif()
 215
 216 if(MSVC)
 217     set(CPP_DEFS ${CPP_DEFS} _CRT_SECURE_NO_WARNINGS)
 218     check_cxx_compiler_flag(/permissive- HAVE_PERMISSIVE_SWITCH)
 219     if(HAVE_PERMISSIVE_SWITCH)
 220         set(C_FLAGS ${C_FLAGS} $<$<COMPILE_LANGUAGE:CXX>:/permissive->)
 221     endif()
 222     set(C_FLAGS ${C_FLAGS} /W4 /w14640 /wd4065 /wd4127 /wd4268 /wd4324 /wd5030)
 223     # Remove /W3, which is added by default, since we set /W4. Some build
 224     # generators with MSVC complain about both /W3 and /W4 being specified.
 225     foreach(flag_var  CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 226         if(${flag_var} MATCHES "/W3")
 227             string(REGEX REPLACE "/W3" "" ${flag_var} "${${flag_var}}")
 228         endif()
 229     endforeach()
 230
 231     if(NOT DXSDK_DIR)
 232         string(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 233     else()
 234         string(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 235     endif()
 236     if(DXSDK_DIR)
 237         message(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 238     endif()
 239
 240     option(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 241     if(FORCE_STATIC_VCRT)
 242         foreach(flag_var
 243                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 244                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 245                 CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
 246                 CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 247             if(${flag_var} MATCHES "/MD")
 248                 string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 249             endif()
 250         endforeach(flag_var)
 251     endif()
 252 else()
 253     set(C_FLAGS ${C_FLAGS} -Winline -Wunused -Wall -Wextra -Wshadow -Wconversion -Wcast-align
 254         -Wpedantic
 255         $<$<COMPILE_LANGUAGE:CXX>:-Wold-style-cast -Wnon-virtual-dtor -Woverloaded-virtual>)
 256
 257     if(ALSOFT_WERROR)
 258         set(C_FLAGS ${C_FLAGS} -Werror)
 259     endif()
 260
 261     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 262     # instead of NDEBUG)
 263     foreach(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 264         if(${flag_var} MATCHES "-DNDEBUG")
 265             string(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 266         endif()
 267     endforeach()
 268
 269     check_c_compiler_flag(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 270     if(HAVE_FNO_MATH_ERRNO)
 271         set(C_FLAGS ${C_FLAGS} -fno-math-errno)
 272     endif()
 273
 274     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 275     if(ALSOFT_STATIC_LIBGCC)
 276         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 277         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 278         check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBGCC_SWITCH)
 279         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 280         unset(OLD_REQUIRED_LIBRARIES)
 281
 282         if(NOT HAVE_STATIC_LIBGCC_SWITCH)
 283             message(FATAL_ERROR "Cannot static link libgcc")
 284         endif()
 285         set(LINKER_FLAGS ${LINKER_FLAGS} -static-libgcc)
 286     endif()
 287
 288     option(ALSOFT_STATIC_STDCXX "Static link libstdc++" OFF)
 289     if(ALSOFT_STATIC_STDCXX)
 290         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 291         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-Wl,--push-state,-Bstatic,-lstdc++,--pop-state")
 292         check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBSTDCXX_SWITCH)
 293         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 294         unset(OLD_REQUIRED_LIBRARIES)
 295
 296         if(NOT HAVE_STATIC_LIBSTDCXX_SWITCH)
 297             message(FATAL_ERROR "Cannot static link libstdc++")
 298         endif()
 299         set(LINKER_FLAGS ${LINKER_FLAGS} "-Wl,--push-state,-Bstatic,-lstdc++,--pop-state")
 300     endif()
 301
 302     if(WIN32)
 303         option(ALSOFT_STATIC_WINPTHREAD "Static link libwinpthread" OFF)
 304         if(ALSOFT_STATIC_WINPTHREAD)
 305             set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 306             set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-Wl,--push-state,-Bstatic,-lwinpthread,--pop-state")
 307             check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBWINPTHREAD_SWITCH)
 308             set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 309             unset(OLD_REQUIRED_LIBRARIES)
 310
 311             if(NOT HAVE_STATIC_LIBWINPTHREAD_SWITCH)
 312                 message(FATAL_ERROR "Cannot static link libwinpthread")
 313             endif()
 314             set(LINKER_FLAGS ${LINKER_FLAGS} "-Wl,--push-state,-Bstatic,-lwinpthread,--pop-state")
 315         endif()
 316     endif()
 317 endif()
 318
 319 # Set visibility/export options if available
 320 if(WIN32)
 321     if(NOT LIBTYPE STREQUAL "STATIC")
 322         set(EXPORT_DECL "__declspec(dllexport)")
 323     endif()
 324 else()
 325     set(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 326     # Yes GCC, really don't accept visibility modes you don't support
 327     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 328
 329     check_c_source_compiles("int foo() __attribute__((visibility(\"protected\")));
 330                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 331     if(HAVE_GCC_PROTECTED_VISIBILITY)
 332         if(NOT LIBTYPE STREQUAL "STATIC")
 333             set(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 334         endif()
 335     else()
 336         check_c_source_compiles("int foo() __attribute__((visibility(\"default\")));
 337                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 338         if(HAVE_GCC_DEFAULT_VISIBILITY)
 339             if(NOT LIBTYPE STREQUAL "STATIC")
 340                 set(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 341             endif()
 342         endif()
 343     endif()
 344
 345     if(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 346         check_c_compiler_flag(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 347         if(HAVE_VISIBILITY_HIDDEN_SWITCH)
 348             set(C_FLAGS ${C_FLAGS} -fvisibility=hidden)
 349         endif()
 350     endif()
 351
 352     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 353 endif()
 354
 355
 356 set(SSE2_SWITCH "")
 357
 358 if(NOT MSVC)
 359     set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 360     # Yes GCC, really don't accept command line options you don't support
 361     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Werror")
 362     check_c_compiler_flag(-msse2 HAVE_MSSE2_SWITCH)
 363     if(HAVE_MSSE2_SWITCH)
 364         set(SSE2_SWITCH "-msse2")
 365     endif()
 366     set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 367     unset(OLD_REQUIRED_FLAGS)
 368 endif()
 369
 370 check_include_file(xmmintrin.h HAVE_XMMINTRIN_H)
 371 check_include_file(emmintrin.h HAVE_EMMINTRIN_H)
 372 check_include_file(pmmintrin.h HAVE_PMMINTRIN_H)
 373 check_include_file(smmintrin.h HAVE_SMMINTRIN_H)
 374 check_include_file(arm_neon.h HAVE_ARM_NEON_H)
 375
 376 set(HAVE_SSE        0)
 377 set(HAVE_SSE2       0)
 378 set(HAVE_SSE3       0)
 379 set(HAVE_SSE4_1     0)
 380 set(HAVE_NEON       0)
 381
 382 # Check for SSE support
 383 option(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 384 if(HAVE_XMMINTRIN_H)
 385     option(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 386     if(ALSOFT_CPUEXT_SSE)
 387         set(HAVE_SSE 1)
 388     endif()
 389 endif()
 390 if(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 391     message(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 392 endif()
 393
 394 option(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 395 if(HAVE_EMMINTRIN_H)
 396     option(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 397     if(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 398         set(HAVE_SSE2 1)
 399     endif()
 400 endif()
 401 if(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 402     message(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 403 endif()
 404
 405 option(ALSOFT_REQUIRE_SSE3 "Require SSE3 support" OFF)
 406 if(HAVE_PMMINTRIN_H)
 407     option(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 408     if(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 409         set(HAVE_SSE3 1)
 410     endif()
 411 endif()
 412 if(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 413     message(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 414 endif()
 415
 416 option(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 417 if(HAVE_SMMINTRIN_H)
 418     option(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 419     if(HAVE_SSE3 AND ALSOFT_CPUEXT_SSE4_1)
 420         set(HAVE_SSE4_1 1)
 421     endif()
 422 endif()
 423 if(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 424     message(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 425 endif()
 426
 427 # Check for ARM Neon support
 428 option(ALSOFT_REQUIRE_NEON "Require ARM NEON support" OFF)
 429 if(HAVE_ARM_NEON_H)
 430     option(ALSOFT_CPUEXT_NEON "Enable ARM NEON support" ON)
 431     if(ALSOFT_CPUEXT_NEON)
 432         check_c_source_compiles("#include <arm_neon.h>
 433             int main()
 434             {
 435                 int32x4_t ret4 = vdupq_n_s32(0);
 436                 return vgetq_lane_s32(ret4, 0);
 437             }" HAVE_NEON_INTRINSICS)
 438         if(HAVE_NEON_INTRINSICS)
 439             set(HAVE_NEON 1)
 440         endif()
 441     endif()
 442 endif()
 443 if(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 444     message(FATAL_ERROR "Failed to enabled required ARM NEON CPU extensions")
 445 endif()
 446
 447
 448 set(SSE_FLAGS )
 449 set(FPMATH_SET "0")
 450 if(CMAKE_SIZEOF_VOID_P MATCHES "4" AND HAVE_SSE2)
 451     option(ALSOFT_ENABLE_SSE2_CODEGEN "Enable SSE2 code generation instead of x87 for 32-bit targets." TRUE)
 452     if(ALSOFT_ENABLE_SSE2_CODEGEN)
 453         if(MSVC)
 454             check_c_compiler_flag("/arch:SSE2" HAVE_ARCH_SSE2)
 455             if(HAVE_ARCH_SSE2)
 456                 set(SSE_FLAGS ${SSE_FLAGS} "/arch:SSE2")
 457                 set(C_FLAGS ${C_FLAGS} ${SSE_FLAGS})
 458                 set(FPMATH_SET 2)
 459             endif()
 460         elseif(SSE2_SWITCH)
 461             check_c_compiler_flag("${SSE2_SWITCH} -mfpmath=sse" HAVE_MFPMATH_SSE_2)
 462             if(HAVE_MFPMATH_SSE_2)
 463                 set(SSE_FLAGS ${SSE_FLAGS} ${SSE2_SWITCH} -mfpmath=sse)
 464                 set(C_FLAGS ${C_FLAGS} ${SSE_FLAGS})
 465                 set(FPMATH_SET 2)
 466             endif()
 467             # SSE depends on a 16-byte aligned stack, and by default, GCC
 468             # assumes the stack is suitably aligned. Older Linux code or other
 469             # OSs don't guarantee this on 32-bit, so externally-callable
 470             # functions need to ensure an aligned stack.
 471             set(EXPORT_DECL "${EXPORT_DECL} __attribute__((force_align_arg_pointer))")
 472         endif()
 473     endif()
 474 endif()
 475
 476 if(HAVE_SSE2)
 477     set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 478     foreach(flag_var ${SSE_FLAGS})
 479         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${flag_var}")
 480     endforeach()
 481
 482     check_c_source_compiles("#include <emmintrin.h>
 483         int main() {_mm_pause(); return 0;}" HAVE_SSE_INTRINSICS)
 484
 485     set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 486 endif()
 487
 488
 489 check_include_file(malloc.h HAVE_MALLOC_H)
 490 check_include_file(cpuid.h HAVE_CPUID_H)
 491 check_include_file(intrin.h HAVE_INTRIN_H)
 492 check_include_file(guiddef.h HAVE_GUIDDEF_H)
 493 if(NOT HAVE_GUIDDEF_H)
 494     check_include_file(initguid.h HAVE_INITGUID_H)
 495 endif()
 496
 497 # Some systems need libm for some math functions to work
 498 set(MATH_LIB )
 499 check_library_exists(m pow "" HAVE_LIBM)
 500 if(HAVE_LIBM)
 501     set(MATH_LIB ${MATH_LIB} m)
 502     set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 503 endif()
 504
 505 # Some systems need to link with -lrt for clock_gettime as used by the common
 506 # eaxmple functions.
 507 set(RT_LIB )
 508 check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 509 if(HAVE_LIBRT)
 510     set(RT_LIB rt)
 511 endif()
 512
 513 # Check for the dlopen API (for dynamicly loading backend libs)
 514 if(ALSOFT_DLOPEN)
 515     check_include_file(dlfcn.h HAVE_DLFCN_H)
 516     check_library_exists(dl dlopen "" HAVE_LIBDL)
 517     if(HAVE_LIBDL)
 518         set(EXTRA_LIBS dl ${EXTRA_LIBS})
 519         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 520     endif()
 521 endif()
 522
 523 # Check for a cpuid intrinsic
 524 if(HAVE_CPUID_H)
 525     check_c_source_compiles("#include <cpuid.h>
 526         int main()
 527         {
 528             unsigned int eax, ebx, ecx, edx;
 529             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 530         }" HAVE_GCC_GET_CPUID)
 531 endif()
 532 if(HAVE_INTRIN_H)
 533     check_c_source_compiles("#include <intrin.h>
 534         int main()
 535         {
 536             int regs[4];
 537             __cpuid(regs, 0);
 538             return regs[0];
 539         }" HAVE_CPUID_INTRINSIC)
 540 endif()
 541
 542 check_symbol_exists(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 543 check_symbol_exists(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 544 check_symbol_exists(proc_pidpath     libproc.h HAVE_PROC_PIDPATH)
 545
 546 if(NOT WIN32)
 547     # We need pthreads outside of Windows, for semaphores. It's also used to
 548     # set the priority and name of threads, when possible.
 549     check_include_file(pthread.h HAVE_PTHREAD_H)
 550     if(NOT HAVE_PTHREAD_H)
 551         message(FATAL_ERROR "PThreads is required for non-Windows builds!")
 552     endif()
 553
 554     check_c_compiler_flag(-pthread HAVE_PTHREAD)
 555     if(HAVE_PTHREAD)
 556         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 557         set(C_FLAGS ${C_FLAGS} -pthread)
 558         set(LINKER_FLAGS ${LINKER_FLAGS} -pthread)
 559     endif()
 560
 561     check_symbol_exists(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 562
 563     # Some systems need pthread_np.h to get pthread_setname_np
 564     check_include_files("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 565     if(HAVE_PTHREAD_NP_H)
 566         check_symbol_exists(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 567         if(NOT HAVE_PTHREAD_SETNAME_NP)
 568             check_symbol_exists(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 569         endif()
 570     else()
 571         check_symbol_exists(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 572         if(NOT HAVE_PTHREAD_SETNAME_NP)
 573             check_symbol_exists(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 574         endif()
 575     endif()
 576 endif()
 577
 578 check_symbol_exists(getopt unistd.h HAVE_GETOPT)
 579
 580
 581 # Common sources used by both the OpenAL implementation library, the OpenAL
 582 # router, and certain tools and examples.
 583 set(COMMON_OBJS
 584     common/albit.h
 585     common/albyte.h
 586     common/alcomplex.cpp
 587     common/alcomplex.h
 588     common/aldeque.h
 589     common/alfstream.cpp
 590     common/alfstream.h
 591     common/almalloc.cpp
 592     common/almalloc.h
 593     common/alnumbers.h
 594     common/alnumeric.h
 595     common/aloptional.h
 596     common/alspan.h
 597     common/alstring.cpp
 598     common/alstring.h
 599     common/atomic.h
 600     common/comptr.h
 601     common/dynload.cpp
 602     common/dynload.h
 603     common/intrusive_ptr.h
 604     common/opthelpers.h
 605     common/phase_shifter.h
 606     common/polyphase_resampler.cpp
 607     common/polyphase_resampler.h
 608     common/pragmadefs.h
 609     common/ringbuffer.cpp
 610     common/ringbuffer.h
 611     common/strutils.cpp
 612     common/strutils.h
 613     common/threads.cpp
 614     common/threads.h
 615     common/vecmat.h
 616     common/vector.h)
 617
 618 # Core library routines
 619 set(CORE_OBJS
 620     core/ambdec.cpp
 621     core/ambdec.h
 622     core/ambidefs.cpp
 623     core/ambidefs.h
 624     core/async_event.h
 625     core/bformatdec.cpp
 626     core/bformatdec.h
 627     core/bs2b.cpp
 628     core/bs2b.h
 629     core/bsinc_defs.h
 630     core/bsinc_tables.cpp
 631     core/bsinc_tables.h
 632     core/bufferline.h
 633     core/buffer_storage.cpp
 634     core/buffer_storage.h
 635     core/context.cpp
 636     core/context.h
 637     core/converter.cpp
 638     core/converter.h
 639     core/cpu_caps.cpp
 640     core/cpu_caps.h
 641     core/devformat.cpp
 642     core/devformat.h
 643     core/device.cpp
 644     core/device.h
 645     core/effects/base.h
 646     core/effectslot.cpp
 647     core/effectslot.h
 648     core/except.cpp
 649     core/except.h
 650     core/filters/biquad.h
 651     core/filters/biquad.cpp
 652     core/filters/nfc.cpp
 653     core/filters/nfc.h
 654     core/filters/splitter.cpp
 655     core/filters/splitter.h
 656     core/fmt_traits.cpp
 657     core/fmt_traits.h
 658     core/fpu_ctrl.cpp
 659     core/fpu_ctrl.h
 660     core/front_stablizer.h
 661     core/helpers.cpp
 662     core/helpers.h
 663     core/hrtf.cpp
 664     core/hrtf.h
 665     core/logging.cpp
 666     core/logging.h
 667     core/mastering.cpp
 668     core/mastering.h
 669     core/mixer.cpp
 670     core/mixer.h
 671     core/resampler_limits.h
 672     core/uhjfilter.cpp
 673     core/uhjfilter.h
 674     core/uiddefs.cpp
 675     core/voice.cpp
 676     core/voice.h
 677     core/voice_change.h)
 678
 679 set(HAVE_RTKIT 0)
 680 option(ALSOFT_REQUIRE_RTKIT "Require RTKit/D-Bus support" FALSE)
 681 find_package(DBus1 QUIET)
 682 if(NOT DBus1_FOUND AND PkgConfig_FOUND)
 683     pkg_check_modules(DBUS dbus-1)
 684 endif()
 685 if(DBus1_FOUND OR DBUS_FOUND)
 686     option(ALSOFT_RTKIT "Enable RTKit support" ON)
 687     if(ALSOFT_RTKIT)
 688         set(HAVE_RTKIT 1)
 689         set(CORE_OBJS ${CORE_OBJS} core/dbus_wrap.cpp core/dbus_wrap.h core/rtkit.cpp core/rtkit.h)
 690         if(NOT DBus1_FOUND)
 691             set(INC_PATHS ${INC_PATHS} ${DBUS_INCLUDE_DIRS})
 692             set(CPP_DEFS ${CPP_DEFS} ${DBUS_CFLAGS_OTHER})
 693             if(NOT WIN32 AND NOT HAVE_DLFCN_H)
 694                 set(EXTRA_LIBS ${EXTRA_LIBS} ${DBUS_LINK_LIBRARIES})
 695             endif()
 696         elseif(WIN32 OR HAVE_DLFCN_H)
 697             set(INC_PATHS ${INC_PATHS} ${DBus1_INCLUDE_DIRS})
 698             set(CPP_DEFS ${CPP_DEFS} ${DBus1_DEFINITIONS})
 699         else()
 700             set(EXTRA_LIBS ${EXTRA_LIBS} ${DBus1_LIBRARIES})
 701         endif()
 702     endif()
 703 else()
 704     set(MISSING_VARS "")
 705     if(NOT DBus1_INCLUDE_DIRS)
 706         set(MISSING_VARS "${MISSING_VARS} DBus1_INCLUDE_DIRS")
 707     endif()
 708     if(NOT DBus1_LIBRARIES)
 709         set(MISSING_VARS "${MISSING_VARS} DBus1_LIBRARIES")
 710     endif()
 711     message(STATUS "Could NOT find DBus1 (missing:${MISSING_VARS})")
 712     unset(MISSING_VARS)
 713 endif()
 714 if(ALSOFT_REQUIRE_RTKIT AND NOT HAVE_RTKIT)
 715     message(FATAL_ERROR "Failed to enabled required RTKit support")
 716 endif()
 717
 718 # Default mixers, always available
 719 set(CORE_OBJS ${CORE_OBJS}
 720     core/mixer/defs.h
 721     core/mixer/hrtfbase.h
 722     core/mixer/hrtfdefs.h
 723     core/mixer/mixer_c.cpp)
 724
 725 # AL and related routines
 726 set(OPENAL_OBJS
 727     al/auxeffectslot.cpp
 728     al/auxeffectslot.h
 729     al/buffer.cpp
 730     al/buffer.h
 731     al/effect.cpp
 732     al/effect.h
 733     al/effects/autowah.cpp
 734     al/effects/chorus.cpp
 735     al/effects/compressor.cpp
 736     al/effects/convolution.cpp
 737     al/effects/dedicated.cpp
 738     al/effects/distortion.cpp
 739     al/effects/echo.cpp
 740         al/effects/effects.cpp
 741     al/effects/effects.h
 742     al/effects/equalizer.cpp
 743     al/effects/fshifter.cpp
 744     al/effects/modulator.cpp
 745     al/effects/null.cpp
 746     al/effects/pshifter.cpp
 747     al/effects/reverb.cpp
 748     al/effects/vmorpher.cpp
 749     al/error.cpp
 750     al/event.cpp
 751     al/event.h
 752     al/extension.cpp
 753     al/filter.cpp
 754     al/filter.h
 755     al/listener.cpp
 756     al/listener.h
 757     al/source.cpp
 758     al/source.h
 759     al/state.cpp)
 760
 761 # ALC and related routines
 762 set(ALC_OBJS
 763     alc/alc.cpp
 764     alc/alu.cpp
 765     alc/alu.h
 766     alc/alconfig.cpp
 767     alc/alconfig.h
 768     alc/context.cpp
 769     alc/context.h
 770     alc/device.cpp
 771     alc/device.h
 772     alc/effects/base.h
 773     alc/effects/autowah.cpp
 774     alc/effects/chorus.cpp
 775     alc/effects/compressor.cpp
 776     alc/effects/convolution.cpp
 777     alc/effects/dedicated.cpp
 778     alc/effects/distortion.cpp
 779     alc/effects/echo.cpp
 780     alc/effects/equalizer.cpp
 781     alc/effects/fshifter.cpp
 782     alc/effects/modulator.cpp
 783     alc/effects/null.cpp
 784     alc/effects/pshifter.cpp
 785     alc/effects/reverb.cpp
 786     alc/effects/vmorpher.cpp
 787     alc/inprogext.h
 788     alc/panning.cpp)
 789
 790 if (ALSOFT_EAX)
 791     set(OPENAL_OBJS
 792         ${OPENAL_OBJS}
 793         al/eax_api.cpp
 794         al/eax_api.h
 795         al/eax_eax_call.cpp
 796         al/eax_eax_call.h
 797         al/eax_effect.cpp
 798         al/eax_effect.h
 799         al/eax_exception.cpp
 800         al/eax_exception.h
 801         al/eax_fx_slot_index.cpp
 802         al/eax_fx_slot_index.h
 803         al/eax_fx_slots.cpp
 804         al/eax_fx_slots.h
 805         al/eax_globals.cpp
 806         al/eax_globals.h
 807         al/eax_utils.cpp
 808         al/eax_utils.h
 809         al/eax_x_ram.cpp
 810         al/eax_x_ram.h
 811 )
 812 endif ()
 813
 814 # Include SIMD mixers
 815 set(CPU_EXTS "Default")
 816 if(HAVE_SSE)
 817     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse.cpp)
 818     set(CPU_EXTS "${CPU_EXTS}, SSE")
 819 endif()
 820 if(HAVE_SSE2)
 821     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse2.cpp)
 822     set(CPU_EXTS "${CPU_EXTS}, SSE2")
 823 endif()
 824 if(HAVE_SSE3)
 825     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse3.cpp)
 826     set(CPU_EXTS "${CPU_EXTS}, SSE3")
 827 endif()
 828 if(HAVE_SSE4_1)
 829     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse41.cpp)
 830     set(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 831 endif()
 832 if(HAVE_NEON)
 833     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_neon.cpp)
 834     set(CPU_EXTS "${CPU_EXTS}, Neon")
 835 endif()
 836
 837
 838 set(HAVE_ALSA       0)
 839 set(HAVE_OSS        0)
 840 set(HAVE_PIPEWIRE   0)
 841 set(HAVE_SOLARIS    0)
 842 set(HAVE_SNDIO      0)
 843 set(HAVE_DSOUND     0)
 844 set(HAVE_WASAPI     0)
 845 set(HAVE_WINMM      0)
 846 set(HAVE_PORTAUDIO  0)
 847 set(HAVE_PULSEAUDIO 0)
 848 set(HAVE_COREAUDIO  0)
 849 set(HAVE_OPENSL     0)
 850 set(HAVE_OBOE       0)
 851 set(HAVE_WAVE       0)
 852 set(HAVE_SDL2       0)
 853
 854 if(WIN32 OR HAVE_DLFCN_H)
 855     set(IS_LINKED "")
 856     macro(ADD_BACKEND_LIBS _LIBS)
 857     endmacro()
 858 else()
 859     set(IS_LINKED " (linked)")
 860     macro(ADD_BACKEND_LIBS _LIBS)
 861         set(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 862     endmacro()
 863 endif()
 864
 865 set(BACKENDS "")
 866 set(ALC_OBJS  ${ALC_OBJS}
 867     alc/backends/base.cpp
 868     alc/backends/base.h
 869     # Default backends, always available
 870     alc/backends/loopback.cpp
 871     alc/backends/loopback.h
 872     alc/backends/null.cpp
 873     alc/backends/null.h
 874 )
 875
 876 # Check ALSA backend
 877 option(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 878 find_package(ALSA)
 879 if(ALSA_FOUND)
 880     option(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 881     if(ALSOFT_BACKEND_ALSA)
 882         set(HAVE_ALSA 1)
 883         set(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 884         set(ALC_OBJS  ${ALC_OBJS} alc/backends/alsa.cpp alc/backends/alsa.h)
 885         add_backend_libs(${ALSA_LIBRARIES})
 886         set(INC_PATHS ${INC_PATHS} ${ALSA_INCLUDE_DIRS})
 887     endif()
 888 endif()
 889 if(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 890     message(FATAL_ERROR "Failed to enabled required ALSA backend")
 891 endif()
 892
 893 # Check OSS backend
 894 option(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 895 find_package(OSS)
 896 if(OSS_FOUND)
 897     option(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 898     if(ALSOFT_BACKEND_OSS)
 899         set(HAVE_OSS 1)
 900         set(BACKENDS  "${BACKENDS} OSS,")
 901         set(ALC_OBJS  ${ALC_OBJS} alc/backends/oss.cpp alc/backends/oss.h)
 902         if(OSS_LIBRARIES)
 903             set(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 904         endif()
 905         set(INC_PATHS ${INC_PATHS} ${OSS_INCLUDE_DIRS})
 906     endif()
 907 endif()
 908 if(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 909     message(FATAL_ERROR "Failed to enabled required OSS backend")
 910 endif()
 911
 912 # Check PipeWire backend
 913 option(ALSOFT_REQUIRE_PIPEWIRE "Require PipeWire backend" OFF)
 914 if(PkgConfig_FOUND)
 915     pkg_check_modules(PIPEWIRE libpipewire-0.3>=0.3.23)
 916     if(PIPEWIRE_FOUND)
 917         option(ALSOFT_BACKEND_PIPEWIRE "Enable PipeWire backend" ON)
 918         if(ALSOFT_BACKEND_PIPEWIRE)
 919             set(HAVE_PIPEWIRE 1)
 920             set(BACKENDS  "${BACKENDS} PipeWire${IS_LINKED},")
 921             set(ALC_OBJS  ${ALC_OBJS} alc/backends/pipewire.cpp alc/backends/pipewire.h)
 922             add_backend_libs(${PIPEWIRE_LIBRARIES})
 923             set(INC_PATHS ${INC_PATHS} ${PIPEWIRE_INCLUDE_DIRS})
 924         endif()
 925     endif()
 926 endif()
 927 if(ALSOFT_REQUIRE_PIPEWIRE AND NOT HAVE_PIPEWIRE)
 928     message(FATAL_ERROR "Failed to enabled required PipeWire backend")
 929 endif()
 930
 931 # Check Solaris backend
 932 option(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 933 find_package(AudioIO)
 934 if(AUDIOIO_FOUND)
 935     option(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 936     if(ALSOFT_BACKEND_SOLARIS)
 937         set(HAVE_SOLARIS 1)
 938         set(BACKENDS  "${BACKENDS} Solaris,")
 939         set(ALC_OBJS  ${ALC_OBJS} alc/backends/solaris.cpp alc/backends/solaris.h)
 940         set(INC_PATHS ${INC_PATHS} ${AUDIOIO_INCLUDE_DIRS})
 941     endif()
 942 endif()
 943 if(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 944     message(FATAL_ERROR "Failed to enabled required Solaris backend")
 945 endif()
 946
 947 # Check SndIO backend
 948 option(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 949 find_package(SoundIO)
 950 if(SOUNDIO_FOUND)
 951     option(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 952     if(ALSOFT_BACKEND_SNDIO)
 953         set(HAVE_SNDIO 1)
 954         set(BACKENDS  "${BACKENDS} SndIO (linked),")
 955         set(ALC_OBJS  ${ALC_OBJS} alc/backends/sndio.cpp alc/backends/sndio.h)
 956         set(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 957         set(INC_PATHS ${INC_PATHS} ${SOUNDIO_INCLUDE_DIRS})
 958     endif()
 959 endif()
 960 if(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 961     message(FATAL_ERROR "Failed to enabled required SndIO backend")
 962 endif()
 963
 964 # Check Windows-only backends
 965 option(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 966 option(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 967 option(ALSOFT_REQUIRE_WASAPI "Require WASAPI backend" OFF)
 968 if(WIN32)
 969     # Check MMSystem backend
 970     option(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 971     if(ALSOFT_BACKEND_WINMM)
 972         set(HAVE_WINMM 1)
 973         set(BACKENDS "${BACKENDS} WinMM,")
 974         set(ALC_OBJS ${ALC_OBJS} alc/backends/winmm.cpp alc/backends/winmm.h)
 975         # There doesn't seem to be good way to search for winmm.lib for MSVC.
 976         # find_library doesn't find it without being told to look in a specific
 977         # place in the WindowsSDK, but it links anyway. If there ends up being
 978         # Windows targets without this, another means to detect it is needed.
 979         set(EXTRA_LIBS winmm ${EXTRA_LIBS})
 980     endif()
 981
 982     # Check DSound backend
 983     check_include_file(dsound.h HAVE_DSOUND_H)
 984     if(DXSDK_DIR)
 985         find_path(DSOUND_INCLUDE_DIR NAMES "dsound.h"
 986             PATHS "${DXSDK_DIR}" PATH_SUFFIXES include
 987             DOC "The DirectSound include directory")
 988     endif()
 989     if(HAVE_DSOUND_H OR DSOUND_INCLUDE_DIR)
 990         option(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 991         if(ALSOFT_BACKEND_DSOUND)
 992             set(HAVE_DSOUND 1)
 993             set(BACKENDS "${BACKENDS} DirectSound,")
 994             set(ALC_OBJS ${ALC_OBJS} alc/backends/dsound.cpp alc/backends/dsound.h)
 995
 996             if(NOT HAVE_DSOUND_H)
 997                 set(INC_PATHS ${INC_PATHS} ${DSOUND_INCLUDE_DIR})
 998             endif()
 999         endif()
1000     endif()
1001
1002     # Check for WASAPI backend
1003     check_include_file(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
1004     if(HAVE_MMDEVICEAPI_H)
1005         option(ALSOFT_BACKEND_WASAPI "Enable WASAPI backend" ON)
1006         if(ALSOFT_BACKEND_WASAPI)
1007             set(HAVE_WASAPI 1)
1008             set(BACKENDS  "${BACKENDS} WASAPI,")
1009             set(ALC_OBJS  ${ALC_OBJS} alc/backends/wasapi.cpp alc/backends/wasapi.h)
1010         endif()
1011     endif()
1012 endif()
1013 if(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
1014     message(FATAL_ERROR "Failed to enabled required WinMM backend")
1015 endif()
1016 if(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
1017     message(FATAL_ERROR "Failed to enabled required DSound backend")
1018 endif()
1019 if(ALSOFT_REQUIRE_WASAPI AND NOT HAVE_WASAPI)
1020     message(FATAL_ERROR "Failed to enabled required WASAPI backend")
1021 endif()
1022
1023 # Check PortAudio backend
1024 option(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
1025 find_package(PortAudio)
1026 if(PORTAUDIO_FOUND)
1027     option(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
1028     if(ALSOFT_BACKEND_PORTAUDIO)
1029         set(HAVE_PORTAUDIO 1)
1030         set(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1031         set(ALC_OBJS  ${ALC_OBJS} alc/backends/portaudio.cpp alc/backends/portaudio.h)
1032         add_backend_libs(${PORTAUDIO_LIBRARIES})
1033         set(INC_PATHS ${INC_PATHS} ${PORTAUDIO_INCLUDE_DIRS})
1034     endif()
1035 endif()
1036 if(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1037     message(FATAL_ERROR "Failed to enabled required PortAudio backend")
1038 endif()
1039
1040 # Check PulseAudio backend
1041 option(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1042 find_package(PulseAudio)
1043 if(PULSEAUDIO_FOUND)
1044     option(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1045     if(ALSOFT_BACKEND_PULSEAUDIO)
1046         set(HAVE_PULSEAUDIO 1)
1047         set(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1048         set(ALC_OBJS  ${ALC_OBJS} alc/backends/pulseaudio.cpp alc/backends/pulseaudio.h)
1049         add_backend_libs(${PULSEAUDIO_LIBRARIES})
1050         set(INC_PATHS ${INC_PATHS} ${PULSEAUDIO_INCLUDE_DIRS})
1051     endif()
1052 endif()
1053 if(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1054     message(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1055 endif()
1056
1057 # Check JACK backend
1058 option(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1059 find_package(JACK)
1060 if(JACK_FOUND)
1061     option(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1062     if(ALSOFT_BACKEND_JACK)
1063         set(HAVE_JACK 1)
1064         set(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1065         set(ALC_OBJS  ${ALC_OBJS} alc/backends/jack.cpp alc/backends/jack.h)
1066         add_backend_libs(${JACK_LIBRARIES})
1067         set(INC_PATHS ${INC_PATHS} ${JACK_INCLUDE_DIRS})
1068     endif()
1069 endif()
1070 if(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1071     message(FATAL_ERROR "Failed to enabled required JACK backend")
1072 endif()
1073
1074 # Check CoreAudio backend
1075 option(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1076 find_library(COREAUDIO_FRAMEWORK NAMES CoreAudio)
1077 find_path(AUDIOUNIT_INCLUDE_DIR NAMES AudioUnit/AudioUnit.h)
1078 if(COREAUDIO_FRAMEWORK AND AUDIOUNIT_INCLUDE_DIR)
1079     option(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1080     if(ALSOFT_BACKEND_COREAUDIO)
1081         set(HAVE_COREAUDIO 1)
1082         set(ALC_OBJS  ${ALC_OBJS} alc/backends/coreaudio.cpp alc/backends/coreaudio.h)
1083         set(BACKENDS  "${BACKENDS} CoreAudio,")
1084         if(CMAKE_SYSTEM_NAME STREQUAL "iOS")
1085             find_library(COREFOUNDATION_FRAMEWORK NAMES CoreFoundation)
1086             set(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${COREFOUNDATION_FRAMEWORK} ${EXTRA_LIBS})
1087         else()
1088             set(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} /System/Library/Frameworks/AudioUnit.framework
1089                 /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1090         endif()
1091
1092         # Some versions of OSX may need the AudioToolbox framework. Add it if
1093         # it's found.
1094         find_library(AUDIOTOOLBOX_LIBRARY NAMES AudioToolbox)
1095         if(AUDIOTOOLBOX_LIBRARY)
1096             set(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1097         endif()
1098
1099         set(INC_PATHS ${INC_PATHS} ${AUDIOUNIT_INCLUDE_DIR})
1100     endif()
1101 endif()
1102 if(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1103     message(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1104 endif()
1105
1106 # Check for OpenSL (Android) backend
1107 option(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1108 find_package(OpenSL)
1109 if(OPENSL_FOUND)
1110     option(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1111     if(ALSOFT_BACKEND_OPENSL)
1112         set(HAVE_OPENSL 1)
1113         set(ALC_OBJS  ${ALC_OBJS} alc/backends/opensl.cpp alc/backends/opensl.h)
1114         set(BACKENDS  "${BACKENDS} OpenSL,")
1115         set(EXTRA_LIBS "OpenSL::OpenSLES" ${EXTRA_LIBS})
1116     endif()
1117 endif()
1118 if(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1119     message(FATAL_ERROR "Failed to enabled required OpenSL backend")
1120 endif()
1121
1122 # Check for Oboe (Android) backend
1123 set(OBOE_TARGET )
1124 if(ANDROID)
1125     set(OBOE_SOURCE "" CACHE STRING "Source directory for Oboe.")
1126     if(OBOE_SOURCE)
1127         # Force Oboe to build with hidden symbols. Don't want to be exporting
1128         # them from OpenAL.
1129         set(OLD_CXX_FLAGS ${CMAKE_CXX_FLAGS})
1130         check_cxx_compiler_flag(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
1131         if(HAVE_VISIBILITY_HIDDEN_SWITCH)
1132             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
1133         endif()
1134         add_subdirectory(${OBOE_SOURCE} ./oboe)
1135         set(CMAKE_CXX_FLAGS ${OLD_CXX_FLAGS})
1136         unset(OLD_CXX_FLAGS)
1137
1138         set(OBOE_TARGET oboe)
1139     else()
1140         find_package(Oboe)
1141         if(OBOE_FOUND)
1142             set(OBOE_TARGET "oboe::oboe")
1143         endif()
1144     endif()
1145 endif()
1146
1147 option(ALSOFT_REQUIRE_OBOE "Require Oboe backend" OFF)
1148 if(OBOE_TARGET)
1149     option(ALSOFT_BACKEND_OBOE "Enable Oboe backend" ON)
1150     if(ALSOFT_BACKEND_OBOE)
1151         set(HAVE_OBOE 1)
1152         set(ALC_OBJS  ${ALC_OBJS} alc/backends/oboe.cpp alc/backends/oboe.h)
1153         set(BACKENDS  "${BACKENDS} Oboe,")
1154         set(EXTRA_LIBS ${OBOE_TARGET} ${EXTRA_LIBS})
1155     endif()
1156 endif()
1157 if(ALSOFT_REQUIRE_OBOE AND NOT HAVE_OBOE)
1158     message(FATAL_ERROR "Failed to enabled required Oboe backend")
1159 endif()
1160
1161 # Check for SDL2 backend
1162 option(ALSOFT_REQUIRE_SDL2 "Require SDL2 backend" OFF)
1163 find_package(SDL2)
1164 if(SDL2_FOUND)
1165     # Off by default, since it adds a runtime dependency
1166     option(ALSOFT_BACKEND_SDL2 "Enable SDL2 backend" OFF)
1167     if(ALSOFT_BACKEND_SDL2)
1168         set(HAVE_SDL2 1)
1169         set(ALC_OBJS  ${ALC_OBJS} alc/backends/sdl2.cpp alc/backends/sdl2.h)
1170         set(BACKENDS  "${BACKENDS} SDL2,")
1171         set(EXTRA_LIBS ${SDL2_LIBRARY} ${EXTRA_LIBS})
1172         set(INC_PATHS ${INC_PATHS} ${SDL2_INCLUDE_DIR})
1173     endif()
1174 endif()
1175 if(ALSOFT_REQUIRE_SDL2 AND NOT SDL2_FOUND)
1176     message(FATAL_ERROR "Failed to enabled required SDL2 backend")
1177 endif()
1178
1179 # Optionally enable the Wave Writer backend
1180 option(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1181 if(ALSOFT_BACKEND_WAVE)
1182     set(HAVE_WAVE 1)
1183     set(ALC_OBJS  ${ALC_OBJS} alc/backends/wave.cpp alc/backends/wave.h)
1184     set(BACKENDS  "${BACKENDS} WaveFile,")
1185 endif()
1186
1187 # This is always available
1188 set(BACKENDS  "${BACKENDS} Null")
1189
1190
1191 find_package(Git)
1192 if(ALSOFT_UPDATE_BUILD_VERSION AND GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1193     # Get the current working branch and its latest abbreviated commit hash
1194     add_custom_target(build_version
1195         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE} -D LIB_VERSION=${LIB_VERSION}
1196             -D LIB_VERSION_NUM=${LIB_VERSION_NUM} -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1197             -D DST=${OpenAL_BINARY_DIR}/version.h -P ${OpenAL_SOURCE_DIR}/version.cmake
1198         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1199         VERBATIM
1200     )
1201 else()
1202     set(GIT_BRANCH "UNKNOWN")
1203     set(GIT_COMMIT_HASH "unknown")
1204     configure_file(
1205         "${OpenAL_SOURCE_DIR}/version.h.in"
1206         "${OpenAL_BINARY_DIR}/version.h")
1207 endif()
1208
1209
1210 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" ON)
1211 if(ALSOFT_EMBED_HRTF_DATA)
1212     macro(make_hrtf_header FILENAME VARNAME)
1213         set(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1214         set(outfile  "${OpenAL_BINARY_DIR}/${VARNAME}.h")
1215
1216         add_custom_command(OUTPUT "${outfile}"
1217             COMMAND ${CMAKE_COMMAND} -D "INPUT_FILE=${infile}" -D "OUTPUT_FILE=${outfile}"
1218                 -D "VARIABLE_NAME=${VARNAME}" -P "${CMAKE_MODULE_PATH}/bin2h.script.cmake"
1219             WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1220             DEPENDS "${infile}" "${CMAKE_MODULE_PATH}/bin2h.script.cmake"
1221             VERBATIM
1222         )
1223         set(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1224     endmacro()
1225
1226     make_hrtf_header("Default HRTF.mhr" "hrtf_default")
1227 endif()
1228
1229
1230 if(ALSOFT_UTILS)
1231     find_package(MySOFA)
1232     if(NOT ALSOFT_NO_CONFIG_UTIL)
1233         find_package(Qt5Widgets QUIET)
1234         if(NOT Qt5Widgets_FOUND)
1235             message(STATUS "Could NOT find Qt5Widgets")
1236         endif()
1237     endif()
1238 endif()
1239 if(ALSOFT_UTILS OR ALSOFT_EXAMPLES)
1240     find_package(SndFile)
1241     find_package(SDL2)
1242     if(SDL2_FOUND)
1243         find_package(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1244     endif()
1245 endif()
1246
1247 if(NOT WIN32)
1248     set(LIBNAME "openal")
1249 else()
1250     set(LIBNAME "OpenAL32")
1251 endif()
1252
1253 # Needed for openal.pc.in
1254 set(prefix ${CMAKE_INSTALL_PREFIX})
1255 set(exec_prefix "\${prefix}")
1256 set(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1257 set(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1258 set(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1259 set(PACKAGE_VERSION "${LIB_VERSION}")
1260 set(PKG_CONFIG_CFLAGS )
1261 set(PKG_CONFIG_PRIVATE_LIBS )
1262 if(LIBTYPE STREQUAL "STATIC")
1263     set(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC)
1264     foreach(FLAG  ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1265         # If this is already a linker flag, or is a full path+file, add it
1266         # as-is. Otherwise, it's a name intended to be dressed as -lname.
1267         if(FLAG MATCHES "^-.*" OR EXISTS "${FLAG}")
1268             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} ${FLAG}")
1269         else()
1270             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} -l${FLAG}")
1271         endif()
1272     endforeach()
1273 endif()
1274
1275 # End configuration
1276 configure_file(
1277     "${OpenAL_SOURCE_DIR}/config.h.in"
1278     "${OpenAL_BINARY_DIR}/config.h")
1279 configure_file(
1280     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1281     "${OpenAL_BINARY_DIR}/openal.pc"
1282     @ONLY)
1283
1284
1285 add_library(common STATIC EXCLUDE_FROM_ALL ${COMMON_OBJS})
1286 target_include_directories(common PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/include)
1287 target_compile_definitions(common PRIVATE ${CPP_DEFS})
1288 target_compile_options(common PRIVATE ${C_FLAGS})
1289 set_target_properties(common PROPERTIES POSITION_INDEPENDENT_CODE TRUE)
1290
1291
1292 unset(HAS_ROUTER)
1293 set(IMPL_TARGET OpenAL) # Either OpenAL or soft_oal.
1294
1295 # Build main library
1296 if(LIBTYPE STREQUAL "STATIC")
1297     add_library(${IMPL_TARGET} STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS} ${CORE_OBJS})
1298     target_compile_definitions(${IMPL_TARGET} PUBLIC AL_LIBTYPE_STATIC)
1299     target_link_libraries(${IMPL_TARGET} PRIVATE ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1300
1301     if(WIN32)
1302         # This option is for static linking OpenAL Soft into another project
1303         # that already defines the IDs. It is up to that project to ensure all
1304         # required IDs are defined.
1305         option(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
1306         if(ALSOFT_NO_UID_DEFS)
1307             target_compile_definitions(${IMPL_TARGET} PRIVATE AL_NO_UID_DEFS)
1308         endif()
1309     endif()
1310 else()
1311     set(RC_CONFIG resources/openal32.rc)
1312     if(WIN32 AND ALSOFT_BUILD_ROUTER)
1313         add_library(OpenAL SHARED
1314             resources/router.rc
1315             router/router.cpp
1316             router/router.h
1317             router/alc.cpp
1318             router/al.cpp
1319         )
1320         target_compile_definitions(OpenAL
1321             PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES "ALC_API=${EXPORT_DECL}"
1322             "AL_API=${EXPORT_DECL}" ${CPP_DEFS})
1323         target_compile_options(OpenAL PRIVATE ${C_FLAGS})
1324         target_link_libraries(OpenAL PRIVATE common ${LINKER_FLAGS})
1325         target_include_directories(OpenAL
1326           PUBLIC
1327             $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include>
1328             $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
1329           PRIVATE
1330             ${OpenAL_SOURCE_DIR}/common
1331             ${OpenAL_BINARY_DIR}
1332         )
1333         set_target_properties(OpenAL PROPERTIES PREFIX "")
1334         set_target_properties(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1335         if(TARGET build_version)
1336             add_dependencies(OpenAL build_version)
1337         endif()
1338         set(HAS_ROUTER 1)
1339
1340         set(LIBNAME "soft_oal")
1341         set(IMPL_TARGET soft_oal)
1342         set(RC_CONFIG resources/soft_oal.rc)
1343     endif()
1344
1345     # !important: for osx framework public header works, the headers must be in
1346     # the project
1347     set(TARGET_PUBLIC_HEADERS include/AL/al.h include/AL/alc.h include/AL/alext.h include/AL/efx.h)
1348     add_library(${IMPL_TARGET} SHARED ${OPENAL_OBJS} ${ALC_OBJS} ${CORE_OBJS} ${RC_CONFIG}
1349         ${TARGET_PUBLIC_HEADERS})
1350     if(WIN32)
1351         set_target_properties(${IMPL_TARGET} PROPERTIES PREFIX "")
1352     endif()
1353     target_link_libraries(${IMPL_TARGET} PRIVATE common ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1354
1355     if(APPLE AND ALSOFT_OSX_FRAMEWORK)
1356         # Sets framework name to soft_oal to avoid ambiguity with the system OpenAL.framework
1357         set(LIBNAME "soft_oal")
1358         if(GIT_FOUND)
1359             EXECUTE_PROCESS(COMMAND ${GIT_EXECUTABLE} rev-list --count head
1360                 TIMEOUT 5
1361                 OUTPUT_VARIABLE BUNDLE_VERSION
1362                 OUTPUT_STRIP_TRAILING_WHITESPACE)
1363         else()
1364             set(BUNDLE_VERSION 1)
1365         endif()
1366
1367         # Build: Fix rpath in iOS shared libraries
1368         # If this flag is not set, the final dylib binary ld path will be
1369         # /User/xxx/*/soft_oal.framework/soft_oal, which can't be loaded by iOS devices.
1370         # See also: https://github.com/libjpeg-turbo/libjpeg-turbo/commit/c80ddef7a4ce21ace9e3ca0fd190d320cc8cdaeb
1371         if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG)
1372             set(CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG "-Wl,-rpath,")
1373         endif()
1374
1375         set_target_properties(${IMPL_TARGET} PROPERTIES
1376             FRAMEWORK TRUE
1377             FRAMEWORK_VERSION C
1378             MACOSX_FRAMEWORK_NAME "${IMPL_TARGET}"
1379             MACOSX_FRAMEWORK_IDENTIFIER "org.openal-soft.openal"
1380             MACOSX_FRAMEWORK_SHORT_VERSION_STRING ${LIB_VERSION}
1381             MACOSX_FRAMEWORK_BUNDLE_VERSION ${BUNDLE_VERSION}
1382             XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY ""
1383             XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED "NO"
1384             XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED "NO"
1385             PUBLIC_HEADER "${TARGET_PUBLIC_HEADERS}"
1386             MACOSX_RPATH TRUE)
1387     endif()
1388 endif()
1389
1390 target_include_directories(${IMPL_TARGET}
1391   PUBLIC
1392     $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include>
1393   INTERFACE
1394     $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include/AL>
1395     $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
1396     $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/AL>
1397   PRIVATE
1398     ${INC_PATHS}
1399     ${OpenAL_BINARY_DIR}
1400     ${OpenAL_SOURCE_DIR}
1401     ${OpenAL_SOURCE_DIR}/common
1402 )
1403
1404 set_target_properties(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1405     VERSION ${LIB_VERSION}
1406     SOVERSION ${LIB_MAJOR_VERSION}
1407 )
1408 target_compile_definitions(${IMPL_TARGET}
1409     PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES "ALC_API=${EXPORT_DECL}" "AL_API=${EXPORT_DECL}"
1410     ${CPP_DEFS})
1411 target_compile_options(${IMPL_TARGET} PRIVATE ${C_FLAGS})
1412
1413 if(TARGET build_version)
1414     add_dependencies(${IMPL_TARGET} build_version)
1415 endif()
1416
1417 if(WIN32 AND MINGW AND ALSOFT_BUILD_IMPORT_LIB AND NOT LIBTYPE STREQUAL "STATIC")
1418     find_program(SED_EXECUTABLE NAMES sed DOC "sed executable")
1419     if(NOT SED_EXECUTABLE OR NOT CMAKE_DLLTOOL)
1420         message(STATUS "")
1421         if(NOT SED_EXECUTABLE)
1422             message(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1423         endif()
1424         if(NOT CMAKE_DLLTOOL)
1425             message(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1426         endif()
1427     else()
1428         set_property(TARGET OpenAL APPEND_STRING PROPERTY
1429             LINK_FLAGS " -Wl,--output-def,OpenAL32.def")
1430         add_custom_command(TARGET OpenAL POST_BUILD
1431             COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1432             COMMAND "${CMAKE_DLLTOOL}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1433             COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1434             VERBATIM
1435         )
1436     endif()
1437 endif()
1438
1439 if(HAS_ROUTER)
1440     message(STATUS "")
1441     message(STATUS "Building DLL router")
1442 endif()
1443
1444 message(STATUS "")
1445 message(STATUS "Building OpenAL with support for the following backends:")
1446 message(STATUS "   ${BACKENDS}")
1447 message(STATUS "")
1448 message(STATUS "Building with support for CPU extensions:")
1449 message(STATUS "    ${CPU_EXTS}")
1450 message(STATUS "")
1451 if(FPMATH_SET)
1452     message(STATUS "Building with SSE${FPMATH_SET} codegen")
1453     message(STATUS "")
1454 endif()
1455
1456 if(ALSOFT_EAX)
1457     message(STATUS "Building with legacy EAX extension support")
1458     message(STATUS "")
1459 endif()
1460
1461 if(ALSOFT_EMBED_HRTF_DATA)
1462     message(STATUS "Embedding HRTF datasets")
1463     message(STATUS "")
1464 endif()
1465
1466 # An alias for sub-project builds
1467 add_library(OpenAL::OpenAL ALIAS OpenAL)
1468
1469 # Install main library
1470 if(ALSOFT_INSTALL)
1471     configure_package_config_file(OpenALConfig.cmake.in OpenALConfig.cmake
1472         INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL)
1473     install(TARGETS OpenAL EXPORT OpenAL
1474         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1475         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1476         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1477         FRAMEWORK DESTINATION ${CMAKE_INSTALL_LIBDIR}
1478         INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL)
1479     export(TARGETS OpenAL
1480         NAMESPACE OpenAL::
1481         FILE OpenALTargets.cmake)
1482     install(EXPORT OpenAL
1483         DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1484         NAMESPACE OpenAL::
1485         FILE OpenALTargets.cmake)
1486     install(DIRECTORY include/AL
1487         DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
1488     install(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1489         DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1490     install(FILES "${OpenAL_BINARY_DIR}/OpenALConfig.cmake"
1491         DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL")
1492     if(TARGET soft_oal)
1493         install(TARGETS soft_oal
1494             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
1495     endif()
1496     message(STATUS "Installing library and headers")
1497 else()
1498     message(STATUS "NOT installing library and headers")
1499 endif()
1500
1501 if(ALSOFT_INSTALL_CONFIG)
1502     install(FILES alsoftrc.sample
1503         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1504     message(STATUS "Installing sample configuration")
1505 endif()
1506
1507 if(ALSOFT_INSTALL_HRTF_DATA)
1508     install(DIRECTORY hrtf
1509         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1510     message(STATUS "Installing HRTF data files")
1511 endif()
1512
1513 if(ALSOFT_INSTALL_AMBDEC_PRESETS)
1514     install(DIRECTORY presets
1515         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1516     message(STATUS "Installing AmbDec presets")
1517 endif()
1518 message(STATUS "")
1519
1520 set(UNICODE_FLAG )
1521 if(MINGW)
1522     set(UNICODE_FLAG ${UNICODE_FLAG} -municode)
1523 endif()
1524 set(EXTRA_INSTALLS )
1525 if(ALSOFT_UTILS)
1526     add_executable(openal-info utils/openal-info.c)
1527     target_include_directories(openal-info PRIVATE ${OpenAL_SOURCE_DIR}/common)
1528     target_compile_options(openal-info PRIVATE ${C_FLAGS})
1529     target_link_libraries(openal-info PRIVATE ${LINKER_FLAGS} OpenAL ${UNICODE_FLAG})
1530     if(ALSOFT_INSTALL_EXAMPLES)
1531         set(EXTRA_INSTALLS ${EXTRA_INSTALLS} openal-info)
1532     endif()
1533
1534     if(SNDFILE_FOUND)
1535         add_executable(uhjdecoder utils/uhjdecoder.cpp)
1536         target_compile_definitions(uhjdecoder PRIVATE ${CPP_DEFS})
1537         target_include_directories(uhjdecoder
1538             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/common)
1539         target_compile_options(uhjdecoder PRIVATE ${C_FLAGS})
1540         target_link_libraries(uhjdecoder PUBLIC common
1541             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ${UNICODE_FLAG})
1542
1543         add_executable(uhjencoder utils/uhjencoder.cpp)
1544         target_compile_definitions(uhjencoder PRIVATE ${CPP_DEFS})
1545         target_include_directories(uhjencoder
1546             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/common)
1547         target_compile_options(uhjencoder PRIVATE ${C_FLAGS})
1548         target_link_libraries(uhjencoder PUBLIC common
1549             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ${UNICODE_FLAG})
1550     endif()
1551
1552     if(MYSOFA_FOUND)
1553         set(SOFA_SUPPORT_SRCS
1554             utils/sofa-support.cpp
1555             utils/sofa-support.h)
1556         add_library(sofa-support STATIC EXCLUDE_FROM_ALL ${SOFA_SUPPORT_SRCS})
1557         target_compile_definitions(sofa-support PRIVATE ${CPP_DEFS})
1558         target_include_directories(sofa-support PUBLIC ${OpenAL_SOURCE_DIR}/common)
1559         target_compile_options(sofa-support PRIVATE ${C_FLAGS})
1560         target_link_libraries(sofa-support PUBLIC common MySOFA::MySOFA PRIVATE ${LINKER_FLAGS})
1561
1562         set(MAKEMHR_SRCS
1563             utils/makemhr/loaddef.cpp
1564             utils/makemhr/loaddef.h
1565             utils/makemhr/loadsofa.cpp
1566             utils/makemhr/loadsofa.h
1567             utils/makemhr/makemhr.cpp
1568             utils/makemhr/makemhr.h)
1569         if(NOT HAVE_GETOPT)
1570             set(MAKEMHR_SRCS  ${MAKEMHR_SRCS} utils/getopt.c utils/getopt.h)
1571         endif()
1572         add_executable(makemhr ${MAKEMHR_SRCS})
1573         target_compile_definitions(makemhr PRIVATE ${CPP_DEFS})
1574         target_include_directories(makemhr
1575             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/utils)
1576         target_compile_options(makemhr PRIVATE ${C_FLAGS})
1577         target_link_libraries(makemhr PRIVATE ${LINKER_FLAGS} sofa-support ${UNICODE_FLAG})
1578         if(ALSOFT_INSTALL_EXAMPLES)
1579             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} makemhr)
1580         endif()
1581
1582         set(SOFAINFO_SRCS  utils/sofa-info.cpp)
1583         add_executable(sofa-info ${SOFAINFO_SRCS})
1584         target_compile_definitions(sofa-info PRIVATE ${CPP_DEFS})
1585         target_include_directories(sofa-info PRIVATE ${OpenAL_SOURCE_DIR}/utils)
1586         target_compile_options(sofa-info PRIVATE ${C_FLAGS})
1587         target_link_libraries(sofa-info PRIVATE ${LINKER_FLAGS} sofa-support ${UNICODE_FLAG})
1588     endif()
1589     message(STATUS "Building utility programs")
1590
1591     if(NOT ALSOFT_NO_CONFIG_UTIL)
1592         add_subdirectory(utils/alsoft-config)
1593     endif()
1594     message(STATUS "")
1595 endif()
1596
1597
1598 # Add a static library with common functions used by multiple example targets
1599 add_library(ex-common STATIC EXCLUDE_FROM_ALL
1600     examples/common/alhelpers.c
1601     examples/common/alhelpers.h)
1602 target_compile_definitions(ex-common PUBLIC ${CPP_DEFS})
1603 target_include_directories(ex-common PUBLIC ${OpenAL_SOURCE_DIR}/common)
1604 target_compile_options(ex-common PUBLIC ${C_FLAGS})
1605 target_link_libraries(ex-common PUBLIC OpenAL PRIVATE ${RT_LIB})
1606
1607 if(ALSOFT_EXAMPLES)
1608     add_executable(altonegen examples/altonegen.c)
1609     target_link_libraries(altonegen PRIVATE ${LINKER_FLAGS} ${MATH_LIB} ex-common ${UNICODE_FLAG})
1610
1611     add_executable(alrecord examples/alrecord.c)
1612     target_link_libraries(alrecord PRIVATE ${LINKER_FLAGS} ex-common ${UNICODE_FLAG})
1613
1614     if(ALSOFT_INSTALL_EXAMPLES)
1615         set(EXTRA_INSTALLS ${EXTRA_INSTALLS} altonegen alrecord)
1616     endif()
1617
1618     message(STATUS "Building example programs")
1619
1620     if(SNDFILE_FOUND)
1621         add_executable(alplay examples/alplay.c)
1622         target_link_libraries(alplay PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1623             ${UNICODE_FLAG})
1624
1625         add_executable(alstream examples/alstream.c)
1626         target_link_libraries(alstream PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1627             ${UNICODE_FLAG})
1628
1629         add_executable(alreverb examples/alreverb.c)
1630         target_link_libraries(alreverb PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1631             ${UNICODE_FLAG})
1632
1633         add_executable(almultireverb examples/almultireverb.c)
1634         target_link_libraries(almultireverb
1635             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common ${MATH_LIB} ${UNICODE_FLAG})
1636
1637         add_executable(allatency examples/allatency.c)
1638         target_link_libraries(allatency PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1639             ${UNICODE_FLAG})
1640
1641         add_executable(alhrtf examples/alhrtf.c)
1642         target_link_libraries(alhrtf
1643             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common ${MATH_LIB} ${UNICODE_FLAG})
1644
1645         add_executable(alstreamcb examples/alstreamcb.cpp)
1646         target_link_libraries(alstreamcb PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1647             ${UNICODE_FLAG})
1648
1649         add_executable(alconvolve examples/alconvolve.c)
1650         target_link_libraries(alconvolve PRIVATE ${LINKER_FLAGS} common SndFile::SndFile ex-common
1651             ${UNICODE_FLAG})
1652
1653         if(ALSOFT_INSTALL_EXAMPLES)
1654             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alplay alstream alreverb almultireverb allatency
1655                 alhrtf)
1656         endif()
1657
1658         message(STATUS "Building SndFile example programs")
1659     endif()
1660
1661     if(SDL2_FOUND)
1662         add_executable(alloopback examples/alloopback.c)
1663         target_include_directories(alloopback PRIVATE ${SDL2_INCLUDE_DIR})
1664         target_link_libraries(alloopback
1665             PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ex-common ${MATH_LIB})
1666
1667         if(ALSOFT_INSTALL_EXAMPLES)
1668             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alloopback)
1669         endif()
1670
1671         message(STATUS "Building SDL example programs")
1672
1673         set(FFVER_OK FALSE)
1674         if(FFMPEG_FOUND)
1675             set(FFVER_OK TRUE)
1676             if(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1677                 message(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1678                 set(FFVER_OK FALSE)
1679             endif()
1680             if(AVCODEC_VERSION VERSION_LESS "57.64.101")
1681                 message(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1682                 set(FFVER_OK FALSE)
1683             endif()
1684             if(AVUTIL_VERSION VERSION_LESS "55.34.101")
1685                 message(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1686                 set(FFVER_OK FALSE)
1687             endif()
1688             if(SWSCALE_VERSION VERSION_LESS "4.2.100")
1689                 message(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1690                 set(FFVER_OK FALSE)
1691             endif()
1692             if(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1693                 message(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1694                 set(FFVER_OK FALSE)
1695             endif()
1696         endif()
1697         if(FFVER_OK)
1698             add_executable(alffplay examples/alffplay.cpp)
1699             target_include_directories(alffplay
1700                 PRIVATE ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS})
1701             target_link_libraries(alffplay
1702                 PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} ex-common)
1703
1704             if(ALSOFT_INSTALL_EXAMPLES)
1705                 set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alffplay)
1706             endif()
1707             message(STATUS "Building SDL+FFmpeg example programs")
1708         endif()
1709     endif()
1710     message(STATUS "")
1711 endif()
1712
1713 if(EXTRA_INSTALLS)
1714     install(TARGETS ${EXTRA_INSTALLS}
1715         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1716         BUNDLE  DESTINATION ${CMAKE_INSTALL_BINDIR}
1717         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1718         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
1719 endif()