lisp/org-timer.el

   1 ;;; org-timer.el --- The relative timer code for Org-mode
   2
   3 ;; Copyright (C) 2008, 2009, 2010 Free Software Foundation, Inc.
   4
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;; Keywords: outlines, hypermedia, calendar, wp
   7 ;; Homepage: http://orgmode.org
   8 ;; Version: 7.01b
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file contains the relative timer code for Org-mode
  29
  30 ;;; Code:
  31
  32 (require 'org)
  33
  34 (declare-function org-show-notification "org-clock" (parameters))
  35 (declare-function org-agenda-error "org-agenda" ())
  36
  37 (defvar org-timer-start-time nil
  38   "t=0 for the running timer.")
  39
  40 (defvar org-timer-pause-time nil
  41   "Time when the timer was paused.")
  42
  43 (defconst org-timer-re "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
  44   "Regular expression used to match timer stamps.")
  45
  46 (defcustom org-timer-format "%s "
  47   "The format to insert the time of the timer.
  48 This format must contain one instance of \"%s\" which will be replaced by
  49 the value of the relative timer."
  50   :group 'org-time
  51   :type 'string)
  52
  53 (defcustom org-timer-default-timer 0
  54   "The default timer when a timer is set.
  55 When 0, the user is prompted for a value."
  56   :group 'org-time
  57   :type 'number)
  58
  59 (defvar org-timer-start-hook nil
  60   "Hook run after relative timer is started.")
  61
  62 (defvar org-timer-stop-hook nil
  63   "Hook run before relative timer is stopped.")
  64
  65 (defvar org-timer-pause-hook nil
  66   "Hook run before relative timer is paused.")
  67
  68 (defvar org-timer-set-hook nil
  69   "Hook run after countdown timer is set.")
  70
  71 (defvar org-timer-done-hook nil
  72   "Hook run after countdown timer reaches zero.")
  73
  74 (defvar org-timer-cancel-hook nil
  75   "Hook run before countdown timer is canceled.")
  76
  77 ;;;###autoload
  78 (defun org-timer-start (&optional offset)
  79   "Set the starting time for the relative timer to now.
  80 When called with prefix argument OFFSET, prompt the user for an offset time,
  81 with the default taken from a timer stamp at point, if any.
  82 If OFFSET is a string or an integer, it is directly taken to be the offset
  83 without user interaction.
  84 When called with a double prefix arg, all timer strings in the active
  85 region will be shifted by a specific amount.  You will be prompted for
  86 the amount, with the default to make the first timer string in
  87 the region 0:00:00."
  88   (interactive "P")
  89   (if (equal offset '(16))
  90       (call-interactively 'org-timer-change-times-in-region)
  91     (let (delta def s)
  92       (if (not offset)
  93           (setq org-timer-start-time (current-time))
  94         (cond
  95          ((integerp offset) (setq delta offset))
  96          ((stringp offset) (setq delta (org-timer-hms-to-secs offset)))
  97          (t
  98           (setq def (if (org-in-regexp org-timer-re)
  99                         (match-string 0)
 100                       "0:00:00")
 101                 s (read-string
 102                    (format "Restart timer with offset [%s]: " def)))
 103           (unless (string-match "\\S-" s) (setq s def))
 104           (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete s)))))
 105         (setq org-timer-start-time
 106               (seconds-to-time
 107                (- (org-float-time) delta))))
 108       (org-timer-set-mode-line 'on)
 109       (message "Timer start time set to %s, current value is %s"
 110                (format-time-string "%T" org-timer-start-time)
 111                (org-timer-secs-to-hms (or delta 0)))
 112       (run-hooks 'org-timer-start-hook))))
 113
 114 (defun org-timer-pause-or-continue (&optional stop)
 115   "Pause or continue the relative timer.
 116 With prefix arg STOP, stop it entirely."
 117   (interactive "P")
 118   (cond
 119    (stop (org-timer-stop))
 120    ((not org-timer-start-time) (error "No timer is running"))
 121    (org-timer-pause-time
 122     ;; timer is paused, continue
 123     (setq org-timer-start-time
 124           (seconds-to-time
 125            (-
 126             (org-float-time)
 127             (- (org-float-time org-timer-pause-time)
 128                (org-float-time org-timer-start-time))))
 129           org-timer-pause-time nil)
 130     (org-timer-set-mode-line 'on)
 131     (message "Timer continues at %s" (org-timer-value-string)))
 132    (t
 133     ;; pause timer
 134     (run-hooks 'org-timer-pause-hook)
 135     (setq org-timer-pause-time (current-time))
 136     (org-timer-set-mode-line 'pause)
 137     (message "Timer paused at %s" (org-timer-value-string)))))
 138
 139 (defun org-timer-stop ()
 140   "Stop the relative timer."
 141   (interactive)
 142   (run-hooks 'org-timer-stop-hook)
 143   (setq org-timer-start-time nil
 144         org-timer-pause-time nil)
 145   (org-timer-set-mode-line 'off))
 146
 147 ;;;###autoload
 148 (defun org-timer (&optional restart)
 149   "Insert a H:MM:SS string from the timer into the buffer.
 150 The first time this command is used, the timer is started.  When used with
 151 a \\[universal-argument] prefix, force restarting the timer.
 152 When used with a double prefix argument \
 153 \\[universal-argument] \\universal-argument], change all the timer string
 154 in the region by a fixed amount.  This can be used to recalibrate a timer
 155 that was not started at the correct moment."
 156   (interactive "P")
 157   (if (equal restart '(4)) (org-timer-start))
 158   (or org-timer-start-time (org-timer-start))
 159   (insert (org-timer-value-string)))
 160
 161 (defun org-timer-value-string ()
 162   (format org-timer-format (org-timer-secs-to-hms (floor (org-timer-seconds)))))
 163
 164 (defun org-timer-seconds ()
 165   (- (org-float-time (or org-timer-pause-time (current-time)))
 166      (org-float-time org-timer-start-time)))
 167
 168 ;;;###autoload
 169 (defun org-timer-change-times-in-region (beg end delta)
 170   "Change all h:mm:ss time in region by a DELTA."
 171   (interactive
 172    "r\nsEnter time difference like \"-1:08:26\". Default is first time to zero: ")
 173   (let ((re "[-+]?[0-9]+:[0-9]\\{2\\}:[0-9]\\{2\\}") p)
 174     (unless (string-match "\\S-" delta)
 175       (save-excursion
 176         (goto-char beg)
 177         (when (re-search-forward re end t)
 178           (setq delta (match-string 0))
 179           (if (equal (string-to-char delta) ?-)
 180               (setq delta (substring delta 1))
 181             (setq delta (concat "-" delta))))))
 182     (setq delta (org-timer-hms-to-secs (org-timer-fix-incomplete delta)))
 183     (when (= delta 0) (error "No change"))
 184     (save-excursion
 185       (goto-char end)
 186       (while (re-search-backward re beg t)
 187         (setq p (point))
 188         (replace-match
 189          (save-match-data
 190            (org-timer-secs-to-hms (+ (org-timer-hms-to-secs (match-string 0)) delta)))
 191          t t)
 192         (goto-char p)))))
 193
 194 ;;;###autoload
 195 (defun org-timer-item (&optional arg)
 196   "Insert a description-type item with the current timer value."
 197   (interactive "P")
 198   (let ((ind 0))
 199     (save-excursion
 200       (skip-chars-backward " \n\t")
 201       (condition-case nil
 202           (progn
 203             (org-beginning-of-item)
 204             (setq ind (org-get-indentation)))
 205         (error nil)))
 206     (or (bolp) (newline))
 207     (org-indent-line-to ind)
 208     (insert "- ")
 209     (org-timer (if arg '(4)))
 210     (insert ":: ")))
 211
 212 (defun org-timer-fix-incomplete (hms)
 213   "If hms is a H:MM:SS string with missing hour or hour and minute, fix it."
 214   (if (string-match "\\(?:\\([0-9]+:\\)?\\([0-9]+:\\)\\)?\\([0-9]+\\)" hms)
 215       (replace-match
 216        (format "%d:%02d:%02d"
 217                (if (match-end 1) (string-to-number (match-string 1 hms)) 0)
 218                (if (match-end 2) (string-to-number (match-string 2 hms)) 0)
 219                (string-to-number (match-string 3 hms)))
 220        t t hms)
 221     (error "Cannot parse HMS string \"%s\"" hms)))
 222
 223 (defun org-timer-hms-to-secs (hms)
 224   "Convert h:mm:ss string to an integer time.
 225 If the string starts with a minus sign, the integer will be negative."
 226   (if (not (string-match
 227             "\\([-+]?[0-9]+\\):\\([0-9]\\{2\\}\\):\\([0-9]\\{2\\}\\)"
 228             hms))
 229       0
 230     (let* ((h (string-to-number (match-string 1 hms)))
 231            (m (string-to-number (match-string 2 hms)))
 232            (s (string-to-number (match-string 3 hms)))
 233            (sign (equal (substring (match-string 1 hms) 0 1) "-")))
 234       (setq h (abs h))
 235       (* (if sign -1 1) (+ s (* 60 (+ m (* 60 h))))))))
 236
 237 (defun org-timer-secs-to-hms (s)
 238   "Convert integer S into h:mm:ss.
 239 If the integer is negative, the string will start with \"-\"."
 240   (let (sign m h)
 241     (setq sign (if (< s 0) "-" "")
 242           s (abs s)
 243           m (/ s 60) s (- s (* 60 m))
 244           h (/ m 60) m (- m (* 60 h)))
 245     (format "%s%d:%02d:%02d" sign h m s)))
 246
 247 (defvar org-timer-mode-line-timer nil)
 248 (defvar org-timer-mode-line-string nil)
 249
 250 (defun org-timer-set-mode-line (value)
 251   "Set the mode-line display of the relative timer.
 252 VALUE can be `on', `off', or `pause'."
 253   (or global-mode-string (setq global-mode-string '("")))
 254   (or (memq 'org-timer-mode-line-string global-mode-string)
 255       (setq global-mode-string
 256             (append global-mode-string '(org-timer-mode-line-string))))
 257   (cond
 258    ((equal value 'off)
 259     (when org-timer-mode-line-timer
 260       (cancel-timer org-timer-mode-line-timer)
 261       (setq org-timer-mode-line-timer nil))
 262     (setq global-mode-string
 263           (delq 'org-timer-mode-line-string global-mode-string))
 264     (force-mode-line-update))
 265    ((equal value 'pause)
 266     (when org-timer-mode-line-timer
 267       (cancel-timer org-timer-mode-line-timer)
 268       (setq org-timer-mode-line-timer nil)))
 269    ((equal value 'on)
 270     (or global-mode-string (setq global-mode-string '("")))
 271     (or (memq 'org-timer-mode-line-string global-mode-string)
 272         (setq global-mode-string
 273               (append global-mode-string '(org-timer-mode-line-string))))
 274     (org-timer-update-mode-line)
 275     (when org-timer-mode-line-timer
 276       (cancel-timer org-timer-mode-line-timer))
 277     (setq org-timer-mode-line-timer
 278           (run-with-timer 1 1 'org-timer-update-mode-line)))))
 279
 280 (defun org-timer-update-mode-line ()
 281   "Update the timer time in the mode line."
 282   (if org-timer-pause-time
 283       nil
 284     (setq org-timer-mode-line-string
 285           (concat " <" (substring (org-timer-value-string) 0 -1) ">"))
 286     (force-mode-line-update)))
 287
 288 (defvar org-timer-current-timer nil)
 289 (defun org-timer-cancel-timer ()
 290   "Cancel the current timer."
 291   (interactive)
 292   (when (eval org-timer-current-timer)
 293     (run-hooks 'org-timer-cancel-hook)
 294     (cancel-timer org-timer-current-timer)
 295     (setq org-timer-current-timer nil))
 296   (message "Last timer canceled"))
 297
 298 (defun org-timer-show-remaining-time ()
 299   "Display the remaining time before the timer ends."
 300   (interactive)
 301   (require 'time)
 302   (if (not org-timer-current-timer)
 303       (message "No timer set")
 304     (let* ((rtime (decode-time
 305                    (time-subtract (timer--time org-timer-current-timer)
 306                                   (current-time))))
 307            (rsecs (nth 0 rtime))
 308            (rmins (nth 1 rtime)))
 309       (message "%d minute(s) %d seconds left before next time out"
 310                rmins rsecs))))
 311
 312 (defun bzg-test (&optional test)
 313   (interactive "P")
 314   test)
 315
 316 ;;;###autoload
 317 (defun org-timer-set-timer (&optional opt)
 318   "Prompt for a duration and set a timer.
 319
 320 If `org-timer-default-timer' is not zero, suggest this value as
 321 the default duration for the timer.  If a timer is already set,
 322 prompt the use if she wants to replace it.
 323
 324 Called with a numeric prefix argument, use this numeric value as
 325 the duration of the timer.
 326
 327 Called with a `C-u' prefix arguments, use `org-timer-default-timer'
 328 without prompting the user for a duration.
 329
 330 With two `C-u' prefix arguments, use `org-timer-default-timer'
 331 without prompting the user for a duration and automatically
 332 replace any running timer."
 333   (interactive "P")
 334   (let ((minutes (or (and (numberp opt) (number-to-string opt))
 335                      (and (listp opt) (not (null opt))
 336                           (number-to-string org-timer-default-timer))
 337                      (read-from-minibuffer
 338                       "How many minutes left? "
 339                       (if (not (eq org-timer-default-timer 0))
 340                           (number-to-string org-timer-default-timer))))))
 341     (if (not (string-match "[0-9]+" minutes))
 342         (org-timer-show-remaining-time)
 343     (let* ((mins (string-to-number (match-string 0 minutes)))
 344            (secs (* mins 60))
 345            (hl (cond
 346                 ((string-match "Org Agenda" (buffer-name))
 347                  (let* ((marker (or (get-text-property (point) 'org-marker)
 348                                     (org-agenda-error)))
 349                         (hdmarker (or (get-text-property (point) 'org-hd-marker)
 350                                       marker))
 351                         (pos (marker-position marker)))
 352                    (with-current-buffer (marker-buffer marker)
 353                      (widen)
 354                      (goto-char pos)
 355                      (org-show-entry)
 356                      (org-get-heading))))
 357                 ((eq major-mode 'org-mode)
 358                  (org-get-heading))
 359                 (t (error "Not in an Org buffer"))))
 360            timer-set)
 361       (if (or (and org-timer-current-timer
 362                    (or (equal opt '(16))
 363                        (y-or-n-p "Replace current timer? ")))
 364               (not org-timer-current-timer))
 365           (progn
 366             (when org-timer-current-timer
 367               (cancel-timer org-timer-current-timer))
 368             (setq org-timer-current-timer
 369                   (run-with-timer
 370                    secs nil `(lambda ()
 371                                (setq org-timer-current-timer nil)
 372                                (org-notify ,(format "%s: time out" hl) t)
 373                                (run-hooks 'org-timer-done-hook))))
 374             (run-hooks 'org-timer-set-hook))
 375         (message "No timer set"))))))
 376
 377 (provide 'org-timer)
 378
 379 ;; arch-tag: 97538f8c-3871-4509-8f23-1e7b3ff3d107
 380
 381 ;;; org-timer.el ends here