CMakeLists.txt

   1 # CMake build file list for OpenAL
   2
   3 cmake_minimum_required(VERSION 3.0.2)
   4
   5 if(APPLE)
   6     # The workaround for try_compile failing with code signing
   7     # since cmake-3.18.2, not required
   8     set(CMAKE_TRY_COMPILE_PLATFORM_VARIABLES
   9         ${CMAKE_TRY_COMPILE_PLATFORM_VARIABLES}
  10         "CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED"
  11         "CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED")
  12     set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED NO)
  13     set(CMAKE_XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED NO)
  14 endif()
  15
  16 if(CMAKE_SYSTEM_NAME STREQUAL "iOS")
  17     # Fix compile failure with armv7 deployment target >= 11.0, xcode clang
  18     # will report:
  19     # error: invalid iOS deployment version '--target=armv7-apple-ios13.6',
  20     # iOS 10 is the maximum deployment target for 32-bit targets
  21     # If CMAKE_OSX_DEPLOYMENT_TARGET is not defined, cmake will choose latest
  22     # deployment target
  23     if("${CMAKE_OSX_ARCHITECTURES}" MATCHES ".*armv7.*")
  24         if(NOT DEFINED CMAKE_OSX_DEPLOYMENT_TARGET
  25             OR NOT CMAKE_OSX_DEPLOYMENT_TARGET VERSION_LESS "11.0")
  26             message(STATUS "Forcing iOS deployment target to 10.0 for armv7")
  27             set(CMAKE_OSX_DEPLOYMENT_TARGET "10.0" CACHE STRING "Minimum OS X deployment version"
  28                 FORCE)
  29         endif()
  30     endif()
  31 endif()
  32
  33 set(CMAKE_C_VISIBILITY_PRESET hidden)
  34 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  35
  36 if(COMMAND CMAKE_POLICY)
  37     cmake_policy(SET CMP0003 NEW)
  38     cmake_policy(SET CMP0005 NEW)
  39     if(POLICY CMP0020)
  40         cmake_policy(SET CMP0020 NEW)
  41     endif(POLICY CMP0020)
  42     if(POLICY CMP0042)
  43         cmake_policy(SET CMP0042 NEW)
  44     endif(POLICY CMP0042)
  45     if(POLICY CMP0054)
  46         cmake_policy(SET CMP0054 NEW)
  47     endif(POLICY CMP0054)
  48     if(POLICY CMP0058)
  49         cmake_policy(SET CMP0058 NEW)
  50     endif(POLICY CMP0058)
  51     if(POLICY CMP0063)
  52         cmake_policy(SET CMP0063 NEW)
  53     endif(POLICY CMP0063)
  54     if(POLICY CMP0075)
  55         cmake_policy(SET CMP0075 NEW)
  56     endif(POLICY CMP0075)
  57     if(POLICY CMP0092)
  58         cmake_policy(SET CMP0092 NEW)
  59     endif(POLICY CMP0092)
  60     if(POLICY CMP0117)
  61         cmake_policy(SET CMP0117 NEW)
  62     endif(POLICY CMP0117)
  63 endif(COMMAND CMAKE_POLICY)
  64
  65 project(OpenAL)
  66
  67 if(NOT CMAKE_BUILD_TYPE)
  68     set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING
  69         "Choose the type of build, options are: Debug Release RelWithDebInfo MinSizeRel."
  70         FORCE)
  71 endif()
  72 if(NOT CMAKE_DEBUG_POSTFIX)
  73     set(CMAKE_DEBUG_POSTFIX "" CACHE STRING
  74         "Library postfix for debug builds. Normally left blank."
  75         FORCE)
  76 endif()
  77
  78 set(CMAKE_MODULE_PATH "${OpenAL_SOURCE_DIR}/cmake")
  79
  80 include(CheckFunctionExists)
  81 include(CheckLibraryExists)
  82 include(CheckIncludeFile)
  83 include(CheckIncludeFiles)
  84 include(CheckSymbolExists)
  85 include(CheckCCompilerFlag)
  86 include(CheckCXXCompilerFlag)
  87 include(CheckCSourceCompiles)
  88 include(CheckCXXSourceCompiles)
  89 include(CheckStructHasMember)
  90 include(CMakePackageConfigHelpers)
  91 include(GNUInstallDirs)
  92
  93 find_package(PkgConfig)
  94
  95
  96 option(ALSOFT_DLOPEN  "Check for the dlopen API for loading optional libs"  ON)
  97
  98 option(ALSOFT_WERROR  "Treat compile warnings as errors"      OFF)
  99
 100 option(ALSOFT_UTILS "Build utility programs"  ON)
 101 option(ALSOFT_NO_CONFIG_UTIL "Disable building the alsoft-config utility" OFF)
 102
 103 option(ALSOFT_EXAMPLES  "Build example programs"  ON)
 104
 105 option(ALSOFT_INSTALL "Install main library" ON)
 106 option(ALSOFT_INSTALL_CONFIG "Install alsoft.conf sample configuration file" ON)
 107 option(ALSOFT_INSTALL_HRTF_DATA "Install HRTF data files" ON)
 108 option(ALSOFT_INSTALL_AMBDEC_PRESETS "Install AmbDec preset files" ON)
 109 option(ALSOFT_INSTALL_EXAMPLES "Install example programs (alplay, alstream, ...)" ON)
 110 option(ALSOFT_INSTALL_UTILS "Install utility programs (openal-info, alsoft-config, ...)" ON)
 111 option(ALSOFT_UPDATE_BUILD_VERSION "Update git build version info" ON)
 112
 113 option(ALSOFT_EAX "Enable legacy EAX extensions" ${WIN32})
 114
 115 option(ALSOFT_SEARCH_INSTALL_DATADIR "Search the installation data directory" OFF)
 116 if(ALSOFT_SEARCH_INSTALL_DATADIR)
 117     set(ALSOFT_INSTALL_DATADIR ${CMAKE_INSTALL_FULL_DATADIR})
 118 endif()
 119
 120 if(DEFINED SHARE_INSTALL_DIR)
 121     message(WARNING "SHARE_INSTALL_DIR is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
 122     set(CMAKE_INSTALL_DATADIR "${SHARE_INSTALL_DIR}")
 123 endif()
 124
 125 if(DEFINED LIB_SUFFIX)
 126     message(WARNING "LIB_SUFFIX is deprecated.  Use the variables provided by the GNUInstallDirs module instead")
 127 endif()
 128 if(DEFINED ALSOFT_CONFIG)
 129     message(WARNING "ALSOFT_CONFIG is deprecated. Use ALSOFT_INSTALL_CONFIG instead")
 130 endif()
 131 if(DEFINED ALSOFT_HRTF_DEFS)
 132     message(WARNING "ALSOFT_HRTF_DEFS is deprecated. Use ALSOFT_INSTALL_HRTF_DATA instead")
 133 endif()
 134 if(DEFINED ALSOFT_AMBDEC_PRESETS)
 135     message(WARNING "ALSOFT_AMBDEC_PRESETS is deprecated. Use ALSOFT_INSTALL_AMBDEC_PRESETS instead")
 136 endif()
 137
 138
 139 set(CPP_DEFS ) # C pre-processor, not C++
 140 set(INC_PATHS )
 141 set(C_FLAGS )
 142 set(LINKER_FLAGS )
 143 set(EXTRA_LIBS )
 144
 145 if(WIN32)
 146     set(CPP_DEFS ${CPP_DEFS} _WIN32 NOMINMAX)
 147     if(MINGW)
 148         set(CPP_DEFS ${CPP_DEFS} __USE_MINGW_ANSI_STDIO)
 149     endif()
 150
 151     option(ALSOFT_BUILD_ROUTER  "Build the router (EXPERIMENTAL; creates OpenAL32.dll and soft_oal.dll)"  OFF)
 152     if(MINGW)
 153         option(ALSOFT_BUILD_IMPORT_LIB "Build an import .lib using dlltool (requires sed)" ON)
 154     endif()
 155 elseif(APPLE)
 156     option(ALSOFT_OSX_FRAMEWORK "Build as macOS framework" OFF)
 157 endif()
 158
 159
 160 # QNX's gcc do not uses /usr/include and /usr/lib pathes by default
 161 if("${CMAKE_C_PLATFORM_ID}" STREQUAL "QNX")
 162     set(INC_PATHS ${INC_PATHS} /usr/include)
 163     set(LINKER_FLAGS ${LINKER_FLAGS} -L/usr/lib)
 164 endif()
 165
 166 # When the library is built for static linking, apps should define
 167 # AL_LIBTYPE_STATIC when including the AL headers.
 168 if(NOT LIBTYPE)
 169     set(LIBTYPE SHARED)
 170 endif()
 171
 172 set(LIB_MAJOR_VERSION "1")
 173 set(LIB_MINOR_VERSION "23")
 174 set(LIB_REVISION "0")
 175 set(LIB_VERSION "${LIB_MAJOR_VERSION}.${LIB_MINOR_VERSION}.${LIB_REVISION}")
 176 set(LIB_VERSION_NUM ${LIB_MAJOR_VERSION},${LIB_MINOR_VERSION},${LIB_REVISION},0)
 177
 178 set(EXPORT_DECL "")
 179
 180
 181 # Require C++14
 182 set(CMAKE_CXX_STANDARD 14)
 183 set(CMAKE_CXX_STANDARD_REQUIRED TRUE)
 184
 185 # Prefer C11, but support C99 and C90 too.
 186 set(CMAKE_C_STANDARD 11)
 187
 188 if(NOT WIN32)
 189     # Check if _POSIX_C_SOURCE and _XOPEN_SOURCE needs to be set for POSIX functions
 190     check_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_DEFAULT)
 191     if(NOT HAVE_POSIX_MEMALIGN_DEFAULT)
 192         set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 193         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=600")
 194         check_symbol_exists(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN_POSIX)
 195         if(NOT HAVE_POSIX_MEMALIGN_POSIX)
 196             set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 197         else()
 198             set(CPP_DEFS ${CPP_DEFS} _POSIX_C_SOURCE=200112L _XOPEN_SOURCE=600)
 199         endif()
 200     endif()
 201     unset(OLD_REQUIRED_FLAGS)
 202 endif()
 203
 204 # C99 has restrict, but C++ does not, so we can only utilize __restrict.
 205 check_cxx_source_compiles("int *__restrict foo;
 206 int main() { return 0; }" HAVE___RESTRICT)
 207 if(HAVE___RESTRICT)
 208     set(CPP_DEFS ${CPP_DEFS} RESTRICT=__restrict)
 209 else()
 210     set(CPP_DEFS ${CPP_DEFS} "RESTRICT=")
 211 endif()
 212
 213 # Some systems may need libatomic for atomic functions to work
 214 set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 215 set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES} atomic)
 216 check_cxx_source_compiles("#include <atomic>
 217 std::atomic<int> foo{0};
 218 int main() { return foo.fetch_add(2); }"
 219 HAVE_LIBATOMIC)
 220 if(NOT HAVE_LIBATOMIC)
 221     set(CMAKE_REQUIRED_LIBRARIES "${OLD_REQUIRED_LIBRARIES}")
 222 else()
 223     set(EXTRA_LIBS atomic ${EXTRA_LIBS})
 224 endif()
 225 unset(OLD_REQUIRED_LIBRARIES)
 226
 227 if(ANDROID)
 228     # Include liblog for Android logging
 229     check_library_exists(log __android_log_print "" HAVE_LIBLOG)
 230     if(HAVE_LIBLOG)
 231         set(EXTRA_LIBS log ${EXTRA_LIBS})
 232         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} log)
 233     endif()
 234 endif()
 235
 236 if(MSVC)
 237     set(CPP_DEFS ${CPP_DEFS} _CRT_SECURE_NO_WARNINGS)
 238     check_cxx_compiler_flag(/permissive- HAVE_PERMISSIVE_SWITCH)
 239     if(HAVE_PERMISSIVE_SWITCH)
 240         set(C_FLAGS ${C_FLAGS} $<$<COMPILE_LANGUAGE:CXX>:/permissive->)
 241     endif()
 242     set(C_FLAGS ${C_FLAGS} /W4 /w14640 /wd4065 /wd4127 /wd4268 /wd4324 /wd5030 /wd5051)
 243
 244     if(NOT DXSDK_DIR)
 245         string(REGEX REPLACE "\\\\" "/" DXSDK_DIR "$ENV{DXSDK_DIR}")
 246     else()
 247         string(REGEX REPLACE "\\\\" "/" DXSDK_DIR "${DXSDK_DIR}")
 248     endif()
 249     if(DXSDK_DIR)
 250         message(STATUS "Using DirectX SDK directory: ${DXSDK_DIR}")
 251     endif()
 252
 253     option(FORCE_STATIC_VCRT "Force /MT for static VC runtimes" OFF)
 254     if(FORCE_STATIC_VCRT)
 255         foreach(flag_var
 256                 CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 257                 CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO
 258                 CMAKE_CXX_FLAGS CMAKE_CXX_FLAGS_DEBUG CMAKE_CXX_FLAGS_RELEASE
 259                 CMAKE_CXX_FLAGS_MINSIZEREL CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 260             if(${flag_var} MATCHES "/MD")
 261                 string(REGEX REPLACE "/MD" "/MT" ${flag_var} "${${flag_var}}")
 262             endif()
 263         endforeach(flag_var)
 264     endif()
 265 else()
 266     set(C_FLAGS ${C_FLAGS} -Winline -Wunused -Wall -Wextra -Wshadow -Wconversion -Wcast-align
 267         -Wpedantic
 268         $<$<COMPILE_LANGUAGE:CXX>:-Wold-style-cast -Wnon-virtual-dtor -Woverloaded-virtual>)
 269
 270     check_cxx_compiler_flag(-Wno-c++20-attribute-extensions HAVE_WNO_CXX20_ATTR_EXT)
 271     if(HAVE_WNO_CXX20_ATTR_EXT)
 272         set(C_FLAGS ${C_FLAGS} $<$<COMPILE_LANGUAGE:CXX>:-Wno-c++20-attribute-extensions>)
 273     else()
 274         check_cxx_compiler_flag(-Wno-c++20-extensions HAVE_WNO_CXX20_EXT)
 275         if(HAVE_WNO_CXX20_EXT)
 276             set(C_FLAGS ${C_FLAGS} $<$<COMPILE_LANGUAGE:CXX>:-Wno-c++20-extensions>)
 277         endif()
 278     endif()
 279
 280     if(ALSOFT_WERROR)
 281         set(C_FLAGS ${C_FLAGS} -Werror)
 282     endif()
 283
 284     # We want RelWithDebInfo to actually include debug stuff (define _DEBUG
 285     # instead of NDEBUG)
 286     foreach(flag_var  CMAKE_C_FLAGS_RELWITHDEBINFO CMAKE_CXX_FLAGS_RELWITHDEBINFO)
 287         if(${flag_var} MATCHES "-DNDEBUG")
 288             string(REGEX REPLACE "-DNDEBUG" "-D_DEBUG" ${flag_var} "${${flag_var}}")
 289         endif()
 290     endforeach()
 291
 292     check_c_compiler_flag(-fno-math-errno HAVE_FNO_MATH_ERRNO)
 293     if(HAVE_FNO_MATH_ERRNO)
 294         set(C_FLAGS ${C_FLAGS} -fno-math-errno)
 295     endif()
 296
 297     option(ALSOFT_STATIC_LIBGCC "Force -static-libgcc for static GCC runtimes" OFF)
 298     if(ALSOFT_STATIC_LIBGCC)
 299         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 300         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc)
 301         check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBGCC_SWITCH)
 302         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 303         unset(OLD_REQUIRED_LIBRARIES)
 304
 305         if(NOT HAVE_STATIC_LIBGCC_SWITCH)
 306             message(FATAL_ERROR "Cannot static link libgcc")
 307         endif()
 308         set(LINKER_FLAGS ${LINKER_FLAGS} -static-libgcc)
 309     endif()
 310
 311     option(ALSOFT_STATIC_STDCXX "Static link libstdc++" OFF)
 312     if(ALSOFT_STATIC_STDCXX)
 313         set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 314         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-Wl,--push-state,-Bstatic,-lstdc++,--pop-state")
 315         check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBSTDCXX_SWITCH)
 316         set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 317         unset(OLD_REQUIRED_LIBRARIES)
 318
 319         if(NOT HAVE_STATIC_LIBSTDCXX_SWITCH)
 320             message(FATAL_ERROR "Cannot static link libstdc++")
 321         endif()
 322         set(LINKER_FLAGS ${LINKER_FLAGS} "-Wl,--push-state,-Bstatic,-lstdc++,--pop-state")
 323     endif()
 324
 325     if(WIN32)
 326         option(ALSOFT_STATIC_WINPTHREAD "Static link libwinpthread" OFF)
 327         if(ALSOFT_STATIC_WINPTHREAD)
 328             set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
 329             set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} "-Wl,--push-state,-Bstatic,-lwinpthread,--pop-state")
 330             check_cxx_source_compiles("int main() { }" HAVE_STATIC_LIBWINPTHREAD_SWITCH)
 331             set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
 332             unset(OLD_REQUIRED_LIBRARIES)
 333
 334             if(NOT HAVE_STATIC_LIBWINPTHREAD_SWITCH)
 335                 message(FATAL_ERROR "Cannot static link libwinpthread")
 336             endif()
 337             set(LINKER_FLAGS ${LINKER_FLAGS} "-Wl,--push-state,-Bstatic,-lwinpthread,--pop-state")
 338         endif()
 339     endif()
 340 endif()
 341
 342 # Set visibility/export options if available
 343 if(WIN32)
 344     if(NOT LIBTYPE STREQUAL "STATIC")
 345         set(EXPORT_DECL "__declspec(dllexport)")
 346     endif()
 347 else()
 348     set(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
 349     # Yes GCC, really don't accept visibility modes you don't support
 350     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
 351
 352     check_c_source_compiles("int foo() __attribute__((visibility(\"protected\")));
 353                              int main() {return 0;}" HAVE_GCC_PROTECTED_VISIBILITY)
 354     if(HAVE_GCC_PROTECTED_VISIBILITY)
 355         if(NOT LIBTYPE STREQUAL "STATIC")
 356             set(EXPORT_DECL "__attribute__((visibility(\"protected\")))")
 357         endif()
 358     else()
 359         check_c_source_compiles("int foo() __attribute__((visibility(\"default\")));
 360                                  int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
 361         if(HAVE_GCC_DEFAULT_VISIBILITY)
 362             if(NOT LIBTYPE STREQUAL "STATIC")
 363                 set(EXPORT_DECL "__attribute__((visibility(\"default\")))")
 364             endif()
 365         endif()
 366     endif()
 367
 368     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
 369 endif()
 370
 371
 372 set(SSE2_SWITCH "")
 373
 374 if(NOT MSVC)
 375     set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 376     # Yes GCC, really don't accept command line options you don't support
 377     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Werror")
 378     check_c_compiler_flag(-msse2 HAVE_MSSE2_SWITCH)
 379     if(HAVE_MSSE2_SWITCH)
 380         set(SSE2_SWITCH "-msse2")
 381     endif()
 382     set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 383     unset(OLD_REQUIRED_FLAGS)
 384 endif()
 385
 386 check_include_file(xmmintrin.h HAVE_XMMINTRIN_H)
 387 check_include_file(emmintrin.h HAVE_EMMINTRIN_H)
 388 check_include_file(pmmintrin.h HAVE_PMMINTRIN_H)
 389 check_include_file(smmintrin.h HAVE_SMMINTRIN_H)
 390 check_include_file(arm_neon.h HAVE_ARM_NEON_H)
 391
 392 set(HAVE_SSE        0)
 393 set(HAVE_SSE2       0)
 394 set(HAVE_SSE3       0)
 395 set(HAVE_SSE4_1     0)
 396 set(HAVE_NEON       0)
 397
 398 # Check for SSE support
 399 option(ALSOFT_REQUIRE_SSE "Require SSE support" OFF)
 400 if(HAVE_XMMINTRIN_H)
 401     option(ALSOFT_CPUEXT_SSE "Enable SSE support" ON)
 402     if(ALSOFT_CPUEXT_SSE)
 403         set(HAVE_SSE 1)
 404     endif()
 405 endif()
 406 if(ALSOFT_REQUIRE_SSE AND NOT HAVE_SSE)
 407     message(FATAL_ERROR "Failed to enabled required SSE CPU extensions")
 408 endif()
 409
 410 option(ALSOFT_REQUIRE_SSE2 "Require SSE2 support" OFF)
 411 if(HAVE_EMMINTRIN_H)
 412     option(ALSOFT_CPUEXT_SSE2 "Enable SSE2 support" ON)
 413     if(HAVE_SSE AND ALSOFT_CPUEXT_SSE2)
 414         set(HAVE_SSE2 1)
 415     endif()
 416 endif()
 417 if(ALSOFT_REQUIRE_SSE2 AND NOT HAVE_SSE2)
 418     message(FATAL_ERROR "Failed to enable required SSE2 CPU extensions")
 419 endif()
 420
 421 option(ALSOFT_REQUIRE_SSE3 "Require SSE3 support" OFF)
 422 if(HAVE_PMMINTRIN_H)
 423     option(ALSOFT_CPUEXT_SSE3 "Enable SSE3 support" ON)
 424     if(HAVE_SSE2 AND ALSOFT_CPUEXT_SSE3)
 425         set(HAVE_SSE3 1)
 426     endif()
 427 endif()
 428 if(ALSOFT_REQUIRE_SSE3 AND NOT HAVE_SSE3)
 429     message(FATAL_ERROR "Failed to enable required SSE3 CPU extensions")
 430 endif()
 431
 432 option(ALSOFT_REQUIRE_SSE4_1 "Require SSE4.1 support" OFF)
 433 if(HAVE_SMMINTRIN_H)
 434     option(ALSOFT_CPUEXT_SSE4_1 "Enable SSE4.1 support" ON)
 435     if(HAVE_SSE3 AND ALSOFT_CPUEXT_SSE4_1)
 436         set(HAVE_SSE4_1 1)
 437     endif()
 438 endif()
 439 if(ALSOFT_REQUIRE_SSE4_1 AND NOT HAVE_SSE4_1)
 440     message(FATAL_ERROR "Failed to enable required SSE4.1 CPU extensions")
 441 endif()
 442
 443 # Check for ARM Neon support
 444 option(ALSOFT_REQUIRE_NEON "Require ARM NEON support" OFF)
 445 if(HAVE_ARM_NEON_H)
 446     option(ALSOFT_CPUEXT_NEON "Enable ARM NEON support" ON)
 447     if(ALSOFT_CPUEXT_NEON)
 448         check_c_source_compiles("#include <arm_neon.h>
 449             int main()
 450             {
 451                 int32x4_t ret4 = vdupq_n_s32(0);
 452                 return vgetq_lane_s32(ret4, 0);
 453             }" HAVE_NEON_INTRINSICS)
 454         if(HAVE_NEON_INTRINSICS)
 455             set(HAVE_NEON 1)
 456         endif()
 457     endif()
 458 endif()
 459 if(ALSOFT_REQUIRE_NEON AND NOT HAVE_NEON)
 460     message(FATAL_ERROR "Failed to enabled required ARM NEON CPU extensions")
 461 endif()
 462
 463
 464 set(SSE_FLAGS )
 465 set(FPMATH_SET "0")
 466 if(CMAKE_SIZEOF_VOID_P MATCHES "4" AND HAVE_SSE2)
 467     option(ALSOFT_ENABLE_SSE2_CODEGEN "Enable SSE2 code generation instead of x87 for 32-bit targets." TRUE)
 468     if(ALSOFT_ENABLE_SSE2_CODEGEN)
 469         if(MSVC)
 470             check_c_compiler_flag("/arch:SSE2" HAVE_ARCH_SSE2)
 471             if(HAVE_ARCH_SSE2)
 472                 set(SSE_FLAGS ${SSE_FLAGS} "/arch:SSE2")
 473                 set(C_FLAGS ${C_FLAGS} ${SSE_FLAGS})
 474                 set(FPMATH_SET 2)
 475             endif()
 476         elseif(SSE2_SWITCH)
 477             check_c_compiler_flag("${SSE2_SWITCH} -mfpmath=sse" HAVE_MFPMATH_SSE_2)
 478             if(HAVE_MFPMATH_SSE_2)
 479                 set(SSE_FLAGS ${SSE_FLAGS} ${SSE2_SWITCH} -mfpmath=sse)
 480                 set(C_FLAGS ${C_FLAGS} ${SSE_FLAGS})
 481                 set(FPMATH_SET 2)
 482             endif()
 483             # SSE depends on a 16-byte aligned stack, and by default, GCC
 484             # assumes the stack is suitably aligned. Older Linux code or other
 485             # OSs don't guarantee this on 32-bit, so externally-callable
 486             # functions need to ensure an aligned stack.
 487             set(EXPORT_DECL "${EXPORT_DECL}__attribute__((force_align_arg_pointer))")
 488         endif()
 489     endif()
 490 endif()
 491
 492 if(HAVE_SSE2)
 493     set(OLD_REQUIRED_FLAGS ${CMAKE_REQUIRED_FLAGS})
 494     foreach(flag_var ${SSE_FLAGS})
 495         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} ${flag_var}")
 496     endforeach()
 497
 498     check_c_source_compiles("#include <emmintrin.h>
 499         int main() {_mm_pause(); return 0;}" HAVE_SSE_INTRINSICS)
 500
 501     set(CMAKE_REQUIRED_FLAGS ${OLD_REQUIRED_FLAGS})
 502 endif()
 503
 504
 505 check_include_file(malloc.h HAVE_MALLOC_H)
 506 check_include_file(cpuid.h HAVE_CPUID_H)
 507 check_include_file(intrin.h HAVE_INTRIN_H)
 508 check_include_file(guiddef.h HAVE_GUIDDEF_H)
 509 if(NOT HAVE_GUIDDEF_H)
 510     check_include_file(initguid.h HAVE_INITGUID_H)
 511 endif()
 512
 513 # Some systems need libm for some math functions to work
 514 set(MATH_LIB )
 515 check_library_exists(m pow "" HAVE_LIBM)
 516 if(HAVE_LIBM)
 517     set(MATH_LIB ${MATH_LIB} m)
 518     set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} m)
 519 endif()
 520
 521 # Some systems need to link with -lrt for clock_gettime as used by the common
 522 # eaxmple functions.
 523 set(RT_LIB )
 524 check_library_exists(rt clock_gettime "" HAVE_LIBRT)
 525 if(HAVE_LIBRT)
 526     set(RT_LIB rt)
 527 endif()
 528
 529 # Check for the dlopen API (for dynamicly loading backend libs)
 530 if(ALSOFT_DLOPEN)
 531     check_include_file(dlfcn.h HAVE_DLFCN_H)
 532     check_library_exists(dl dlopen "" HAVE_LIBDL)
 533     if(HAVE_LIBDL)
 534         set(EXTRA_LIBS dl ${EXTRA_LIBS})
 535         set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} dl)
 536     endif()
 537 endif()
 538
 539 # Check for a cpuid intrinsic
 540 if(HAVE_CPUID_H)
 541     check_c_source_compiles("#include <cpuid.h>
 542         int main()
 543         {
 544             unsigned int eax, ebx, ecx, edx;
 545             return __get_cpuid(0, &eax, &ebx, &ecx, &edx);
 546         }" HAVE_GCC_GET_CPUID)
 547 endif()
 548 if(HAVE_INTRIN_H)
 549     check_c_source_compiles("#include <intrin.h>
 550         int main()
 551         {
 552             int regs[4];
 553             __cpuid(regs, 0);
 554             return regs[0];
 555         }" HAVE_CPUID_INTRINSIC)
 556 endif()
 557
 558 check_symbol_exists(posix_memalign   stdlib.h HAVE_POSIX_MEMALIGN)
 559 check_symbol_exists(_aligned_malloc  malloc.h HAVE__ALIGNED_MALLOC)
 560 check_symbol_exists(proc_pidpath     libproc.h HAVE_PROC_PIDPATH)
 561
 562 if(NOT WIN32)
 563     # We need pthreads outside of Windows, for semaphores. It's also used to
 564     # set the priority and name of threads, when possible.
 565     check_include_file(pthread.h HAVE_PTHREAD_H)
 566     if(NOT HAVE_PTHREAD_H)
 567         message(FATAL_ERROR "PThreads is required for non-Windows builds!")
 568     endif()
 569
 570     check_c_compiler_flag(-pthread HAVE_PTHREAD)
 571     if(HAVE_PTHREAD)
 572         set(CMAKE_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS} -pthread")
 573         set(C_FLAGS ${C_FLAGS} -pthread)
 574         set(LINKER_FLAGS ${LINKER_FLAGS} -pthread)
 575     endif()
 576
 577     check_symbol_exists(pthread_setschedparam pthread.h HAVE_PTHREAD_SETSCHEDPARAM)
 578
 579     # Some systems need pthread_np.h to get pthread_setname_np
 580     check_include_files("pthread.h;pthread_np.h" HAVE_PTHREAD_NP_H)
 581     if(HAVE_PTHREAD_NP_H)
 582         check_symbol_exists(pthread_setname_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SETNAME_NP)
 583         if(NOT HAVE_PTHREAD_SETNAME_NP)
 584             check_symbol_exists(pthread_set_name_np "pthread.h;pthread_np.h" HAVE_PTHREAD_SET_NAME_NP)
 585         endif()
 586     else()
 587         check_symbol_exists(pthread_setname_np pthread.h HAVE_PTHREAD_SETNAME_NP)
 588         if(NOT HAVE_PTHREAD_SETNAME_NP)
 589             check_symbol_exists(pthread_set_name_np pthread.h HAVE_PTHREAD_SET_NAME_NP)
 590         endif()
 591     endif()
 592 endif()
 593
 594 check_symbol_exists(getopt unistd.h HAVE_GETOPT)
 595
 596
 597 # Common sources used by both the OpenAL implementation library, the OpenAL
 598 # router, and certain tools and examples.
 599 set(COMMON_OBJS
 600     common/albit.h
 601     common/albyte.h
 602     common/alcomplex.cpp
 603     common/alcomplex.h
 604     common/aldeque.h
 605     common/alfstream.cpp
 606     common/alfstream.h
 607     common/almalloc.cpp
 608     common/almalloc.h
 609     common/alnumbers.h
 610     common/alnumeric.h
 611     common/aloptional.h
 612     common/alspan.h
 613     common/alstring.cpp
 614     common/alstring.h
 615     common/atomic.h
 616     common/comptr.h
 617     common/dynload.cpp
 618     common/dynload.h
 619     common/intrusive_ptr.h
 620     common/opthelpers.h
 621     common/phase_shifter.h
 622     common/polyphase_resampler.cpp
 623     common/polyphase_resampler.h
 624     common/pragmadefs.h
 625     common/ringbuffer.cpp
 626     common/ringbuffer.h
 627     common/strutils.cpp
 628     common/strutils.h
 629     common/threads.cpp
 630     common/threads.h
 631     common/vecmat.h
 632     common/vector.h)
 633
 634 # Core library routines
 635 set(CORE_OBJS
 636     core/ambdec.cpp
 637     core/ambdec.h
 638     core/ambidefs.cpp
 639     core/ambidefs.h
 640     core/async_event.h
 641     core/bformatdec.cpp
 642     core/bformatdec.h
 643     core/bs2b.cpp
 644     core/bs2b.h
 645     core/bsinc_defs.h
 646     core/bsinc_tables.cpp
 647     core/bsinc_tables.h
 648     core/bufferline.h
 649     core/buffer_storage.cpp
 650     core/buffer_storage.h
 651     core/context.cpp
 652     core/context.h
 653     core/converter.cpp
 654     core/converter.h
 655     core/cpu_caps.cpp
 656     core/cpu_caps.h
 657     core/devformat.cpp
 658     core/devformat.h
 659     core/device.cpp
 660     core/device.h
 661     core/effects/base.h
 662     core/effectslot.cpp
 663     core/effectslot.h
 664     core/except.cpp
 665     core/except.h
 666     core/filters/biquad.h
 667     core/filters/biquad.cpp
 668     core/filters/nfc.cpp
 669     core/filters/nfc.h
 670     core/filters/splitter.cpp
 671     core/filters/splitter.h
 672     core/fmt_traits.cpp
 673     core/fmt_traits.h
 674     core/fpu_ctrl.cpp
 675     core/fpu_ctrl.h
 676     core/front_stablizer.h
 677     core/helpers.cpp
 678     core/helpers.h
 679     core/hrtf.cpp
 680     core/hrtf.h
 681     core/logging.cpp
 682     core/logging.h
 683     core/mastering.cpp
 684     core/mastering.h
 685     core/mixer.cpp
 686     core/mixer.h
 687     core/resampler_limits.h
 688     core/uhjfilter.cpp
 689     core/uhjfilter.h
 690     core/uiddefs.cpp
 691     core/voice.cpp
 692     core/voice.h
 693     core/voice_change.h)
 694
 695 set(HAVE_RTKIT 0)
 696 if(NOT WIN32)
 697     option(ALSOFT_REQUIRE_RTKIT "Require RTKit/D-Bus support" FALSE)
 698     find_package(DBus1 QUIET)
 699     if(NOT DBus1_FOUND AND PkgConfig_FOUND)
 700         pkg_check_modules(DBUS dbus-1)
 701     endif()
 702     if(DBus1_FOUND OR DBUS_FOUND)
 703         option(ALSOFT_RTKIT "Enable RTKit support" ON)
 704         if(ALSOFT_RTKIT)
 705             set(HAVE_RTKIT 1)
 706             set(CORE_OBJS ${CORE_OBJS} core/dbus_wrap.cpp core/dbus_wrap.h
 707                 core/rtkit.cpp core/rtkit.h)
 708             if(NOT DBus1_FOUND)
 709                 set(INC_PATHS ${INC_PATHS} ${DBUS_INCLUDE_DIRS})
 710                 set(CPP_DEFS ${CPP_DEFS} ${DBUS_CFLAGS_OTHER})
 711                 if(NOT HAVE_DLFCN_H)
 712                     set(EXTRA_LIBS ${EXTRA_LIBS} ${DBUS_LINK_LIBRARIES})
 713                 endif()
 714             elseif(HAVE_DLFCN_H)
 715                 set(INC_PATHS ${INC_PATHS} ${DBus1_INCLUDE_DIRS})
 716                 set(CPP_DEFS ${CPP_DEFS} ${DBus1_DEFINITIONS})
 717             else()
 718                 set(EXTRA_LIBS ${EXTRA_LIBS} ${DBus1_LIBRARIES})
 719             endif()
 720         endif()
 721     else()
 722         set(MISSING_VARS "")
 723         if(NOT DBus1_INCLUDE_DIRS)
 724             set(MISSING_VARS "${MISSING_VARS} DBus1_INCLUDE_DIRS")
 725         endif()
 726         if(NOT DBus1_LIBRARIES)
 727             set(MISSING_VARS "${MISSING_VARS} DBus1_LIBRARIES")
 728         endif()
 729         message(STATUS "Could NOT find DBus1 (missing:${MISSING_VARS})")
 730         unset(MISSING_VARS)
 731     endif()
 732 endif()
 733 if(ALSOFT_REQUIRE_RTKIT AND NOT HAVE_RTKIT)
 734     message(FATAL_ERROR "Failed to enabled required RTKit support")
 735 endif()
 736
 737 # Default mixers, always available
 738 set(CORE_OBJS ${CORE_OBJS}
 739     core/mixer/defs.h
 740     core/mixer/hrtfbase.h
 741     core/mixer/hrtfdefs.h
 742     core/mixer/mixer_c.cpp)
 743
 744 # AL and related routines
 745 set(OPENAL_OBJS
 746     al/auxeffectslot.cpp
 747     al/auxeffectslot.h
 748     al/buffer.cpp
 749     al/buffer.h
 750     al/effect.cpp
 751     al/effect.h
 752     al/effects/autowah.cpp
 753     al/effects/chorus.cpp
 754     al/effects/compressor.cpp
 755     al/effects/convolution.cpp
 756     al/effects/dedicated.cpp
 757     al/effects/distortion.cpp
 758     al/effects/echo.cpp
 759         al/effects/effects.cpp
 760     al/effects/effects.h
 761     al/effects/equalizer.cpp
 762     al/effects/fshifter.cpp
 763     al/effects/modulator.cpp
 764     al/effects/null.cpp
 765     al/effects/pshifter.cpp
 766     al/effects/reverb.cpp
 767     al/effects/vmorpher.cpp
 768     al/error.cpp
 769     al/event.cpp
 770     al/event.h
 771     al/extension.cpp
 772     al/filter.cpp
 773     al/filter.h
 774     al/listener.cpp
 775     al/listener.h
 776     al/source.cpp
 777     al/source.h
 778     al/state.cpp)
 779
 780 # ALC and related routines
 781 set(ALC_OBJS
 782     alc/alc.cpp
 783     alc/alu.cpp
 784     alc/alu.h
 785     alc/alconfig.cpp
 786     alc/alconfig.h
 787     alc/context.cpp
 788     alc/context.h
 789     alc/device.cpp
 790     alc/device.h
 791     alc/effects/base.h
 792     alc/effects/autowah.cpp
 793     alc/effects/chorus.cpp
 794     alc/effects/compressor.cpp
 795     alc/effects/convolution.cpp
 796     alc/effects/dedicated.cpp
 797     alc/effects/distortion.cpp
 798     alc/effects/echo.cpp
 799     alc/effects/equalizer.cpp
 800     alc/effects/fshifter.cpp
 801     alc/effects/modulator.cpp
 802     alc/effects/null.cpp
 803     alc/effects/pshifter.cpp
 804     alc/effects/reverb.cpp
 805     alc/effects/vmorpher.cpp
 806     alc/inprogext.h
 807     alc/panning.cpp)
 808
 809 if (ALSOFT_EAX)
 810     set(OPENAL_OBJS
 811         ${OPENAL_OBJS}
 812         al/eax/api.cpp
 813         al/eax/api.h
 814         al/eax/call.cpp
 815         al/eax/call.h
 816         al/eax/effect.h
 817         al/eax/exception.cpp
 818         al/eax/exception.h
 819         al/eax/fx_slot_index.cpp
 820         al/eax/fx_slot_index.h
 821         al/eax/fx_slots.cpp
 822         al/eax/fx_slots.h
 823         al/eax/globals.cpp
 824         al/eax/globals.h
 825         al/eax/utils.cpp
 826         al/eax/utils.h
 827         al/eax/x_ram.h
 828 )
 829 endif ()
 830
 831 # Include SIMD mixers
 832 set(CPU_EXTS "Default")
 833 if(HAVE_SSE)
 834     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse.cpp)
 835     set(CPU_EXTS "${CPU_EXTS}, SSE")
 836 endif()
 837 if(HAVE_SSE2)
 838     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse2.cpp)
 839     set(CPU_EXTS "${CPU_EXTS}, SSE2")
 840 endif()
 841 if(HAVE_SSE3)
 842     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse3.cpp)
 843     set(CPU_EXTS "${CPU_EXTS}, SSE3")
 844 endif()
 845 if(HAVE_SSE4_1)
 846     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_sse41.cpp)
 847     set(CPU_EXTS "${CPU_EXTS}, SSE4.1")
 848 endif()
 849 if(HAVE_NEON)
 850     set(CORE_OBJS  ${CORE_OBJS} core/mixer/mixer_neon.cpp)
 851     set(CPU_EXTS "${CPU_EXTS}, Neon")
 852 endif()
 853
 854
 855 set(HAVE_ALSA       0)
 856 set(HAVE_OSS        0)
 857 set(HAVE_PIPEWIRE   0)
 858 set(HAVE_SOLARIS    0)
 859 set(HAVE_SNDIO      0)
 860 set(HAVE_DSOUND     0)
 861 set(HAVE_WASAPI     0)
 862 set(HAVE_WINMM      0)
 863 set(HAVE_PORTAUDIO  0)
 864 set(HAVE_PULSEAUDIO 0)
 865 set(HAVE_COREAUDIO  0)
 866 set(HAVE_OPENSL     0)
 867 set(HAVE_OBOE       0)
 868 set(HAVE_WAVE       0)
 869 set(HAVE_SDL2       0)
 870
 871 if(WIN32 OR HAVE_DLFCN_H)
 872     set(IS_LINKED "")
 873     macro(ADD_BACKEND_LIBS _LIBS)
 874     endmacro()
 875 else()
 876     set(IS_LINKED " (linked)")
 877     macro(ADD_BACKEND_LIBS _LIBS)
 878         set(EXTRA_LIBS ${_LIBS} ${EXTRA_LIBS})
 879     endmacro()
 880 endif()
 881
 882 set(BACKENDS "")
 883 set(ALC_OBJS  ${ALC_OBJS}
 884     alc/backends/base.cpp
 885     alc/backends/base.h
 886     # Default backends, always available
 887     alc/backends/loopback.cpp
 888     alc/backends/loopback.h
 889     alc/backends/null.cpp
 890     alc/backends/null.h
 891 )
 892
 893 # Check ALSA backend
 894 option(ALSOFT_REQUIRE_ALSA "Require ALSA backend" OFF)
 895 find_package(ALSA)
 896 if(ALSA_FOUND)
 897     option(ALSOFT_BACKEND_ALSA "Enable ALSA backend" ON)
 898     if(ALSOFT_BACKEND_ALSA)
 899         set(HAVE_ALSA 1)
 900         set(BACKENDS  "${BACKENDS} ALSA${IS_LINKED},")
 901         set(ALC_OBJS  ${ALC_OBJS} alc/backends/alsa.cpp alc/backends/alsa.h)
 902         add_backend_libs(${ALSA_LIBRARIES})
 903         set(INC_PATHS ${INC_PATHS} ${ALSA_INCLUDE_DIRS})
 904     endif()
 905 endif()
 906 if(ALSOFT_REQUIRE_ALSA AND NOT HAVE_ALSA)
 907     message(FATAL_ERROR "Failed to enabled required ALSA backend")
 908 endif()
 909
 910 # Check OSS backend
 911 option(ALSOFT_REQUIRE_OSS "Require OSS backend" OFF)
 912 find_package(OSS)
 913 if(OSS_FOUND)
 914     option(ALSOFT_BACKEND_OSS "Enable OSS backend" ON)
 915     if(ALSOFT_BACKEND_OSS)
 916         set(HAVE_OSS 1)
 917         set(BACKENDS  "${BACKENDS} OSS,")
 918         set(ALC_OBJS  ${ALC_OBJS} alc/backends/oss.cpp alc/backends/oss.h)
 919         if(OSS_LIBRARIES)
 920             set(EXTRA_LIBS ${OSS_LIBRARIES} ${EXTRA_LIBS})
 921         endif()
 922         set(INC_PATHS ${INC_PATHS} ${OSS_INCLUDE_DIRS})
 923     endif()
 924 endif()
 925 if(ALSOFT_REQUIRE_OSS AND NOT HAVE_OSS)
 926     message(FATAL_ERROR "Failed to enabled required OSS backend")
 927 endif()
 928
 929 # Check PipeWire backend
 930 option(ALSOFT_REQUIRE_PIPEWIRE "Require PipeWire backend" OFF)
 931 if(PkgConfig_FOUND)
 932     pkg_check_modules(PIPEWIRE libpipewire-0.3>=0.3.23)
 933     if(PIPEWIRE_FOUND)
 934         option(ALSOFT_BACKEND_PIPEWIRE "Enable PipeWire backend" ON)
 935         if(ALSOFT_BACKEND_PIPEWIRE)
 936             set(HAVE_PIPEWIRE 1)
 937             set(BACKENDS  "${BACKENDS} PipeWire${IS_LINKED},")
 938             set(ALC_OBJS  ${ALC_OBJS} alc/backends/pipewire.cpp alc/backends/pipewire.h)
 939             add_backend_libs(${PIPEWIRE_LIBRARIES})
 940             set(INC_PATHS ${INC_PATHS} ${PIPEWIRE_INCLUDE_DIRS})
 941         endif()
 942     endif()
 943 endif()
 944 if(ALSOFT_REQUIRE_PIPEWIRE AND NOT HAVE_PIPEWIRE)
 945     message(FATAL_ERROR "Failed to enabled required PipeWire backend")
 946 endif()
 947
 948 # Check Solaris backend
 949 option(ALSOFT_REQUIRE_SOLARIS "Require Solaris backend" OFF)
 950 find_package(AudioIO)
 951 if(AUDIOIO_FOUND)
 952     option(ALSOFT_BACKEND_SOLARIS "Enable Solaris backend" ON)
 953     if(ALSOFT_BACKEND_SOLARIS)
 954         set(HAVE_SOLARIS 1)
 955         set(BACKENDS  "${BACKENDS} Solaris,")
 956         set(ALC_OBJS  ${ALC_OBJS} alc/backends/solaris.cpp alc/backends/solaris.h)
 957         set(INC_PATHS ${INC_PATHS} ${AUDIOIO_INCLUDE_DIRS})
 958     endif()
 959 endif()
 960 if(ALSOFT_REQUIRE_SOLARIS AND NOT HAVE_SOLARIS)
 961     message(FATAL_ERROR "Failed to enabled required Solaris backend")
 962 endif()
 963
 964 # Check SndIO backend
 965 option(ALSOFT_REQUIRE_SNDIO "Require SndIO backend" OFF)
 966 find_package(SoundIO)
 967 if(SOUNDIO_FOUND)
 968     option(ALSOFT_BACKEND_SNDIO "Enable SndIO backend" ON)
 969     if(ALSOFT_BACKEND_SNDIO)
 970         set(HAVE_SNDIO 1)
 971         set(BACKENDS  "${BACKENDS} SndIO (linked),")
 972         set(ALC_OBJS  ${ALC_OBJS} alc/backends/sndio.cpp alc/backends/sndio.h)
 973         set(EXTRA_LIBS ${SOUNDIO_LIBRARIES} ${EXTRA_LIBS})
 974         set(INC_PATHS ${INC_PATHS} ${SOUNDIO_INCLUDE_DIRS})
 975     endif()
 976 endif()
 977 if(ALSOFT_REQUIRE_SNDIO AND NOT HAVE_SNDIO)
 978     message(FATAL_ERROR "Failed to enabled required SndIO backend")
 979 endif()
 980
 981 # Check Windows-only backends
 982 option(ALSOFT_REQUIRE_WINMM "Require Windows Multimedia backend" OFF)
 983 option(ALSOFT_REQUIRE_DSOUND "Require DirectSound backend" OFF)
 984 option(ALSOFT_REQUIRE_WASAPI "Require WASAPI backend" OFF)
 985 if(WIN32)
 986     # Check MMSystem backend
 987     option(ALSOFT_BACKEND_WINMM "Enable Windows Multimedia backend" ON)
 988     if(ALSOFT_BACKEND_WINMM)
 989         set(HAVE_WINMM 1)
 990         set(BACKENDS "${BACKENDS} WinMM,")
 991         set(ALC_OBJS ${ALC_OBJS} alc/backends/winmm.cpp alc/backends/winmm.h)
 992         # There doesn't seem to be good way to search for winmm.lib for MSVC.
 993         # find_library doesn't find it without being told to look in a specific
 994         # place in the WindowsSDK, but it links anyway. If there ends up being
 995         # Windows targets without this, another means to detect it is needed.
 996         set(EXTRA_LIBS winmm ${EXTRA_LIBS})
 997     endif()
 998
 999     # Check DSound backend
