lisp/ox-md.el

   1 ;;; ox-md.el --- Markdown Back-End for Org Export Engine
   2
   3 ;; Copyright (C) 2012, 2013  Free Software Foundation, Inc.
   4
   5 ;; Author: Nicolas Goaziou <n.goaziou@gmail.com>
   6 ;; Keywords: org, wp, tex
   7
   8 ;; GNU Emacs is free software: you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation, either version 3 of the License, or
  11 ;; (at your option) any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 ;;; Commentary:
  22
  23 ;; This library implements a Markdown back-end (vanilla flavour) for
  24 ;; Org exporter, based on `html' back-end.
  25 ;;
  26 ;; It provides two commands for export, depending on the desired
  27 ;; output: `org-md-export-as-markdown' (temporary buffer) and
  28 ;; `org-md-export-to-markdown' ("md" file).
  29
  30 ;;; Code:
  31
  32 (eval-when-compile (require 'cl))
  33 (require 'ox-html)
  34
  35
  36 \f
  37 ;;; User-Configurable Variables
  38
  39 (defgroup org-export-md nil
  40   "Options specific to Markdown export back-end."
  41   :tag "Org Markdown"
  42   :group 'org-export
  43   :version "24.2")
  44
  45 (defcustom org-md-headline-style 'atx
  46   "Style used to format headlines.
  47 This variable can be set to either `atx' or `setext'."
  48   :group 'org-export-md
  49   :type '(choice
  50           (const :tag "Use \"atx\" style" atx)
  51           (const :tag "Use \"Setext\" style" setext)))
  52
  53
  54 \f
  55 ;;; Define Back-End
  56
  57 (org-export-define-derived-backend md html
  58   :export-block ("MD" "MARKDOWN")
  59   :filters-alist ((:filter-parse-tree . org-md-separate-elements))
  60   :menu-entry
  61   (?m "Export to Markdown"
  62       ((?M "To temporary buffer"
  63            (lambda (a s v b) (org-md-export-as-markdown a s v)))
  64        (?m "To file" (lambda (a s v b) (org-md-export-to-markdown a s v)))
  65        (?o "To file and open"
  66            (lambda (a s v b)
  67              (if a (org-md-export-to-markdown t s v)
  68                (org-open-file (org-md-export-to-markdown nil s v)))))))
  69   :translate-alist ((bold . org-md-bold)
  70                     (code . org-md-verbatim)
  71                     (comment . (lambda (&rest args) ""))
  72                     (comment-block . (lambda (&rest args) ""))
  73                     (example-block . org-md-example-block)
  74                     (fixed-width . org-md-example-block)
  75                     (footnote-definition . ignore)
  76                     (footnote-reference . ignore)
  77                     (headline . org-md-headline)
  78                     (horizontal-rule . org-md-horizontal-rule)
  79                     (inline-src-block . org-md-verbatim)
  80                     (italic . org-md-italic)
  81                     (item . org-md-item)
  82                     (line-break . org-md-line-break)
  83                     (link . org-md-link)
  84                     (paragraph . org-md-paragraph)
  85                     (plain-list . org-md-plain-list)
  86                     (plain-text . org-md-plain-text)
  87                     (quote-block . org-md-quote-block)
  88                     (quote-section . org-md-example-block)
  89                     (section . org-md-section)
  90                     (src-block . org-md-example-block)
  91                     (template . org-md-template)
  92                     (verbatim . org-md-verbatim)))
  93
  94
  95 \f
  96 ;;; Filters
  97
  98 (defun org-md-separate-elements (tree backend info)
  99   "Make sure elements are separated by at least one blank line.
 100
 101 TREE is the parse tree being exported.  BACKEND is the export
 102 back-end used.  INFO is a plist used as a communication channel.
 103
 104 Assume BACKEND is `md'."
 105   (org-element-map tree org-element-all-elements
 106     (lambda (elem)
 107       (unless (eq (org-element-type elem) 'org-data)
 108         (org-element-put-property
 109          elem :post-blank
 110          (let ((post-blank (org-element-property :post-blank elem)))
 111            (if (not post-blank) 1 (max 1 post-blank)))))))
 112   ;; Return updated tree.
 113   tree)
 114
 115
 116 \f
 117 ;;; Transcode Functions
 118
 119 ;;;; Bold
 120
 121 (defun org-md-bold (bold contents info)
 122   "Transcode BOLD object into Markdown format.
 123 CONTENTS is the text within bold markup.  INFO is a plist used as
 124 a communication channel."
 125   (format "**%s**" contents))
 126
 127
 128 ;;;; Code and Verbatim
 129
 130 (defun org-md-verbatim (verbatim contents info)
 131   "Transcode VERBATIM object into Markdown format.
 132 CONTENTS is nil.  INFO is a plist used as a communication
 133 channel."
 134   (let ((value (org-element-property :value verbatim)))
 135     (format (cond ((not (string-match "`" value)) "`%s`")
 136                   ((or (string-match "\\``" value)
 137                        (string-match "`\\'" value))
 138                    "`` %s ``")
 139                   (t "``%s``"))
 140             value)))
 141
 142
 143 ;;;; Example Block and Src Block
 144
 145 (defun org-md-example-block (example-block contents info)
 146   "Transcode EXAMPLE-BLOCK element into Markdown format.
 147 CONTENTS is nil.  INFO is a plist used as a communication
 148 channel."
 149   (replace-regexp-in-string
 150    "^" "    "
 151    (org-remove-indentation
 152     (org-element-property :value example-block))))
 153
 154
 155 ;;;; Headline
 156
 157 (defun org-md-headline (headline contents info)
 158   "Transcode HEADLINE element into Markdown format.
 159 CONTENTS is the headline contents.  INFO is a plist used as
 160 a communication channel."
 161   (unless (org-element-property :footnote-section-p headline)
 162     (let* ((level (org-export-get-relative-level headline info))
 163            (title (org-export-data (org-element-property :title headline) info))
 164            (todo (and (plist-get info :with-todo-keywords)
 165                       (let ((todo (org-element-property :todo-keyword
 166                                                         headline)))
 167                         (and todo (concat (org-export-data todo info) " ")))))
 168            (tags (and (plist-get info :with-tags)
 169                       (let ((tag-list (org-export-get-tags headline info)))
 170                         (and tag-list
 171                              (format "     :%s:"
 172                                      (mapconcat 'identity tag-list ":"))))))
 173            (priority
 174             (and (plist-get info :with-priority)
 175                  (let ((char (org-element-property :priority headline)))
 176                    (and char (format "[#%c] " char)))))
 177            ;; Headline text without tags.
 178            (heading (concat todo priority title)))
 179       (cond
 180        ;; Cannot create a headline.  Fall-back to a list.
 181        ((or (org-export-low-level-p headline info)
 182             (not (memq org-md-headline-style '(atx setext)))
 183             (and (eq org-md-headline-style 'atx) (> level 6))
 184             (and (eq org-md-headline-style 'setext) (> level 2)))
 185         (let ((bullet
 186                (if (not (org-export-numbered-headline-p headline info)) "-"
 187                  (concat (number-to-string
 188                           (car (last (org-export-get-headline-number
 189                                       headline info))))
 190                          "."))))
 191           (concat bullet (make-string (- 4 (length bullet)) ? ) heading tags
 192                   "\n\n"
 193                   (and contents
 194                        (replace-regexp-in-string "^" "    " contents)))))
 195        ;; Use "Setext" style.
 196        ((eq org-md-headline-style 'setext)
 197         (concat heading tags "\n"
 198                 (make-string (length heading) (if (= level 1) ?= ?-))
 199                 "\n\n"
 200                 contents))
 201        ;; Use "atx" style.
 202        (t (concat (make-string level ?#) " " heading tags "\n\n" contents))))))
 203
 204
 205 ;;;; Horizontal Rule
 206
 207 (defun org-md-horizontal-rule (horizontal-rule contents info)
 208   "Transcode HORIZONTAL-RULE element into Markdown format.
 209 CONTENTS is the horizontal rule contents.  INFO is a plist used
 210 as a communication channel."
 211   "---")
 212
 213
 214 ;;;; Italic
 215
 216 (defun org-md-italic (italic contents info)
 217   "Transcode ITALIC object into Markdown format.
 218 CONTENTS is the text within italic markup.  INFO is a plist used
 219 as a communication channel."
 220   (format "*%s*" contents))
 221
 222
 223 ;;;; Item
 224
 225 (defun org-md-item (item contents info)
 226   "Transcode ITEM element into Markdown format.
 227 CONTENTS is the item contents.  INFO is a plist used as
 228 a communication channel."
 229   (let* ((type (org-element-property :type (org-export-get-parent item)))
 230          (struct (org-element-property :structure item))
 231          (bullet (if (not (eq type 'ordered)) "-"
 232                    (concat (number-to-string
 233                             (car (last (org-list-get-item-number
 234                                         (org-element-property :begin item)
 235                                         struct
 236                                         (org-list-prevs-alist struct)
 237                                         (org-list-parents-alist struct)))))
 238                            "."))))
 239     (concat bullet
 240             (make-string (- 4 (length bullet)) ? )
 241             (case (org-element-property :checkbox item)
 242               (on "[X] ")
 243               (trans "[-] ")
 244               (off "[ ] "))
 245             (let ((tag (org-element-property :tag item)))
 246               (and tag (format "**%s:** "(org-export-data tag info))))
 247             (org-trim (replace-regexp-in-string "^" "    " contents)))))
 248
 249
 250 ;;;; Line Break
 251
 252 (defun org-md-line-break (line-break contents info)
 253   "Transcode LINE-BREAK object into Markdown format.
 254 CONTENTS is nil.  INFO is a plist used as a communication
 255 channel."
 256   "  \n")
 257
 258
 259 ;;;; Link
 260
 261 (defun org-md-link (link contents info)
 262   "Transcode LINE-BREAK object into Markdown format.
 263 CONTENTS is the link's description.  INFO is a plist used as
 264 a communication channel."
 265   (let ((--link-org-files-as-html-maybe
 266          (function
 267           (lambda (raw-path info)
 268             ;; Treat links to `file.org' as links to `file.html', if
 269             ;; needed.  See `org-html-link-org-files-as-html'.
 270             (cond
 271              ((and org-html-link-org-files-as-html
 272                    (string= ".org"
 273                             (downcase (file-name-extension raw-path "."))))
 274               (concat (file-name-sans-extension raw-path) "."
 275                       (plist-get info :html-extension)))
 276              (t raw-path)))))
 277         (type (org-element-property :type link)))
 278     (cond ((member type '("custom-id" "id"))
 279            (let ((destination (org-export-resolve-id-link link info)))
 280              (if (stringp destination)  ; External file.
 281                  (let ((path (funcall --link-org-files-as-html-maybe
 282                                       destination info)))
 283                    (if (not contents) (format "<%s>" path)
 284                      (format "[%s](%s)" contents path)))
 285                (concat
 286                 (and contents (concat contents " "))
 287                 (format "(%s)"
 288                         (format (org-export-translate "See section %s" :html info)
 289                                 (mapconcat 'number-to-string
 290                                            (org-export-get-headline-number
 291                                             destination info)
 292                                            ".")))))))
 293           ((org-export-inline-image-p link org-html-inline-image-rules)
 294            (let ((path (let ((raw-path (org-element-property :path link)))
 295                          (if (not (file-name-absolute-p raw-path)) raw-path
 296                            (expand-file-name raw-path)))))
 297              (format "![%s](%s)"
 298                      (let ((caption (org-export-get-caption
 299                                      (org-export-get-parent-element link))))
 300                        (when caption (org-export-data caption info)))
 301                      path)))
 302           ((string= type "coderef")
 303            (let ((ref (org-element-property :path link)))
 304              (format (org-export-get-coderef-format ref contents)
 305                      (org-export-resolve-coderef ref info))))
 306           ((equal type "radio")
 307            (let ((destination (org-export-resolve-radio-link link info)))
 308              (org-export-data (org-element-contents destination) info)))
 309           ((equal type "fuzzy")
 310            (let ((destination (org-export-resolve-fuzzy-link link info)))
 311              ;; Ignore invisible "#+TARGET: path".
 312              (unless (eq (org-element-type destination) 'keyword)
 313                (if (org-string-nw-p contents) contents
 314                  (when destination
 315                    (let ((number (org-export-get-ordinal destination info)))
 316                      (when number
 317                        (if (atom number) (number-to-string number)
 318                          (mapconcat 'number-to-string number ".")))))))))
 319           (t (let* ((raw-path (org-element-property :path link))
 320                     (path (cond
 321                            ((member type '("http" "https" "ftp"))
 322                             (concat type ":" raw-path))
 323                            ((equal type "file")
 324                             ;; Treat links to ".org" files as ".html",
 325                             ;; if needed.
 326                             (setq raw-path
 327                                   (funcall --link-org-files-as-html-maybe
 328                                            raw-path info))
 329                             ;; If file path is absolute, prepend it
 330                             ;; with protocol component - "file://".
 331                             (if (not (file-name-absolute-p raw-path)) raw-path
 332                               (concat "file://" (expand-file-name raw-path))))
 333                            (t raw-path))))
 334                (if (not contents) (format "<%s>" path)
 335                  (format "[%s](%s)" contents path)))))))
 336
 337
 338 ;;;; Paragraph
 339
 340 (defun org-md-paragraph (paragraph contents info)
 341   "Transcode PARAGRAPH element into Markdown format.
 342 CONTENTS is the paragraph contents.  INFO is a plist used as
 343 a communication channel."
 344   (let ((first-object (car (org-element-contents paragraph))))
 345     ;; If paragraph starts with a #, protect it.
 346     (if (and (stringp first-object) (string-match "\\`#" first-object))
 347         (replace-regexp-in-string "\\`#" "\\#" contents nil t)
 348       contents)))
 349
 350
 351 ;;;; Plain List
 352
 353 (defun org-md-plain-list (plain-list contents info)
 354   "Transcode PLAIN-LIST element into Markdown format.
 355 CONTENTS is the plain-list contents.  INFO is a plist used as
 356 a communication channel."
 357   contents)
 358
 359
 360 ;;;; Plain Text
 361
 362 (defun org-md-plain-text (text info)
 363   "Transcode a TEXT string into Markdown format.
 364 TEXT is the string to transcode.  INFO is a plist holding
 365 contextual information."
 366   (when (plist-get info :with-smart-quotes)
 367     (setq text (org-export-activate-smart-quotes text :html info)))
 368   ;; Protect ambiguous #.  This will protect # at the beginning of
 369   ;; a line, but not at the beginning of a paragraph.  See
 370   ;; `org-md-paragraph'.
 371   (setq text (replace-regexp-in-string "\n#" "\n\\\\#" text))
 372   ;; Protect ambiguous !
 373   (setq text (replace-regexp-in-string "\\(!\\)\\[" "\\\\!" text nil nil 1))
 374   ;; Protect `, *, _ and \
 375   (setq text (replace-regexp-in-string "[`*_\\]" "\\\\\\&" text))
 376   ;; Handle special strings, if required.
 377   (when (plist-get info :with-special-strings)
 378     (setq text (org-html-convert-special-strings text)))
 379   ;; Handle break preservation, if required.
 380   (when (plist-get info :preserve-breaks)
 381     (setq text (replace-regexp-in-string "[ \t]*\n" "  \n" text)))
 382   ;; Return value.
 383   text)
 384
 385
 386 ;;;; Quote Block
 387
 388 (defun org-md-quote-block (quote-block contents info)
 389   "Transcode QUOTE-BLOCK element into Markdown format.
 390 CONTENTS is the quote-block contents.  INFO is a plist used as
 391 a communication channel."
 392   (replace-regexp-in-string
 393    "^" "> "
 394    (replace-regexp-in-string "\n\\'" "" contents)))
 395
 396
 397 ;;;; Section
 398
 399 (defun org-md-section (section contents info)
 400   "Transcode SECTION element into Markdown format.
 401 CONTENTS is the section contents.  INFO is a plist used as
 402 a communication channel."
 403   contents)
 404
 405
 406 ;;;; Template
 407
 408 (defun org-md-template (contents info)
 409   "Return complete document string after Markdown conversion.
 410 CONTENTS is the transcoded contents string.  INFO is a plist used
 411 as a communication channel."
 412   contents)
 413
 414
 415 \f
 416 ;;; Interactive function
 417
 418 ;;;###autoload
 419 (defun org-md-export-as-markdown (&optional async subtreep visible-only)
 420   "Export current buffer to a text buffer.
 421
 422 If narrowing is active in the current buffer, only export its
 423 narrowed part.
 424
 425 If a region is active, export that region.
 426
 427 A non-nil optional argument ASYNC means the process should happen
 428 asynchronously.  The resulting buffer should be accessible
 429 through the `org-export-stack' interface.
 430
 431 When optional argument SUBTREEP is non-nil, export the sub-tree
 432 at point, extracting information from the headline properties
 433 first.
 434
 435 When optional argument VISIBLE-ONLY is non-nil, don't export
 436 contents of hidden elements.
 437
 438 Export is done in a buffer named \"*Org MD Export*\", which will
 439 be displayed when `org-export-show-temporary-export-buffer' is
 440 non-nil."
 441   (interactive)
 442   (if async
 443       (org-export-async-start
 444           (lambda (output)
 445             (with-current-buffer (get-buffer-create "*Org MD Export*")
 446               (erase-buffer)
 447               (insert output)
 448               (goto-char (point-min))
 449               (text-mode)
 450               (org-export-add-to-stack (current-buffer) 'md)))
 451         `(org-export-as 'md ,subtreep ,visible-only))
 452     (let ((outbuf (org-export-to-buffer
 453                    'md "*Org MD Export*" subtreep visible-only)))
 454       (with-current-buffer outbuf (text-mode))
 455       (when org-export-show-temporary-export-buffer
 456         (switch-to-buffer-other-window outbuf)))))
 457
 458
 459 ;;;###autoload
 460 (defun org-md-export-to-markdown (&optional async subtreep visible-only)
 461   "Export current buffer to a Markdown file.
 462
 463 If narrowing is active in the current buffer, only export its
 464 narrowed part.
 465
 466 If a region is active, export that region.
 467
 468 A non-nil optional argument ASYNC means the process should happen
 469 asynchronously.  The resulting file should be accessible through
 470 the `org-export-stack' interface.
 471
 472 When optional argument SUBTREEP is non-nil, export the sub-tree
 473 at point, extracting information from the headline properties
 474 first.
 475
 476 When optional argument VISIBLE-ONLY is non-nil, don't export
 477 contents of hidden elements.
 478
 479 Return output file's name."
 480   (interactive)
 481   (let ((outfile (org-export-output-file-name ".md" subtreep)))
 482     (if async
 483         (org-export-async-start
 484             (lambda (f) (org-export-add-to-stack f 'md))
 485           `(expand-file-name
 486             (org-export-to-file 'md ,outfile ,subtreep ,visible-only)))
 487       (org-export-to-file 'md outfile subtreep visible-only))))
 488
 489
 490 (provide 'ox-md)
 491
 492 ;; Local variables:
 493 ;; generated-autoload-file: "org-loaddefs.el"
 494 ;; End:
 495
 496 ;;; ox-md.el ends here