config/ompi_case_sensitive_fs_setup.m4

   1 dnl -*- shell-script -*-
   2 dnl
   3 dnl Copyright (c) 2004-2005 The Trustees of Indiana University and Indiana
   4 dnl                         University Research and Technology
   5 dnl                         Corporation.  All rights reserved.
   6 dnl Copyright (c) 2004-2005 The University of Tennessee and The University
   7 dnl                         of Tennessee Research Foundation.  All rights
   8 dnl                         reserved.
   9 dnl Copyright (c) 2004-2005 High Performance Computing Center Stuttgart,
  10 dnl                         University of Stuttgart.  All rights reserved.
  11 dnl Copyright (c) 2004-2005 The Regents of the University of California.
  12 dnl                         All rights reserved.
  13 dnl $COPYRIGHT$
  14 dnl
  15 dnl Additional copyrights may follow
  16 dnl
  17 dnl $HEADER$
  18 dnl
  19
  20 AC_DEFUN([OMPI_CASE_SENSITIVE_FS_SETUP],[
  21 #
  22 # Arguments: none
  23 #
  24 # Dependencies: None
  25 #
  26 # See if we are on a case sensitive filesystem.  Some filesystems
  27 # (like HFS+ on MacOS X and MS Windows) are not case sensitive - mpicc
  28 # and mpiCC are the same file.
  29 #
  30 # Sets prefix_OS_HAVE_CASE_SENSITIVE_FS to 1 if filesystem is case
  31 # sensitive (ie, mpicc and mpiCC will be different files) or 0 if
  32 # filesystem is not case sensitive (ie, mpicc and mpiCC will be
  33 # the same file).
  34 #
  35 #
  36
  37 have_cs_fs=1
  38
  39 AC_MSG_CHECKING([if build filesystem is case sensitive])
  40 cat > conf_fs_test.$$ <<EOF
  41 lowercase
  42 EOF
  43
  44 cat > CONF_FS_TEST.$$ <<EOF
  45 uppercase
  46 EOF
  47
  48 if test "`cat conf_fs_test.$$`" = "lowercase"; then
  49     have_cs_fs=1
  50     AC_MSG_RESULT([yes])
  51 else
  52     have_cs_fs=0
  53     AC_MSG_RESULT([no])
  54 fi
  55
  56 rm -f conf_fs_test.$$ CONF_FS_TEST.$$
  57
  58 #
  59 # Now see what the user wants to do...
  60 #
  61 AC_MSG_CHECKING([if configuring for case sensitive filesystem])
  62 AC_ARG_WITH(cs_fs,
  63             AC_HELP_STRING([--with-cs-fs],
  64                            [Destination FS is case sensitive (default: set to value of the build FS's case sensitivity)]))
  65
  66 if test "$with_cs_fs" = "yes"; then
  67     OMPI_WANT_CS_FS=1
  68 elif test -z "$with_cs_fs"; then
  69     OMPI_WANT_CS_FS=$have_cs_fs
  70 else
  71     OMPI_WANT_CS_FS=0
  72 fi
  73
  74 if test "$OMPI_WANT_CS_FS" = "1"; then
  75     AC_MSG_RESULT([yes])
  76 else
  77     AC_MSG_RESULT([no])
  78 fi
  79
  80 AM_CONDITIONAL(CASE_SENSITIVE_FS, test "$OMPI_WANT_CS_FS" = "1")
  81
  82 if test "$OMPI_WANT_CS_FS" = "0"; then
  83         cat <<EOF
  84
  85 *******************************************************************************
  86 NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE
  87 *******************************************************************************
  88
  89 Because Open MPI is being installed on a non-case sensitive file
  90 system, the C++ wrapper compiler will be named mpic++ instead of the
  91 traditional mpiCC.
  92
  93 Please update any makefiles appropriately.
  94
  95 *******************************************************************************
  96 NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE NOTE
  97 *******************************************************************************
  98
  99 EOF
 100 fi
 101
 102 # Clean up
 103 unset have_cs_fs])dnl