recipes/ifupdown/ifupdown_0.6.10.bb

   1 DESCRIPTION = "High level tools to configure network interfaces \
   2 This package provides the tools ifup and ifdown which may be used to \
   3 configure (or, respectively, deconfigure) network interfaces, based on \
   4 the file /etc/network/interfaces."
   5 LICENSE = "GPL"
   6 SECTION = "base"
   7 PR = "r3"
   8
   9
  10 SRC_URI = "${DEBIAN_MIRROR}/main/i/ifupdown/ifupdown_${PV}.tar.gz;name=ifupdown \
  11            file://busybox.patch \
  12            file://zeroconf.patch \
  13            file://init "
  14
  15 EXTRA_OEMAKE = ""
  16
  17 inherit update-rc.d
  18
  19 do_compile () {
  20         chmod a+rx *.pl *.sh
  21         oe_runmake 'CC=${CC}' "CFLAGS=${CFLAGS} -Wall -W -D'IFUPDOWN_VERSION=\"${PV}\"'"
  22 }
  23
  24 do_install () {
  25         install -d ${D}${sysconfdir}/init.d \
  26                    ${D}${sysconfdir}/network/run/ \
  27                    ${D}${mandir}/man8 \
  28                    ${D}${mandir}/man5 \
  29                    ${D}${base_sbindir}
  30         install -m 0755 ifup ${D}${base_sbindir}/
  31         ln ${D}${base_sbindir}/ifup ${D}${base_sbindir}/ifdown
  32         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/ifup
  33         install -m 0644 ifup.8 ${D}${mandir}/man8
  34         install -m 0644 interfaces.5 ${D}${mandir}/man5
  35         cd ${D}${mandir}/man8 && ln -s ifup.8 ifdown.8
  36         mv ${D}${base_sbindir}/ifup ${D}${base_sbindir}/ifup.${PN}
  37         mv ${D}${base_sbindir}/ifdown ${D}${base_sbindir}/ifdown.${PN}
  38 }
  39
  40 pkg_postinst_${PN} () {
  41         update-alternatives --install ${base_sbindir}/ifup ifup ifup.${PN} 100
  42         update-alternatives --install ${base_sbindir}/ifdown ifdown ifdown.${PN} 100
  43 }
  44
  45 pkg_prerm_${PN} () {
  46         update-alternatives --remove ifup ifup.${PN}
  47         update-alternatives --remove ifdown ifdown.${PN}
  48 }
  49
  50 INITSCRIPT_NAME = "ifup"
  51 INITSCRIPT_PARAMS = "start 39 S . stop 39 0 6 1 ."
  52
  53 SRC_URI[ifupdown.md5sum] = "70db0d8caf06a17d65b612fa8919732b"
  54 SRC_URI[ifupdown.sha256sum] = "d4ada5d3f1b1f7c93cb608bfb505605b4765e0d4791ce6a1c435fe924dd67101"