CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.9)
   2
   3 if(NOT BINARY_NAME)
   4     set(BINARY_NAME openttd)
   5 endif()
   6
   7 project(${BINARY_NAME}
   8     VERSION 1.12.0
   9 )
  10
  11 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR)
  12     message(FATAL_ERROR "In-source builds not allowed. Please run \"cmake ..\" from the build directory. You may need to delete \"${CMAKE_SOURCE_DIR}/CMakeCache.txt\" first.")
  13 endif()
  14
  15 # Debug mode by default.
  16 if(NOT CMAKE_BUILD_TYPE)
  17     set(CMAKE_BUILD_TYPE Debug)
  18 endif()
  19
  20 if (EMSCRIPTEN)
  21     set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/os/emscripten/cmake")
  22 endif()
  23
  24 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake")
  25 set(CMAKE_OSX_DEPLOYMENT_TARGET 10.9)
  26
  27 # Use GNUInstallDirs to allow customisation
  28 # but set our own default data and bin dir
  29 if(NOT CMAKE_INSTALL_DATADIR)
  30     set(CMAKE_INSTALL_DATADIR "share/games")
  31 endif()
  32 if(NOT CMAKE_INSTALL_BINDIR)
  33     set(CMAKE_INSTALL_BINDIR "games")
  34 endif()
  35 include(GNUInstallDirs)
  36
  37 include(Options)
  38 set_options()
  39 set_directory_options()
  40
  41 include(Static)
  42 set_static_if_needed()
  43
  44 set(CMAKE_CXX_STANDARD 17)
  45 set(CMAKE_CXX_STANDARD_REQUIRED YES)
  46 set(CMAKE_CXX_EXTENSIONS NO)
  47
  48 set(CMAKE_EXPORT_COMPILE_COMMANDS YES)
  49
  50 # An empty target for the tools
  51 add_custom_target(tools)
  52
  53 include(Endian)
  54 add_endian_definition()
  55
  56 include(CompileFlags)
  57 compile_flags()
  58
  59 if(APPLE OR UNIX)
  60     add_definitions(-DUNIX)
  61 endif()
  62
  63 if(UNIX)
  64     find_package(Doxygen)
  65 endif()
  66
  67 list(APPEND GENERATED_SOURCE_FILES "${CMAKE_BINARY_DIR}/generated/rev.cpp")
  68 if(WIN32)
  69     list(APPEND GENERATED_SOURCE_FILES "${CMAKE_BINARY_DIR}/generated/ottdres.rc")
  70 endif()
  71
  72 # Generate a target to determine version, which is execute every 'make' run
  73 add_custom_target(find_version
  74         ${CMAKE_COMMAND}
  75                 -DFIND_VERSION_BINARY_DIR=${CMAKE_BINARY_DIR}/generated
  76                 -DCPACK_BINARY_DIR=${CMAKE_BINARY_DIR}
  77                 -DREV_MAJOR=${CMAKE_PROJECT_VERSION_MAJOR}
  78                 -DREV_MINOR=${CMAKE_PROJECT_VERSION_MINOR}
  79                 -DREV_BUILD=${CMAKE_PROJECT_VERSION_PATCH}
  80                 -P "${CMAKE_SOURCE_DIR}/cmake/scripts/FindVersion.cmake"
  81         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
  82         BYPRODUCTS ${GENERATED_SOURCE_FILES}
  83 )
  84
  85 # Documentation
  86 if(DOXYGEN_EXECUTABLE)
  87     add_custom_target(docs)
  88     add_custom_target(docs_source
  89         ${CMAKE_COMMAND} -E make_directory ${CMAKE_BINARY_DIR}/docs
  90         COMMAND ${DOXYGEN_EXECUTABLE} ${CMAKE_BINARY_DIR}/Doxyfile
  91         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
  92         COMMENT "Generating documentation for source"
  93     )
  94     add_dependencies(docs_source
  95         find_version
  96     )
  97     add_dependencies(docs
  98         docs_source
  99     )
 100 endif()
 101
 102 include(AddCustomXXXTimestamp)
 103
 104 if(OPTION_TOOLS_ONLY)
 105     if(HOST_BINARY_DIR)
 106         unset(HOST_BINARY_DIR CACHE)
 107     endif()
 108     add_subdirectory(${CMAKE_SOURCE_DIR}/src)
 109     return()
 110 endif()
 111
 112 if(APPLE)
 113         # Avoid searching for headers in Frameworks, and libraries in LIBDIR.
 114         set(CMAKE_FIND_FRAMEWORK LAST)
 115 endif()
 116
 117 # Prefer -pthread over -lpthread, which is often the better option of the two.
 118 set(CMAKE_THREAD_PREFER_PTHREAD YES)
 119 # Make sure we have Threads available.
 120 find_package(Threads REQUIRED)
 121
 122 find_package(ZLIB)
 123 find_package(LibLZMA)
 124 find_package(LZO)
 125 find_package(PNG)
 126
 127 if(NOT OPTION_DEDICATED)
 128     if(NOT WIN32)
 129         find_package(Allegro)
 130         if(NOT APPLE)
 131             find_package(Freetype)
 132             find_package(SDL2)
 133             if(NOT SDL2_FOUND)
 134                 find_package(SDL)
 135             endif()
 136             find_package(Fluidsynth)
 137             find_package(Fontconfig)
 138             find_package(ICU OPTIONAL_COMPONENTS i18n lx)
 139         endif()
 140     endif()
 141 endif()
 142 if(APPLE)
 143     find_package(Iconv)
 144
 145     find_library(AUDIOTOOLBOX_LIBRARY AudioToolbox)
 146     find_library(AUDIOUNIT_LIBRARY AudioUnit)
 147     find_library(COCOA_LIBRARY Cocoa)
 148     find_library(QUARTZCORE_LIBRARY QuartzCore)
 149 endif()
 150
 151 if(NOT EMSCRIPTEN AND NOT OPTION_DEDICATED)
 152     find_package(OpenGL COMPONENTS OpenGL)
 153 endif()
 154
 155 if(MSVC)
 156     find_package(Editbin REQUIRED)
 157 endif()
 158
 159 find_package(SSE)
 160 find_package(Xaudio2)
 161
 162 find_package(Grfcodec)
 163
 164 include(CheckIPOSupported)
 165 check_ipo_supported(RESULT IPO_FOUND)
 166
 167 show_options()
 168
 169 if(UNIX AND NOT APPLE AND NOT OPTION_DEDICATED)
 170     if(NOT SDL_FOUND AND NOT SDL2_FOUND AND NOT ALLEGRO_FOUND)
 171         message(FATAL_ERROR "SDL, SDL2 or Allegro is required for this platform")
 172     endif()
 173 endif()
 174 if(APPLE)
 175     if(NOT AUDIOTOOLBOX_LIBRARY)
 176         message(FATAL_ERROR "AudioToolbox is required for this platform")
 177     endif()
 178     if(NOT AUDIOUNIT_LIBRARY)
 179         message(FATAL_ERROR "AudioUnit is required for this platform")
 180     endif()
 181     if(NOT COCOA_LIBRARY)
 182         message(FATAL_ERROR "Cocoa is required for this platform")
 183     endif()
 184     if(NOT QUARTZCORE_LIBRARY)
 185         message(FATAL_ERROR "QuartzCore is required for this platform")
 186     endif()
 187 endif()
 188
 189 if(OPTION_PACKAGE_DEPENDENCIES)
 190     if(NOT UNIX)
 191         message(FATAL_ERROR "Can only package dependencies on Linux")
 192     endif()
 193     if(OPTION_INSTALL_FHS)
 194         message(FATAL_ERROR "Cannot install in FHS folders when we are packaging dependencies")
 195     endif()
 196     if(${CMAKE_VERSION} VERSION_LESS "3.16.0")
 197         message(FATAL_ERROR "OPTION_PACKAGE_DEPENDENCIES can only work with CMake 3.16+; you are using ${CMAKE_VERSION}")
 198     endif()
 199
 200     # If we are packaging dependencies, we do two things:
 201     # 1) set the RPATH to include $ORIGIN/lib; $ORIGIN (that literal string)
 202     #    is a Linux indicator for "path where application is". In CMake, we
 203     #    have to do this before add_executable() is executed.
 204     # 2) copy the libraries that we compile against to the "lib" folder.
 205     #    This is done in InstallAndPackage.cmake.
 206     set(CMAKE_INSTALL_RPATH "\$ORIGIN/lib")
 207     set(CMAKE_BUILD_WITH_INSTALL_RPATH ON)
 208 endif()
 209
 210 include(SourceList)
 211
 212 # Needed by rev.cpp
 213 include_directories(${CMAKE_SOURCE_DIR}/src)
 214 # Needed by everything that uses Squirrel
 215 include_directories(${CMAKE_SOURCE_DIR}/src/3rdparty/squirrel/include)
 216
 217 include(MSVCFilters)
 218
 219 add_executable(openttd WIN32 ${GENERATED_SOURCE_FILES})
 220 set_target_properties(openttd PROPERTIES OUTPUT_NAME "${BINARY_NAME}")
 221 # All other files are added via target_sources()
 222
 223 if(MSVC)
 224     # Add DPI manifest to project; other WIN32 targets get this via ottdres.rc
 225     target_sources(openttd PRIVATE "${CMAKE_SOURCE_DIR}/os/windows/openttd.manifest")
 226 endif()
 227
 228 add_subdirectory(${CMAKE_SOURCE_DIR}/bin)
 229 add_subdirectory(${CMAKE_SOURCE_DIR}/src)
 230 add_subdirectory(${CMAKE_SOURCE_DIR}/media)
 231
 232 add_dependencies(openttd
 233     find_version)
 234
 235 target_link_libraries(openttd
 236     openttd::languages
 237     openttd::settings
 238     openttd::media
 239     openttd::basesets
 240     openttd::script_api
 241     Threads::Threads
 242 )
 243
 244 if(IPO_FOUND)
 245     set_target_properties(openttd PROPERTIES INTERPROCEDURAL_OPTIMIZATION_RELEASE True)
 246     set_target_properties(openttd PROPERTIES INTERPROCEDURAL_OPTIMIZATION_MINSIZEREL True)
 247     set_target_properties(openttd PROPERTIES INTERPROCEDURAL_OPTIMIZATION_RELWITHDEBINFO True)
 248 endif()
 249 set_target_properties(openttd PROPERTIES VS_DEBUGGER_WORKING_DIRECTORY "${CMAKE_BINARY_DIR}")
 250 process_compile_flags()
 251
 252 include(LinkPackage)
 253 link_package(PNG TARGET PNG::PNG ENCOURAGED)
 254 link_package(ZLIB TARGET ZLIB::ZLIB ENCOURAGED)
 255 link_package(LIBLZMA TARGET LibLZMA::LibLZMA ENCOURAGED)
 256 link_package(LZO)
 257
 258 if(NOT OPTION_DEDICATED)
 259     link_package(Fluidsynth)
 260     link_package(SDL)
 261     link_package(SDL2 TARGET SDL2::SDL2)
 262     link_package(Allegro)
 263     link_package(FREETYPE TARGET Freetype::Freetype)
 264     link_package(Fontconfig TARGET Fontconfig::Fontconfig)
 265     link_package(ICU_lx)
 266     link_package(ICU_i18n)
 267
 268     if(SDL2_FOUND AND OPENGL_FOUND AND UNIX)
 269         # SDL2 dynamically loads OpenGL if needed, so do not link to OpenGL when
 270         # on Linux. For Windows, we need to link to OpenGL as we also have a win32
 271         # driver using it.
 272         add_definitions(-DWITH_OPENGL)
 273         message(STATUS "OpenGL found -- -DWITH_OPENGL -- (via SDL2)")
 274     else()
 275         link_package(OpenGL TARGET OpenGL::GL)
 276     endif()
 277 endif()
 278
 279 if(APPLE)
 280     link_package(Iconv TARGET Iconv::Iconv)
 281
 282     target_link_libraries(openttd
 283         ${AUDIOTOOLBOX_LIBRARY}
 284         ${AUDIOUNIT_LIBRARY}
 285         ${COCOA_LIBRARY}
 286         ${QUARTZCORE_LIBRARY}
 287     )
 288
 289     add_definitions(
 290         -DWITH_COCOA
 291     )
 292 endif()
 293
 294 if(EMSCRIPTEN)
 295     add_library(WASM::WASM INTERFACE IMPORTED)
 296
 297     # Allow heap-growth, and start with a bigger memory size.
 298     target_link_libraries(WASM::WASM INTERFACE "-s ALLOW_MEMORY_GROWTH=1")
 299     target_link_libraries(WASM::WASM INTERFACE "-s INITIAL_MEMORY=33554432")
 300     target_link_libraries(WASM::WASM INTERFACE "-s DISABLE_EXCEPTION_CATCHING=0")
 301     add_definitions(-s DISABLE_EXCEPTION_CATCHING=0)
 302
 303     # Export functions to Javascript.
 304     target_link_libraries(WASM::WASM INTERFACE "-s EXPORTED_FUNCTIONS='[\"_main\", \"_em_openttd_add_server\"]' -s EXTRA_EXPORTED_RUNTIME_METHODS='[\"cwrap\"]'")
 305
 306     # Preload all the files we generate during build.
 307     # As we do not compile with FreeType / FontConfig, we also have no way to
 308     # render several languages (like Chinese, ..), so where do you draw the
 309     # line what languages to include and which not? In the end, especially as
 310     # the more languages you add the slower downloading becomes, we decided to
 311     # only ship the English language.
 312     target_link_libraries(WASM::WASM INTERFACE "--preload-file ${CMAKE_BINARY_DIR}/baseset@/baseset")
 313     target_link_libraries(WASM::WASM INTERFACE "--preload-file ${CMAKE_BINARY_DIR}/lang/english.lng@/lang/english.lng")
 314     target_link_libraries(WASM::WASM INTERFACE "--preload-file ${CMAKE_SOURCE_DIR}/bin/ai@/ai")
 315     target_link_libraries(WASM::WASM INTERFACE "--preload-file ${CMAKE_SOURCE_DIR}/bin/game@/game")
 316
 317     # We use IDBFS for persistent storage.
 318     target_link_libraries(WASM::WASM INTERFACE "-lidbfs.js")
 319
 320     # Use custom pre-js and shell.html.
 321     target_link_libraries(WASM::WASM INTERFACE "--pre-js ${CMAKE_SOURCE_DIR}/os/emscripten/pre.js")
 322     target_link_libraries(WASM::WASM INTERFACE "--shell-file ${CMAKE_SOURCE_DIR}/os/emscripten/shell.html")
 323
 324     # Build the .html (which builds the .js, .wasm, and .data too).
 325     set_target_properties(openttd PROPERTIES SUFFIX ".html")
 326     target_link_libraries(openttd WASM::WASM)
 327 endif()
 328
 329 if(NOT PERSONAL_DIR STREQUAL "(not set)")
 330     add_definitions(
 331         -DWITH_PERSONAL_DIR
 332         -DPERSONAL_DIR="${PERSONAL_DIR}"
 333     )
 334 endif()
 335
 336 if(NOT SHARED_DIR STREQUAL "(not set)")
 337     add_definitions(
 338         -DWITH_SHARED_DIR
 339         -DSHARED_DIR="${SHARED_DIR}"
 340     )
 341 endif()
 342
 343 if(NOT GLOBAL_DIR STREQUAL "(not set)")
 344     add_definitions(
 345         -DGLOBAL_DATA_DIR="${GLOBAL_DIR}"
 346     )
 347 endif()
 348
 349 link_package(SSE)
 350
 351 add_definitions_based_on_options()
 352
 353 if(WIN32)
 354     add_definitions(
 355         -DUNICODE
 356         -D_UNICODE
 357         -DWITH_UNISCRIBE
 358     )
 359
 360     target_link_libraries(openttd
 361         ws2_32
 362         winmm
 363         imm32
 364     )
 365 endif()
 366
 367 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
 368     add_definitions(-D_SQ64)
 369 endif()
 370
 371 include(CreateRegression)
 372 create_regression()
 373
 374 if(APPLE OR WIN32)
 375     find_package(Pandoc)
 376 endif()
 377
 378 include(InstallAndPackage)