CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 cmake_minimum_required(VERSION 3.0.2)
   4
   5 if(APPLE)
   6     # The workaround for try_compile failing with code signing
   7     # since cmake-3.18.2, not required
   8     set(CMAKE_TRY_COMPILE_PLATFORM_VARIABLES
   9         ${CMAKE_TRY_COMPILE_PLATFORM_VARIABLES}
  10         "CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED"
  11         "CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED")
  12     set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED NO)
  13     set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED NO)
  14 endif()
  15
  16 if(CMAKE_SYSTEM_NAME STREQUAL "iOS")
  17     # Fix compile failure with armv7 deployment target >= 11.0, xcode clang
  18     # will report:
  19     # error: invalid iOS deployment version '--target=armv7-apple-ios13.6',
  20     # iOS 10 is the maximum deployment target for 32-bit targets
  21     # If CMAKE_OSX_DEPLOYMENT_TARGET is not defined, cmake will choose latest
  22     # deployment target
  23     if("${CMAKE_OSX_ARCHITECTURES}" MATCHES ".*armv7.*")
  24         if(NOT DEFINED CMAKE_OSX_DEPLOYMENT_TARGET
  25             OR NOT CMAKE_OSX_DEPLOYMENT_TARGET VERSION_LESS "11.0")
  26             message(STATUS "Forcing iOS deployment target to 10.0 for armv7")
  27             set(CMAKE_OSX_DEPLOYMENT_TARGET "10.0" CACHE STRING "Minimum OS X deployment version"
  28                 FORCE)
  29         endif()
  30     endif()
  31 endif()
  32
  33 project(OpenAL)
  34
  35 if(COMMAND CMAKE_POLICY)
  36     cmake_policy(SET CMP0003 NEW)
  37     cmake_policy(SET CMP0005 NEW)
  38     if(POLICY CMP0020)
  39         cmake_policy(SET CMP0020 NEW)
  40     endif(POLICY CMP0020)
  41     if(POLICY CMP0042)
  42         cmake_policy(SET CMP0042 NEW)
  43     endif(POLICY CMP0042)
  44     if(POLICY CMP0054)
  45         cmake_policy(SET CMP0054 NEW)
  46     endif(POLICY CMP0054)
  47     if(POLICY CMP0075)
  48         cmake_policy(SET CMP0075 NEW)
  49     endif(POLICY CMP0075)
  50 endif(COMMAND CMAKE_POLICY)
  51
  52 if(NOT CMAKE_BUILD_TYPE)
  53     set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  54         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
  55         FORCE)
  56 endif()
  57 if(NOT CMAKE_DEBUG_POSTFIX)
  58     set(CMAKE_DEBUG_POSTFIX "" CACHE STRING
  59         "Library postfix for debug builds. Normally left blank."
  60         FORCE)
  61 endif()
  62
  63 set(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  64
  65 include(CheckFunctionExists)
  66 include(CheckLibraryExists)
  67 include(CheckIncludeFile)
  68 include(CheckIncludeFiles)
  69 include(CheckSymbolExists)
  70 include(CheckCCompilerFlag)
  71 include(CheckCXXCompilerFlag)
  72 include(CheckCSourceCompiles)
  73 include(CheckCXXSourceCompiles)
  74 include(CheckStructHasMember)
  75 include(CMakePackageConfigHelpers)
  76 include(GNUInstallDirs)
  77
  78 find_package(PkgConfig)
  79
  80
  81 option(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  82
  83 option(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  84
  85 option(ALSOFT_UTILS "Build utility programs"  ON)
  86 option(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
  87
  88 option(ALSOFT_EXAMPLES  "Build example programs"  ON)
  89
  90 option(ALSOFT_INSTALL "Install main library" ON)
  91 option(ALSOFT_INSTALL_CONFIG "Install alsoft.conf sample configuration file" ON)
  92 option(ALSOFT_INSTALL_HRTF_DATA "Install HRTF data files" ON)
  93 option(ALSOFT_INSTALL_AMBDEC_PRESETS "Install AmbDec preset files" ON)
  94 option(ALSOFT_INSTALL_EXAMPLES "Install example programs (alplay, alstream, ...)" ON)
  95 option(ALSOFT_INSTALL_UTILS "Install utility programs (openal-info, alsoft-config, ...)" ON)
  96 option(ALSOFT_UPDATE_BUILD_VERSION "Update git build version info" ON)
  97
  98 option(ALSOFT_EAX "Enable legacy EAX extensions" ${WIN32})
  99
 100 if(DEFINED SHARE_INSTALL_DIR)
 101     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
 102     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
 103 endif()
 104
 105 if(DEFINED LIB_SUFFIX)
 106     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
 107 endif()
 108 if(DEFINED ALSOFT_CONFIG)
 109     message(WARNING "ALSOFT_CONFIG is deprecated. Use ALSOFT_INSTALL_CONFIG instead")
 110 endif()
 111 if(DEFINED ALSOFT_HRTF_DEFS)
 112     message(WARNING "ALSOFT_HRTF_DEFS is deprecated. Use ALSOFT_INSTALL_HRTF_DATA instead")
 113 endif()
 114 if(DEFINED ALSOFT_AMBDEC_PRESETS)
 115     message(WARNING "ALSOFT_AMBDEC_PRESETS is deprecated. Use ALSOFT_INSTALL_AMBDEC_PRESETS instead")
 116 endif()
 117
 118
 119 set(CPP_DEFS ) # C pre-processor, not C++
 120 set(INC_PATHS )
 121 set(C_FLAGS )
 122 set(LINKER_FLAGS )
 123 set(EXTRA_LIBS )
 124
 125 if(WIN32)
 126     set(CPP_DEFS ${CPP_DEFS} _WIN32 NOMINMAX)
 127     if(MINGW)
 128         set(CPP_DEFS ${CPP_DEFS} __USE_MINGW_ANSI_STDIO)
 129     endif()
 130
 131     option(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
 132     if(MINGW)
 133         option(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
 134     endif()
 135 elseif(APPLE)
 136     option(ALSOFT_OSX_FRAMEWORK "Build as macOS framework" OFF)
 137 endif()
 138
 139
 140 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
 141 if("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 142     set(INC_PATHS ${INC_PATHS} /usr/include)
 143     set(LINKER_FLAGS ${LINKER_FLAGS} -L/usr/lib)
 144 endif()
 145
 146 # When the library is built for static linking, apps should define
 147 # AL_LIBTYPE_STATIC when including the AL headers.
 148 if(NOT LIBTYPE)
 149     set(LIBTYPE SHARED)
 150 endif()
 151
 152 set(LIB_MAJOR_VERSION "1")
 153 set(LIB_MINOR_VERSION "22")
 154 set(LIB_REVISION "0")
 155 set(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 156 set(LIB_VERSION_NUM ${LIB_MAJOR_VERSION},${LIB_MINOR_VERSION},${LIB_REVISION},0)
 157
 158 set(EXPORT_DECL "")
 159
 160
 161 # Require C++14
 162 set(CMAKE_CXX_STANDARD 14)
 163 set(CMAKE_CXX_STANDARD_REQUIRED TRUE)
 164
 165 # Prefer C11, but support C99 and C90 too.
 166 set(CMAKE_C_STANDARD 11)
 167
 168 if(NOT WIN32)
 169     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 170     check_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 171     if(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 172         set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 173         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 174         check_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 175         if(NOT HAVE_POSIX_MEMALIGN_POSIX)
 176             set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 177         else()
 178             set(CPP_DEFS ${CPP_DEFS} _POSIX_C_SOURCE=200112L _XOPEN_SOURCE=600)
 179         endif()
 180     endif()
 181     unset(OLD_REQUIRED_FLAGS)
 182 endif()
 183
 184 # C99 has restrict, but C++ does not, so we can only utilize __restrict.
 185 check_cxx_source_compiles("int *__restrict foo;
 186 int main() { return 0; }" HAVE___RESTRICT)
 187 if(HAVE___RESTRICT)
 188     set(CPP_DEFS ${CPP_DEFS} RESTRICT=__restrict)
 189 else()
 190     set(CPP_DEFS ${CPP_DEFS} "RESTRICT=")
 191 endif()
 192
 193 # Some systems may need libatomic for atomic functions to work
 194 set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 195 set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 196 check_cxx_source_compiles("#include <atomic>
 197 std::atomic<int> foo{0};
 198 int main() { return foo.fetch_add(2); }"
 199 HAVE_LIBATOMIC)
 200 if(NOT HAVE_LIBATOMIC)
 201     set(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 202 else()
 203     set(EXTRA_LIBS atomic ${EXTRA_LIBS})
 204 endif()
 205 unset(OLD_REQUIRED_LIBRARIES)
 206
 207 if(ANDROID)
 208     # Include liblog for Android logging
 209     check_library_exists(log __android_log_print "" HAVE_LIBLOG)
 210     if(HAVE_LIBLOG)
 211         set(EXTRA_LIBS log ${EXTRA_LIBS})
 212         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 213     endif()
 214 endif()
 215
 216 if(MSVC)
 217     set(CPP_DEFS ${CPP_DEFS} _CRT_SECURE_NO_WARNINGS)
 218     check_cxx_compiler_flag(/permissive- HAVE_PERMISSIVE_SWITCH)
 219     if(HAVE_PERMISSIVE_SWITCH)
 220         set(C_FLAGS ${C_FLAGS} $<$<COMPILE_LANGUAGE:CXX>:/permissive->)
 221     endif()
 222     set(C_FLAGS ${C_FLAGS} /W4 /w14640 /wd4065 /wd4127 /wd4268 /wd4324 /wd5030)
 223     # Remove /W3, which is added by default, since we set /W4. Some build
 224     # generators with MSVC complain about both /W3 and /W4 being specified.
 225     foreach(flag_var  CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 226         if(${flag_var} MATCHES "/W3")
 227             string(REGEX REPLACE "/W3" "" ${flag_var} "${${flag_var}}")
 228         endif()
 229     endforeach()
 230
 231     if(NOT DXSDK_DIR)
 232         string(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 233     else()
 234         string(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 235     endif()
 236     if(DXSDK_DIR)
 237         message(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 238     endif()
 239
 240     option(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 241     if(FORCE_STATIC_VCRT)
 242         foreach(flag_var
 243                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 244                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 245                 CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
 246                 CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 247             if(${flag_var} MATCHES "/MD")
 248                 string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 249             endif()
 250         endforeach(flag_var)
 251     endif()
 252 else()
 253     set(C_FLAGS ${C_FLAGS} -Winline -Wunused -Wall -Wextra -Wshadow -Wconversion -Wcast-align
 254         -Wpedantic
 255         $<$<COMPILE_LANGUAGE:CXX>:-Wold-style-cast -Wnon-virtual-dtor -Woverloaded-virtual>)
 256
 257     if(ALSOFT_WERROR)
 258         set(C_FLAGS ${C_FLAGS} -Werror)
 259     endif()
 260
 261     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 262     # instead of NDEBUG)
 263     foreach(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 264         if(${flag_var} MATCHES "-DNDEBUG")
 265             string(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 266         endif()
 267     endforeach()
 268
 269     check_c_compiler_flag(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 270     if(HAVE_FNO_MATH_ERRNO)
 271         set(C_FLAGS ${C_FLAGS} -fno-math-errno)
 272     endif()
 273
 274     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 275     if(ALSOFT_STATIC_LIBGCC)
 276         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 277         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 278         check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBGCC_SWITCH)
 279         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 280         unset(OLD_REQUIRED_LIBRARIES)
 281
 282         if(NOT HAVE_STATIC_LIBGCC_SWITCH)
 283             message(FATAL_ERROR "Cannot static link libgcc")
 284         endif()
 285         set(LINKER_FLAGS ${LINKER_FLAGS} -static-libgcc)
 286     endif()
 287
 288     option(ALSOFT_STATIC_STDCXX "Static link libstdc++" OFF)
 289     if(ALSOFT_STATIC_STDCXX)
 290         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 291         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-Wl,--push-state,-Bstatic,-lstdc++,--pop-state")
 292         check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBSTDCXX_SWITCH)
 293         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 294         unset(OLD_REQUIRED_LIBRARIES)
 295
 296         if(NOT HAVE_STATIC_LIBSTDCXX_SWITCH)
 297             message(FATAL_ERROR "Cannot static link libstdc++")
 298         endif()
 299         set(LINKER_FLAGS ${LINKER_FLAGS} "-Wl,--push-state,-Bstatic,-lstdc++,--pop-state")
 300     endif()
 301
 302     if(WIN32)
 303         option(ALSOFT_STATIC_WINPTHREAD "Static link libwinpthread" OFF)
 304         if(ALSOFT_STATIC_WINPTHREAD)
 305             set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 306             set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-Wl,--push-state,-Bstatic,-lwinpthread,--pop-state")
 307             check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBWINPTHREAD_SWITCH)
 308             set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 309             unset(OLD_REQUIRED_LIBRARIES)
 310
 311             if(NOT HAVE_STATIC_LIBWINPTHREAD_SWITCH)
 312                 message(FATAL_ERROR "Cannot static link libwinpthread")
 313             endif()
 314             set(LINKER_FLAGS ${LINKER_FLAGS} "-Wl,--push-state,-Bstatic,-lwinpthread,--pop-state")
 315         endif()
 316     endif()
 317 endif()
 318
 319 # Set visibility/export options if available
 320 if(WIN32)
 321     if(NOT LIBTYPE STREQUAL "STATIC")
 322         set(EXPORT_DECL "__declspec(dllexport)")
 323     endif()
 324 else()
 325     set(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 326     # Yes GCC, really don't accept visibility modes you don't support
 327     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 328
 329     check_c_source_compiles("int foo() __attribute__((visibility(\"protected\")));
 330                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 331     if(HAVE_GCC_PROTECTED_VISIBILITY)
 332         if(NOT LIBTYPE STREQUAL "STATIC")
 333             set(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 334         endif()
 335     else()
 336         check_c_source_compiles("int foo() __attribute__((visibility(\"default\")));
 337                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 338         if(HAVE_GCC_DEFAULT_VISIBILITY)
 339             if(NOT LIBTYPE STREQUAL "STATIC")
 340                 set(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 341             endif()
 342         endif()
 343     endif()
 344
 345     if(HAVE_GCC_PROTECTED_VISIBILITY OR HAVE_GCC_DEFAULT_VISIBILITY)
 346         check_c_compiler_flag(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
 347         if(HAVE_VISIBILITY_HIDDEN_SWITCH)
 348             set(C_FLAGS ${C_FLAGS} -fvisibility=hidden)
 349         endif()
 350     endif()
 351
 352     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 353 endif()
 354
 355
 356 set(SSE2_SWITCH "")
 357
 358 if(NOT MSVC)
 359     set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 360     # Yes GCC, really don't accept command line options you don't support
 361     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Werror")
 362     check_c_compiler_flag(-msse2 HAVE_MSSE2_SWITCH)
 363     if(HAVE_MSSE2_SWITCH)
 364         set(SSE2_SWITCH "-msse2")
 365     endif()
 366     set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 367     unset(OLD_REQUIRED_FLAGS)
 368 endif()
 369
 370 check_include_file(xmmintrin.h HAVE_XMMINTRIN_H)
 371 check_include_file(emmintrin.h HAVE_EMMINTRIN_H)
 372 check_include_file(pmmintrin.h HAVE_PMMINTRIN_H)
 373 check_include_file(smmintrin.h HAVE_SMMINTRIN_H)
 374 check_include_file(arm_neon.h HAVE_ARM_NEON_H)
 375
 376 set(HAVE_SSE        0)
 377 set(HAVE_SSE2       0)
 378 set(HAVE_SSE3       0)
 379 set(HAVE_SSE4_1     0)
 380 set(HAVE_NEON       0)
 381
 382 # Check for SSE support
 383 option(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 384 if(HAVE_XMMINTRIN_H)
 385     option(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 386     if(ALSOFT_CPUEXT_SSE)
 387         set(HAVE_SSE 1)
 388     endif()
 389 endif()
 390 if(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 391     message(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 392 endif()
 393
 394 option(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 395 if(HAVE_EMMINTRIN_H)
 396     option(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 397     if(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 398         set(HAVE_SSE2 1)
 399     endif()
 400 endif()
 401 if(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 402     message(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 403 endif()
 404
 405 option(ALSOFT_REQUIRE_SSE3 "Require SSE3 support" OFF)
 406 if(HAVE_PMMINTRIN_H)
 407     option(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 408     if(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 409         set(HAVE_SSE3 1)
 410     endif()
 411 endif()
 412 if(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 413     message(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 414 endif()
 415
 416 option(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 417 if(HAVE_SMMINTRIN_H)
 418     option(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 419     if(HAVE_SSE3 AND ALSOFT_CPUEXT_SSE4_1)
 420         set(HAVE_SSE4_1 1)
 421     endif()
 422 endif()
 423 if(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 424     message(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 425 endif()
 426
 427 # Check for ARM Neon support
 428 option(ALSOFT_REQUIRE_NEON "Require ARM NEON support" OFF)
 429 if(HAVE_ARM_NEON_H)
 430     option(ALSOFT_CPUEXT_NEON "Enable ARM NEON support" ON)
 431     if(ALSOFT_CPUEXT_NEON)
 432         check_c_source_compiles("#include <arm_neon.h>
 433             int main()
 434             {
 435                 int32x4_t ret4 = vdupq_n_s32(0);
 436                 return vgetq_lane_s32(ret4, 0);
 437             }" HAVE_NEON_INTRINSICS)
 438         if(HAVE_NEON_INTRINSICS)
 439             set(HAVE_NEON 1)
 440         endif()
 441     endif()
 442 endif()
 443 if(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 444     message(FATAL_ERROR "Failed to enabled required ARM NEON CPU extensions")
 445 endif()
 446
 447
 448 set(SSE_FLAGS )
 449 set(FPMATH_SET "0")
 450 if(CMAKE_SIZEOF_VOID_P MATCHES "4" AND HAVE_SSE2)
 451     option(ALSOFT_ENABLE_SSE2_CODEGEN "Enable SSE2 code generation instead of x87 for 32-bit targets." TRUE)
 452     if(ALSOFT_ENABLE_SSE2_CODEGEN)
 453         if(MSVC)
 454             check_c_compiler_flag("/arch:SSE2" HAVE_ARCH_SSE2)
 455             if(HAVE_ARCH_SSE2)
 456                 set(SSE_FLAGS ${SSE_FLAGS} "/arch:SSE2")
 457                 set(C_FLAGS ${C_FLAGS} ${SSE_FLAGS})
 458                 set(FPMATH_SET 2)
 459             endif()
 460         elseif(SSE2_SWITCH)
 461             check_c_compiler_flag("${SSE2_SWITCH} -mfpmath=sse" HAVE_MFPMATH_SSE_2)
 462             if(HAVE_MFPMATH_SSE_2)
 463                 set(SSE_FLAGS ${SSE_FLAGS} ${SSE2_SWITCH} -mfpmath=sse)
 464                 set(C_FLAGS ${C_FLAGS} ${SSE_FLAGS})
 465                 set(FPMATH_SET 2)
 466             endif()
 467             # SSE depends on a 16-byte aligned stack, and by default, GCC
 468             # assumes the stack is suitably aligned. Older Linux code or other
 469             # OSs don't guarantee this on 32-bit, so externally-callable
 470             # functions need to ensure an aligned stack.
 471             set(EXPORT_DECL "${EXPORT_DECL} __attribute__((force_align_arg_pointer))")
 472         endif()
 473     endif()
 474 endif()
 475
 476 if(HAVE_SSE2)
 477     set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 478     foreach(flag_var ${SSE_FLAGS})
 479         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${flag_var}")
 480     endforeach()
 481
 482     check_c_source_compiles("#include <emmintrin.h>
 483         int main() {_mm_pause(); return 0;}" HAVE_SSE_INTRINSICS)
 484
 485     set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 486 endif()
 487
 488
 489 check_include_file(malloc.h HAVE_MALLOC_H)
 490 check_include_file(cpuid.h HAVE_CPUID_H)
 491 check_include_file(intrin.h HAVE_INTRIN_H)
 492 check_include_file(guiddef.h HAVE_GUIDDEF_H)
 493 if(NOT HAVE_GUIDDEF_H)
 494     check_include_file(initguid.h HAVE_INITGUID_H)
 495 endif()
 496
 497 # Some systems need libm for some math functions to work
 498 set(MATH_LIB )
 499 check_library_exists(m pow "" HAVE_LIBM)
 500 if(HAVE_LIBM)
 501     set(MATH_LIB ${MATH_LIB} m)
 502     set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 503 endif()
 504
 505 # Some systems need to link with -lrt for clock_gettime as used by the common
 506 # eaxmple functions.
 507 set(RT_LIB )
 508 check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 509 if(HAVE_LIBRT)
 510     set(RT_LIB rt)
 511 endif()
 512
 513 # Check for the dlopen API (for dynamicly loading backend libs)
 514 if(ALSOFT_DLOPEN)
 515     check_include_file(dlfcn.h HAVE_DLFCN_H)
 516     check_library_exists(dl dlopen "" HAVE_LIBDL)
 517     if(HAVE_LIBDL)
 518         set(EXTRA_LIBS dl ${EXTRA_LIBS})
 519         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 520     endif()
 521 endif()
 522
 523 # Check for a cpuid intrinsic
 524 if(HAVE_CPUID_H)
 525     check_c_source_compiles("#include <cpuid.h>
 526         int main()
 527         {
 528             unsigned int eax, ebx, ecx, edx;
 529             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 530         }" HAVE_GCC_GET_CPUID)
 531 endif()
 532 if(HAVE_INTRIN_H)
 533     check_c_source_compiles("#include <intrin.h>
 534         int main()
 535         {
 536             int regs[4];
 537             __cpuid(regs, 0);
 538             return regs[0];
 539         }" HAVE_CPUID_INTRINSIC)
 540 endif()
 541
 542 check_symbol_exists(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 543 check_symbol_exists(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 544 check_symbol_exists(proc_pidpath     libproc.h HAVE_PROC_PIDPATH)
 545
 546 if(NOT WIN32)
 547     # We need pthreads outside of Windows, for semaphores. It's also used to
 548     # set the priority and name of threads, when possible.
 549     check_include_file(pthread.h HAVE_PTHREAD_H)
 550     if(NOT HAVE_PTHREAD_H)
 551         message(FATAL_ERROR "PThreads is required for non-Windows builds!")
 552     endif()
 553
 554     check_c_compiler_flag(-pthread HAVE_PTHREAD)
 555     if(HAVE_PTHREAD)
 556         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 557         set(C_FLAGS ${C_FLAGS} -pthread)
 558         set(LINKER_FLAGS ${LINKER_FLAGS} -pthread)
 559     endif()
 560
 561     check_symbol_exists(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 562
 563     # Some systems need pthread_np.h to get pthread_setname_np
 564     check_include_files("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 565     if(HAVE_PTHREAD_NP_H)
 566         check_symbol_exists(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 567         if(NOT HAVE_PTHREAD_SETNAME_NP)
 568             check_symbol_exists(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 569         endif()
 570     else()
 571         check_symbol_exists(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 572         if(NOT HAVE_PTHREAD_SETNAME_NP)
 573             check_symbol_exists(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 574         endif()
 575     endif()
 576 endif()
 577
 578 check_symbol_exists(getopt unistd.h HAVE_GETOPT)
 579
 580
 581 # Common sources used by both the OpenAL implementation library, the OpenAL
 582 # router, and certain tools and examples.
 583 set(COMMON_OBJS
 584     common/albit.h
 585     common/albyte.h
 586     common/alcomplex.cpp
 587     common/alcomplex.h
 588     common/aldeque.h
 589     common/alfstream.cpp
 590     common/alfstream.h
 591     common/almalloc.cpp
 592     common/almalloc.h
 593     common/alnumbers.h
 594     common/alnumeric.h
 595     common/aloptional.h
 596     common/alspan.h
 597     common/alstring.cpp
 598     common/alstring.h
 599     common/atomic.h
 600     common/comptr.h
 601     common/dynload.cpp
 602     common/dynload.h
 603     common/intrusive_ptr.h
 604     common/opthelpers.h
 605     common/phase_shifter.h
 606     common/polyphase_resampler.cpp
 607     common/polyphase_resampler.h
 608     common/pragmadefs.h
 609     common/ringbuffer.cpp
 610     common/ringbuffer.h
 611     common/strutils.cpp
 612     common/strutils.h
 613     common/threads.cpp
 614     common/threads.h
 615     common/vecmat.h
 616     common/vector.h)
 617
 618 # Core library routines
 619 set(CORE_OBJS
 620     core/ambdec.cpp
 621     core/ambdec.h
 622     core/ambidefs.cpp
 623     core/ambidefs.h
 624     core/async_event.h
 625     core/bformatdec.cpp
 626     core/bformatdec.h
 627     core/bs2b.cpp
 628     core/bs2b.h
 629     core/bsinc_defs.h
 630     core/bsinc_tables.cpp
 631     core/bsinc_tables.h
 632     core/bufferline.h
 633     core/buffer_storage.cpp
 634     core/buffer_storage.h
 635     core/context.cpp
 636     core/context.h
 637     core/converter.cpp
 638     core/converter.h
 639     core/cpu_caps.cpp
 640     core/cpu_caps.h
 641     core/devformat.cpp
 642     core/devformat.h
 643     core/device.cpp
 644     core/device.h
 645     core/effects/base.h
 646     core/effectslot.cpp
 647     core/effectslot.h
 648     core/except.cpp
 649     core/except.h
 650     core/filters/biquad.h
 651     core/filters/biquad.cpp
 652     core/filters/nfc.cpp
 653     core/filters/nfc.h
 654     core/filters/splitter.cpp
 655     core/filters/splitter.h
 656     core/fmt_traits.cpp
 657     core/fmt_traits.h
 658     core/fpu_ctrl.cpp
 659     core/fpu_ctrl.h
 660     core/front_stablizer.h
 661     core/helpers.cpp
 662     core/helpers.h
 663     core/hrtf.cpp
 664     core/hrtf.h
 665     core/logging.cpp
 666     core/logging.h
 667     core/mastering.cpp
 668     core/mastering.h
 669     core/mixer.cpp
 670     core/mixer.h
 671     core/resampler_limits.h
 672     core/uhjfilter.cpp
 673     core/uhjfilter.h
 674     core/uiddefs.cpp
 675     core/voice.cpp
 676     core/voice.h
 677     core/voice_change.h)
 678
 679 set(HAVE_RTKIT 0)
 680 option(ALSOFT_REQUIRE_RTKIT "Require RTKit/D-Bus support" FALSE)
 681 find_package(DBus1 QUIET)
 682 if(DBus1_FOUND)
 683     option(ALSOFT_RTKIT "Enable RTKit support" ON)
 684     if(ALSOFT_RTKIT)
 685         set(HAVE_RTKIT 1)
 686         set(CORE_OBJS ${CORE_OBJS} core/dbus_wrap.cpp core/dbus_wrap.h core/rtkit.cpp core/rtkit.h)
 687         if(WIN32 OR HAVE_DLFCN_H)
 688             set(INC_PATHS ${INC_PATHS} ${DBus1_INCLUDE_DIRS})
 689             set(CPP_DEFS ${CPP_DEFS} ${DBus1_DEFINITIONS})
 690         else()
 691             set(EXTRA_LIBS ${EXTRA_LIBS} ${DBus1_LIBRARIES})
 692         endif()
 693     endif()
 694 else()
 695     set(MISSING_VARS "")
 696     if(NOT DBus1_INCLUDE_DIRS)
 697         set(MISSING_VARS "${MISSING_VARS} DBus1_INCLUDE_DIRS")
 698     endif()
 699     if(NOT DBus1_LIBRARIES)
 700         set(MISSING_VARS "${MISSING_VARS} DBus1_LIBRARIES")
 701     endif()
 702     message(STATUS "Could NOT find DBus1 (missing:${MISSING_VARS})")
 703     unset(MISSING_VARS)
 704 endif()
 705 if(ALSOFT_REQUIRE_RTKIT AND NOT HAVE_RTKIT)
 706     message(FATAL_ERROR "Failed to enabled required RTKit support")
 707 endif()
 708
 709 # Default mixers, always available
 710 set(CORE_OBJS ${CORE_OBJS}
 711     core/mixer/defs.h
 712     core/mixer/hrtfbase.h
 713     core/mixer/hrtfdefs.h
 714     core/mixer/mixer_c.cpp)
 715
 716 # AL and related routines
 717 set(OPENAL_OBJS
 718     al/auxeffectslot.cpp
 719     al/auxeffectslot.h
 720     al/buffer.cpp
 721     al/buffer.h
 722     al/effect.cpp
 723     al/effect.h
 724     al/effects/autowah.cpp
 725     al/effects/chorus.cpp
 726     al/effects/compressor.cpp
 727     al/effects/convolution.cpp
 728     al/effects/dedicated.cpp
 729     al/effects/distortion.cpp
 730     al/effects/echo.cpp
 731         al/effects/effects.cpp
 732     al/effects/effects.h
 733     al/effects/equalizer.cpp
 734     al/effects/fshifter.cpp
 735     al/effects/modulator.cpp
 736     al/effects/null.cpp
 737     al/effects/pshifter.cpp
 738     al/effects/reverb.cpp
 739     al/effects/vmorpher.cpp
 740     al/error.cpp
 741     al/event.cpp
 742     al/event.h
 743     al/extension.cpp
 744     al/filter.cpp
 745     al/filter.h
 746     al/listener.cpp
 747     al/listener.h
 748     al/source.cpp
 749     al/source.h
 750     al/state.cpp)
 751
 752 # ALC and related routines
 753 set(ALC_OBJS
 754     alc/alc.cpp
 755     alc/alu.cpp
 756     alc/alu.h
 757     alc/alconfig.cpp
 758     alc/alconfig.h
 759     alc/context.cpp
 760     alc/context.h
 761     alc/device.cpp
 762     alc/device.h
 763     alc/effects/base.h
 764     alc/effects/autowah.cpp
 765     alc/effects/chorus.cpp
 766     alc/effects/compressor.cpp
 767     alc/effects/convolution.cpp
 768     alc/effects/dedicated.cpp
 769     alc/effects/distortion.cpp
 770     alc/effects/echo.cpp
 771     alc/effects/equalizer.cpp
 772     alc/effects/fshifter.cpp
 773     alc/effects/modulator.cpp
 774     alc/effects/null.cpp
 775     alc/effects/pshifter.cpp
 776     alc/effects/reverb.cpp
 777     alc/effects/vmorpher.cpp
 778     alc/inprogext.h
 779     alc/panning.cpp)
 780
 781 if (ALSOFT_EAX)
 782     set(OPENAL_OBJS
 783         ${OPENAL_OBJS}
 784         al/eax_api.cpp
 785         al/eax_api.h
 786         al/eax_eax_call.cpp
 787         al/eax_eax_call.h
 788         al/eax_effect.cpp
 789         al/eax_effect.h
 790         al/eax_exception.cpp
 791         al/eax_exception.h
 792         al/eax_fx_slot_index.cpp
 793         al/eax_fx_slot_index.h
 794         al/eax_fx_slots.cpp
 795         al/eax_fx_slots.h
 796         al/eax_globals.cpp
 797         al/eax_globals.h
 798         al/eax_utils.cpp
 799         al/eax_utils.h
 800         al/eax_x_ram.cpp
 801         al/eax_x_ram.h
 802 )
 803 endif ()
 804
 805 # Include SIMD mixers
 806 set(CPU_EXTS "Default")
 807 if(HAVE_SSE)
 808     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse.cpp)
 809     set(CPU_EXTS "${CPU_EXTS}, SSE")
 810 endif()
 811 if(HAVE_SSE2)
 812     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse2.cpp)
 813     set(CPU_EXTS "${CPU_EXTS}, SSE2")
 814 endif()
 815 if(HAVE_SSE3)
 816     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse3.cpp)
 817     set(CPU_EXTS "${CPU_EXTS}, SSE3")
 818 endif()
 819 if(HAVE_SSE4_1)
 820     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse41.cpp)
 821     set(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 822 endif()
 823 if(HAVE_NEON)
 824     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_neon.cpp)
 825     set(CPU_EXTS "${CPU_EXTS}, Neon")
 826 endif()
 827
 828
 829 set(HAVE_ALSA       0)
 830 set(HAVE_OSS        0)
 831 set(HAVE_PIPEWIRE   0)
 832 set(HAVE_SOLARIS    0)
 833 set(HAVE_SNDIO      0)
 834 set(HAVE_DSOUND     0)
 835 set(HAVE_WASAPI     0)
 836 set(HAVE_WINMM      0)
 837 set(HAVE_PORTAUDIO  0)
 838 set(HAVE_PULSEAUDIO 0)
 839 set(HAVE_COREAUDIO  0)
 840 set(HAVE_OPENSL     0)
 841 set(HAVE_OBOE       0)
 842 set(HAVE_WAVE       0)
 843 set(HAVE_SDL2       0)
 844
 845 if(WIN32 OR HAVE_DLFCN_H)
 846     set(IS_LINKED "")
 847     macro(ADD_BACKEND_LIBS _LIBS)
 848     endmacro()
 849 else()
 850     set(IS_LINKED " (linked)")
 851     macro(ADD_BACKEND_LIBS _LIBS)
 852         set(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 853     endmacro()
 854 endif()
 855
 856 set(BACKENDS "")
 857 set(ALC_OBJS  ${ALC_OBJS}
 858     alc/backends/base.cpp
 859     alc/backends/base.h
 860     # Default backends, always available
 861     alc/backends/loopback.cpp
 862     alc/backends/loopback.h
 863     alc/backends/null.cpp
 864     alc/backends/null.h
 865 )
 866
 867 # Check ALSA backend
 868 option(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 869 find_package(ALSA)
 870 if(ALSA_FOUND)
 871     option(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 872     if(ALSOFT_BACKEND_ALSA)
 873         set(HAVE_ALSA 1)
 874         set(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 875         set(ALC_OBJS  ${ALC_OBJS} alc/backends/alsa.cpp alc/backends/alsa.h)
 876         add_backend_libs(${ALSA_LIBRARIES})
 877         set(INC_PATHS ${INC_PATHS} ${ALSA_INCLUDE_DIRS})
 878     endif()
 879 endif()
 880 if(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 881     message(FATAL_ERROR "Failed to enabled required ALSA backend")
 882 endif()
 883
 884 # Check OSS backend
 885 option(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 886 find_package(OSS)
 887 if(OSS_FOUND)
 888     option(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 889     if(ALSOFT_BACKEND_OSS)
 890         set(HAVE_OSS 1)
 891         set(BACKENDS  "${BACKENDS} OSS,")
 892         set(ALC_OBJS  ${ALC_OBJS} alc/backends/oss.cpp alc/backends/oss.h)
 893         if(OSS_LIBRARIES)
 894             set(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 895         endif()
 896         set(INC_PATHS ${INC_PATHS} ${OSS_INCLUDE_DIRS})
 897     endif()
 898 endif()
 899 if(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 900     message(FATAL_ERROR "Failed to enabled required OSS backend")
 901 endif()
 902
 903 # Check PipeWire backend
 904 option(ALSOFT_REQUIRE_PIPEWIRE "Require PipeWire backend" OFF)
 905 if(PkgConfig_FOUND)
 906     pkg_check_modules(PIPEWIRE libpipewire-0.3)
 907     if(PIPEWIRE_FOUND)
 908         option(ALSOFT_BACKEND_PIPEWIRE "Enable PipeWire backend" ON)
 909         if(ALSOFT_BACKEND_PIPEWIRE)
 910             set(HAVE_PIPEWIRE 1)
 911             set(BACKENDS  "${BACKENDS} PipeWire${IS_LINKED},")
 912             set(ALC_OBJS  ${ALC_OBJS} alc/backends/pipewire.cpp alc/backends/pipewire.h)
 913             add_backend_libs(${PIPEWIRE_LIBRARIES})
 914             set(INC_PATHS ${INC_PATHS} ${PIPEWIRE_INCLUDE_DIRS})
 915         endif()
 916     endif()
 917 endif()
 918 if(ALSOFT_REQUIRE_PIPEWIRE AND NOT HAVE_PIPEWIRE)
 919     message(FATAL_ERROR "Failed to enabled required PipeWire backend")
 920 endif()
 921
 922 # Check Solaris backend
 923 option(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 924 find_package(AudioIO)
 925 if(AUDIOIO_FOUND)
 926     option(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 927     if(ALSOFT_BACKEND_SOLARIS)
 928         set(HAVE_SOLARIS 1)
 929         set(BACKENDS  "${BACKENDS} Solaris,")
 930         set(ALC_OBJS  ${ALC_OBJS} alc/backends/solaris.cpp alc/backends/solaris.h)
 931         set(INC_PATHS ${INC_PATHS} ${AUDIOIO_INCLUDE_DIRS})
 932     endif()
 933 endif()
 934 if(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 935     message(FATAL_ERROR "Failed to enabled required Solaris backend")
 936 endif()
 937
 938 # Check SndIO backend
 939 option(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 940 find_package(SoundIO)
 941 if(SOUNDIO_FOUND)
 942     option(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 943     if(ALSOFT_BACKEND_SNDIO)
 944         set(HAVE_SNDIO 1)
 945         set(BACKENDS  "${BACKENDS} SndIO (linked),")
 946         set(ALC_OBJS  ${ALC_OBJS} alc/backends/sndio.cpp alc/backends/sndio.h)
 947         set(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 948         set(INC_PATHS ${INC_PATHS} ${SOUNDIO_INCLUDE_DIRS})
 949     endif()
 950 endif()
 951 if(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 952     message(FATAL_ERROR "Failed to enabled required SndIO backend")
 953 endif()
 954
 955 # Check Windows-only backends
 956 option(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 957 option(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 958 option(ALSOFT_REQUIRE_WASAPI "Require WASAPI backend" OFF)
 959 if(WIN32)
 960     # Check MMSystem backend
 961     option(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 962     if(ALSOFT_BACKEND_WINMM)
 963         set(HAVE_WINMM 1)
 964         set(BACKENDS "${BACKENDS} WinMM,")
 965         set(ALC_OBJS ${ALC_OBJS} alc/backends/winmm.cpp alc/backends/winmm.h)
 966         # There doesn't seem to be good way to search for winmm.lib for MSVC.
 967         # find_library doesn't find it without being told to look in a specific
 968         # place in the WindowsSDK, but it links anyway. If there ends up being
 969         # Windows targets without this, another means to detect it is needed.
 970         set(EXTRA_LIBS winmm ${EXTRA_LIBS})
 971     endif()
 972
 973     # Check DSound backend
 974     check_include_file(dsound.h HAVE_DSOUND_H)
 975     if(DXSDK_DIR)
 976         find_path(DSOUND_INCLUDE_DIR NAMES "dsound.h"
 977             PATHS "${DXSDK_DIR}" PATH_SUFFIXES include
 978             DOC "The DirectSound include directory")
 979     endif()
 980     if(HAVE_DSOUND_H OR DSOUND_INCLUDE_DIR)
 981         option(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
 982         if(ALSOFT_BACKEND_DSOUND)
 983             set(HAVE_DSOUND 1)
 984             set(BACKENDS "${BACKENDS} DirectSound,")
 985             set(ALC_OBJS ${ALC_OBJS} alc/backends/dsound.cpp alc/backends/dsound.h)
 986
 987             if(NOT HAVE_DSOUND_H)
 988                 set(INC_PATHS ${INC_PATHS} ${DSOUND_INCLUDE_DIR})
 989             endif()
 990         endif()
 991     endif()
 992
 993     # Check for WASAPI backend
 994     check_include_file(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
 995     if(HAVE_MMDEVICEAPI_H)
 996         option(ALSOFT_BACKEND_WASAPI "Enable WASAPI backend" ON)
 997         if(ALSOFT_BACKEND_WASAPI)
 998             set(HAVE_WASAPI 1)
 999             set(BACKENDS  "${BACKENDS} WASAPI,")
1000             set(ALC_OBJS  ${ALC_OBJS} alc/backends/wasapi.cpp alc/backends/wasapi.h)
1001         endif()
1002     endif()
1003 endif()
1004 if(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
1005     message(FATAL_ERROR "Failed to enabled required WinMM backend")
1006 endif()
1007 if(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
1008     message(FATAL_ERROR "Failed to enabled required DSound backend")
1009 endif()
1010 if(ALSOFT_REQUIRE_WASAPI AND NOT HAVE_WASAPI)
1011     message(FATAL_ERROR "Failed to enabled required WASAPI backend")
1012 endif()
1013
1014 # Check PortAudio backend
1015 option(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
1016 find_package(PortAudio)
1017 if(PORTAUDIO_FOUND)
1018     option(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
1019     if(ALSOFT_BACKEND_PORTAUDIO)
1020         set(HAVE_PORTAUDIO 1)
1021         set(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1022         set(ALC_OBJS  ${ALC_OBJS} alc/backends/portaudio.cpp alc/backends/portaudio.h)
1023         add_backend_libs(${PORTAUDIO_LIBRARIES})
1024         set(INC_PATHS ${INC_PATHS} ${PORTAUDIO_INCLUDE_DIRS})
1025     endif()
1026 endif()
1027 if(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1028     message(FATAL_ERROR "Failed to enabled required PortAudio backend")
1029 endif()
1030
1031 # Check PulseAudio backend
1032 option(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1033 find_package(PulseAudio)
1034 if(PULSEAUDIO_FOUND)
1035     option(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1036     if(ALSOFT_BACKEND_PULSEAUDIO)
1037         set(HAVE_PULSEAUDIO 1)
1038         set(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1039         set(ALC_OBJS  ${ALC_OBJS} alc/backends/pulseaudio.cpp alc/backends/pulseaudio.h)
1040         add_backend_libs(${PULSEAUDIO_LIBRARIES})
1041         set(INC_PATHS ${INC_PATHS} ${PULSEAUDIO_INCLUDE_DIRS})
1042     endif()
1043 endif()
1044 if(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1045     message(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1046 endif()
1047
1048 # Check JACK backend
1049 option(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1050 find_package(JACK)
1051 if(JACK_FOUND)
1052     option(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1053     if(ALSOFT_BACKEND_JACK)
1054         set(HAVE_JACK 1)
1055         set(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1056         set(ALC_OBJS  ${ALC_OBJS} alc/backends/jack.cpp alc/backends/jack.h)
1057         add_backend_libs(${JACK_LIBRARIES})
1058         set(INC_PATHS ${INC_PATHS} ${JACK_INCLUDE_DIRS})
1059     endif()
1060 endif()
1061 if(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1062     message(FATAL_ERROR "Failed to enabled required JACK backend")
1063 endif()
1064
1065 # Check CoreAudio backend
1066 option(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1067 find_library(COREAUDIO_FRAMEWORK NAMES CoreAudio)
1068 find_path(AUDIOUNIT_INCLUDE_DIR NAMES AudioUnit/AudioUnit.h)
1069 if(COREAUDIO_FRAMEWORK AND AUDIOUNIT_INCLUDE_DIR)
1070     option(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1071     if(ALSOFT_BACKEND_COREAUDIO)
1072         set(HAVE_COREAUDIO 1)
1073         set(ALC_OBJS  ${ALC_OBJS} alc/backends/coreaudio.cpp alc/backends/coreaudio.h)
1074         set(BACKENDS  "${BACKENDS} CoreAudio,")
1075         if(CMAKE_SYSTEM_NAME STREQUAL "iOS")
1076             find_library(COREFOUNDATION_FRAMEWORK NAMES CoreFoundation)
1077             set(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} ${COREFOUNDATION_FRAMEWORK} ${EXTRA_LIBS})
1078         else()
1079             set(EXTRA_LIBS ${COREAUDIO_FRAMEWORK} /System/Library/Frameworks/AudioUnit.framework
1080                 /System/Library/Frameworks/ApplicationServices.framework ${EXTRA_LIBS})
1081         endif()
1082
1083         # Some versions of OSX may need the AudioToolbox framework. Add it if
1084         # it's found.
1085         find_library(AUDIOTOOLBOX_LIBRARY NAMES AudioToolbox)
1086         if(AUDIOTOOLBOX_LIBRARY)
1087             set(EXTRA_LIBS ${AUDIOTOOLBOX_LIBRARY} ${EXTRA_LIBS})
1088         endif()
1089
1090         set(INC_PATHS ${INC_PATHS} ${AUDIOUNIT_INCLUDE_DIR})
1091     endif()
1092 endif()
1093 if(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1094     message(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1095 endif()
1096
1097 # Check for OpenSL (Android) backend
1098 option(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1099 find_package(OpenSL)
1100 if(OPENSL_FOUND)
1101     option(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1102     if(ALSOFT_BACKEND_OPENSL)
1103         set(HAVE_OPENSL 1)
1104         set(ALC_OBJS  ${ALC_OBJS} alc/backends/opensl.cpp alc/backends/opensl.h)
1105         set(BACKENDS  "${BACKENDS} OpenSL,")
1106         set(EXTRA_LIBS "OpenSL::OpenSLES" ${EXTRA_LIBS})
1107     endif()
1108 endif()
1109 if(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1110     message(FATAL_ERROR "Failed to enabled required OpenSL backend")
1111 endif()
1112
1113 # Check for Oboe (Android) backend
1114 set(OBOE_TARGET )
1115 if(ANDROID)
1116     set(OBOE_SOURCE "" CACHE STRING "Source directory for Oboe.")
1117     if(OBOE_SOURCE)
1118         # Force Oboe to build with hidden symbols. Don't want to be exporting
1119         # them from OpenAL.
1120         set(OLD_CXX_FLAGS ${CMAKE_CXX_FLAGS})
1121         check_cxx_compiler_flag(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
1122         if(HAVE_VISIBILITY_HIDDEN_SWITCH)
1123             set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
1124         endif()
1125         add_subdirectory(${OBOE_SOURCE} ./oboe)
1126         set(CMAKE_CXX_FLAGS ${OLD_CXX_FLAGS})
1127         unset(OLD_CXX_FLAGS)
1128
1129         set(OBOE_TARGET oboe)
1130     else()
1131         find_package(Oboe)
1132         if(OBOE_FOUND)
1133             set(OBOE_TARGET "oboe::oboe")
1134         endif()
1135     endif()
1136 endif()
1137
1138 option(ALSOFT_REQUIRE_OBOE "Require Oboe backend" OFF)
1139 if(OBOE_TARGET)
1140     option(ALSOFT_BACKEND_OBOE "Enable Oboe backend" ON)
1141     if(ALSOFT_BACKEND_OBOE)
1142         set(HAVE_OBOE 1)
1143         set(ALC_OBJS  ${ALC_OBJS} alc/backends/oboe.cpp alc/backends/oboe.h)
1144         set(BACKENDS  "${BACKENDS} Oboe,")
1145         set(EXTRA_LIBS ${OBOE_TARGET} ${EXTRA_LIBS})
1146     endif()
1147 endif()
1148 if(ALSOFT_REQUIRE_OBOE AND NOT HAVE_OBOE)
1149     message(FATAL_ERROR "Failed to enabled required Oboe backend")
1150 endif()
1151
1152 # Check for SDL2 backend
1153 option(ALSOFT_REQUIRE_SDL2 "Require SDL2 backend" OFF)
1154 find_package(SDL2)
1155 if(SDL2_FOUND)
1156     # Off by default, since it adds a runtime dependency
1157     option(ALSOFT_BACKEND_SDL2 "Enable SDL2 backend" OFF)
1158     if(ALSOFT_BACKEND_SDL2)
1159         set(HAVE_SDL2 1)
1160         set(ALC_OBJS  ${ALC_OBJS} alc/backends/sdl2.cpp alc/backends/sdl2.h)
1161         set(BACKENDS  "${BACKENDS} SDL2,")
1162         set(EXTRA_LIBS ${SDL2_LIBRARY} ${EXTRA_LIBS})
1163         set(INC_PATHS ${INC_PATHS} ${SDL2_INCLUDE_DIR})
1164     endif()
1165 endif()
1166 if(ALSOFT_REQUIRE_SDL2 AND NOT SDL2_FOUND)
1167     message(FATAL_ERROR "Failed to enabled required SDL2 backend")
1168 endif()
1169
1170 # Optionally enable the Wave Writer backend
1171 option(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1172 if(ALSOFT_BACKEND_WAVE)
1173     set(HAVE_WAVE 1)
1174     set(ALC_OBJS  ${ALC_OBJS} alc/backends/wave.cpp alc/backends/wave.h)
1175     set(BACKENDS  "${BACKENDS} WaveFile,")
1176 endif()
1177
1178 # This is always available
1179 set(BACKENDS  "${BACKENDS} Null")
1180
1181
1182 find_package(Git)
1183 if(ALSOFT_UPDATE_BUILD_VERSION AND GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1184     # Get the current working branch and its latest abbreviated commit hash
1185     add_custom_target(build_version
1186         ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE} -D LIB_VERSION=${LIB_VERSION}
1187             -D LIB_VERSION_NUM=${LIB_VERSION_NUM} -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1188             -D DST=${OpenAL_BINARY_DIR}/version.h -P ${OpenAL_SOURCE_DIR}/version.cmake
1189         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1190         VERBATIM
1191     )
1192 else()
1193     set(GIT_BRANCH "UNKNOWN")
1194     set(GIT_COMMIT_HASH "unknown")
1195     configure_file(
1196         "${OpenAL_SOURCE_DIR}/version.h.in"
1197         "${OpenAL_BINARY_DIR}/version.h")
1198 endif()
1199
1200
1201 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" ON)
1202 if(ALSOFT_EMBED_HRTF_DATA)
1203     macro(make_hrtf_header FILENAME VARNAME)
1204         set(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1205         set(outfile  "${OpenAL_BINARY_DIR}/${VARNAME}.h")
1206
1207         add_custom_command(OUTPUT "${outfile}"
1208             COMMAND ${CMAKE_COMMAND} -D "INPUT_FILE=${infile}" -D "OUTPUT_FILE=${outfile}"
1209                 -D "VARIABLE_NAME=${VARNAME}" -P "${CMAKE_MODULE_PATH}/bin2h.script.cmake"
1210             WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1211             DEPENDS "${infile}" "${CMAKE_MODULE_PATH}/bin2h.script.cmake"
1212             VERBATIM
1213         )
1214         set(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1215     endmacro()
1216
1217     make_hrtf_header("Default HRTF.mhr" "hrtf_default")
1218 endif()
1219
1220
1221 if(ALSOFT_UTILS)
1222     find_package(MySOFA)
1223     if(NOT ALSOFT_NO_CONFIG_UTIL)
1224         find_package(Qt5Widgets QUIET)
1225         if(NOT Qt5Widgets_FOUND)
1226             message(STATUS "Could NOT find Qt5Widgets")
1227         endif()
1228     endif()
1229 endif()
1230 if(ALSOFT_UTILS OR ALSOFT_EXAMPLES)
1231     find_package(SndFile)
1232     find_package(SDL2)
1233     if(SDL2_FOUND)
1234         find_package(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1235     endif()
1236 endif()
1237
1238 if(NOT WIN32)
1239     set(LIBNAME "openal")
1240 else()
1241     set(LIBNAME "OpenAL32")
1242 endif()
1243
1244 # Needed for openal.pc.in
1245 set(prefix ${CMAKE_INSTALL_PREFIX})
1246 set(exec_prefix "\${prefix}")
1247 set(libdir "\${exec_prefix}/${CMAKE_INSTALL_LIBDIR}")
1248 set(bindir "\${exec_prefix}/${CMAKE_INSTALL_BINDIR}")
1249 set(includedir "\${prefix}/${CMAKE_INSTALL_INCLUDEDIR}")
1250 set(PACKAGE_VERSION "${LIB_VERSION}")
1251 set(PKG_CONFIG_CFLAGS )
1252 set(PKG_CONFIG_PRIVATE_LIBS )
1253 if(LIBTYPE STREQUAL "STATIC")
1254     set(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC)
1255     foreach(FLAG  ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1256         # If this is already a linker flag, or is a full path+file, add it
1257         # as-is. Otherwise, it's a name intended to be dressed as -lname.
1258         if(FLAG MATCHES "^-.*" OR EXISTS "${FLAG}")
1259             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} ${FLAG}")
1260         else()
1261             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} -l${FLAG}")
1262         endif()
1263     endforeach()
1264 endif()
1265
1266 # End configuration
1267 configure_file(
1268     "${OpenAL_SOURCE_DIR}/config.h.in"
1269     "${OpenAL_BINARY_DIR}/config.h")
1270 configure_file(
1271     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1272     "${OpenAL_BINARY_DIR}/openal.pc"
1273     @ONLY)
1274
1275
1276 add_library(common STATIC EXCLUDE_FROM_ALL ${COMMON_OBJS})
1277 target_include_directories(common PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/include)
1278 target_compile_definitions(common PRIVATE ${CPP_DEFS})
1279 target_compile_options(common PRIVATE ${C_FLAGS})
1280 set_target_properties(common PROPERTIES POSITION_INDEPENDENT_CODE TRUE)
1281
1282
1283 unset(HAS_ROUTER)
1284 set(IMPL_TARGET OpenAL) # Either OpenAL or soft_oal.
1285
1286 # Build main library
1287 if(LIBTYPE STREQUAL "STATIC")
1288     add_library(${IMPL_TARGET} STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS} ${CORE_OBJS})
1289     target_compile_definitions(${IMPL_TARGET} PUBLIC AL_LIBTYPE_STATIC)
1290     target_link_libraries(${IMPL_TARGET} PRIVATE ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1291
1292     if(WIN32)
1293         # This option is for static linking OpenAL Soft into another project
1294         # that already defines the IDs. It is up to that project to ensure all
1295         # required IDs are defined.
1296         option(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
1297         if(ALSOFT_NO_UID_DEFS)
1298             target_compile_definitions(${IMPL_TARGET} PRIVATE AL_NO_UID_DEFS)
1299         endif()
1300     endif()
1301 else()
1302     set(RC_CONFIG resources/openal32.rc)
1303     if(WIN32 AND ALSOFT_BUILD_ROUTER)
1304         add_library(OpenAL SHARED
1305             resources/router.rc
1306             router/router.cpp
1307             router/router.h
1308             router/alc.cpp
1309             router/al.cpp
1310         )
1311         target_compile_definitions(OpenAL
1312             PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES "ALC_API=${EXPORT_DECL}"
1313             "AL_API=${EXPORT_DECL}" ${CPP_DEFS})
1314         target_compile_options(OpenAL PRIVATE ${C_FLAGS})
1315         target_link_libraries(OpenAL PRIVATE common ${LINKER_FLAGS})
1316         target_include_directories(OpenAL
1317           PUBLIC
1318             $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include>
1319             $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
1320           PRIVATE
1321             ${OpenAL_SOURCE_DIR}/common
1322             ${OpenAL_BINARY_DIR}
1323         )
1324         set_target_properties(OpenAL PROPERTIES PREFIX "")
1325         set_target_properties(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1326         if(TARGET build_version)
1327             add_dependencies(OpenAL build_version)
1328         endif()
1329         set(HAS_ROUTER 1)
1330
1331         set(LIBNAME "soft_oal")
1332         set(IMPL_TARGET soft_oal)
1333         set(RC_CONFIG resources/soft_oal.rc)
1334     endif()
1335
1336     # !important: for osx framework public header works, the headers must be in
1337     # the project
1338     set(TARGET_PUBLIC_HEADERS include/AL/al.h include/AL/alc.h include/AL/alext.h include/AL/efx.h)
1339     add_library(${IMPL_TARGET} SHARED ${OPENAL_OBJS} ${ALC_OBJS} ${CORE_OBJS} ${RC_CONFIG}
1340         ${TARGET_PUBLIC_HEADERS})
1341     if(WIN32)
1342         set_target_properties(${IMPL_TARGET} PROPERTIES PREFIX "")
1343     endif()
1344     target_link_libraries(${IMPL_TARGET} PRIVATE common ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1345
1346     if(APPLE AND ALSOFT_OSX_FRAMEWORK)
1347         # Sets framework name to soft_oal to avoid ambiguity with the system OpenAL.framework
1348         set(LIBNAME "soft_oal")
1349         if(GIT_FOUND)
1350             EXECUTE_PROCESS(COMMAND ${GIT_EXECUTABLE} rev-list --count head
1351                 TIMEOUT 5
1352                 OUTPUT_VARIABLE BUNDLE_VERSION
1353                 OUTPUT_STRIP_TRAILING_WHITESPACE)
1354         else()
1355             set(BUNDLE_VERSION 1)
1356         endif()
1357
1358         # Build: Fix rpath in iOS shared libraries
1359         # If this flag is not set, the final dylib binary ld path will be
1360         # /User/xxx/*/soft_oal.framework/soft_oal, which can't be loaded by iOS devices.
1361         # See also: https://github.com/libjpeg-turbo/libjpeg-turbo/commit/c80ddef7a4ce21ace9e3ca0fd190d320cc8cdaeb
1362         if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG)
1363             set(CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG "-Wl,-rpath,")
1364         endif()
1365
1366         set_target_properties(${IMPL_TARGET} PROPERTIES
1367             FRAMEWORK TRUE
1368             FRAMEWORK_VERSION C
1369             MACOSX_FRAMEWORK_NAME "${IMPL_TARGET}"
1370             MACOSX_FRAMEWORK_IDENTIFIER "org.openal-soft.openal"
1371             MACOSX_FRAMEWORK_SHORT_VERSION_STRING ${LIB_VERSION}
1372             MACOSX_FRAMEWORK_BUNDLE_VERSION ${BUNDLE_VERSION}
1373             XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY ""
1374             XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED "NO"
1375             XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED "NO"
1376             PUBLIC_HEADER "${TARGET_PUBLIC_HEADERS}"
1377             MACOSX_RPATH TRUE)
1378     endif()
1379 endif()
1380
1381 target_include_directories(${IMPL_TARGET}
1382   PUBLIC
1383     $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include>
1384   INTERFACE
1385     $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include/AL>
1386     $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
1387     $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/AL>
1388   PRIVATE
1389     ${INC_PATHS}
1390     ${OpenAL_BINARY_DIR}
1391     ${OpenAL_SOURCE_DIR}
1392     ${OpenAL_SOURCE_DIR}/common
1393 )
1394
1395 set_target_properties(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1396     VERSION ${LIB_VERSION}
1397     SOVERSION ${LIB_MAJOR_VERSION}
1398 )
1399 target_compile_definitions(${IMPL_TARGET}
1400     PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES "ALC_API=${EXPORT_DECL}" "AL_API=${EXPORT_DECL}"
1401     ${CPP_DEFS})
1402 target_compile_options(${IMPL_TARGET} PRIVATE ${C_FLAGS})
1403
1404 if(TARGET build_version)
1405     add_dependencies(${IMPL_TARGET} build_version)
1406 endif()
1407
1408 if(WIN32 AND MINGW AND ALSOFT_BUILD_IMPORT_LIB AND NOT LIBTYPE STREQUAL "STATIC")
1409     find_program(SED_EXECUTABLE NAMES sed DOC "sed executable")
1410     if(NOT SED_EXECUTABLE OR NOT CMAKE_DLLTOOL)
1411         message(STATUS "")
1412         if(NOT SED_EXECUTABLE)
1413             message(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1414         endif()
1415         if(NOT CMAKE_DLLTOOL)
1416             message(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1417         endif()
1418     else()
1419         set_property(TARGET OpenAL APPEND_STRING PROPERTY
1420             LINK_FLAGS " -Wl,--output-def,OpenAL32.def")
1421         add_custom_command(TARGET OpenAL POST_BUILD
1422             COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1423             COMMAND "${CMAKE_DLLTOOL}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1424             COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1425             VERBATIM
1426         )
1427     endif()
1428 endif()
1429
1430 if(HAS_ROUTER)
1431     message(STATUS "")
1432     message(STATUS "Building DLL router")
1433 endif()
1434
1435 message(STATUS "")
1436 message(STATUS "Building OpenAL with support for the following backends:")
1437 message(STATUS "   ${BACKENDS}")
1438 message(STATUS "")
1439 message(STATUS "Building with support for CPU extensions:")
1440 message(STATUS "    ${CPU_EXTS}")
1441 message(STATUS "")
1442 if(FPMATH_SET)
1443     message(STATUS "Building with SSE${FPMATH_SET} codegen")
1444     message(STATUS "")
1445 endif()
1446
1447 if(ALSOFT_EAX)
1448     message(STATUS "Building with legacy EAX extension support")
1449     message(STATUS "")
1450 endif()
1451
1452 if(ALSOFT_EMBED_HRTF_DATA)
1453     message(STATUS "Embedding HRTF datasets")
1454     message(STATUS "")
1455 endif()
1456
1457 # An alias for sub-project builds
1458 add_library(OpenAL::OpenAL ALIAS OpenAL)
1459
1460 # Install main library
1461 if(ALSOFT_INSTALL)
1462     configure_package_config_file(OpenALConfig.cmake.in OpenALConfig.cmake
1463         INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL)
1464     install(TARGETS OpenAL EXPORT OpenAL
1465         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1466         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1467         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1468         FRAMEWORK DESTINATION ${CMAKE_INSTALL_LIBDIR}
1469         INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL)
1470     export(TARGETS OpenAL
1471         NAMESPACE OpenAL::
1472         FILE OpenALTargets.cmake)
1473     install(EXPORT OpenAL
1474         DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1475         NAMESPACE OpenAL::
1476         FILE OpenALTargets.cmake)
1477     install(DIRECTORY include/AL
1478         DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
1479     install(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1480         DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1481     install(FILES "${OpenAL_BINARY_DIR}/OpenALConfig.cmake"
1482         DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL")
1483     if(TARGET soft_oal)
1484         install(TARGETS soft_oal
1485             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
1486     endif()
1487     message(STATUS "Installing library and headers")
1488 else()
1489     message(STATUS "NOT installing library and headers")
1490 endif()
1491
1492 if(ALSOFT_INSTALL_CONFIG)
1493     install(FILES alsoftrc.sample
1494         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1495     message(STATUS "Installing sample configuration")
1496 endif()
1497
1498 if(ALSOFT_INSTALL_HRTF_DATA)
1499     install(DIRECTORY hrtf
1500         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1501     message(STATUS "Installing HRTF data files")
1502 endif()
1503
1504 if(ALSOFT_INSTALL_AMBDEC_PRESETS)
1505     install(DIRECTORY presets
1506         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1507     message(STATUS "Installing AmbDec presets")
1508 endif()
1509 message(STATUS "")
1510
1511 set(UNICODE_FLAG )
1512 if(MINGW)
1513     set(UNICODE_FLAG ${UNICODE_FLAG} -municode)
1514 endif()
1515 set(EXTRA_INSTALLS )
1516 if(ALSOFT_UTILS)
1517     add_executable(openal-info utils/openal-info.c)
1518     target_include_directories(openal-info PRIVATE ${OpenAL_SOURCE_DIR}/common)
1519     target_compile_options(openal-info PRIVATE ${C_FLAGS})
1520     target_link_libraries(openal-info PRIVATE ${LINKER_FLAGS} OpenAL ${UNICODE_FLAG})
1521     if(ALSOFT_INSTALL_EXAMPLES)
1522         set(EXTRA_INSTALLS ${EXTRA_INSTALLS} openal-info)
1523     endif()
1524
1525     if(SNDFILE_FOUND)
1526         add_executable(uhjdecoder utils/uhjdecoder.cpp)
1527         target_compile_definitions(uhjdecoder PRIVATE ${CPP_DEFS})
1528         target_include_directories(uhjdecoder
1529             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/common)
1530         target_compile_options(uhjdecoder PRIVATE ${C_FLAGS})
1531         target_link_libraries(uhjdecoder PUBLIC common
1532             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ${UNICODE_FLAG})
1533
1534         add_executable(uhjencoder utils/uhjencoder.cpp)
1535         target_compile_definitions(uhjencoder PRIVATE ${CPP_DEFS})
1536         target_include_directories(uhjencoder
1537             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/common)
1538         target_compile_options(uhjencoder PRIVATE ${C_FLAGS})
1539         target_link_libraries(uhjencoder PUBLIC common
1540             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ${UNICODE_FLAG})
1541     endif()
1542
1543     if(MYSOFA_FOUND)
1544         set(SOFA_SUPPORT_SRCS
1545             utils/sofa-support.cpp
1546             utils/sofa-support.h)
1547         add_library(sofa-support STATIC EXCLUDE_FROM_ALL ${SOFA_SUPPORT_SRCS})
1548         target_compile_definitions(sofa-support PRIVATE ${CPP_DEFS})
1549         target_include_directories(sofa-support PUBLIC ${OpenAL_SOURCE_DIR}/common)
1550         target_compile_options(sofa-support PRIVATE ${C_FLAGS})
1551         target_link_libraries(sofa-support PUBLIC common MySOFA::MySOFA PRIVATE ${LINKER_FLAGS})
1552
1553         set(MAKEMHR_SRCS
1554             utils/makemhr/loaddef.cpp
1555             utils/makemhr/loaddef.h
1556             utils/makemhr/loadsofa.cpp
1557             utils/makemhr/loadsofa.h
1558             utils/makemhr/makemhr.cpp
1559             utils/makemhr/makemhr.h)
1560         if(NOT HAVE_GETOPT)
1561             set(MAKEMHR_SRCS  ${MAKEMHR_SRCS} utils/getopt.c utils/getopt.h)
1562         endif()
1563         add_executable(makemhr ${MAKEMHR_SRCS})
1564         target_compile_definitions(makemhr PRIVATE ${CPP_DEFS})
1565         target_include_directories(makemhr
1566             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/utils)
1567         target_compile_options(makemhr PRIVATE ${C_FLAGS})
1568         target_link_libraries(makemhr PRIVATE ${LINKER_FLAGS} sofa-support ${UNICODE_FLAG})
1569         if(ALSOFT_INSTALL_EXAMPLES)
1570             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} makemhr)
1571         endif()
1572
1573         set(SOFAINFO_SRCS  utils/sofa-info.cpp)
1574         add_executable(sofa-info ${SOFAINFO_SRCS})
1575         target_compile_definitions(sofa-info PRIVATE ${CPP_DEFS})
1576         target_include_directories(sofa-info PRIVATE ${OpenAL_SOURCE_DIR}/utils)
1577         target_compile_options(sofa-info PRIVATE ${C_FLAGS})
1578         target_link_libraries(sofa-info PRIVATE ${LINKER_FLAGS} sofa-support ${UNICODE_FLAG})
1579     endif()
1580     message(STATUS "Building utility programs")
1581
1582     if(NOT ALSOFT_NO_CONFIG_UTIL)
1583         add_subdirectory(utils/alsoft-config)
1584     endif()
1585     message(STATUS "")
1586 endif()
1587
1588
1589 # Add a static library with common functions used by multiple example targets
1590 add_library(ex-common STATIC EXCLUDE_FROM_ALL
1591     examples/common/alhelpers.c
1592     examples/common/alhelpers.h)
1593 target_compile_definitions(ex-common PUBLIC ${CPP_DEFS})
1594 target_include_directories(ex-common PUBLIC ${OpenAL_SOURCE_DIR}/common)
1595 target_compile_options(ex-common PUBLIC ${C_FLAGS})
1596 target_link_libraries(ex-common PUBLIC OpenAL PRIVATE ${RT_LIB})
1597
1598 if(ALSOFT_EXAMPLES)
1599     add_executable(altonegen examples/altonegen.c)
1600     target_link_libraries(altonegen PRIVATE ${LINKER_FLAGS} ${MATH_LIB} ex-common ${UNICODE_FLAG})
1601
1602     add_executable(alrecord examples/alrecord.c)
1603     target_link_libraries(alrecord PRIVATE ${LINKER_FLAGS} ex-common ${UNICODE_FLAG})
1604
1605     if(ALSOFT_INSTALL_EXAMPLES)
1606         set(EXTRA_INSTALLS ${EXTRA_INSTALLS} altonegen alrecord)
1607     endif()
1608
1609     message(STATUS "Building example programs")
1610
1611     if(SNDFILE_FOUND)
1612         add_executable(alplay examples/alplay.c)
1613         target_link_libraries(alplay PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1614             ${UNICODE_FLAG})
1615
1616         add_executable(alstream examples/alstream.c)
1617         target_link_libraries(alstream PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1618             ${UNICODE_FLAG})
1619
1620         add_executable(alreverb examples/alreverb.c)
1621         target_link_libraries(alreverb PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1622             ${UNICODE_FLAG})
1623
1624         add_executable(almultireverb examples/almultireverb.c)
1625         target_link_libraries(almultireverb
1626             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common ${MATH_LIB} ${UNICODE_FLAG})
1627
1628         add_executable(allatency examples/allatency.c)
1629         target_link_libraries(allatency PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1630             ${UNICODE_FLAG})
1631
1632         add_executable(alhrtf examples/alhrtf.c)
1633         target_link_libraries(alhrtf
1634             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common ${MATH_LIB} ${UNICODE_FLAG})
1635
1636         add_executable(alstreamcb examples/alstreamcb.cpp)
1637         target_link_libraries(alstreamcb PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1638             ${UNICODE_FLAG})
1639
1640         add_executable(alconvolve examples/alconvolve.c)
1641         target_link_libraries(alconvolve PRIVATE ${LINKER_FLAGS} common SndFile::SndFile ex-common
1642             ${UNICODE_FLAG})
1643
1644         if(ALSOFT_INSTALL_EXAMPLES)
1645             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alplay alstream alreverb almultireverb allatency
1646                 alhrtf)
1647         endif()
1648
1649         message(STATUS "Building SndFile example programs")
1650     endif()
1651
1652     if(SDL2_FOUND)
1653         add_executable(alloopback examples/alloopback.c)
1654         target_include_directories(alloopback PRIVATE ${SDL2_INCLUDE_DIR})
1655         target_link_libraries(alloopback
1656             PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ex-common ${MATH_LIB})
1657
1658         if(ALSOFT_INSTALL_EXAMPLES)
1659             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alloopback)
1660         endif()
1661
1662         message(STATUS "Building SDL example programs")
1663
1664         set(FFVER_OK FALSE)
1665         if(FFMPEG_FOUND)
1666             set(FFVER_OK TRUE)
1667             if(AVFORMAT_VERSION VERSION_LESS "57.56.101")
1668                 message(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 57.56.101)")
1669                 set(FFVER_OK FALSE)
1670             endif()
1671             if(AVCODEC_VERSION VERSION_LESS "57.64.101")
1672                 message(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 57.64.101)")
1673                 set(FFVER_OK FALSE)
1674             endif()
1675             if(AVUTIL_VERSION VERSION_LESS "55.34.101")
1676                 message(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 55.34.101)")
1677                 set(FFVER_OK FALSE)
1678             endif()
1679             if(SWSCALE_VERSION VERSION_LESS "4.2.100")
1680                 message(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 4.2.100)")
1681                 set(FFVER_OK FALSE)
1682             endif()
1683             if(SWRESAMPLE_VERSION VERSION_LESS "2.3.100")
1684                 message(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 2.3.100)")
1685                 set(FFVER_OK FALSE)
1686             endif()
1687         endif()
1688         if(FFVER_OK)
1689             add_executable(alffplay examples/alffplay.cpp)
1690             target_include_directories(alffplay
1691                 PRIVATE ${SDL2_INCLUDE_DIR} ${FFMPEG_INCLUDE_DIRS})
1692             target_link_libraries(alffplay
1693                 PRIVATE ${LINKER_FLAGS} ${SDL2_LIBRARY} ${FFMPEG_LIBRARIES} ex-common)
1694
1695             if(ALSOFT_INSTALL_EXAMPLES)
1696                 set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alffplay)
1697             endif()
1698             message(STATUS "Building SDL+FFmpeg example programs")
1699         endif()
1700     endif()
1701     message(STATUS "")
1702 endif()
1703
1704 if(EXTRA_INSTALLS)
1705     install(TARGETS ${EXTRA_INSTALLS}
1706         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1707         BUNDLE  DESTINATION ${CMAKE_INSTALL_BINDIR}
1708         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1709         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
1710 endif()