CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 cmake_minimum_required(VERSION 3.0.2)
   4
   5 # The workaround for try_compile failing with code signing
   6 # since cmake-3.18.2, not required
   7 set(CMAKE_TRY_COMPILE_PLATFORM_VARIABLES
   8     "CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED"
   9     "CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED")
  10 set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED NO)
  11 set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED NO)
  12
  13 # Fix compile failure with armv7 deployment target >= 11.0, xcode clang will
  14 # report:
  15 # error: invalid iOS deployment version '--target=armv7-apple-ios13.6',
  16 # iOS 10 is the maximum deployment target for 32-bit targets
  17 # If CMAKE_OSX_DEPLOYMENT_TARGET is not defined, cmake will choose latest
  18 # deployment target
  19 if(CMAKE_SYSTEM_NAME STREQUAL "iOS")
  20     if("${CMAKE_OSX_ARCHITECTURES}" MATCHES ".*armv7.*")
  21         if(NOT DEFINED CMAKE_OSX_DEPLOYMENT_TARGET
  22             OR NOT CMAKE_OSX_DEPLOYMENT_TARGET VERSION_LESS "11.0")
  23             message(STATUS "Forcing iOS deployment target to 10.0 for armv7")
  24             set(CMAKE_OSX_DEPLOYMENT_TARGET "10.0" CACHE STRING "Minimum OS X deployment version"
  25                 FORCE)
  26         endif()
  27     endif()
  28 endif()
  29
  30 project(OpenAL)
  31
  32 if(COMMAND CMAKE_POLICY)
  33     cmake_policy(SET CMP0003 NEW)
  34     cmake_policy(SET CMP0005 NEW)
  35     if(POLICY CMP0020)
  36         cmake_policy(SET CMP0020 NEW)
  37     endif(POLICY CMP0020)
  38     if(POLICY CMP0042)
  39         cmake_policy(SET CMP0042 NEW)
  40     endif(POLICY CMP0042)
  41     if(POLICY CMP0054)
  42         cmake_policy(SET CMP0054 NEW)
  43     endif(POLICY CMP0054)
  44     if(POLICY CMP0075)
  45         cmake_policy(SET CMP0075 NEW)
  46     endif(POLICY CMP0075)
  47 endif(COMMAND CMAKE_POLICY)
  48
  49 if(NOT CMAKE_BUILD_TYPE)
  50     set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  51         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
  52         FORCE)
  53 endif()
  54 if(NOT CMAKE_DEBUG_POSTFIX)
  55     set(CMAKE_DEBUG_POSTFIX "" CACHE STRING
  56         "Library postfix for debug builds. Normally left blank."
  57         FORCE)
  58 endif()
  59
  60 set(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  61
  62 include(CheckFunctionExists)
  63 include(CheckLibraryExists)
  64 include(CheckIncludeFile)
  65 include(CheckIncludeFiles)
  66 include(CheckSymbolExists)
  67 include(CheckCCompilerFlag)
  68 include(CheckCXXCompilerFlag)
  69 include(CheckCSourceCompiles)
  70 include(CheckCXXSourceCompiles)
  71 include(CheckStructHasMember)
  72 include(GNUInstallDirs)
  73
  74
  75 option(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  76
  77 option(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  78
  79 option(ALSOFT_UTILS "Build utility programs"  ON)
  80 option(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  81
  82 option(ALSOFT_EXAMPLES  "Build example programs"  ON)
  83
  84 option(ALSOFT_INSTALL "Install main library" ON)
  85 option(ALSOFT_INSTALL_CONFIG "Install alsoft.conf sample configuration file" ON)
  86 option(ALSOFT_INSTALL_HRTF_DATA "Install HRTF data files" ON)
  87 option(ALSOFT_INSTALL_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  88 option(ALSOFT_INSTALL_EXAMPLES "Install example programs (alplay, alstream, ...)" ON)
  89 option(ALSOFT_INSTALL_UTILS "Install utility programs (openal-info, alsoft-config, ...)" ON)
  90 option(ALSOFT_UPDATE_BUILD_VERSION "Update git build version info" ON)
  91
  92 if(DEFINED SHARE_INSTALL_DIR)
  93     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  94     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
  95 endif()
  96
  97 if(DEFINED LIB_SUFFIX)
  98     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
  99 endif()
 100 if(DEFINED ALSOFT_CONFIG)
 101     message(WARNING "ALSOFT_CONFIG is deprecated. Use ALSOFT_INSTALL_CONFIG instead")
 102 endif()
 103 if(DEFINED ALSOFT_HRTF_DEFS)
 104     message(WARNING "ALSOFT_HRTF_DEFS is deprecated. Use ALSOFT_INSTALL_HRTF_DATA instead")
 105 endif()
 106 if(DEFINED ALSOFT_AMBDEC_PRESETS)
 107     message(WARNING "ALSOFT_AMBDEC_PRESETS is deprecated. Use ALSOFT_INSTALL_AMBDEC_PRESETS instead")
 108 endif()
 109
 110
 111 set(CPP_DEFS ) # C pre-processor, not C++
 112 set(INC_PATHS )
 113 set(C_FLAGS )
 114 set(LINKER_FLAGS )
 115 set(EXTRA_LIBS )
 116
 117 if(WIN32)
 118     set(CPP_DEFS ${CPP_DEFS} _WIN32)
 119     if(MINGW)
 120         set(CPP_DEFS ${CPP_DEFS} __USE_MINGW_ANSI_STDIO)
 121     endif()
 122
 123     option(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
 124     if(MINGW)
 125         option(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
 126     endif()
 127 elseif(APPLE)
 128     option(ALSOFT_OSX_FRAMEWORK "Build as macOS framework" OFF)
 129 endif()
 130
 131
 132 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
 133 if("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 134     set(INC_PATHS ${INC_PATHS} /usr/include)
 135     set(LINKER_FLAGS ${LINKER_FLAGS} -L/usr/lib)
 136 endif()
 137
 138 if(NOT LIBTYPE)
 139     set(LIBTYPE SHARED)
 140 endif()
 141
 142 set(LIB_MAJOR_VERSION "1")
 143 set(LIB_MINOR_VERSION "20")
 144 set(LIB_REVISION "1")
 145 set(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 146 set(LIB_VERSION_NUM ${LIB_MAJOR_VERSION},${LIB_MINOR_VERSION},${LIB_REVISION},0)
 147
 148 set(EXPORT_DECL "")
 149
 150
 151 # Require C++14
 152 set(CMAKE_CXX_STANDARD 14)
 153 set(CMAKE_CXX_STANDARD_REQUIRED TRUE)
 154
 155 # Prefer C11, but support C99 and C90 too.
 156 set(CMAKE_C_STANDARD 11)
 157
 158 if(NOT WIN32)
 159     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 160     check_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 161     if(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 162         set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 163         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 164         check_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 165         if(NOT HAVE_POSIX_MEMALIGN_POSIX)
 166             set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 167         else()
 168             set(CPP_DEFS ${CPP_DEFS} _POSIX_C_SOURCE=200112L _XOPEN_SOURCE=600)
 169         endif()
 170     endif()
 171     unset(OLD_REQUIRED_FLAGS)
 172 endif()
 173
 174 # C99 has restrict, but C++ does not, so we can only utilize __restrict.
 175 check_cxx_source_compiles("int *__restrict foo;
 176 int main() { return 0; }" HAVE___RESTRICT)
 177 if(HAVE___RESTRICT)
 178     set(CPP_DEFS ${CPP_DEFS} RESTRICT=__restrict)
 179 else()
 180     set(CPP_DEFS ${CPP_DEFS} "RESTRICT=")
 181 endif()
 182
 183 # Some systems may need libatomic for atomic functions to work
 184 set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 185 set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 186 check_cxx_source_compiles("#include <atomic>
 187 std::atomic<int> foo{0};
 188 int main() { return foo.fetch_add(2); }"
 189 HAVE_LIBATOMIC)
 190 if(NOT HAVE_LIBATOMIC)
 191     set(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 192 else()
 193     set(EXTRA_LIBS atomic ${EXTRA_LIBS})
 194 endif()
 195 unset(OLD_REQUIRED_LIBRARIES)
 196
 197 # Include liblog for Android logging
 198 check_library_exists(log __android_log_print "" HAVE_LIBLOG)
 199 if(HAVE_LIBLOG)
 200     set(EXTRA_LIBS log ${EXTRA_LIBS})
 201     set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 202 endif()
 203
 204 if(MSVC)
 205     set(CPP_DEFS ${CPP_DEFS} _CRT_SECURE_NO_WARNINGS NOMINMAX)
 206     check_cxx_compiler_flag(/permissive- HAVE_PERMISSIVE_SWITCH)
 207     if(HAVE_PERMISSIVE_SWITCH)
 208         set(C_FLAGS ${C_FLAGS} $<$<COMPILE_LANGUAGE:CXX>:/permissive->)
 209     endif()
 210     set(C_FLAGS ${C_FLAGS} /W4 /w14640 /wd4065 /wd4268 /wd4324 /wd5030)
 211
 212     if(NOT DXSDK_DIR)
 213         string(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 214     else()
 215         string(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 216     endif()
 217     if(DXSDK_DIR)
 218         message(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 219     endif()
 220
 221     option(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 222     if(FORCE_STATIC_VCRT)
 223         foreach(flag_var
 224                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 225                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 226                 CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
 227                 CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 228             if(${flag_var} MATCHES "/MD")
 229                 string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 230             endif()
 231         endforeach(flag_var)
 232     endif()
 233 else()
 234     set(C_FLAGS ${C_FLAGS} -Winline -Wunused -Wall -Wextra -Wshadow -Wconversion -Wcast-align
 235         -Wpedantic
 236         $<$<COMPILE_LANGUAGE:CXX>:-Wold-style-cast -Wnon-virtual-dtor -Woverloaded-virtual>)
 237
 238     if(ALSOFT_WERROR)
 239         set(C_FLAGS ${C_FLAGS} -Werror)
 240     endif()
 241
 242     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 243     # instead of NDEBUG)
 244     foreach(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 245         if(${flag_var} MATCHES "-DNDEBUG")
 246             string(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 247         endif()
 248     endforeach()
 249
 250     check_c_compiler_flag(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 251     if(HAVE_FNO_MATH_ERRNO)
 252         set(C_FLAGS ${C_FLAGS} -fno-math-errno)
 253     endif()
 254
 255     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 256     if(ALSOFT_STATIC_LIBGCC)
 257         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 258         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 259         check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBGCC_SWITCH)
 260         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 261         unset(OLD_REQUIRED_LIBRARIES)
 262
 263         if(NOT HAVE_STATIC_LIBGCC_SWITCH)
 264             message(FATAL_ERROR "Cannot static link libgcc")
 265         endif()
 266         set(LINKER_FLAGS ${LINKER_FLAGS} -static-libgcc)
 267     endif()
 268
 269     option(ALSOFT_STATIC_STDCXX "Static link libstdc++" OFF)
 270     if(ALSOFT_STATIC_STDCXX)
 271         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 272         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-Wl,--push-state,-Bstatic,-lstdc++,--pop-state")
 273         check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBSTDCXX_SWITCH)
 274         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 275         unset(OLD_REQUIRED_LIBRARIES)
 276
 277         if(NOT HAVE_STATIC_LIBSTDCXX_SWITCH)
 278             message(FATAL_ERROR "Cannot static link libstdc++")
 279         endif()
 280         set(LINKER_FLAGS ${LINKER_FLAGS} "-Wl,--push-state,-Bstatic,-lstdc++,--pop-state")
 281     endif()
 282
 283     if(WIN32)
 284         option(ALSOFT_STATIC_WINPTHREAD "Static link libwinpthread" OFF)
 285         if(ALSOFT_STATIC_WINPTHREAD)
 286             set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 287             set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-Wl,--push-state,-Bstatic,-lwinpthread,--pop-state")
 288             check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBWINPTHREAD_SWITCH)
 289             set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 290             unset(OLD_REQUIRED_LIBRARIES)
 291
 292             if(NOT HAVE_STATIC_LIBWINPTHREAD_SWITCH)
 293                 message(FATAL_ERROR "Cannot static link libwinpthread")
 294             endif()
 295             set(LINKER_FLAGS ${LINKER_FLAGS} "-Wl,--push-state,-Bstatic,-lwinpthread,--pop-state")
 296         endif()
 297     endif()
 298 endif()
 299
 300 # Set visibility/export options if available
 301 if(WIN32)
 302     if(NOT LIBTYPE STREQUAL "STATIC")
 303         set(EXPORT_DECL "__declspec(dllexport)")
 304     endif()
 305 else()
 306     set(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 307     # Yes GCC, really don't accept visibility modes you don't support
 308     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 309
 310     check_c_source_compiles("int foo() __attribute__((visibility(\"protected\")));
 311                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 312     if(HAVE_GCC_PROTECTED_VISIBILITY)
 313         if(NOT LIBTYPE STREQUAL "STATIC")
 314             set(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 315         endif()
 316     else()
 317         check_c_source_compiles("int foo() __attribute__((visibility(\"default\")));
 318                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 319         if(HAVE_GCC_DEFAULT_VISIBILITY)
 320             if(NOT LIBTYPE STREQUAL "STATIC")
 321                 set(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 322             endif()
 323         endif()
 324     endif()
 325
 326     if(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 327         check_c_compiler_flag(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 328         if(HAVE_VISIBILITY_HIDDEN_SWITCH)
 329             set(C_FLAGS ${C_FLAGS} -fvisibility=hidden)
 330         endif()
 331     endif()
 332
 333     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 334 endif()
 335
 336
 337 set(SSE2_SWITCH "")
 338 set(SSE3_SWITCH "")
 339 set(SSE4_1_SWITCH "")
 340 set(FPU_NEON_SWITCH "")
 341
 342 set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 343 if(NOT MSVC)
 344     # Yes GCC, really don't accept command line options you don't support
 345     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Werror")
 346 endif()
 347 check_c_compiler_flag(-msse2 HAVE_MSSE2_SWITCH)
 348 if(HAVE_MSSE2_SWITCH)
 349     set(SSE2_SWITCH "-msse2")
 350     check_c_compiler_flag(-msse3 HAVE_MSSE3_SWITCH)
 351     if(HAVE_MSSE3_SWITCH)
 352         set(SSE3_SWITCH "-msse3")
 353         check_c_compiler_flag(-msse4.1 HAVE_MSSE4_1_SWITCH)
 354         if(HAVE_MSSE4_1_SWITCH)
 355             set(SSE4_1_SWITCH "-msse4.1")
 356         endif()
 357     endif()
 358 endif()
 359 check_c_compiler_flag(-mfpu=neon HAVE_MFPU_NEON_SWITCH)
 360 if(HAVE_MFPU_NEON_SWITCH)
 361     set(FPU_NEON_SWITCH "-mfpu=neon")
 362 endif()
 363 set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 364 unset(OLD_REQUIRED_FLAGS)
 365
 366 check_include_file(xmmintrin.h HAVE_XMMINTRIN_H ${SSE2_SWITCH})
 367 check_include_file(emmintrin.h HAVE_EMMINTRIN_H ${SSE2_SWITCH})
 368 check_include_file(pmmintrin.h HAVE_PMMINTRIN_H ${SSE3_SWITCH})
 369 check_include_file(smmintrin.h HAVE_SMMINTRIN_H ${SSE4_1_SWITCH})
 370 check_include_file(arm_neon.h HAVE_ARM_NEON_H ${FPU_NEON_SWITCH})
 371
 372 set(SSE_FLAGS )
 373 set(FPMATH_SET "0")
 374 if(CMAKE_SIZEOF_VOID_P MATCHES "4" AND (SSE2_SWITCH OR MSVC))
 375     option(ALSOFT_ENABLE_SSE2_CODEGEN "Enable SSE2 code generation instead of x87 for 32-bit targets." TRUE)
 376     if(ALSOFT_ENABLE_SSE2_CODEGEN)
 377         if(SSE2_SWITCH)
 378             check_c_compiler_flag("${SSE2_SWITCH} -mfpmath=sse" HAVE_MFPMATH_SSE_2)
 379             if(HAVE_MFPMATH_SSE_2)
 380                 set(SSE_FLAGS ${SSE_FLAGS} ${SSE2_SWITCH} -mfpmath=sse)
 381                 set(C_FLAGS ${C_FLAGS} ${SSE_FLAGS})
 382                 set(FPMATH_SET 2)
 383             endif()
 384             # SSE depends on a 16-byte aligned stack, and by default, GCC
 385             # assumes the stack is suitably aligned. Older Linux code or other
 386             # OSs don't guarantee this on 32-bit, so externally-callable
 387             # functions need to ensure an aligned stack.
 388             set(EXPORT_DECL "${EXPORT_DECL} __attribute__((force_align_arg_pointer))")
 389         elseif(MSVC)
 390             check_c_compiler_flag("/arch:SSE2" HAVE_ARCH_SSE2)
 391             if(HAVE_ARCH_SSE2)
 392                 set(SSE_FLAGS ${SSE_FLAGS} "/arch:SSE2")
 393                 set(C_FLAGS ${C_FLAGS} ${SSE_FLAGS})
 394                 set(FPMATH_SET 2)
 395             endif()
 396         endif()
 397     endif()
 398 endif()
 399
 400 if(HAVE_EMMINTRIN_H)
 401     set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 402     foreach(flag_var ${SSE_FLAGS})
 403         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${flag_var}")
 404     endforeach()
 405
 406     check_c_source_compiles("#include <emmintrin.h>
 407                              int main() {_mm_pause(); return 0;}" HAVE_SSE_INTRINSICS)
 408
 409     set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 410 endif()
 411
 412
 413 check_include_file(malloc.h HAVE_MALLOC_H)
 414 check_include_file(cpuid.h HAVE_CPUID_H)
 415 check_include_file(intrin.h HAVE_INTRIN_H)
 416 check_include_file(guiddef.h HAVE_GUIDDEF_H)
 417 if(NOT HAVE_GUIDDEF_H)
 418     check_include_file(initguid.h HAVE_INITGUID_H)
 419 endif()
 420
 421 # Some systems need libm for some math functions to work
 422 set(MATH_LIB )
 423 check_library_exists(m pow "" HAVE_LIBM)
 424 if(HAVE_LIBM)
 425     set(MATH_LIB ${MATH_LIB} m)
 426     set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 427 endif()
 428
 429 # Some systems need to link with -lrt for clock_gettime as used by the common
 430 # eaxmple functions.
 431 set(RT_LIB )
 432 check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 433 if(HAVE_LIBRT)
 434     set(RT_LIB rt)
 435 endif()
 436
 437 # Check for the dlopen API (for dynamicly loading backend libs)
 438 if(ALSOFT_DLOPEN)
 439     check_include_file(dlfcn.h HAVE_DLFCN_H)
 440     check_library_exists(dl dlopen "" HAVE_LIBDL)
 441     if(HAVE_LIBDL)
 442         set(EXTRA_LIBS dl ${EXTRA_LIBS})
 443         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 444     endif()
 445 endif()
 446
 447 # Check for a cpuid intrinsic
 448 if(HAVE_CPUID_H)
 449     check_c_source_compiles("#include <cpuid.h>
 450         int main()
 451         {
 452             unsigned int eax, ebx, ecx, edx;
 453             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 454         }" HAVE_GCC_GET_CPUID)
 455 endif()
 456 if(HAVE_INTRIN_H)
 457     check_c_source_compiles("#include <intrin.h>
 458         int main()
 459         {
 460             int regs[4];
 461             __cpuid(regs, 0);
 462             return regs[0];
 463         }" HAVE_CPUID_INTRINSIC)
 464 endif()
 465
 466 check_cxx_source_compiles("#include <cstdlib>
 467 int main()
 468 {
 469     void *ptr{std::aligned_alloc(alignof(int), sizeof(int))};
 470     std::free(ptr);
 471     return 0;
 472 }" HAVE_STD_ALIGNED_ALLOC)
 473 check_symbol_exists(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 474 check_symbol_exists(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 475 check_symbol_exists(proc_pidpath     libproc.h HAVE_PROC_PIDPATH)
 476
 477 if(NOT WIN32)
 478     # We need pthreads outside of Windows, for semaphores. It's also used to
 479     # set the priority and name of threads, when possible.
 480     check_include_file(pthread.h HAVE_PTHREAD_H)
 481     if(NOT HAVE_PTHREAD_H)
 482         message(FATAL_ERROR "PThreads is required for non-Windows builds!")
 483     endif()
 484
 485     check_c_compiler_flag(-pthread HAVE_PTHREAD)
 486     if(HAVE_PTHREAD)
 487         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 488         set(C_FLAGS ${C_FLAGS} -pthread)
 489         set(LINKER_FLAGS ${LINKER_FLAGS} -pthread)
 490     endif()
 491
 492     check_symbol_exists(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 493
 494     # Some systems need pthread_np.h to get pthread_setname_np
 495     check_include_files("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 496     if(HAVE_PTHREAD_NP_H)
 497         check_symbol_exists(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 498         if(NOT HAVE_PTHREAD_SETNAME_NP)
 499             check_symbol_exists(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 500         else()
 501             check_c_source_compiles("
 502 #include <pthread.h>
 503 #include <pthread_np.h>
 504 int main()
 505 {
 506     pthread_setname_np(\"testname\");
 507     return 0;
 508 }"
 509                 PTHREAD_SETNAME_NP_ONE_PARAM
 510             )
 511             check_c_source_compiles("
 512 #include <pthread.h>
 513 #include <pthread_np.h>
 514 int main()
 515 {
 516     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 517     return 0;
 518 }"
 519                 PTHREAD_SETNAME_NP_THREE_PARAMS
 520             )
 521         endif()
 522     else()
 523         check_symbol_exists(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 524         if(NOT HAVE_PTHREAD_SETNAME_NP)
 525             check_symbol_exists(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 526         else()
 527             check_c_source_compiles("
 528 #include <pthread.h>
 529 int main()
 530 {
 531     pthread_setname_np(\"testname\");
 532     return 0;
 533 }"
 534                 PTHREAD_SETNAME_NP_ONE_PARAM
 535             )
 536             check_c_source_compiles("
 537 #include <pthread.h>
 538 int main()
 539 {
 540     pthread_setname_np(pthread_self(), \"%s\", \"testname\");
 541     return 0;
 542 }"
 543                 PTHREAD_SETNAME_NP_THREE_PARAMS
 544             )
 545         endif()
 546     endif()
 547 endif()
 548
 549 check_symbol_exists(getopt unistd.h HAVE_GETOPT)
 550
 551
 552 # Common sources used by both the OpenAL implementation library and potentially
 553 # the OpenAL router.
 554 set(COMMON_OBJS
 555     common/albyte.h
 556     common/alcomplex.cpp
 557     common/alcomplex.h
 558     common/alexcpt.cpp
 559     common/alexcpt.h
 560     common/alfstream.cpp
 561     common/alfstream.h
 562     common/almalloc.cpp
 563     common/almalloc.h
 564     common/alnumeric.h
 565     common/aloptional.h
 566     common/alspan.h
 567     common/alstring.cpp
 568     common/alstring.h
 569     common/atomic.h
 570     common/dynload.cpp
 571     common/dynload.h
 572     common/endiantest.h
 573     common/intrusive_ptr.h
 574     common/math_defs.h
 575     common/opthelpers.h
 576     common/polyphase_resampler.cpp
 577     common/polyphase_resampler.h
 578     common/pragmadefs.h
 579     common/strutils.cpp
 580     common/strutils.h
 581     common/threads.cpp
 582     common/threads.h
 583     common/vecmat.h
 584     common/vector.h
 585 )
 586 set(OPENAL_OBJS
 587     al/auxeffectslot.cpp
 588     al/auxeffectslot.h
 589     al/buffer.cpp
 590     al/buffer.h
 591     al/effect.cpp
 592     al/effect.h
 593     al/error.cpp
 594     al/event.cpp
 595     al/event.h
 596     al/extension.cpp
 597     al/filter.cpp
 598     al/filter.h
 599     al/listener.cpp
 600     al/listener.h
 601     al/source.cpp
 602     al/source.h
 603     al/state.cpp
 604 )
 605 set(ALC_OBJS
 606     alc/alc.cpp
 607     alc/alcmain.h
 608     alc/alu.cpp
 609     alc/alu.h
 610     alc/alconfig.cpp
 611     alc/alconfig.h
 612     alc/alcontext.h
 613     alc/ambdec.cpp
 614     alc/ambdec.h
 615     alc/ambidefs.h
 616     alc/bformatdec.cpp
 617     alc/bformatdec.h
 618     alc/bs2b.cpp
 619     alc/bs2b.h
 620     alc/bsinc_defs.h
 621     alc/bsinc_tables.cpp
 622     alc/bsinc_tables.h
 623     alc/bufferline.h
 624     alc/buffer_storage.cpp
 625     alc/buffer_storage.h
 626     alc/compat.h
 627     alc/converter.cpp
 628     alc/converter.h
 629     alc/cpu_caps.cpp
 630     alc/cpu_caps.h
 631     alc/devformat.h
 632     alc/effects/base.h
 633     alc/effects/autowah.cpp
 634     alc/effects/chorus.cpp
 635     alc/effects/compressor.cpp
 636     alc/effects/convolution.cpp
 637     alc/effects/dedicated.cpp
 638     alc/effects/distortion.cpp
 639     alc/effects/echo.cpp
 640     alc/effects/equalizer.cpp
 641     alc/effects/fshifter.cpp
 642     alc/effects/modulator.cpp
 643     alc/effects/null.cpp
 644     alc/effects/pshifter.cpp
 645     alc/effects/reverb.cpp
 646     alc/effects/vmorpher.cpp
 647     alc/filters/biquad.h
 648     alc/filters/biquad.cpp
 649     alc/filters/nfc.cpp
 650     alc/filters/nfc.h
 651     alc/filters/splitter.cpp
 652     alc/filters/splitter.h
 653     alc/fmt_traits.cpp
 654     alc/fmt_traits.h
 655     alc/fpu_ctrl.cpp
 656     alc/fpu_ctrl.h
 657     alc/front_stablizer.h
 658     alc/helpers.cpp
 659     alc/hrtf.cpp
 660     alc/hrtf.h
 661     alc/inprogext.h
 662     alc/logging.h
 663     alc/mastering.cpp
 664     alc/mastering.h
 665     alc/panning.cpp
 666     alc/ringbuffer.cpp
 667     alc/ringbuffer.h
 668     alc/uhjfilter.cpp
 669     alc/uhjfilter.h
 670     alc/uiddefs.cpp
 671     alc/voice.cpp
 672     alc/voice.h
 673     alc/mixer/defs.h
 674     alc/mixer/hrtfbase.h
 675     alc/mixer/mixer_c.cpp
 676 )
 677
 678
 679 set(CPU_EXTS "Default")
 680 set(HAVE_SSE        0)
 681 set(HAVE_SSE2       0)
 682 set(HAVE_SSE3       0)
 683 set(HAVE_SSE4_1     0)
 684 set(HAVE_NEON       0)
 685
 686 # Check for SSE+SSE2 support
 687 option(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 688 option(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 689 if(HAVE_XMMINTRIN_H AND HAVE_EMMINTRIN_H)
 690     option(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 691     option(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 692     if(ALSOFT_CPUEXT_SSE AND ALSOFT_CPUEXT_SSE2)
 693         set(HAVE_SSE 1)
 694         set(HAVE_SSE2 1)
 695         set(ALC_OBJS  ${ALC_OBJS} alc/mixer/mixer_sse.cpp alc/mixer/mixer_sse2.cpp)
 696         if(SSE2_SWITCH)
 697             set_source_files_properties(alc/mixer/mixer_sse.cpp alc/mixer/mixer_sse2.cpp
 698                 PROPERTIES COMPILE_FLAGS "${SSE2_SWITCH}")
 699         endif()
 700         set(CPU_EXTS "${CPU_EXTS}, SSE, SSE2")
 701     endif()
 702 endif()
 703 if(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 704     message(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 705 endif()
 706 if(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 707     message(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 708 endif()
 709
 710 option(ALSOFT_REQUIRE_SSE3 "Require SSE3 support" OFF)
 711 if(HAVE_EMMINTRIN_H)
 712     option(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 713     if(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 714         set(HAVE_SSE3 1)
 715         set(ALC_OBJS  ${ALC_OBJS} alc/mixer/mixer_sse3.cpp)
 716         if(SSE2_SWITCH)
 717             set_source_files_properties(alc/mixer/mixer_sse3.cpp PROPERTIES
 718                 COMPILE_FLAGS "${SSE3_SWITCH}")
 719         endif()
 720         set(CPU_EXTS "${CPU_EXTS}, SSE3")
 721     endif()
 722 endif()
 723 if(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 724     message(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 725 endif()
 726
 727 option(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 728 if(HAVE_SMMINTRIN_H)
 729     option(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 730     if(HAVE_SSE3 AND ALSOFT_CPUEXT_SSE4_1)
 731         set(HAVE_SSE4_1 1)
 732         set(ALC_OBJS  ${ALC_OBJS} alc/mixer/mixer_sse41.cpp)
 733         if(SSE4_1_SWITCH)
 734             set_source_files_properties(alc/mixer/mixer_sse41.cpp PROPERTIES
 735                 COMPILE_FLAGS "${SSE4_1_SWITCH}")
 736         endif()
 737         set(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 738     endif()
 739 endif()
 740 if(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 741     message(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 742 endif()
 743
 744 # Check for ARM Neon support
 745 option(ALSOFT_REQUIRE_NEON "Require ARM Neon support" OFF)
 746 if(HAVE_ARM_NEON_H)
 747     option(ALSOFT_CPUEXT_NEON "Enable ARM Neon support" ON)
 748     if(ALSOFT_CPUEXT_NEON)
 749         set(HAVE_NEON 1)
 750         set(ALC_OBJS  ${ALC_OBJS} alc/mixer/mixer_neon.cpp)
 751         if(FPU_NEON_SWITCH)
 752             set_source_files_properties(alc/mixer/mixer_neon.cpp PROPERTIES
 753                 COMPILE_FLAGS "${FPU_NEON_SWITCH}")
 754         endif()
 755         set(CPU_EXTS "${CPU_EXTS}, Neon")
 756     endif()
 757 endif()
 758 if(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 759     message(FATAL_ERROR "Failed to enabled required ARM Neon CPU extensions")
 760 endif()
 761
 762
 763 set(HAVE_ALSA       0)
 764 set(HAVE_OSS        0)
 765 set(HAVE_SOLARIS    0)
 766 set(HAVE_SNDIO      0)
 767 set(HAVE_DSOUND     0)
 768 set(HAVE_WASAPI     0)
 769 set(HAVE_WINMM      0)
 770 set(HAVE_PORTAUDIO  0)
 771 set(HAVE_PULSEAUDIO 0)
 772 set(HAVE_COREAUDIO  0)
 773 set(HAVE_OPENSL     0)
 774 set(HAVE_OBOE       0)
 775 set(HAVE_WAVE       0)
 776 set(HAVE_SDL2       0)
 777
 778 if(WIN32 OR HAVE_DLFCN_H)
 779     set(IS_LINKED "")
 780     macro(ADD_BACKEND_LIBS _LIBS)
 781     endmacro()
 782 else()
 783     set(IS_LINKED " (linked)")
 784     macro(ADD_BACKEND_LIBS _LIBS)
 785         set(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 786     endmacro()
 787 endif()
 788
 789 set(BACKENDS "")
 790 set(ALC_OBJS  ${ALC_OBJS}
 791     alc/backends/base.cpp
 792     alc/backends/base.h
 793     # Default backends, always available
 794     alc/backends/loopback.cpp
 795     alc/backends/loopback.h
 796     alc/backends/null.cpp
 797     alc/backends/null.h
 798 )
 799
 800 # Check ALSA backend
 801 option(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 802 find_package(ALSA)
 803 if(ALSA_FOUND)
 804     option(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 805     if(ALSOFT_BACKEND_ALSA)
 806         set(HAVE_ALSA 1)
 807         set(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 808         set(ALC_OBJS  ${ALC_OBJS} alc/backends/alsa.cpp alc/backends/alsa.h)
 809         add_backend_libs(${ALSA_LIBRARIES})
 810         set(INC_PATHS ${INC_PATHS} ${ALSA_INCLUDE_DIRS})
 811     endif()
 812 endif()
 813 if(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 814     message(FATAL_ERROR "Failed to enabled required ALSA backend")
 815 endif()
 816
 817 # Check OSS backend
 818 option(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 819 find_package(OSS)
 820 if(OSS_FOUND)
 821     option(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 822     if(ALSOFT_BACKEND_OSS)
 823         set(HAVE_OSS 1)
 824         set(BACKENDS  "${BACKENDS} OSS,")
 825         set(ALC_OBJS  ${ALC_OBJS} alc/backends/oss.cpp alc/backends/oss.h)
 826         if(OSS_LIBRARIES)
 827             set(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 828         endif()
 829         set(INC_PATHS ${INC_PATHS} ${OSS_INCLUDE_DIRS})
 830     endif()
 831 endif()
 832 if(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 833     message(FATAL_ERROR "Failed to enabled required OSS backend")
 834 endif()
 835
 836 # Check Solaris backend
 837 option(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 838 find_package(AudioIO)
 839 if(AUDIOIO_FOUND)
 840     option(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 841     if(ALSOFT_BACKEND_SOLARIS)
 842         set(HAVE_SOLARIS 1)
 843         set(BACKENDS  "${BACKENDS} Solaris,")
 844         set(ALC_OBJS  ${ALC_OBJS} alc/backends/solaris.cpp alc/backends/solaris.h)
 845         set(INC_PATHS ${INC_PATHS} ${AUDIOIO_INCLUDE_DIRS})
 846     endif()
 847 endif()
 848 if(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 849     message(FATAL_ERROR "Failed to enabled required Solaris backend")
 850 endif()
 851
 852 # Check SndIO backend
 853 option(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 854 find_package(SoundIO)
 855 if(SOUNDIO_FOUND)
 856     option(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 857     if(ALSOFT_BACKEND_SNDIO)
 858         set(HAVE_SNDIO 1)
 859         set(BACKENDS  "${BACKENDS} SndIO (linked),")
 860         set(ALC_OBJS  ${ALC_OBJS} alc/backends/sndio.cpp alc/backends/sndio.h)
 861         set(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 862         set(INC_PATHS ${INC_PATHS} ${SOUNDIO_INCLUDE_DIRS})
 863     endif()
 864 endif()
 865 if(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 866     message(FATAL_ERROR "Failed to enabled required SndIO backend")
 867 endif()
 868
 869 # Check Windows-only backends
 870 option(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 871 option(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 872 option(ALSOFT_REQUIRE_WASAPI "Require WASAPI backend" OFF)
 873 if(WIN32)
 874     set(WINSDK_LIB_DIRS )
 875     set(WINSDK_INCLUDE_DIRS )
 876     find_package(WindowsSDK)
 877     if(WINDOWSSDK_FOUND)
 878         get_windowssdk_library_dirs(${WINDOWSSDK_PREFERRED_DIR} WINSDK_LIB_DIRS)
 879         get_windowssdk_include_dirs(${WINDOWSSDK_PREFERRED_DIR} WINSDK_INCLUDE_DIRS)
 880     endif()
 881
 882     # Check MMSystem backend
 883     check_include_files("windows.h;mmsystem.h" HAVE_MMSYSTEM_H)
 884     find_library(WINMM_LIBRARY NAMES winmm
 885         PATHS ${WINSDK_LIB_DIRS})
 886     if(HAVE_MMSYSTEM_H AND WINMM_LIBRARY)
 887         option(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 888         if(ALSOFT_BACKEND_WINMM)
 889             set(HAVE_WINMM 1)
 890             set(BACKENDS  "${BACKENDS} WinMM,")
 891             set(ALC_OBJS  ${ALC_OBJS} alc/backends/winmm.cpp alc/backends/winmm.h)
 892             set(EXTRA_LIBS ${WINMM_LIBRARY} ${EXTRA_LIBS})
 893         endif()
 894     endif()
 895
 896     # Check DSound backend
 897     find_package(DSound)
 898     if(DSOUND_FOUND)
 899         option(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 900         if(ALSOFT_BACKEND_DSOUND)
 901             set(HAVE_DSOUND 1)
 902             set(BACKENDS  "${BACKENDS} DirectSound${IS_LINKED},")
 903             set(ALC_OBJS  ${ALC_OBJS} alc/backends/dsound.cpp alc/backends/dsound.h)
 904             add_backend_libs(${DSOUND_LIBRARIES})
 905             set(INC_PATHS ${INC_PATHS} ${DSOUND_INCLUDE_DIRS})
 906         endif()
 907     endif()
 908
 909     # Check for WASAPI backend
 910     check_include_file(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 911     if(HAVE_MMDEVICEAPI_H)
 912         option(ALSOFT_BACKEND_WASAPI "Enable WASAPI backend" ON)
 913         if(ALSOFT_BACKEND_WASAPI)
 914             set(HAVE_WASAPI 1)
 915             set(BACKENDS  "${BACKENDS} WASAPI,")
 916             set(ALC_OBJS  ${ALC_OBJS} alc/backends/wasapi.cpp alc/backends/wasapi.h)
 917         endif()
 918     endif()
 919 endif()
 920 if(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
 921     message(FATAL_ERROR "Failed to enabled required WinMM backend")
 922 endif()
 923 if(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
 924     message(FATAL_ERROR "Failed to enabled required DSound backend")
 925 endif()
 926 if(ALSOFT_REQUIRE_WASAPI AND NOT HAVE_WASAPI)
 927     message(FATAL_ERROR "Failed to enabled required WASAPI backend")
 928 endif()
 929
 930 # Check PortAudio backend
 931 option(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
 932 find_package(PortAudio)
 933 if(PORTAUDIO_FOUND)
 934     option(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
 935     if(ALSOFT_BACKEND_PORTAUDIO)
 936         set(HAVE_PORTAUDIO 1)
 937         set(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
 938         set(ALC_OBJS  ${ALC_OBJS} alc/backends/portaudio.cpp alc/backends/portaudio.h)
 939         add_backend_libs(${PORTAUDIO_LIBRARIES})
 940         set(INC_PATHS ${INC_PATHS} ${PORTAUDIO_INCLUDE_DIRS})
 941     endif()
 942 endif()
 943 if(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
 944     message(FATAL_ERROR "Failed to enabled required PortAudio backend")
 945 endif()
 946
 947 # Check PulseAudio backend
 948 option(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
 949 find_package(PulseAudio)
 950 if(PULSEAUDIO_FOUND)
 951     option(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
 952     if(ALSOFT_BACKEND_PULSEAUDIO)
 953         set(HAVE_PULSEAUDIO 1)
 954         set(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
 955         set(ALC_OBJS  ${ALC_OBJS} alc/backends/pulseaudio.cpp alc/backends/pulseaudio.h)
 956         add_backend_libs(${PULSEAUDIO_LIBRARIES})
 957         set(INC_PATHS ${INC_PATHS} ${PULSEAUDIO_INCLUDE_DIRS})
 958     endif()
 959 endif()
 960 if(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
 961     message(FATAL_ERROR "Failed to enabled required PulseAudio backend")
 962 endif()
 963
 964 # Check JACK backend
 965 option(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
 966 find_package(JACK)
 967 if(JACK_FOUND)
 968     option(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
 969     if(ALSOFT_BACKEND_JACK)
 970         set(HAVE_JACK 1)
 971         set(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
 972         set(ALC_OBJS  ${ALC_OBJS} alc/backends/jack.cpp alc/backends/jack.h)
 973         add_backend_libs(${JACK_LIBRARIES})
 974         set(INC_PATHS ${INC_PATHS} ${JACK_INCLUDE_DIRS})
 975     endif()
 976 endif()
 977 if(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
 978     message(FATAL_ERROR "Failed to enabled required JACK backend")
 979 endif()
 980
 981 # Check CoreAudio backend
 982 option(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
 983 find_library(COREAUDIO_FRAMEWORK NAMES CoreAudio)
 984 find_path(AUDIOUNIT_INCLUDE_DIR NAMES AudioUnit/AudioUnit.h)
 985 if(COREAUDIO_FRAMEWORK AND AUDIOUNIT_INCLUDE_DIR)
 986     option(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
 987     if(ALSOFT_BACKEND_COREAUDIO)
 988         set(HAVE_COREAUDIO 1)
 989         set(ALC_OBJS  ${ALC_OBJS} alc/backends/coreaudio.cpp alc/backends/coreaudio.h)
 990         set(BACKENDS  "${BACKENDS} CoreAudio,")
 991         if(CMAKE_SYSTEM_NAME STREQUAL "iOS")
 992             find_library(COREFOUNDATION_FRAMEWORK NAMES CoreFoundation)
 993             set(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${COREFOUNDATION_FRAMEWORK} ${EXTRA_LIBS})
 994         else()
 995             set(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} /System/Library/Frameworks/AudioUnit.framework
 996                 /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
 997         endif()
 998
 999         # Some versions of OSX may need the AudioToolbox framework. Add it if
1000         # it's found.
1001         find_library(AUDIOTOOLBOX_LIBRARY NAMES AudioToolbox)
1002         if(AUDIOTOOLBOX_LIBRARY)
1003             set(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1004         endif()
1005
1006         set(INC_PATHS ${INC_PATHS} ${AUDIOUNIT_INCLUDE_DIR})
1007     endif()
1008 endif()
1009 if(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1010     message(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1011 endif()
1012
1013 # Check for OpenSL (Android) backend
1014 option(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1015 find_package(OpenSL)
1016 if(OPENSL_FOUND)
1017     option(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1018     if(ALSOFT_BACKEND_OPENSL)
1019         set(HAVE_OPENSL 1)
1020         set(ALC_OBJS  ${ALC_OBJS} alc/backends/opensl.cpp alc/backends/opensl.h)
1021         set(BACKENDS  "${BACKENDS} OpenSL,")
1022         set(EXTRA_LIBS ${OPENSL_LIBRARIES} ${EXTRA_LIBS})
1023         set(INC_PATHS ${INC_PATHS} ${OPENSL_INCLUDE_DIRS})
1024     endif()
1025 endif()
1026 if(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1027     message(FATAL_ERROR "Failed to enabled required OpenSL backend")
1028 endif()
1029
1030 # Check for Oboe (Android) backend
1031 set(OBOE_TARGET )
1032 if(ANDROID)
1033     set(OBOE_SOURCE "" CACHE STRING "Source directory for Oboe.")
1034     if(OBOE_SOURCE)
1035         # Force Oboe to build with hidden symbols. Don't want to be exporting
1036         # them from OpenAL.
1037         set(OLD_CXX_FLAGS ${CMAKE_CXX_FLAGS})
1038         check_cxx_compiler_flag(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
1039         if(HAVE_VISIBILITY_HIDDEN_SWITCH)
1040             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
1041         endif()
1042         add_subdirectory(${OBOE_SOURCE} ./oboe)
1043         set(CMAKE_CXX_FLAGS ${OLD_CXX_FLAGS})
1044         unset(OLD_CXX_FLAGS)
1045
1046         set(OBOE_TARGET oboe)
1047     else()
1048         find_package(Oboe)
1049         if(OBOE_FOUND)
1050             set(OBOE_TARGET "oboe::oboe")
1051         endif()
1052     endif()
1053 endif()
1054
1055 option(ALSOFT_REQUIRE_OBOE "Require Oboe backend" OFF)
1056 if(OBOE_TARGET)
1057     option(ALSOFT_BACKEND_OBOE "Enable Oboe backend" ON)
1058     if(ALSOFT_BACKEND_OBOE)
1059         set(HAVE_OBOE 1)
1060         set(ALC_OBJS  ${ALC_OBJS} alc/backends/oboe.cpp alc/backends/oboe.h)
1061         set(BACKENDS  "${BACKENDS} Oboe,")
1062         set(EXTRA_LIBS ${OBOE_TARGET} ${EXTRA_LIBS})
1063     endif()
1064 endif()
1065 if(ALSOFT_REQUIRE_OBOE AND NOT HAVE_OBOE)
1066     message(FATAL_ERROR "Failed to enabled required Oboe backend")
1067 endif()
1068
1069 # Check for SDL2 backend
1070 option(ALSOFT_REQUIRE_SDL2 "Require SDL2 backend" OFF)
1071 find_package(SDL2)
1072 if(SDL2_FOUND)
1073     # Off by default, since it adds a runtime dependency
1074     option(ALSOFT_BACKEND_SDL2 "Enable SDL2 backend" OFF)
1075     if(ALSOFT_BACKEND_SDL2)
1076         set(HAVE_SDL2 1)
1077         set(ALC_OBJS  ${ALC_OBJS} alc/backends/sdl2.cpp alc/backends/sdl2.h)
1078         set(BACKENDS  "${BACKENDS} SDL2,")
1079         set(EXTRA_LIBS ${SDL2_LIBRARY} ${EXTRA_LIBS})
1080         set(INC_PATHS ${INC_PATHS} ${SDL2_INCLUDE_DIR})
1081     endif()
1082 endif()
1083 if(ALSOFT_REQUIRE_SDL2 AND NOT SDL2_FOUND)
1084     message(FATAL_ERROR "Failed to enabled required SDL2 backend")
1085 endif()
1086
1087 # Optionally enable the Wave Writer backend
1088 option(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1089 if(ALSOFT_BACKEND_WAVE)
1090     set(HAVE_WAVE 1)
1091     set(ALC_OBJS  ${ALC_OBJS} alc/backends/wave.cpp alc/backends/wave.h)
1092     set(BACKENDS  "${BACKENDS} WaveFile,")
1093 endif()
1094
1095 # This is always available
1096 set(BACKENDS  "${BACKENDS} Null")
1097
1098
1099 find_package(Git)
1100 if(ALSOFT_UPDATE_BUILD_VERSION AND GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1101     # Get the current working branch and its latest abbreviated commit hash
1102     add_custom_target(build_version
1103         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE} -D LIB_VERSION=${LIB_VERSION}
1104             -D LIB_VERSION_NUM=${LIB_VERSION_NUM} -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1105             -D DST=${OpenAL_BINARY_DIR}/version.h -P ${OpenAL_SOURCE_DIR}/version.cmake
1106         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1107         VERBATIM
1108     )
1109 else()
1110     set(GIT_BRANCH "UNKNOWN")
1111     set(GIT_COMMIT_HASH "unknown")
1112     configure_file(
1113         "${OpenAL_SOURCE_DIR}/version.h.in"
1114         "${OpenAL_BINARY_DIR}/version.h")
1115 endif()
1116
1117
1118 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" ON)
1119 if(ALSOFT_EMBED_HRTF_DATA)
1120     macro(make_hrtf_header FILENAME VARNAME)
1121         set(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1122         set(outfile  "${OpenAL_BINARY_DIR}/${VARNAME}.h")
1123
1124         add_custom_command(OUTPUT "${outfile}"
1125             COMMAND ${CMAKE_COMMAND} -D "INPUT_FILE=${infile}" -D "OUTPUT_FILE=${outfile}"
1126                 -D "VARIABLE_NAME=${VARNAME}" -P "${CMAKE_MODULE_PATH}/bin2h.script.cmake"
1127             WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1128             DEPENDS "${infile}" "${CMAKE_MODULE_PATH}/bin2h.script.cmake"
1129             VERBATIM
1130         )
1131         set(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1132     endmacro()
1133
1134     make_hrtf_header("Default HRTF.mhr" "hrtf_default")
1135 endif()
1136
1137
1138 if(ALSOFT_UTILS AND NOT ALSOFT_NO_CONFIG_UTIL)
1139     find_package(Qt5Widgets)
1140 endif()
1141 if(ALSOFT_EXAMPLES)
1142     find_package(SndFile)
1143     find_package(SDL2)
1144     if(SDL2_FOUND)
1145         find_package(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1146     endif()
1147 endif()
1148
1149 if(NOT WIN32)
1150     set(LIBNAME "openal")
1151 else()
1152     set(LIBNAME "OpenAL32")
1153 endif()
1154
1155 # Needed for openal.pc.in
1156 set(prefix ${CMAKE_INSTALL_PREFIX})
1157 set(exec_prefix "\${prefix}")
1158 set(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1159 set(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1160 set(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1161 set(PACKAGE_VERSION "${LIB_VERSION}")
1162 set(PKG_CONFIG_CFLAGS )
1163 set(PKG_CONFIG_PRIVATE_LIBS )
1164 if(LIBTYPE STREQUAL "STATIC")
1165     set(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC)
1166     foreach(FLAG  ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1167         # If this is already a linker flag, or is a full path+file, add it
1168         # as-is. Otherwise, it's a name intended to be dressed as -lname.
1169         if(FLAG MATCHES "^-.*" OR EXISTS "${FLAG}")
1170             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} ${FLAG}")
1171         else()
1172             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} -l${FLAG}")
1173         endif()
1174     endforeach()
1175 endif()
1176
1177 # End configuration
1178 configure_file(
1179     "${OpenAL_SOURCE_DIR}/config.h.in"
1180     "${OpenAL_BINARY_DIR}/config.h")
1181 configure_file(
1182     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1183     "${OpenAL_BINARY_DIR}/openal.pc"
1184     @ONLY)
1185
1186
1187 add_library(common STATIC EXCLUDE_FROM_ALL ${COMMON_OBJS})
1188 target_include_directories(common PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/include)
1189 target_compile_definitions(common PRIVATE ${CPP_DEFS})
1190 target_compile_options(common PRIVATE ${C_FLAGS})
1191 set_target_properties(common PROPERTIES POSITION_INDEPENDENT_CODE TRUE)
1192
1193
1194 unset(HAS_ROUTER)
1195 set(IMPL_TARGET OpenAL) # Either OpenAL or soft_oal.
1196
1197 # Build main library
1198 if(LIBTYPE STREQUAL "STATIC")
1199     add_library(${IMPL_TARGET} STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS})
1200     target_compile_definitions(${IMPL_TARGET} PUBLIC AL_LIBTYPE_STATIC)
1201     target_link_libraries(${IMPL_TARGET} PRIVATE ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1202     if(WIN32)
1203         # This option is for static linking OpenAL Soft into another project
1204         # that already defines the IDs. It is up to that project to ensure all
1205         # required IDs are defined.
1206         option(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
1207         if(ALSOFT_NO_UID_DEFS)
1208             target_compile_definitions(${IMPL_TARGET} PRIVATE AL_NO_UID_DEFS)
1209         endif()
1210     endif()
1211 else()
1212     set(RC_CONFIG resources/openal32.rc)
1213     if(WIN32 AND ALSOFT_BUILD_ROUTER)
1214         add_library(OpenAL SHARED
1215             resources/router.rc
1216             router/router.cpp
1217             router/router.h
1218             router/alc.cpp
1219             router/al.cpp
1220         )
1221         target_compile_definitions(OpenAL
1222             PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1223         target_compile_options(OpenAL PRIVATE ${C_FLAGS})
1224         target_link_libraries(OpenAL PRIVATE common ${LINKER_FLAGS})
1225         target_include_directories(OpenAL
1226           PUBLIC
1227             $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include>
1228             $<INSTALL_INTERFACE:include>
1229           PRIVATE
1230             ${OpenAL_SOURCE_DIR}/common
1231             ${OpenAL_BINARY_DIR}
1232         )
1233         set_target_properties(OpenAL PROPERTIES PREFIX "")
1234         set_target_properties(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1235         if(TARGET build_version)
1236             add_dependencies(OpenAL build_version)
1237         endif()
1238         set(HAS_ROUTER 1)
1239
1240         set(LIBNAME "soft_oal")
1241         set(IMPL_TARGET soft_oal)
1242         set(RC_CONFIG resources/soft_oal.rc)
1243     endif()
1244
1245     # !important: for osx framework public header works, the headers must be in
1246     # the project
1247     set(TARGET_PUBLIC_HEADERS include/AL/al.h include/AL/alc.h include/AL/alext.h include/AL/efx.h)
1248     add_library(${IMPL_TARGET} SHARED ${OPENAL_OBJS} ${ALC_OBJS} ${RC_CONFIG}
1249         ${TARGET_PUBLIC_HEADERS})
1250     if(WIN32)
1251         set_target_properties(${IMPL_TARGET} PROPERTIES PREFIX "")
1252     endif()
1253     target_link_libraries(${IMPL_TARGET} PRIVATE common ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1254
1255     if(APPLE AND ALSOFT_OSX_FRAMEWORK)
1256         # Sets framework name to soft_oal to avoid ambiguity with the system OpenAL.framework
1257         set(LIBNAME "soft_oal")
1258         if(GIT_FOUND)
1259             EXECUTE_PROCESS(COMMAND ${GIT_EXECUTABLE} rev-list --count head
1260                 TIMEOUT 5
1261                 OUTPUT_VARIABLE BUNDLE_VERSION
1262                 OUTPUT_STRIP_TRAILING_WHITESPACE)
1263         else()
1264             set(BUNDLE_VERSION 1)
1265         endif()
1266
1267         # Build: Fix rpath in iOS shared libraries
1268         # If this flag is not set, the final dylib binary ld path will be
1269         # /User/xxx/*/soft_oal.framework/soft_oal, which can't be loaded by iOS devices.
1270         # See also: https://github.com/libjpeg-turbo/libjpeg-turbo/commit/c80ddef7a4ce21ace9e3ca0fd190d320cc8cdaeb
1271         if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG)
1272             set(CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG "-Wl,-rpath,")
1273         endif()
1274
1275         set_target_properties(${IMPL_TARGET} PROPERTIES
1276             FRAMEWORK TRUE
1277             FRAMEWORK_VERSION C
1278             MACOSX_FRAMEWORK_NAME "${IMPL_TARGET}"
1279             MACOSX_FRAMEWORK_IDENTIFIER "org.openal-soft.openal"
1280             MACOSX_FRAMEWORK_SHORT_VERSION_STRING ${LIB_VERSION}
1281             MACOSX_FRAMEWORK_BUNDLE_VERSION ${BUNDLE_VERSION}
1282             XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY ""
1283             XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED "NO"
1284             XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED "NO"
1285             PUBLIC_HEADER "${TARGET_PUBLIC_HEADERS}"
1286             MACOSX_RPATH TRUE)
1287     endif()
1288 endif()
1289
1290 target_include_directories(${IMPL_TARGET}
1291   PUBLIC
1292     $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include>
1293     $<INSTALL_INTERFACE:include>
1294   PRIVATE
1295     ${INC_PATHS}
1296     ${OpenAL_BINARY_DIR}
1297     ${OpenAL_SOURCE_DIR}
1298     ${OpenAL_SOURCE_DIR}/alc
1299     ${OpenAL_SOURCE_DIR}/common
1300 )
1301
1302 set_target_properties(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1303     VERSION ${LIB_VERSION}
1304     SOVERSION ${LIB_MAJOR_VERSION}
1305 )
1306 target_compile_definitions(${IMPL_TARGET}
1307     PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES ${CPP_DEFS})
1308 target_compile_options(${IMPL_TARGET} PRIVATE ${C_FLAGS})
1309
1310 if(TARGET build_version)
1311     add_dependencies(${IMPL_TARGET} build_version)
1312 endif()
1313
1314 if(WIN32 AND MINGW AND ALSOFT_BUILD_IMPORT_LIB AND NOT LIBTYPE STREQUAL "STATIC")
1315     find_program(SED_EXECUTABLE NAMES sed DOC "sed executable")
1316     if(NOT SED_EXECUTABLE OR NOT CMAKE_DLLTOOL)
1317         message(STATUS "")
1318         if(NOT SED_EXECUTABLE)
1319             message(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1320         endif()
1321         if(NOT CMAKE_DLLTOOL)
1322             message(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1323         endif()
1324     else()
1325         set_property(TARGET OpenAL APPEND_STRING PROPERTY
1326             LINK_FLAGS " -Wl,--output-def,OpenAL32.def")
1327         add_custom_command(TARGET OpenAL POST_BUILD
1328             COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1329             COMMAND "${CMAKE_DLLTOOL}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1330             COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1331             VERBATIM
1332         )
1333     endif()
1334 endif()
1335
1336 if(HAS_ROUTER)
1337     message(STATUS "")
1338     message(STATUS "Building DLL router")
1339 endif()
1340
1341 message(STATUS "
1342 Building OpenAL with support for the following backends:
1343     ${BACKENDS}
1344
1345 Building with support for CPU extensions:
1346     ${CPU_EXTS}
1347 ")
1348 if(FPMATH_SET)
1349     message(STATUS "Building with SSE${FPMATH_SET} codegen
1350 ")
1351 endif()
1352
1353 if(ALSOFT_EMBED_HRTF_DATA)
1354     message(STATUS "Embedding HRTF datasets
1355 ")
1356 endif()
1357
1358 # Install main library
1359 if(ALSOFT_INSTALL)
1360     install(TARGETS OpenAL EXPORT OpenAL
1361         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1362         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1363         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1364         FRAMEWORK DESTINATION ${CMAKE_INSTALL_LIBDIR}
1365         INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL)
1366     export(TARGETS OpenAL
1367         NAMESPACE OpenAL::
1368         FILE OpenALConfig.cmake)
1369     install(EXPORT OpenAL
1370         DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1371         NAMESPACE OpenAL::
1372         FILE OpenALConfig.cmake)
1373     install(DIRECTORY include/AL
1374         DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
1375     install(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1376         DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1377     if(TARGET soft_oal)
1378         install(TARGETS soft_oal
1379             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
1380     endif()
1381     message(STATUS "Installing library and headers")
1382 else()
1383     message(STATUS "NOT installing library and headers")
1384 endif()
1385
1386 if(ALSOFT_INSTALL_CONFIG)
1387     install(FILES alsoftrc.sample
1388         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1389     message(STATUS "Installing sample configuration")
1390 endif()
1391
1392 if(ALSOFT_INSTALL_HRTF_DATA)
1393     install(DIRECTORY hrtf
1394         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1395     message(STATUS "Installing HRTF data files")
1396 endif()
1397
1398 if(ALSOFT_INSTALL_AMBDEC_PRESETS)
1399     install(DIRECTORY presets
1400         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1401     message(STATUS "Installing AmbDec presets")
1402 endif()
1403 message(STATUS "")
1404
1405 set(UNICODE_FLAG )
1406 if(MINGW)
1407     set(UNICODE_FLAG ${UNICODE_FLAG} -municode)
1408 endif()
1409 set(EXTRA_INSTALLS )
1410 if(ALSOFT_UTILS)
1411     add_executable(openal-info utils/openal-info.c)
1412     target_include_directories(openal-info PRIVATE ${OpenAL_SOURCE_DIR}/common)
1413     target_compile_options(openal-info PRIVATE ${C_FLAGS})
1414     target_link_libraries(openal-info PRIVATE ${LINKER_FLAGS} OpenAL ${UNICODE_FLAG})
1415     if(ALSOFT_INSTALL_EXAMPLES)
1416         set(EXTRA_INSTALLS ${EXTRA_INSTALLS} openal-info)
1417     endif()
1418
1419     find_package(MySOFA)
1420     if(MYSOFA_FOUND)
1421         set(SOFA_SUPPORT_SRCS
1422             utils/sofa-support.cpp
1423             utils/sofa-support.h)
1424         add_library(sofa-support STATIC EXCLUDE_FROM_ALL ${SOFA_SUPPORT_SRCS})
1425         target_compile_definitions(sofa-support PRIVATE ${CPP_DEFS})
1426         target_include_directories(sofa-support PUBLIC ${OpenAL_SOURCE_DIR}/common)
1427         target_compile_options(sofa-support PRIVATE ${C_FLAGS})
1428         target_link_libraries(sofa-support PUBLIC common MySOFA::MySOFA PRIVATE ${LINKER_FLAGS})
1429
1430         set(MAKEMHR_SRCS
1431             utils/makemhr/loaddef.cpp
1432             utils/makemhr/loaddef.h
1433             utils/makemhr/loadsofa.cpp
1434             utils/makemhr/loadsofa.h
1435             utils/makemhr/makemhr.cpp
1436             utils/makemhr/makemhr.h)
1437         if(NOT HAVE_GETOPT)
1438             set(MAKEMHR_SRCS  ${MAKEMHR_SRCS} utils/getopt.c utils/getopt.h)
1439         endif()
1440         add_executable(makemhr ${MAKEMHR_SRCS})
1441         target_compile_definitions(makemhr PRIVATE ${CPP_DEFS})
1442         target_include_directories(makemhr
1443             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/utils)
1444         target_compile_options(makemhr PRIVATE ${C_FLAGS})
1445         target_link_libraries(makemhr PRIVATE ${LINKER_FLAGS} sofa-support ${UNICODE_FLAG})
1446         if(ALSOFT_INSTALL_EXAMPLES)
1447             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} makemhr)
1448         endif()
1449
1450         set(SOFAINFO_SRCS  utils/sofa-info.cpp)
1451         add_executable(sofa-info ${SOFAINFO_SRCS})
1452         target_compile_definitions(sofa-info PRIVATE ${CPP_DEFS})
1453         target_include_directories(sofa-info PRIVATE ${OpenAL_SOURCE_DIR}/utils)
1454         target_compile_options(sofa-info PRIVATE ${C_FLAGS})
1455         target_link_libraries(sofa-info PRIVATE ${LINKER_FLAGS} sofa-support ${UNICODE_FLAG})
1456     endif()
1457     message(STATUS "Building utility programs")
1458
1459     if(NOT ALSOFT_NO_CONFIG_UTIL)
1460         add_subdirectory(utils/alsoft-config)
1461     endif()
1462     message(STATUS "")
1463 endif()
1464
1465
1466 # Add a static library with common functions used by multiple example targets
1467 add_library(ex-common STATIC EXCLUDE_FROM_ALL
1468     examples/common/alhelpers.c
1469     examples/common/alhelpers.h)
1470 target_compile_definitions(ex-common PUBLIC ${CPP_DEFS})
1471 target_include_directories(ex-common PUBLIC ${OpenAL_SOURCE_DIR}/common)
1472 target_compile_options(ex-common PUBLIC ${C_FLAGS})
1473 target_link_libraries(ex-common PUBLIC OpenAL PRIVATE ${RT_LIB})
1474
1475 if(ALSOFT_EXAMPLES)
1476     add_executable(altonegen examples/altonegen.c)
1477     target_link_libraries(altonegen PRIVATE ${LINKER_FLAGS} ${MATH_LIB} ex-common ${UNICODE_FLAG})
1478
1479     add_executable(alrecord examples/alrecord.c)
1480     target_link_libraries(alrecord PRIVATE ${LINKER_FLAGS} ex-common ${UNICODE_FLAG})
1481
1482     if(ALSOFT_INSTALL_EXAMPLES)
1483         set(EXTRA_INSTALLS ${EXTRA_INSTALLS} altonegen alrecord)
1484     endif()
1485
1486     message(STATUS "Building example programs")
1487
1488     if(SNDFILE_FOUND)
1489         add_executable(alplay examples/alplay.c)
1490         target_link_libraries(alplay PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1491             ${UNICODE_FLAG})
1492
1493         add_executable(alstream examples/alstream.c)
1494         target_link_libraries(alstream PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1495             ${UNICODE_FLAG})
1496
1497         add_executable(alreverb examples/alreverb.c)
1498         target_link_libraries(alreverb PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1499             ${UNICODE_FLAG})
1500
1501         add_executable(almultireverb examples/almultireverb.c)
1502         target_link_libraries(almultireverb
1503             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common ${MATH_LIB} ${UNICODE_FLAG})
1504
1505         add_executable(allatency examples/allatency.c)
1506         target_link_libraries(allatency PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1507             ${UNICODE_FLAG})
1508
1509         add_executable(alhrtf examples/alhrtf.c)
1510         target_link_libraries(alhrtf
1511             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common ${MATH_LIB} ${UNICODE_FLAG})
1512
1513         add_executable(alstreamcb examples/alstreamcb.cpp)
1514         target_link_libraries(alstreamcb PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1515             ${UNICODE_FLAG})
1516
1517         add_executable(alconvolve examples/alconvolve.c)
1518         target_link_libraries(alconvolve PRIVATE ${LINKER_FLAGS} common SndFile::SndFile ex-common
1519             ${UNICODE_FLAG})
1520
1521         if(ALSOFT_INSTALL_EXAMPLES)
1522             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alplay alstream alreverb almultireverb allatency
1523                 alhrtf)
1524         endif()
1525
1526         message(STATUS "Building SndFile example programs")
1527     endif()
1528
1529     if(SDL2_FOUND)
1530         add_executable(alloopback examples/alloopback.c)
1531         target_include_directories(alloopback PRIVATE ${SDL2_INCLUDE_DIR})
1532         target_link_libraries(alloopback
1533             PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ex-common ${MATH_LIB})
1534
1535         if(ALSOFT_INSTALL_EXAMPLES)
1536             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alloopback)
1537         endif()
1538
1539         message(STATUS "Building SDL example programs")
1540
1541         set(FFVER_OK FALSE)
1542         if(FFMPEG_FOUND)
1543             set(FFVER_OK TRUE)
1544             if(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1545                 message(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1546                 set(FFVER_OK FALSE)
1547             endif()
1548             if(AVCODEC_VERSION VERSION_LESS "57.64.101")
1549                 message(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1550                 set(FFVER_OK FALSE)
1551             endif()
1552             if(AVUTIL_VERSION VERSION_LESS "55.34.101")
1553                 message(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1554                 set(FFVER_OK FALSE)
1555             endif()
1556             if(SWSCALE_VERSION VERSION_LESS "4.2.100")
1557                 message(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1558                 set(FFVER_OK FALSE)
1559             endif()
1560             if(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1561                 message(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1562                 set(FFVER_OK FALSE)
1563             endif()
1564         endif()
1565         if(FFVER_OK)
1566             add_executable(alffplay examples/alffplay.cpp)
1567             target_include_directories(alffplay
1568                 PRIVATE ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS})
1569             target_link_libraries(alffplay
1570                 PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} ex-common)
1571
1572             if(ALSOFT_INSTALL_EXAMPLES)
1573                 set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alffplay)
1574             endif()
1575             message(STATUS "Building SDL+FFmpeg example programs")
1576         endif()
1577     endif()
1578     message(STATUS "")
1579 endif()
1580
1581 if(EXTRA_INSTALLS)
1582     install(TARGETS ${EXTRA_INSTALLS}
1583         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1584         BUNDLE  DESTINATION ${CMAKE_INSTALL_BINDIR}
1585         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1586         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
1587 endif()