recipes/kdepimpi/kdepimpi-qte.inc

   1 DESCRIPTION = "KDE-Pim Platform Independent - port of KDE Pim to PDA"
   2 DESCRIPTION_kopi = "Korganizer/PI is a powerful calendar and ToDo Tool"
   3 DESCRIPTION_kopi-applet = "KDE Pim/PI applet"
   4 DESCRIPTION_kapi = "KAddressbook/PI is a port of KDE addressbook"
   5 DESCRIPTION_libmicrokdelibs  = "KDE Pim/PI library - microkde"
   6 DESCRIPTION_libmicrokcal     = "KDE Pim/PI library - microkcal"
   7 DESCRIPTION_libmicrokabc     = "KDE Pim/PI library - microkabc"
   8 DESCRIPTION_libmicrokammu    = "KDE Pim/PI fork of libGammu"
   9 DESCRIPTION_kammu            = "KDE Pim/PI fork of gammu"
  10
  11 SECTION = "opie/pim"
  12 PRIORITY = "optional"
  13 LICENSE = "GPL"
  14 HOMEPAGE = "http://www.pi-sync.net/ http://sf.net/projects/kdepimpi/"
  15 MAINTAINER = "Marcin Juszkiewicz <openembedded@hrw.one.pl>"
  16
  17 # we can't build:
  18 # kabc/plugins/sharpdtm - wants libsl     (Sharp ROM 3.x closed source library)
  19 # kabc/plugins/ldap     - wants ldap libs (?)
  20 # kabc/plugins/opie     - wants libopie1  (we don't plan to have it in OE)
  21 # kmicromail            - conflict with OE libetpan, libmailwrapper/OPIE
  22
  23 PARALLEL_MAKE = ""
  24
  25 S = "${WORKDIR}/kdepim"
  26
  27 EXTRA_QMAKEVARS_POST += " \
  28 INCLUDEPATH+=../ \
  29 OBJECTS_DIR=obj/ MOC_DIR=moc/ \
  30 DESTDIR=${S}/dest \
  31 LIBS+=-L${S}/dest/ \
  32 LIBS-=-lzlib \
  33 LIBS+=-lz \
  34 "
  35 # That changes will be needed for KMicroMail/PI to get it build with OE libs
  36 #
  37 #             LIBS-=-lkmicromailwrapper LIBS+=-lmailwrapper LIBS+=-lopiecore2 \
  38
  39 QMAKE_PROFILES= "all.pro"
  40
  41 SUBDIRS="qtcompat libical/src/libical libical/src/libicalss microkde libkcal libkdepim \
  42         kabc korganizer kalarmd kaddressbook kabc/plugins/file kabc/plugins/dir \
  43         kabc/formats/binary kabc/plugins/qtopia \
  44         gammu/emb/common \
  45         gammu/emb/gammu \
  46 #        pwmanager/libcrypt/mpi  \
  47 #        pwmanager/libcrypt/error  \
  48 #        pwmanager/libcrypt/cipher  \
  49 #        pwmanager/libcrypt/zlib \
  50 #        pwmanager/pwmanager \
  51         "
  52
  53 inherit palmtop
  54
  55 do_configure_prepend() {
  56         mv ${S}/kabc/formats/binary/kabcformat_binaryE.pro ${S}/kabc/formats/binary/binaryE.pro
  57         echo -e "TEMPLATE=subdirs\nSUBDIRS=${SUBDIRS}\n" >all.pro
  58         for d in ${SUBDIRS}
  59         do
  60             if [ -f ${d}/`basename ${d}`E.pro ];
  61             then
  62                 mv -f ${d}/`basename ${d}`E.pro ${d}/`basename ${d}`.pro
  63             fi
  64         done
  65 }
  66
  67 do_compile() {
  68     export KDEPIMDIR=${S}
  69     oe_runmake
  70 }
  71
  72 HEADERS_DIRS = "qtcompat \
  73 microkde \
  74 microkde/kdecore \
  75 microkde/kdeui \
  76 microkde/kio \
  77 microkde/kresources \
  78 microkde/kutils \
  79 microkde/opie2 \
  80 kabc \
  81 libkcal \
  82 libkdepim "
  83
  84 do_unstage() {
  85
  86         for dir in ${HEADERS_DIRS};
  87         do
  88                 rm -rf ${STAGING_INCDIR}/kdepimpi/$dir
  89         done
  90
  91     for f in libmicrokde libmicrokdepim libmicrokabc libmicrokcal libmicroqtcompat
  92     do
  93         rm -f ${STAGING_LIBDIR}/kdepimpi/$f*
  94     done
  95 }
  96
  97 addtask unstage before do_configure
  98
  99 do_stage() {
 100
 101         for dir in ${HEADERS_DIRS};
 102         do
 103                 install -d ${STAGING_INCDIR}/kdepimpi/$dir
 104                 install -m 0644 ${S}/$dir/*.h ${STAGING_INCDIR}/kdepimpi/$dir/
 105         done
 106
 107     for f in libmicrokde libmicrokdepim libmicrokabc libmicrokcal libmicroqtcompat
 108     do
 109         oe_libinstall -so -C ${S}/dest/ $f ${STAGING_LIBDIR}/kdepimpi/
 110     done
 111 }
 112
 113 do_install() {
 114     install -d ${D}${palmtopdir}/bin \
 115                ${D}${palmtopdir}/lib \
 116                ${D}${palmtopdir}/apps/1Pim \
 117                ${D}${palmtopdir}/pics/kdepim/korganizer/icons16 \
 118                ${D}${palmtopdir}/pics/kdepim/korganizer/iconsmini \
 119                ${D}${palmtopdir}/pics/kdepim/kaddressbook/icons16 \
 120                ${D}${palmtopdir}/pics/kdepim/kaddressbook/icons22 \
 121                ${D}${palmtopdir}/plugins/applets
 122
 123     install -m 0644 ${S}/bin/kdepim/korganizer/ko16.png ${D}${palmtopdir}/pics/
 124     install -m 0644 ${S}/bin/kdepim/korganizer/ko24.png ${D}${palmtopdir}/pics/
 125     install -m 0644 ${S}/bin/kdepim/korganizer/*.* ${D}${palmtopdir}/pics/kdepim/korganizer
 126     install -m 0644 ${S}/bin/kdepim/korganizer/icons16/*.png ${D}${palmtopdir}/pics/kdepim/korganizer/icons16
 127     install -m 0644 ${S}/bin/kdepim/korganizer/iconsmini/*.png ${D}${palmtopdir}/pics/kdepim/korganizer/iconsmini
 128     install -m 0644 korganizer/korganizer.desktop ${D}${palmtopdir}/apps/1Pim/korganizer.desktop
 129
 130     install -m 0644 ${S}/bin/kdepim/kaddressbook/*.* ${D}${palmtopdir}/pics/kdepim/kaddressbook
 131     install -m 0644 ${S}/bin/kdepim/kaddressbook/icons16/*.png ${D}${palmtopdir}/pics/kdepim/kaddressbook/icons16
 132     install -m 0644 ${S}/bin/kdepim/kaddressbook/icons22/*.png ${D}${palmtopdir}/pics/kdepim/kaddressbook/icons22
 133     install -m 0644 kaddressbook/kaddressbook.desktop ${D}${palmtopdir}/apps/1Pim/kaddressbook.desktop
 134
 135     for f in libmicrokde libmicrokdepim libmicrokabc libmicrokcal libmicroqtcompat libmicrokabc_file libmicrokabc_dir libmicrokabcformat_binary libmicrokabc_qtopia
 136     do
 137         oe_libinstall -so -C ${S}/dest/ $f ${D}${palmtopdir}/lib
 138     done
 139
 140     install -m 0755 ${S}/dest/kopi ${D}${palmtopdir}/bin/kopi
 141     install -m 0755 ${S}/dest/kapi ${D}${palmtopdir}/bin/kapi
 142
 143     install -d ${D}${bindir} ${D}${libdir}
 144     install -m 0755 ${S}/dest/kammu ${D}${bindir}/kammu
 145     oe_libinstall -so -C ${S}/dest/ libmicrokammu ${D}${libdir}
 146
 147     for f in libkopialarmapplet
 148     do
 149         oe_libinstall -so -C ${S}/dest/ $f ${D}${palmtopdir}/plugins/applets
 150     done
 151 }
 152
 153
 154 PACKAGES = "libmicrokcal libmicrokabc kopi-applet kopi kapi libmicrokdelibs kammu libmicrokammu ${PN}"
 155
 156 FILES_kopi = "${palmtopdir}/bin/kopi ${palmtopdir}/apps/1Pim/korganizer.desktop ${palmtopdir}/pics/kdepim/korganizer/* "
 157 FILES_kapi = "${palmtopdir}/bin/kapi ${palmtopdir}/apps/1Pim/kaddressbook.desktop ${palmtopdir}/pics/kdepim/kaddressbook/* ${palmtopdir}/lib/libmicrokabc_* ${palmtopdir}/lib/libmicrokabcformat_binary*"
 158 FILES_kopi-applet = "${palmtopdir}/plugins/applets/* ${palmtopdir}/pics/ko16.png ${palmtopdir}/pics/ko24.png"
 159 FILES_libmicrokabc = "${palmtopdir}/lib/libmicrokabc*"
 160 FILES_libmicrokcal = "${palmtopdir}/lib/libmicrokcal*"
 161 FILES_libmicrokdelibs = "${palmtopdir}/lib/*"
 162 FILES_kammu = "${bindir}/kammu"
 163 FILES_libmicrokammu = "${libdir}/libmicrokammu*"