recipes/mplayer/mplayer_git.bb

   1 DESCRIPTION = "Open Source multimedia player."
   2 SECTION = "multimedia"
   3 PRIORITY = "optional"
   4 HOMEPAGE = "http://www.mplayerhq.hu/"
   5 DEPENDS = "libvpx live555 libdvdread libtheora virtual/libsdl ffmpeg xsp zlib libpng jpeg liba52 freetype fontconfig alsa-lib lzo ncurses lame libxv virtual/libx11 virtual/kernel \
   6            ${@base_conditional('ENTERPRISE_DISTRO', '1', '', 'libmad liba52 lame', d)}"
   7
   8 RDEPENDS_${PN} = "mplayer-common"
   9 LICENSE = "GPL"
  10 SRC_URI = "git://repo.or.cz/mplayer/glamo.git;protocol=git;branch=mplayer2 \
  11    "
  12
  13 SRC_URI_append_armv7a = " \
  14            file://0001-video-out-for-omapfb-support.patch \
  15           "
  16
  17 # This is required for the collie machine only as all stacks in that
  18 # machine seem to be set to executable by the toolchain. If someone
  19 # discovers this is more general than please make this more general
  20 # ie. for all armv4 machines.
  21 SRC_URI_append_collie = "file://disable-executable-stack-test.patch"
  22
  23 SRCREV = "5a2f2b69c67011e7c5c0e0e76f9135f33303ac58"
  24
  25 PACKAGE_ARCH_collie = "collie"
  26 PACKAGE_ARCH_c7x0 = "c7x0"
  27 PACKAGE_ARCH_hx4700 = "hx4700"
  28
  29 ARM_INSTRUCTION_SET = "ARM"
  30
  31 RCONFLICTS_${PN} = "mplayer-atty"
  32 RREPLACES_${PN} = "mplayer-atty"
  33
  34 PV = "2.0+gitr${SRCPV}"
  35 DEFAULT_PREFERENCE = "-1"
  36 DEFAULT_PREFERENCE_shr = "2"
  37
  38 PARALLEL_MAKE = ""
  39
  40 S = "${WORKDIR}/git"
  41
  42 FILES_${PN} = "${bindir}/mplayer ${libdir} /usr/etc/mplayer/"
  43 CONFFILES_${PN} += "/usr/etc/mplayer/input.conf \
  44                     /usr/etc/mplayer/example.conf \
  45                     /usr/etc/mplayer/codecs.conf \
  46                    "
  47
  48 inherit autotools pkgconfig
  49
  50 # We want a kernel header for armv7a, but we don't want to make mplayer machine specific for that
  51 STAGING_KERNEL_DIR = "${STAGING_DIR}/${MACHINE_ARCH}${TARGET_VENDOR}-${TARGET_OS}/kernel"
  52
  53 EXTRA_OECONF = " \
  54         --prefix=/usr \
  55         --mandir=${mandir} \
  56         --target=${SIMPLE_TARGET_SYS} \
  57         \
  58         --enable-largefiles \
  59         --disable-lirc \
  60         --disable-lircc \
  61         --disable-joystick \
  62         --disable-vm \
  63         --disable-xf86keysym \
  64         --enable-tv \
  65         --enable-tv-v4l1 \
  66         --enable-tv-v4l2 \
  67         --disable-tv-bsdbt848 \
  68         --enable-rtc \
  69         --enable-networking \
  70         --disable-smb \
  71         --enable-live \
  72         --disable-dvdnav \
  73         --enable-dvdread \
  74         --disable-dvdread-internal \
  75         --disable-libdvdcss-internal \
  76         --disable-cdparanoia \
  77         --enable-freetype \
  78         --enable-menu \
  79         --enable-sortsub \
  80         --disable-fribidi \
  81         --disable-enca \
  82         --disable-ftp \
  83         --disable-vstream \
  84         \
  85         --disable-gif \
  86         --enable-png \
  87         --enable-jpeg \
  88         --disable-libcdio \
  89         --disable-qtx \
  90         --disable-xanim \
  91         --disable-real \
  92         --disable-xvid \
  93         \
  94         --disable-speex \
  95         --enable-theora \
  96         --disable-ladspa \
  97         --disable-libdv \
  98         --enable-mad \
  99         --disable-xmms \
 100         --disable-musepack \
 101         \
 102         --disable-gl \
 103         --disable-vesa \
 104         --disable-svga \
 105         --enable-sdl \
 106         --disable-aa \
 107         --disable-caca \
 108         --disable-ggi \
 109         --disable-ggiwmh \
 110         --disable-directx \
 111         --disable-dxr3 \
 112         --disable-dvb \
 113         --disable-mga \
 114         --disable-xmga \
 115         --enable-xv \
 116         --disable-xvmc \
 117         --disable-vm \
 118         --disable-xinerama \
 119         --enable-x11 \
 120         --enable-fbdev \
 121         --disable-3dfx \
 122         --disable-tdfxfb \
 123         --disable-s3fb \
 124         --disable-directfb \
 125         --disable-bl \
 126         --disable-tdfxvid \
 127         --disable-tga \
 128         --disable-pnm \
 129         --disable-md5sum \
 130         \
 131         --enable-alsa \
 132         --enable-ossaudio \
 133         --disable-arts \
 134         --disable-esd \
 135         --disable-pulse \
 136         --disable-jack \
 137         --disable-openal \
 138         --disable-nas \
 139         --disable-sgiaudio \
 140         --disable-sunaudio \
 141         --disable-win32waveout \
 142         --enable-select \
 143         \
 144         --extra-libs=' -lBasicUsageEnvironment -lUsageEnvironment -lgroupsock -lliveMedia -lstdc++' \
 145 "
 146
 147 EXTRA_OECONF_append_armv6 = " --enable-armv6"
 148 EXTRA_OECONF_append_armv7a = " --enable-armv6 --enable-neon"
 149
 150 EXTRA_OECONF_append_om-gta02 = " --enable-glamo"
 151
 152 #build with support for the iwmmxt instruction and pxa270fb overlay support (pxa270 and up)
 153 #not every iwmmxt machine has the lcd connected to pxafb, but building the module doesn't hurt
 154 MY_ARCH := "${PACKAGE_ARCH}"
 155 PACKAGE_ARCH = "${@base_contains('MACHINE_FEATURES', 'iwmmxt', 'iwmmxt', '${MY_ARCH}',d)}"
 156
 157 MY_TARGET_CC_ARCH := "${TARGET_CC_ARCH}"
 158 TARGET_CC_ARCH = "${@base_contains('MACHINE_FEATURES', 'iwmmxt', '-march=iwmmxt -mtune=iwmmxt', '${MY_TARGET_CC_ARCH}',d)}"
 159
 160 EXTRA_OECONF_append = " ${@base_contains('MACHINE_FEATURES', 'iwmmxt', ' --enable-iwmmxt', '',d)} "
 161 EXTRA_OECONF_append = " ${@base_contains('MACHINE_FEATURES', 'x86', '--enable-runtime-cpudetection', '',d)} "
 162
 163 FULL_OPTIMIZATION = "-fexpensive-optimizations -fomit-frame-pointer -frename-registers -O4 -ffast-math"
 164 FULL_OPTIMIZATION_armv7a = "-fexpensive-optimizations  -ftree-vectorize -fomit-frame-pointer -O4 -ffast-math"
 165 BUILD_OPTIMIZATION = "${FULL_OPTIMIZATION}"
 166
 167 do_configure_prepend_armv7a() {
 168         cp ${STAGING_KERNEL_DIR}/arch/arm/plat-omap/include/mach/omapfb.h ${S}/libvo/omapfb.h || true
 169         cp ${STAGING_KERNEL_DIR}/include/asm-arm/arch-omap/omapfb.h ${S}/libvo/omapfb.h || true
 170         cp ${STAGING_KERNEL_DIR}/include/linux/omapfb.h ${S}/libvo/omapfb.h || true
 171         sed -e 's/__user//g' -i ${S}/libvo/omapfb.h || true
 172 }
 173
 174 CFLAGS_append = " -I${S}/libdvdread4 "
 175
 176 do_configure() {
 177         sed -i 's|/usr/include|${STAGING_INCDIR}|g' ${S}/configure
 178         sed -i 's|/usr/lib|${STAGING_LIBDIR}|g' ${S}/configure
 179         sed -i 's|/usr/\S*include[\w/]*||g' ${S}/configure
 180         sed -i 's|/usr/\S*lib[\w/]*||g' ${S}/configure
 181         sed -i 's|_install_strip="-s"|_install_strip=""|g' ${S}/configure
 182         sed -i 's|HOST_CC|BUILD_CC|' ${S}/Makefile
 183
 184         export SIMPLE_TARGET_SYS="$(echo ${TARGET_SYS} | sed s:${TARGET_VENDOR}::g)"
 185         ./configure ${EXTRA_OECONF}
 186
 187 }
 188
 189 do_compile () {
 190         oe_runmake
 191 }
 192
 193 do_install_append() {
 194         install -d ${D}/usr/etc/mplayer
 195         install ${S}/etc/input.conf ${D}/usr/etc/mplayer/
 196         install ${S}/etc/example.conf ${D}/usr/etc/mplayer/
 197         install ${S}/etc/codecs.conf ${D}/usr/etc/mplayer/
 198 }