recipes/binutils/binutils_csl-arm-20050416.bb

   1 SECTION = "devel"
   2 inherit autotools gettext
   3
   4 DESCRIPTION = "A GNU collection of binary utilities"
   5 HOMEPAGE = "http://www.gnu.org/software/binutils/"
   6 LICENSE = "GPL"
   7 FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/binutils-cvs"
   8 PV = "2.15.99+csl-arm+cvs20050416"
   9 PR = "r3"
  10 OVERRIDES_prepend = "${TARGET_ARCH}-${TARGET_OS}:"
  11 DEFAULT_PREFERENCE = "-1"
  12 DEFAULT_PREFERENCE_arm-linux = "-1"
  13 DEFAULT_PREFERENCE_arm-linuxeabi = "-1"
  14
  15 PACKAGES = "${PN} ${PN}-dev ${PN}-doc ${PN}-symlinks"
  16
  17 FILES_${PN} = " \
  18         ${bindir}/${TARGET_PREFIX}* \
  19         ${libdir}/lib*-*.so \
  20         ${prefix}/${TARGET_SYS}/bin/*"
  21
  22 FILES_${PN}-dev = " \
  23         ${includedir} \
  24         ${libdir}/*.a \
  25         ${libdir}/*.la \
  26         ${libdir}/libbfd.so \
  27         ${libdir}/libopcodes.so"
  28
  29 FILES_${PN}-symlinks = " \
  30         ${bindir}/addr2line \
  31         ${bindir}/ar \
  32         ${bindir}/as \
  33         ${bindir}/c++filt \
  34         ${bindir}/gprof \
  35         ${bindir}/ld \
  36         ${bindir}/nm \
  37         ${bindir}/objcopy \
  38         ${bindir}/objdump \
  39         ${bindir}/ranlib \
  40         ${bindir}/readelf \
  41         ${bindir}/size \
  42         ${bindir}/strings \
  43         ${bindir}/strip"
  44
  45 SRC_URI = "cvs://anoncvs:anoncvs@sources.redhat.com/cvs/src;module=binutils;method=pserver;localdir=src;tag=binutils-csl-arm-2005q1-branch;date=20050416 \
  46      file://ld_makefile.patch \
  47      file://better_file_error.patch \
  48      file://signed_char_fix.patch"
  49
  50 S = "${WORKDIR}/src"
  51 B = "${S}/build.${HOST_SYS}.${TARGET_SYS}"
  52
  53 EXTRA_OECONF = "--with-sysroot=/ \
  54                 --program-prefix=${TARGET_PREFIX} \
  55                 --enable-shared"
  56
  57 # This is necessary due to a bug in the binutils Makefiles
  58 EXTRA_OEMAKE = "configure-build-libiberty all"
  59
  60 export AR = "${HOST_PREFIX}ar"
  61 export AS = "${HOST_PREFIX}as"
  62 export LD = "${HOST_PREFIX}ld"
  63 export NM = "${HOST_PREFIX}nm"
  64 export RANLIB = "${HOST_PREFIX}ranlib"
  65 export OBJCOPY = "${HOST_PREFIX}objcopy"
  66 export OBJDUMP = "${HOST_PREFIX}objdump"
  67
  68 export AR_FOR_TARGET = "${TARGET_PREFIX}ar"
  69 export AS_FOR_TARGET = "${TARGET_PREFIX}as"
  70 export LD_FOR_TARGET = "${TARGET_PREFIX}ld"
  71 export NM_FOR_TARGET = "${TARGET_PREFIX}nm"
  72 export RANLIB_FOR_TARGET = "${TARGET_PREFIX}ranlib"
  73
  74 export CC_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
  75 export CXX_FOR_HOST = "${CCACHE} ${HOST_PREFIX}gcc"
  76
  77 export CC_FOR_BUILD = "${BUILD_CC}"
  78
  79 export CC = "${CCACHE} ${HOST_PREFIX}gcc"
  80
  81 do_configure () {
  82         (cd ${S}; gnu-configize) || die "Failed to run gnu-configize"
  83         oe_runconf
  84 }
  85
  86 do_install () {
  87         autotools_do_install
  88
  89         # We don't really need these, so we'll remove them...
  90         rm -rf ${D}${libdir}/ldscripts
  91
  92         # Fix the /usr/${TARGET_SYS}/bin/* links
  93         for l in ${D}${prefix}/${TARGET_SYS}/bin/*; do
  94                 rm -f $l
  95                 ln -sf `echo ${prefix}/${TARGET_SYS}/bin \
  96                         | tr -s / \
  97                         | sed -e 's,^/,,' -e 's,[^/]*,..,g'`${bindir}/${TARGET_PREFIX}`basename $l` $l
  98         done
  99
 100         # Install the libiberty header
 101         install -m 644 ${S}/include/ansidecl.h ${D}${includedir}
 102         install -m 644 ${S}/include/libiberty.h ${D}${includedir}
 103
 104         cd ${D}${bindir}
 105
 106         # Symlinks for ease of running these on the native target
 107         for p in ${TARGET_SYS}-* ; do
 108                 ln -sf $p `echo $p | sed -e s,${TARGET_SYS}-,,`
 109         done
 110 }