1000     check_include_file(dsound.h HAVE_DSOUND_H)
1001     if(DXSDK_DIR)
1002         find_path(DSOUND_INCLUDE_DIR NAMES "dsound.h"
1003             PATHS "${DXSDK_DIR}" PATH_SUFFIXES include
1004             DOC "The DirectSound include directory")
1005     endif()
1006     if(HAVE_DSOUND_H OR DSOUND_INCLUDE_DIR)
1007         option(ALSOFT_BACKEND_DSOUND "Enable DirectSound backend" ON)
1008         if(ALSOFT_BACKEND_DSOUND)
1009             set(HAVE_DSOUND 1)
1010             set(BACKENDS "${BACKENDS} DirectSound,")
1011             set(ALC_OBJS ${ALC_OBJS} alc/backends/dsound.cpp alc/backends/dsound.h)
1012
1013             if(NOT HAVE_DSOUND_H)
1014                 set(INC_PATHS ${INC_PATHS} ${DSOUND_INCLUDE_DIR})
1015             endif()
1016         endif()
1017     endif()
1018
1019     # Check for WASAPI backend
1020     check_include_file(mmdeviceapi.h HAVE_MMDEVICEAPI_H)
1021     if(HAVE_MMDEVICEAPI_H)
1022         option(ALSOFT_BACKEND_WASAPI "Enable WASAPI backend" ON)
1023         if(ALSOFT_BACKEND_WASAPI)
1024             set(HAVE_WASAPI 1)
1025             set(BACKENDS  "${BACKENDS} WASAPI,")
1026             set(ALC_OBJS  ${ALC_OBJS} alc/backends/wasapi.cpp alc/backends/wasapi.h)
1027         endif()
1028     endif()
1029 endif()
1030 if(ALSOFT_REQUIRE_WINMM AND NOT HAVE_WINMM)
1031     message(FATAL_ERROR "Failed to enabled required WinMM backend")
1032 endif()
1033 if(ALSOFT_REQUIRE_DSOUND AND NOT HAVE_DSOUND)
1034     message(FATAL_ERROR "Failed to enabled required DSound backend")
1035 endif()
1036 if(ALSOFT_REQUIRE_WASAPI AND NOT HAVE_WASAPI)
1037     message(FATAL_ERROR "Failed to enabled required WASAPI backend")
1038 endif()
1039
1040 # Check PortAudio backend
1041 option(ALSOFT_REQUIRE_PORTAUDIO "Require PortAudio backend" OFF)
1042 find_package(PortAudio)
1043 if(PORTAUDIO_FOUND)
1044     option(ALSOFT_BACKEND_PORTAUDIO "Enable PortAudio backend" ON)
1045     if(ALSOFT_BACKEND_PORTAUDIO)
1046         set(HAVE_PORTAUDIO 1)
1047         set(BACKENDS  "${BACKENDS} PortAudio${IS_LINKED},")
1048         set(ALC_OBJS  ${ALC_OBJS} alc/backends/portaudio.cpp alc/backends/portaudio.h)
1049         add_backend_libs(${PORTAUDIO_LIBRARIES})
1050         set(INC_PATHS ${INC_PATHS} ${PORTAUDIO_INCLUDE_DIRS})
1051     endif()
1052 endif()
1053 if(ALSOFT_REQUIRE_PORTAUDIO AND NOT HAVE_PORTAUDIO)
1054     message(FATAL_ERROR "Failed to enabled required PortAudio backend")
1055 endif()
1056
1057 # Check PulseAudio backend
1058 option(ALSOFT_REQUIRE_PULSEAUDIO "Require PulseAudio backend" OFF)
1059 find_package(PulseAudio)
1060 if(PULSEAUDIO_FOUND)
1061     option(ALSOFT_BACKEND_PULSEAUDIO "Enable PulseAudio backend" ON)
1062     if(ALSOFT_BACKEND_PULSEAUDIO)
1063         set(HAVE_PULSEAUDIO 1)
1064         set(BACKENDS  "${BACKENDS} PulseAudio${IS_LINKED},")
1065         set(ALC_OBJS  ${ALC_OBJS} alc/backends/pulseaudio.cpp alc/backends/pulseaudio.h)
1066         add_backend_libs(${PULSEAUDIO_LIBRARY})
1067         set(INC_PATHS ${INC_PATHS} ${PULSEAUDIO_INCLUDE_DIR})
1068     endif()
1069 endif()
1070 if(ALSOFT_REQUIRE_PULSEAUDIO AND NOT HAVE_PULSEAUDIO)
1071     message(FATAL_ERROR "Failed to enabled required PulseAudio backend")
1072 endif()
1073
1074 # Check JACK backend
1075 option(ALSOFT_REQUIRE_JACK "Require JACK backend" OFF)
1076 find_package(JACK)
1077 if(JACK_FOUND)
1078     option(ALSOFT_BACKEND_JACK "Enable JACK backend" ON)
1079     if(ALSOFT_BACKEND_JACK)
1080         set(HAVE_JACK 1)
1081         set(BACKENDS  "${BACKENDS} JACK${IS_LINKED},")
1082         set(ALC_OBJS  ${ALC_OBJS} alc/backends/jack.cpp alc/backends/jack.h)
1083         add_backend_libs(${JACK_LIBRARIES})
1084         set(INC_PATHS ${INC_PATHS} ${JACK_INCLUDE_DIRS})
1085     endif()
1086 endif()
1087 if(ALSOFT_REQUIRE_JACK AND NOT HAVE_JACK)
1088     message(FATAL_ERROR "Failed to enabled required JACK backend")
1089 endif()
1090
1091 # Check CoreAudio backend
1092 option(ALSOFT_REQUIRE_COREAUDIO "Require CoreAudio backend" OFF)
1093 find_library(COREAUDIO_FRAMEWORK NAMES CoreAudio)
1094 find_path(AUDIOUNIT_INCLUDE_DIR NAMES AudioUnit/AudioUnit.h)
1095 if(COREAUDIO_FRAMEWORK AND AUDIOUNIT_INCLUDE_DIR)
1096     option(ALSOFT_BACKEND_COREAUDIO "Enable CoreAudio backend" ON)
1097     if(ALSOFT_BACKEND_COREAUDIO)
1098         set(HAVE_COREAUDIO 1)
1099         set(ALC_OBJS  ${ALC_OBJS} alc/backends/coreaudio.cpp alc/backends/coreaudio.h)
1100         set(BACKENDS  "${BACKENDS} CoreAudio,")
1101
1102         set(EXTRA_LIBS -Wl,-framework,CoreAudio ${EXTRA_LIBS})
1103         if(CMAKE_SYSTEM_NAME MATCHES "^(iOS|tvOS)$")
1104             find_library(COREFOUNDATION_FRAMEWORK NAMES CoreFoundation)
1105             if(COREFOUNDATION_FRAMEWORK)
1106                 set(EXTRA_LIBS -Wl,-framework,CoreFoundation ${EXTRA_LIBS})
1107             endif()
1108         else()
1109             set(EXTRA_LIBS -Wl,-framework,AudioUnit,-framework,ApplicationServices ${EXTRA_LIBS})
1110         endif()
1111
1112         # Some versions of OSX may need the AudioToolbox framework. Add it if
1113         # it's found.
1114         find_library(AUDIOTOOLBOX_LIBRARY NAMES AudioToolbox)
1115         if(AUDIOTOOLBOX_LIBRARY)
1116             set(EXTRA_LIBS -Wl,-framework,AudioToolbox ${EXTRA_LIBS})
1117         endif()
1118
1119         set(INC_PATHS ${INC_PATHS} ${AUDIOUNIT_INCLUDE_DIR})
1120     endif()
1121 endif()
1122 if(ALSOFT_REQUIRE_COREAUDIO AND NOT HAVE_COREAUDIO)
1123     message(FATAL_ERROR "Failed to enabled required CoreAudio backend")
1124 endif()
1125
1126 # Check for OpenSL (Android) backend
1127 option(ALSOFT_REQUIRE_OPENSL "Require OpenSL backend" OFF)
1128 find_package(OpenSL)
1129 if(OPENSL_FOUND)
1130     option(ALSOFT_BACKEND_OPENSL "Enable OpenSL backend" ON)
1131     if(ALSOFT_BACKEND_OPENSL)
1132         set(HAVE_OPENSL 1)
1133         set(ALC_OBJS  ${ALC_OBJS} alc/backends/opensl.cpp alc/backends/opensl.h)
1134         set(BACKENDS  "${BACKENDS} OpenSL,")
1135         set(EXTRA_LIBS "OpenSL::OpenSLES" ${EXTRA_LIBS})
1136     endif()
1137 endif()
1138 if(ALSOFT_REQUIRE_OPENSL AND NOT HAVE_OPENSL)
1139     message(FATAL_ERROR "Failed to enabled required OpenSL backend")
1140 endif()
1141
1142 # Check for Oboe (Android) backend
1143 set(OBOE_TARGET )
1144 if(ANDROID)
1145     set(OBOE_SOURCE "" CACHE STRING "Source directory for Oboe.")
1146     if(OBOE_SOURCE)
1147         add_subdirectory(${OBOE_SOURCE} ./oboe)
1148         set(OBOE_TARGET oboe)
1149     else()
1150         find_package(oboe CONFIG)
1151         if(NOT TARGET oboe::oboe)
1152             find_package(Oboe)
1153         endif()
1154         if(TARGET oboe::oboe)
1155             set(OBOE_TARGET "oboe::oboe")
1156         endif()
1157     endif()
1158 endif()
1159
1160 option(ALSOFT_REQUIRE_OBOE "Require Oboe backend" OFF)
1161 if(OBOE_TARGET)
1162     option(ALSOFT_BACKEND_OBOE "Enable Oboe backend" ON)
1163     if(ALSOFT_BACKEND_OBOE)
1164         set(HAVE_OBOE 1)
1165         set(ALC_OBJS  ${ALC_OBJS} alc/backends/oboe.cpp alc/backends/oboe.h)
1166         set(BACKENDS  "${BACKENDS} Oboe,")
1167         set(EXTRA_LIBS ${OBOE_TARGET} ${EXTRA_LIBS})
1168     endif()
1169 endif()
1170 if(ALSOFT_REQUIRE_OBOE AND NOT HAVE_OBOE)
1171     message(FATAL_ERROR "Failed to enabled required Oboe backend")
1172 endif()
1173
1174 # Check for SDL2 backend
1175 option(ALSOFT_REQUIRE_SDL2 "Require SDL2 backend" OFF)
1176 find_package(SDL2 QUIET)
1177 if(SDL2_FOUND)
1178     # Off by default, since it adds a runtime dependency
1179     option(ALSOFT_BACKEND_SDL2 "Enable SDL2 backend" OFF)
1180     if(ALSOFT_BACKEND_SDL2)
1181         set(HAVE_SDL2 1)
1182         set(ALC_OBJS  ${ALC_OBJS} alc/backends/sdl2.cpp alc/backends/sdl2.h)
1183         set(BACKENDS  "${BACKENDS} SDL2,")
1184         set(EXTRA_LIBS ${EXTRA_LIBS} SDL2::SDL2)
1185     endif()
1186 else()
1187     message(STATUS "Could NOT find SDL2")
1188 endif()
1189 if(ALSOFT_REQUIRE_SDL2 AND NOT SDL2_FOUND)
1190     message(FATAL_ERROR "Failed to enabled required SDL2 backend")
1191 endif()
1192
1193 # Optionally enable the Wave Writer backend
1194 option(ALSOFT_BACKEND_WAVE "Enable Wave Writer backend" ON)
1195 if(ALSOFT_BACKEND_WAVE)
1196     set(HAVE_WAVE 1)
1197     set(ALC_OBJS  ${ALC_OBJS} alc/backends/wave.cpp alc/backends/wave.h)
1198     set(BACKENDS  "${BACKENDS} WaveFile,")
1199 endif()
1200
1201 # This is always available
1202 set(BACKENDS  "${BACKENDS} Null")
1203
1204
1205 find_package(Git)
1206 if(ALSOFT_UPDATE_BUILD_VERSION AND GIT_FOUND AND EXISTS "${OpenAL_SOURCE_DIR}/.git")
1207     # Get the current working branch and its latest abbreviated commit hash
1208     add_custom_command(OUTPUT "${OpenAL_BINARY_DIR}/version_witness.txt"
1209         BYPRODUCTS "${OpenAL_BINARY_DIR}/version.h"
1210         COMMAND ${CMAKE_COMMAND} -D GIT_EXECUTABLE=${GIT_EXECUTABLE} -D LIB_VERSION=${LIB_VERSION}
1211             -D LIB_VERSION_NUM=${LIB_VERSION_NUM} -D SRC=${OpenAL_SOURCE_DIR}/version.h.in
1212             -D DST=${OpenAL_BINARY_DIR}/version.h -P ${OpenAL_SOURCE_DIR}/version.cmake
1213         COMMAND ${CMAKE_COMMAND} -E touch "${OpenAL_BINARY_DIR}/version_witness.txt"
1214         WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1215         MAIN_DEPENDENCY "${OpenAL_SOURCE_DIR}/version.h.in"
1216         DEPENDS "${OpenAL_SOURCE_DIR}/.git/index" "${OpenAL_SOURCE_DIR}/version.cmake"
1217         VERBATIM
1218     )
1219
1220     add_custom_target(build_version DEPENDS "${OpenAL_BINARY_DIR}/version_witness.txt")
1221 else()
1222     set(GIT_BRANCH "UNKNOWN")
1223     set(GIT_COMMIT_HASH "unknown")
1224     configure_file(
1225         "${OpenAL_SOURCE_DIR}/version.h.in"
1226         "${OpenAL_BINARY_DIR}/version.h")
1227 endif()
1228
1229
1230 option(ALSOFT_EMBED_HRTF_DATA "Embed the HRTF data files (increases library footprint)" ON)
1231 if(ALSOFT_EMBED_HRTF_DATA)
1232     macro(make_hrtf_header FILENAME VARNAME)
1233         set(infile  "${OpenAL_SOURCE_DIR}/hrtf/${FILENAME}")
1234         set(outfile  "${OpenAL_BINARY_DIR}/${VARNAME}.txt")
1235
1236         add_custom_command(OUTPUT "${outfile}"
1237             COMMAND ${CMAKE_COMMAND} -D "INPUT_FILE=${infile}" -D "OUTPUT_FILE=${outfile}"
1238                 -P "${CMAKE_MODULE_PATH}/bin2h.script.cmake"
1239             WORKING_DIRECTORY "${OpenAL_SOURCE_DIR}"
1240             DEPENDS "${infile}" "${CMAKE_MODULE_PATH}/bin2h.script.cmake"
1241             VERBATIM
1242         )
1243         set(ALC_OBJS  ${ALC_OBJS} "${outfile}")
1244     endmacro()
1245
1246     make_hrtf_header("Default HRTF.mhr" "default_hrtf")
1247 endif()
1248
1249
1250 if(ALSOFT_UTILS)
1251     find_package(MySOFA)
1252     if(NOT ALSOFT_NO_CONFIG_UTIL)
1253         find_package(Qt5Widgets QUIET)
1254         if(NOT Qt5Widgets_FOUND)
1255             message(STATUS "Could NOT find Qt5Widgets")
1256         endif()
1257     endif()
1258 endif()
1259 if(ALSOFT_UTILS OR ALSOFT_EXAMPLES)
1260     find_package(SndFile)
1261     if(SDL2_FOUND)
1262         find_package(FFmpeg COMPONENTS AVFORMAT AVCODEC AVUTIL SWSCALE SWRESAMPLE)
1263     endif()
1264 endif()
1265
1266 if(NOT WIN32)
1267     set(LIBNAME "openal")
1268 else()
1269     set(LIBNAME "OpenAL32")
1270 endif()
1271
1272 # Needed for openal.pc.in
1273 set(prefix ${CMAKE_INSTALL_PREFIX})
1274 set(exec_prefix "\${prefix}")
1275 set(libdir "${CMAKE_INSTALL_FULL_LIBDIR}")
1276 set(bindir "${CMAKE_INSTALL_FULL_BINDIR}")
1277 set(includedir "${CMAKE_INSTALL_FULL_INCLUDEDIR}")
1278 set(PACKAGE_VERSION "${LIB_VERSION}")
1279 set(PKG_CONFIG_CFLAGS )
1280 set(PKG_CONFIG_PRIVATE_LIBS )
1281 if(LIBTYPE STREQUAL "STATIC")
1282     set(PKG_CONFIG_CFLAGS -DAL_LIBTYPE_STATIC)
1283     foreach(FLAG  ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1284         # If this is already a linker flag, or is a full path+file, add it
1285         # as-is. If it's an SDL2 target, add the link flag for it. Otherwise,
1286         # it's a name intended to be dressed as -lname.
1287         if(FLAG MATCHES "^-.*" OR EXISTS "${FLAG}")
1288             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} ${FLAG}")
1289         elseif(FLAG MATCHES "^SDL2::SDL2")
1290             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} -lSDL2")
1291         else()
1292             set(PKG_CONFIG_PRIVATE_LIBS "${PKG_CONFIG_PRIVATE_LIBS} -l${FLAG}")
1293         endif()
1294     endforeach()
1295 endif()
1296
1297 # End configuration
1298 configure_file(
1299     "${OpenAL_SOURCE_DIR}/config.h.in"
1300     "${OpenAL_BINARY_DIR}/config.h")
1301 configure_file(
1302     "${OpenAL_SOURCE_DIR}/openal.pc.in"
1303     "${OpenAL_BINARY_DIR}/openal.pc"
1304     @ONLY)
1305
1306
1307 add_library(common STATIC EXCLUDE_FROM_ALL ${COMMON_OBJS})
1308 target_include_directories(common PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/include)
1309 target_compile_definitions(common PRIVATE ${CPP_DEFS})
1310 target_compile_options(common PRIVATE ${C_FLAGS})
1311 set_target_properties(common PROPERTIES POSITION_INDEPENDENT_CODE TRUE)
1312
1313
1314 unset(HAS_ROUTER)
1315 set(IMPL_TARGET OpenAL) # Either OpenAL or soft_oal.
1316
1317 # Build main library
1318 if(LIBTYPE STREQUAL "STATIC")
1319     add_library(${IMPL_TARGET} STATIC ${COMMON_OBJS} ${OPENAL_OBJS} ${ALC_OBJS} ${CORE_OBJS})
1320     target_compile_definitions(${IMPL_TARGET} PUBLIC AL_LIBTYPE_STATIC)
1321     target_link_libraries(${IMPL_TARGET} PRIVATE ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1322
1323     if(WIN32)
1324         # This option is for static linking OpenAL Soft into another project
1325         # that already defines the IDs. It is up to that project to ensure all
1326         # required IDs are defined.
1327         option(ALSOFT_NO_UID_DEFS "Do not define GUIDs, IIDs, CLSIDs, or PropertyKeys" OFF)
1328         if(ALSOFT_NO_UID_DEFS)
1329             target_compile_definitions(${IMPL_TARGET} PRIVATE AL_NO_UID_DEFS)
1330         endif()
1331     endif()
1332 else()
1333     set(RC_CONFIG resources/openal32.rc)
1334     if(WIN32 AND ALSOFT_BUILD_ROUTER)
1335         add_library(OpenAL SHARED
1336             resources/router.rc
1337             router/router.cpp
1338             router/router.h
1339             router/alc.cpp
1340             router/al.cpp
1341         )
1342         target_compile_definitions(OpenAL
1343             PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES "ALC_API=${EXPORT_DECL}"
1344             "AL_API=${EXPORT_DECL}" ${CPP_DEFS})
1345         target_compile_options(OpenAL PRIVATE ${C_FLAGS})
1346         target_link_libraries(OpenAL PRIVATE common ${LINKER_FLAGS})
1347         target_include_directories(OpenAL
1348           PUBLIC
1349             $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include>
1350             $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
1351           PRIVATE
1352             ${OpenAL_SOURCE_DIR}/common
1353             ${OpenAL_BINARY_DIR}
1354         )
1355         set_target_properties(OpenAL PROPERTIES PREFIX "")
1356         set_target_properties(OpenAL PROPERTIES OUTPUT_NAME ${LIBNAME})
1357         if(TARGET build_version)
1358             add_dependencies(OpenAL build_version)
1359         endif()
1360         set(HAS_ROUTER 1)
1361
1362         set(LIBNAME "soft_oal")
1363         set(IMPL_TARGET soft_oal)
1364         set(RC_CONFIG resources/soft_oal.rc)
1365     endif()
1366
1367     # !important: for osx framework public header works, the headers must be in
1368     # the project
1369     set(TARGET_PUBLIC_HEADERS include/AL/al.h include/AL/alc.h include/AL/alext.h include/AL/efx.h
1370         include/AL/efx-presets.h)
1371     add_library(${IMPL_TARGET} SHARED ${OPENAL_OBJS} ${ALC_OBJS} ${CORE_OBJS} ${RC_CONFIG}
1372         ${TARGET_PUBLIC_HEADERS})
1373     if(WIN32)
1374         set_target_properties(${IMPL_TARGET} PROPERTIES PREFIX "")
1375     endif()
1376     target_link_libraries(${IMPL_TARGET} PRIVATE common ${LINKER_FLAGS} ${EXTRA_LIBS} ${MATH_LIB})
1377
1378     if(APPLE AND ALSOFT_OSX_FRAMEWORK)
1379         # Sets framework name to soft_oal to avoid ambiguity with the system OpenAL.framework
1380         set(LIBNAME "soft_oal")
1381         if(GIT_FOUND)
1382             EXECUTE_PROCESS(COMMAND ${GIT_EXECUTABLE} rev-list --count HEAD
1383                 TIMEOUT 5
1384                 OUTPUT_VARIABLE BUNDLE_VERSION
1385                 OUTPUT_STRIP_TRAILING_WHITESPACE)
1386         else()
1387             set(BUNDLE_VERSION 1)
1388         endif()
1389
1390         # Build: Fix rpath in iOS shared libraries
1391         # If this flag is not set, the final dylib binary ld path will be
1392         # /User/xxx/*/soft_oal.framework/soft_oal, which can't be loaded by iOS devices.
1393         # See also: https://github.com/libjpeg-turbo/libjpeg-turbo/commit/c80ddef7a4ce21ace9e3ca0fd190d320cc8cdaeb
1394         if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG)
1395             set(CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG "-Wl,-rpath,")
1396         endif()
1397
1398         set_target_properties(${IMPL_TARGET} PROPERTIES
1399             FRAMEWORK TRUE
1400             FRAMEWORK_VERSION C
1401             MACOSX_FRAMEWORK_NAME "${IMPL_TARGET}"
1402             MACOSX_FRAMEWORK_IDENTIFIER "org.openal-soft.openal"
1403             MACOSX_FRAMEWORK_SHORT_VERSION_STRING "${LIB_VERSION}"
1404             MACOSX_FRAMEWORK_BUNDLE_VERSION "${BUNDLE_VERSION}"
1405             XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY ""
1406             XCODE_ATTRIBUTE_CODE_SIGNING_ALLOWED "NO"
1407             XCODE_ATTRIBUTE_CODE_SIGNING_REQUIRED "NO"
1408             PUBLIC_HEADER "${TARGET_PUBLIC_HEADERS}"
1409             MACOSX_RPATH TRUE)
1410     endif()
1411 endif()
1412
1413 target_include_directories(${IMPL_TARGET}
1414   PUBLIC
1415     $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include>
1416   INTERFACE
1417     $<BUILD_INTERFACE:${OpenAL_SOURCE_DIR}/include/AL>
1418     $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
1419     $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}/AL>
1420   PRIVATE
1421     ${INC_PATHS}
1422     ${OpenAL_BINARY_DIR}
1423     ${OpenAL_SOURCE_DIR}
1424     ${OpenAL_SOURCE_DIR}/common
1425 )
1426
1427 set_target_properties(${IMPL_TARGET} PROPERTIES OUTPUT_NAME ${LIBNAME}
1428     VERSION ${LIB_VERSION}
1429     SOVERSION ${LIB_MAJOR_VERSION}
1430 )
1431 target_compile_definitions(${IMPL_TARGET}
1432     PRIVATE AL_BUILD_LIBRARY AL_ALEXT_PROTOTYPES "ALC_API=${EXPORT_DECL}" "AL_API=${EXPORT_DECL}"
1433     ${CPP_DEFS})
1434 target_compile_options(${IMPL_TARGET} PRIVATE ${C_FLAGS})
1435
1436 if(TARGET build_version)
1437     add_dependencies(${IMPL_TARGET} build_version)
1438 endif()
1439
1440 if(WIN32 AND MINGW AND ALSOFT_BUILD_IMPORT_LIB AND NOT LIBTYPE STREQUAL "STATIC")
1441     find_program(SED_EXECUTABLE NAMES sed DOC "sed executable")
1442     if(NOT SED_EXECUTABLE OR NOT CMAKE_DLLTOOL)
1443         message(STATUS "")
1444         if(NOT SED_EXECUTABLE)
1445             message(STATUS "WARNING: Cannot find sed, disabling .def/.lib generation")
1446         endif()
1447         if(NOT CMAKE_DLLTOOL)
1448             message(STATUS "WARNING: Cannot find dlltool, disabling .def/.lib generation")
1449         endif()
1450     else()
1451         set_property(TARGET OpenAL APPEND_STRING PROPERTY
1452             LINK_FLAGS " -Wl,--output-def,OpenAL32.def")
1453         add_custom_command(TARGET OpenAL POST_BUILD
1454             COMMAND "${SED_EXECUTABLE}" -i -e "s/ @[^ ]*//" OpenAL32.def
1455             COMMAND "${CMAKE_DLLTOOL}" -d OpenAL32.def -l OpenAL32.lib -D OpenAL32.dll
1456             # Technically OpenAL32.def was created by the build, but cmake
1457             # doesn't recognize it due to -Wl,--output-def,OpenAL32.def being
1458             # manually specified. But declaring the file here allows it to be
1459             # properly cleaned, e.g. during make clean.
1460             BYPRODUCTS OpenAL32.def OpenAL32.lib
1461             COMMENT "Stripping ordinals from OpenAL32.def and generating OpenAL32.lib..."
1462             VERBATIM
1463         )
1464     endif()
1465 endif()
1466
1467 if(HAS_ROUTER)
1468     message(STATUS "")
1469     message(STATUS "Building DLL router")
1470 endif()
1471
1472 message(STATUS "")
1473 message(STATUS "Building OpenAL with support for the following backends:")
1474 message(STATUS "   ${BACKENDS}")
1475 message(STATUS "")
1476 message(STATUS "Building with support for CPU extensions:")
1477 message(STATUS "    ${CPU_EXTS}")
1478 message(STATUS "")
1479 if(FPMATH_SET)
1480     message(STATUS "Building with SSE${FPMATH_SET} codegen")
1481     message(STATUS "")
1482 endif()
1483
1484 if(ALSOFT_EAX)
1485     message(STATUS "Building with legacy EAX extension support")
1486     message(STATUS "")
1487 endif()
1488
1489 if(ALSOFT_EMBED_HRTF_DATA)
1490     message(STATUS "Embedding HRTF datasets")
1491     message(STATUS "")
1492 endif()
1493
1494 # An alias for sub-project builds
1495 add_library(OpenAL::OpenAL ALIAS OpenAL)
1496
1497 # Install main library
1498 if(ALSOFT_INSTALL)
1499     configure_package_config_file(OpenALConfig.cmake.in OpenALConfig.cmake
1500         INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL)
1501     install(TARGETS OpenAL EXPORT OpenAL
1502         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1503         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1504         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1505         FRAMEWORK DESTINATION ${CMAKE_INSTALL_LIBDIR}
1506         INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR} ${CMAKE_INSTALL_INCLUDEDIR}/AL)
1507     export(TARGETS OpenAL
1508         NAMESPACE OpenAL::
1509         FILE OpenALTargets.cmake)
1510     install(EXPORT OpenAL
1511         DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL
1512         NAMESPACE OpenAL::
1513         FILE OpenALTargets.cmake)
1514     install(DIRECTORY include/AL
1515         DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
1516     install(FILES "${OpenAL_BINARY_DIR}/openal.pc"
1517         DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
1518     install(FILES "${OpenAL_BINARY_DIR}/OpenALConfig.cmake"
1519         DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/OpenAL")
1520     if(TARGET soft_oal)
1521         install(TARGETS soft_oal
1522             RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
1523     endif()
1524     message(STATUS "Installing library and headers")
1525 else()
1526     message(STATUS "NOT installing library and headers")
1527 endif()
1528
1529 if(ALSOFT_INSTALL_CONFIG)
1530     install(FILES alsoftrc.sample
1531         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1532     message(STATUS "Installing sample configuration")
1533 endif()
1534
1535 if(ALSOFT_INSTALL_HRTF_DATA)
1536     install(DIRECTORY hrtf
1537         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1538     message(STATUS "Installing HRTF data files")
1539 endif()
1540
1541 if(ALSOFT_INSTALL_AMBDEC_PRESETS)
1542     install(DIRECTORY presets
1543         DESTINATION ${CMAKE_INSTALL_DATADIR}/openal)
1544     message(STATUS "Installing AmbDec presets")
1545 endif()
1546 message(STATUS "")
1547
1548 set(UNICODE_FLAG )
1549 if(MINGW)
1550     set(UNICODE_FLAG ${UNICODE_FLAG} -municode)
1551 endif()
1552 set(EXTRA_INSTALLS )
1553 if(ALSOFT_UTILS)
1554     add_executable(openal-info utils/openal-info.c)
1555     target_include_directories(openal-info PRIVATE ${OpenAL_SOURCE_DIR}/common)
1556     target_compile_options(openal-info PRIVATE ${C_FLAGS})
1557     target_link_libraries(openal-info PRIVATE ${LINKER_FLAGS} OpenAL ${UNICODE_FLAG})
1558     if(ALSOFT_INSTALL_EXAMPLES)
1559         set(EXTRA_INSTALLS ${EXTRA_INSTALLS} openal-info)
1560     endif()
1561
1562     if(SNDFILE_FOUND)
1563         add_executable(uhjdecoder utils/uhjdecoder.cpp)
1564         target_compile_definitions(uhjdecoder PRIVATE ${CPP_DEFS})
1565         target_include_directories(uhjdecoder
1566             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/common)
1567         target_compile_options(uhjdecoder PRIVATE ${C_FLAGS})
1568         target_link_libraries(uhjdecoder PUBLIC common
1569             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ${UNICODE_FLAG})
1570
1571         add_executable(uhjencoder utils/uhjencoder.cpp)
1572         target_compile_definitions(uhjencoder PRIVATE ${CPP_DEFS})
1573         target_include_directories(uhjencoder
1574             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/common)
1575         target_compile_options(uhjencoder PRIVATE ${C_FLAGS})
1576         target_link_libraries(uhjencoder PUBLIC common
1577             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ${UNICODE_FLAG})
1578     endif()
1579
1580     if(MYSOFA_FOUND)
1581         set(SOFA_SUPPORT_SRCS
1582             utils/sofa-support.cpp
1583             utils/sofa-support.h)
1584         add_library(sofa-support STATIC EXCLUDE_FROM_ALL ${SOFA_SUPPORT_SRCS})
1585         target_compile_definitions(sofa-support PRIVATE ${CPP_DEFS})
1586         target_include_directories(sofa-support PUBLIC ${OpenAL_SOURCE_DIR}/common)
1587         target_compile_options(sofa-support PRIVATE ${C_FLAGS})
1588         target_link_libraries(sofa-support PUBLIC common MySOFA::MySOFA PRIVATE ${LINKER_FLAGS})
1589
1590         set(MAKEMHR_SRCS
1591             utils/makemhr/loaddef.cpp
1592             utils/makemhr/loaddef.h
1593             utils/makemhr/loadsofa.cpp
1594             utils/makemhr/loadsofa.h
1595             utils/makemhr/makemhr.cpp
1596             utils/makemhr/makemhr.h)
1597         if(NOT HAVE_GETOPT)
1598             set(MAKEMHR_SRCS  ${MAKEMHR_SRCS} utils/getopt.c utils/getopt.h)
1599         endif()
1600         add_executable(makemhr ${MAKEMHR_SRCS})
1601         target_compile_definitions(makemhr PRIVATE ${CPP_DEFS})
1602         target_include_directories(makemhr
1603             PRIVATE ${OpenAL_BINARY_DIR} ${OpenAL_SOURCE_DIR}/utils)
1604         target_compile_options(makemhr PRIVATE ${C_FLAGS})
1605         target_link_libraries(makemhr PRIVATE ${LINKER_FLAGS} sofa-support ${UNICODE_FLAG})
1606         if(ALSOFT_INSTALL_EXAMPLES)
1607             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} makemhr)
1608         endif()
1609
1610         set(SOFAINFO_SRCS  utils/sofa-info.cpp)
1611         add_executable(sofa-info ${SOFAINFO_SRCS})
1612         target_compile_definitions(sofa-info PRIVATE ${CPP_DEFS})
1613         target_include_directories(sofa-info PRIVATE ${OpenAL_SOURCE_DIR}/utils)
1614         target_compile_options(sofa-info PRIVATE ${C_FLAGS})
1615         target_link_libraries(sofa-info PRIVATE ${LINKER_FLAGS} sofa-support ${UNICODE_FLAG})
1616     endif()
1617     message(STATUS "Building utility programs")
1618
1619     if(NOT ALSOFT_NO_CONFIG_UTIL)
1620         add_subdirectory(utils/alsoft-config)
1621     endif()
1622     message(STATUS "")
1623 endif()
1624
1625
1626 # Add a static library with common functions used by multiple example targets
1627 add_library(ex-common STATIC EXCLUDE_FROM_ALL
1628     examples/common/alhelpers.c
1629     examples/common/alhelpers.h)
1630 target_compile_definitions(ex-common PUBLIC ${CPP_DEFS})
1631 target_include_directories(ex-common PUBLIC ${OpenAL_SOURCE_DIR}/common)
1632 target_compile_options(ex-common PUBLIC ${C_FLAGS})
1633 target_link_libraries(ex-common PUBLIC OpenAL PRIVATE ${RT_LIB})
1634
1635 if(ALSOFT_EXAMPLES)
1636     add_executable(altonegen examples/altonegen.c)
1637     target_link_libraries(altonegen PRIVATE ${LINKER_FLAGS} ${MATH_LIB} ex-common ${UNICODE_FLAG})
1638
1639     add_executable(alrecord examples/alrecord.c)
1640     target_link_libraries(alrecord PRIVATE ${LINKER_FLAGS} ex-common ${UNICODE_FLAG})
1641
1642     if(ALSOFT_INSTALL_EXAMPLES)
1643         set(EXTRA_INSTALLS ${EXTRA_INSTALLS} altonegen alrecord)
1644     endif()
1645
1646     message(STATUS "Building example programs")
1647
1648     if(SNDFILE_FOUND)
1649         add_executable(alplay examples/alplay.c)
1650         target_link_libraries(alplay PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1651             ${UNICODE_FLAG})
1652
1653         add_executable(alstream examples/alstream.c)
1654         target_link_libraries(alstream PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1655             ${UNICODE_FLAG})
1656
1657         add_executable(alreverb examples/alreverb.c)
1658         target_link_libraries(alreverb PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1659             ${UNICODE_FLAG})
1660
1661         add_executable(almultireverb examples/almultireverb.c)
1662         target_link_libraries(almultireverb
1663             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common ${MATH_LIB} ${UNICODE_FLAG})
1664
1665         add_executable(allatency examples/allatency.c)
1666         target_link_libraries(allatency PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1667             ${UNICODE_FLAG})
1668
1669         add_executable(alhrtf examples/alhrtf.c)
1670         target_link_libraries(alhrtf
1671             PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common ${MATH_LIB} ${UNICODE_FLAG})
1672
1673         add_executable(alstreamcb examples/alstreamcb.cpp)
1674         target_link_libraries(alstreamcb PRIVATE ${LINKER_FLAGS} SndFile::SndFile ex-common
1675             ${UNICODE_FLAG})
1676
1677         add_executable(alconvolve examples/alconvolve.c)
1678         target_link_libraries(alconvolve PRIVATE ${LINKER_FLAGS} common SndFile::SndFile ex-common
1679             ${UNICODE_FLAG})
1680
1681         if(ALSOFT_INSTALL_EXAMPLES)
1682             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alplay alstream alreverb almultireverb allatency
1683                 alhrtf)
1684         endif()
1685
1686         message(STATUS "Building SndFile example programs")
1687     endif()
1688
1689     if(SDL2_FOUND)
1690         add_executable(alloopback examples/alloopback.c)
1691         target_link_libraries(alloopback
1692             PRIVATE ${LINKER_FLAGS} SDL2::SDL2 ex-common ${MATH_LIB})
1693
1694         if(ALSOFT_INSTALL_EXAMPLES)
1695             set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alloopback)
1696         endif()
1697
1698         message(STATUS "Building SDL example programs")
1699
1700         set(FFVER_OK FALSE)
1701         if(FFMPEG_FOUND)
1702             set(FFVER_OK TRUE)
1703             if(AVFORMAT_VERSION VERSION_LESS "59.27.100")
1704                 message(STATUS "libavformat is too old! (${AVFORMAT_VERSION}, wanted 59.27.100)")
1705                 set(FFVER_OK FALSE)
1706             endif()
1707             if(AVCODEC_VERSION VERSION_LESS "59.37.100")
1708                 message(STATUS "libavcodec is too old! (${AVCODEC_VERSION}, wanted 59.37.100)")
1709                 set(FFVER_OK FALSE)
1710             endif()
1711             if(AVUTIL_VERSION VERSION_LESS "57.28.100")
1712                 message(STATUS "libavutil is too old! (${AVUTIL_VERSION}, wanted 57.28.100)")
1713                 set(FFVER_OK FALSE)
1714             endif()
1715             if(SWSCALE_VERSION VERSION_LESS "6.7.100")
1716                 message(STATUS "libswscale is too old! (${SWSCALE_VERSION}, wanted 6.7.100)")
1717                 set(FFVER_OK FALSE)
1718             endif()
1719             if(SWRESAMPLE_VERSION VERSION_LESS "4.7.100")
1720                 message(STATUS "libswresample is too old! (${SWRESAMPLE_VERSION}, wanted 4.7.100)")
1721                 set(FFVER_OK FALSE)
1722             endif()
1723         endif()
1724         if(FFVER_OK)
1725             add_executable(alffplay examples/alffplay.cpp)
1726             target_include_directories(alffplay PRIVATE ${FFMPEG_INCLUDE_DIRS})
1727             target_link_libraries(alffplay
1728                 PRIVATE ${LINKER_FLAGS} SDL2::SDL2 ${FFMPEG_LIBRARIES} ex-common)
1729
1730             if(ALSOFT_INSTALL_EXAMPLES)
1731                 set(EXTRA_INSTALLS ${EXTRA_INSTALLS} alffplay)
1732             endif()
1733             message(STATUS "Building SDL+FFmpeg example programs")
1734         endif()
1735     endif()
1736     message(STATUS "")
1737 endif()
1738
1739 if(EXTRA_INSTALLS)
1740     install(TARGETS ${EXTRA_INSTALLS}
1741         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
1742         BUNDLE  DESTINATION ${CMAKE_INSTALL_BINDIR}
1743         LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1744         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
1745 endif()