lisp/org-bibtex.el

   1 ;;; org-bibtex.el --- Org links to BibTeX entries
   2 ;;
   3 ;; Copyright (C) 2007-2014 Free Software Foundation, Inc.
   4 ;;
   5 ;; Authors: Bastien Guerry <bzg@gnu.org>
   6 ;;       Carsten Dominik <carsten dot dominik at gmail dot com>
   7 ;;       Eric Schulte <schulte dot eric at gmail dot com>
   8 ;; Keywords: org, wp, capture
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;
  25 ;;; Commentary:
  26 ;;
  27 ;; This file implements links to database entries in BibTeX files.
  28 ;; Instead of defining a special link prefix, it uses the normal file
  29 ;; links combined with a custom search mechanism to find entries
  30 ;; by reference key.  And it constructs a nice description tag for
  31 ;; the link that contains the author name, the year and a short title.
  32 ;;
  33 ;; It also stores detailed information about the entry so that
  34 ;; capture templates can access and enter this information easily.
  35 ;;
  36 ;; The available properties for each entry are listed here:
  37 ;;
  38 ;; :author        :publisher      :volume      :pages
  39 ;; :editor        :url            :number      :journal
  40 ;; :title         :year           :series      :address
  41 ;; :booktitle     :month          :annote      :abstract
  42 ;; :key           :btype
  43 ;;
  44 ;; Here is an example of a capture template that use some of this
  45 ;; information (:author :year :title :journal :pages):
  46 ;;
  47 ;; (setq org-capture-templates
  48 ;;   '((?b "* READ %?\n\n%a\n\n%:author (%:year): %:title\n   \
  49 ;;          In %:journal, %:pages.")))
  50 ;;
  51 ;; Let's say you want to capture this BibTeX entry:
  52 ;;
  53 ;; @Article{dolev83,
  54 ;;   author =    {Danny Dolev and Andrew C. Yao},
  55 ;;   title =     {On the security of public-key protocols},
  56 ;;   journal =   {IEEE Transaction on Information Theory},
  57 ;;   year =      1983,
  58 ;;   volume =    2,
  59 ;;   number =    29,
  60 ;;   pages =     {198--208},
  61 ;;   month =     {Mars}
  62 ;; }
  63 ;;
  64 ;; M-x `org-capture' on this entry will produce this buffer:
  65 ;;
  66 ;; =====================================================================
  67 ;; * READ <== [point here]
  68 ;;
  69 ;; [[file:file.bib::dolev83][Dolev & Yao 1983: security of public key protocols]]
  70 ;;
  71 ;; Danny Dolev and Andrew C. Yao (1983): On the security of public-key protocols
  72 ;; In IEEE Transaction on Information Theory, 198--208.
  73 ;; =====================================================================
  74 ;;
  75 ;; Additionally, the following functions are now available for storing
  76 ;; bibtex entries within Org-mode documents.
  77 ;;
  78 ;; - Run `org-bibtex' to export the current file to a .bib.
  79 ;;
  80 ;; - Run `org-bibtex-check' or `org-bibtex-check-all' to check and
  81 ;;   fill in missing field of either the current, or all headlines
  82 ;;
  83 ;; - Run `org-bibtex-create' to add a bibtex entry
  84 ;;
  85 ;; - Use `org-bibtex-read' to read a bibtex entry after `point' or in
  86 ;;   the active region, then call `org-bibtex-write' in a .org file to
  87 ;;   insert a heading for the read bibtex entry
  88 ;;
  89 ;; - All Bibtex information is taken from the document compiled by
  90 ;;   Andrew Roberts from the Bibtex manual, available at
  91 ;;   http://www.andy-roberts.net/res/writing/latex/bibentries.pdf
  92 ;;
  93 ;;; History:
  94 ;;
  95 ;; The link creation part has been part of Org-mode for a long time.
  96 ;;
  97 ;; Creating better capture template information was inspired by a request
  98 ;; of Austin Frank: http://article.gmane.org/gmane.emacs.orgmode/4112
  99 ;; and then implemented by Bastien Guerry.
 100 ;;
 101 ;; Eric Schulte eventually added the functions for translating between
 102 ;; Org-mode headlines and Bibtex entries, and for fleshing out the Bibtex
 103 ;; fields of existing Org-mode headlines.
 104 ;;
 105 ;; Org-mode loads this module by default - if this is not what you want,
 106 ;; configure the variable `org-modules'.
 107
 108 ;;; Code:
 109
 110 (require 'org)
 111 (require 'bibtex)
 112 (eval-when-compile
 113   (require 'cl))
 114 (require 'org-compat)
 115
 116 (defvar org-bibtex-description nil) ; dynamically scoped from org.el
 117 (defvar org-id-locations)
 118
 119 (declare-function bibtex-beginning-of-entry "bibtex" ())
 120 (declare-function bibtex-generate-autokey "bibtex" ())
 121 (declare-function bibtex-parse-entry "bibtex" (&optional content))
 122 (declare-function bibtex-url "bibtex" (&optional pos no-browse))
 123 (declare-function org-babel-trim "ob" (string &optional regexp))
 124
 125 \f
 126 ;;; Bibtex data
 127 (defvar org-bibtex-types
 128   '((:article
 129      (:description . "An article from a journal or magazine")
 130      (:required :author :title :journal :year)
 131      (:optional :volume :number :pages :month :note))
 132     (:book
 133      (:description . "A book with an explicit publisher")
 134      (:required (:editor :author) :title :publisher :year)
 135      (:optional (:volume :number) :series :address :edition :month :note))
 136     (:booklet
 137      (:description . "A work that is printed and bound, but without a named publisher or sponsoring institution.")
 138      (:required :title)
 139      (:optional :author :howpublished :address :month :year :note))
 140     (:conference
 141      (:description . "")
 142      (:required :author :title :booktitle :year)
 143      (:optional :editor :pages :organization :publisher :address :month :note))
 144     (:inbook
 145      (:description . "A part of a book, which may be a chapter (or section or whatever) and/or a range of pages.")
 146      (:required (:author :editor) :title (:chapter :pages) :publisher :year)
 147      (:optional :crossref (:volume :number) :series :type :address :edition :month :note))
 148     (:incollection
 149      (:description . "A part of a book having its own title.")
 150      (:required :author :title :booktitle :publisher :year)
 151      (:optional :crossref :editor (:volume :number) :series :type :chapter :pages :address :edition :month :note))
 152     (:inproceedings
 153      (:description . "An article in a conference proceedings")
 154      (:required :author :title :booktitle :year)
 155      (:optional :crossref :editor (:volume :number) :series :pages :address :month :organization :publisher :note))
 156     (:manual
 157      (:description . "Technical documentation.")
 158      (:required :title)
 159      (:optional :author :organization :address :edition :month :year :note))
 160     (:mastersthesis
 161      (:description . "A Master’s thesis.")
 162      (:required :author :title :school :year)
 163      (:optional :type :address :month :note))
 164     (:misc
 165      (:description . "Use this type when nothing else fits.")
 166      (:required)
 167      (:optional :author :title :howpublished :month :year :note))
 168     (:phdthesis
 169      (:description . "A PhD thesis.")
 170      (:required :author :title :school :year)
 171      (:optional :type :address :month :note))
 172     (:proceedings
 173      (:description . "The proceedings of a conference.")
 174      (:required :title :year)
 175      (:optional :editor (:volume :number) :series :address :month :organization :publisher :note))
 176     (:techreport
 177      (:description . "A report published by a school or other institution.")
 178      (:required :author :title :institution :year)
 179      (:optional :type :address :month :note))
 180     (:unpublished
 181      (:description . "A document having an author and title, but not formally published.")
 182      (:required :author :title :note)
 183      (:optional :month :year)))
 184   "Bibtex entry types with required and optional parameters.")
 185
 186 (defvar org-bibtex-fields
 187   '((:address      . "Usually the address of the publisher or other type of institution.  For major publishing houses, van Leunen recommends omitting the information entirely.  For small publishers, on the other hand, you can help the reader by giving the complete address.")
 188     (:annote       . "An annotation.  It is not used by the standard bibliography styles, but may be used by others that produce an annotated bibliography.")
 189     (:author       . "The name(s) of the author(s), in the format described in the LaTeX book.  Remember, all names are separated with the and keyword, and not commas.")
 190     (:booktitle    . "Title of a book, part of which is being cited.  See the LaTeX book for how to type titles.  For book entries, use the title field instead.")
 191     (:chapter      . "A chapter (or section or whatever) number.")
 192     (:crossref     . "The database key of the entry being cross referenced.")
 193     (:edition      . "The edition of a book for example, 'Second'.  This should be an ordinal, and should have the first letter capitalized, as shown here; the standard styles convert to lower case when necessary.")
 194     (:editor       . "Name(s) of editor(s), typed as indicated in the LaTeX book.  If there is also an author field, then the editor field gives the editor of the book or collection in which the reference appears.")
 195     (:howpublished . "How something strange has been published.  The first word should be capitalized.")
 196     (:institution  . "The sponsoring institution of a technical report.")
 197     (:journal      . "A journal name.")
 198     (:key          . "Used for alphabetizing, cross-referencing, and creating a label when the author information is missing.  This field should not be confused with the key that appears in the \cite command and at the beginning of the database entry.")
 199     (:month        . "The month in which the work was published or, for an unpublished work, in which it was written.  You should use the standard three-letter abbreviation,")
 200     (:note         . "Any additional information that can help the reader.  The first word should be capitalized.")
 201     (:number       . "Any additional information that can help the reader.  The first word should be capitalized.")
 202     (:organization . "The organization that sponsors a conference or that publishes a manual.")
 203     (:pages        . "One or more page numbers or range of numbers, such as 42-111 or 7,41,73-97 or 43+ (the ‘+’ in this last example indicates pages following that don’t form simple range). BibTEX requires double dashes for page ranges (--).")
 204     (:publisher    . "The publisher’s name.")
 205     (:school       . "The name of the school where a thesis was written.")
 206     (:series       . "The name of a series or set of books.  When citing an entire book, the the title field gives its title and an optional series field gives the name of a series or multi-volume set in which the book is published.")
 207     (:title        . "The work’s title, typed as explained in the LaTeX book.")
 208     (:type         . "The type of a technical report for example, 'Research Note'.")
 209     (:volume       . "The volume of a journal or multi-volume book.")
 210     (:year         . "The year of publication or, for an unpublished work, the year it was written.  Generally it should consist of four numerals, such as 1984, although the standard styles can handle any year whose last four nonpunctuation characters are numerals, such as '(about 1984)'"))
 211   "Bibtex fields with descriptions.")
 212
 213 (defvar org-bibtex-entries nil
 214   "List to hold parsed bibtex entries.")
 215
 216 (defcustom org-bibtex-autogen-keys nil
 217   "Set to a truth value to use `bibtex-generate-autokey' to generate keys."
 218   :group 'org-bibtex
 219   :version "24.1"
 220   :type  'boolean)
 221
 222 (defcustom org-bibtex-prefix nil
 223   "Optional prefix for all bibtex property names.
 224 For example setting to 'BIB_' would allow interoperability with fireforg."
 225   :group 'org-bibtex
 226   :version "24.1"
 227   :type  '(choice
 228            (const nil)
 229            (string)))
 230
 231 (defcustom org-bibtex-treat-headline-as-title t
 232   "Treat headline text as title if title property is absent.
 233 If an entry is missing a title property, use the headline text as
 234 the property.  If this value is t, `org-bibtex-check' will ignore
 235 a missing title field."
 236   :group 'org-bibtex
 237   :version "24.1"
 238   :type 'boolean)
 239
 240 (defcustom org-bibtex-export-arbitrary-fields nil
 241   "When converting to bibtex allow fields not defined in `org-bibtex-fields'.
 242 This only has effect if `org-bibtex-prefix' is defined, so as to
 243 ensure that other org-properties, such as CATEGORY or LOGGING are
 244 not placed in the exported bibtex entry."
 245   :group 'org-bibtex
 246   :version "24.1"
 247   :type 'boolean)
 248
 249 (defcustom org-bibtex-key-property "CUSTOM_ID"
 250   "Property that holds the bibtex key.
 251 By default, this is CUSTOM_ID, which enables easy linking to
 252 bibtex headlines from within an org file.  This can be set to ID
 253 to enable global links, but only with great caution, as global
 254 IDs must be unique."
 255   :group 'org-bibtex
 256   :version "24.1"
 257   :type 'string)
 258
 259 (defcustom org-bibtex-tags nil
 260   "List of tag(s) that should be added to new bib entries."
 261   :group 'org-bibtex
 262   :version "24.1"
 263   :type '(repeat  :tag "Tag" (string)))
 264
 265 (defcustom org-bibtex-tags-are-keywords nil
 266   "Convert the value of the keywords field to tags and vice versa.
 267 If set to t, comma-separated entries in a bibtex entry's keywords
 268 field will be converted to org tags.  Note: spaces will be escaped
 269 with underscores, and characters that are not permitted in org
 270 tags will be removed.
 271
 272 If t, local tags in an org entry will be exported as a
 273 comma-separated string of keywords when exported to bibtex.  Tags
 274 defined in `org-bibtex-tags' or `org-bibtex-no-export-tags' will
 275 not be exported."
 276   :group 'org-bibtex
 277   :version "24.1"
 278   :type 'boolean)
 279
 280 (defcustom org-bibtex-no-export-tags nil
 281   "List of tag(s) that should not be converted to keywords.
 282 This variable is relevant only if `org-bibtex-export-tags-as-keywords' is t."
 283   :group 'org-bibtex
 284   :version "24.1"
 285   :type '(repeat :tag "Tag" (string)))
 286
 287 (defcustom org-bibtex-type-property-name "btype"
 288   "Property in which to store bibtex entry type (e.g., article)."
 289   :group 'org-bibtex
 290   :version "24.1"
 291   :type 'string)
 292
 293 \f
 294 ;;; Utility functions
 295 (defun org-bibtex-get (property)
 296   (let ((it (let ((org-special-properties
 297                    (delete "FILE" (copy-sequence org-special-properties))))
 298               (or
 299                (org-entry-get (point) (upcase property))
 300                (org-entry-get (point) (concat org-bibtex-prefix
 301                                               (upcase property)))))))
 302     (when it (org-babel-trim it))))
 303
 304 (defun org-bibtex-put (property value)
 305   (let ((prop (upcase (if (keywordp property)
 306                           (substring (symbol-name property) 1)
 307                         property))))
 308     (org-set-property
 309      (concat (unless (string= org-bibtex-key-property prop) org-bibtex-prefix)
 310              prop)
 311      value)))
 312
 313 (defun org-bibtex-headline ()
 314   "Return a bibtex entry of the given headline as a string."
 315   (let* ((val (lambda (key lst) (cdr (assoc key lst))))
 316          (to (lambda (string) (intern (concat ":" string))))
 317          (from (lambda (key) (substring (symbol-name key) 1)))
 318          flatten ; silent compiler warning
 319          (flatten (lambda (&rest lsts)
 320                     (apply #'append (mapcar
 321                                      (lambda (e)
 322                                        (if (listp e) (apply flatten e) (list e)))
 323                                      lsts))))
 324          (notes (buffer-string))
 325          (id (org-bibtex-get org-bibtex-key-property))
 326          (type (org-bibtex-get org-bibtex-type-property-name))
 327          (tags (when org-bibtex-tags-are-keywords
 328                  (delq nil
 329                        (mapcar
 330                         (lambda (tag)
 331                           (unless (member tag
 332                                           (append org-bibtex-tags
 333                                                   org-bibtex-no-export-tags))
 334                             tag))
 335                         (org-get-local-tags-at))))))
 336     (when type
 337       (let ((entry (format
 338                     "@%s{%s,\n%s\n}\n" type id
 339                     (mapconcat
 340                      (lambda (pair)
 341                        (format "  %s={%s}" (car pair) (cdr pair)))
 342                      (remove nil
 343                              (if (and org-bibtex-export-arbitrary-fields
 344                                       org-bibtex-prefix)
 345                                  (mapcar
 346                                   (lambda (kv)
 347                                     (let ((key (car kv)) (val0 (cdr kv)))
 348                                       (when (and
 349                                              (string-match org-bibtex-prefix key)
 350                                              (not (string=
 351                                                    (downcase (concat org-bibtex-prefix
 352                                                                      org-bibtex-type-property-name))
 353                                                    (downcase key))))
 354                                         (cons (downcase (replace-regexp-in-string
 355                                                          org-bibtex-prefix "" key))
 356                                               val0))))
 357                                   (org-entry-properties nil 'standard))
 358                                (mapcar
 359                                 (lambda (field)
 360                                   (let ((value (or (org-bibtex-get (funcall from field))
 361                                                    (and (equal :title field)
 362                                                         (nth 4 (org-heading-components))))))
 363                                     (when value (cons (funcall from field) value))))
 364                                 (funcall flatten
 365                                          (funcall val :required (funcall val (funcall to type) org-bibtex-types))
 366                                          (funcall val :optional (funcall val (funcall to type) org-bibtex-types))))))
 367                      ",\n"))))
 368         (with-temp-buffer
 369           (insert entry)
 370           (when tags
 371             (bibtex-beginning-of-entry)
 372             (if (re-search-forward "keywords.*=.*{\\(.*\\)}" nil t)
 373                 (progn (goto-char (match-end 1)) (insert ", "))
 374               (bibtex-make-field "keywords" t t))
 375             (insert (mapconcat #'identity tags ", ")))
 376           (buffer-string))))))
 377
 378 (defun org-bibtex-ask (field)
 379   (unless (assoc field org-bibtex-fields)
 380     (error "Field:%s is not known" field))
 381   (save-window-excursion
 382     (let* ((name (substring (symbol-name field) 1))
 383            (buf-name (format "*Bibtex Help %s*" name)))
 384       (with-output-to-temp-buffer buf-name
 385         (princ (cdr (assoc field org-bibtex-fields))))
 386       (with-current-buffer buf-name (visual-line-mode 1))
 387       (org-fit-window-to-buffer (get-buffer-window buf-name))
 388       (let ((result (read-from-minibuffer (format "%s: " name))))
 389         (when (> (length result) 0) result)))))
 390
 391 (defun org-bibtex-autokey ()
 392   "Generate an autokey for the current headline."
 393   (org-bibtex-put org-bibtex-key-property
 394                   (if org-bibtex-autogen-keys
 395                       (let* ((entry (org-bibtex-headline))
 396                              (key
 397                               (with-temp-buffer
 398                                 (insert entry)
 399                                 (bibtex-generate-autokey))))
 400                         ;; test for duplicate IDs if using global ID
 401                         (when (and
 402                                (equal org-bibtex-key-property "ID")
 403                                (featurep 'org-id)
 404                                (hash-table-p org-id-locations)
 405                                (gethash key org-id-locations))
 406                           (warn "Another entry has the same ID"))
 407                         key)
 408                     (read-from-minibuffer "id: "))))
 409
 410 (defun org-bibtex-fleshout (type &optional optional)
 411   "Fleshout current heading, ensuring all required fields are present.
 412 With optional argument OPTIONAL, also prompt for optional fields."
 413   (let ((val (lambda (key lst) (cdr (assoc key lst))))
 414         (keyword (lambda (name) (intern (concat ":" (downcase name)))))
 415         (name (lambda (keyword) (substring (symbol-name keyword) 1))))
 416     (dolist (field (append
 417                     (if org-bibtex-treat-headline-as-title
 418                         (remove :title (funcall val :required (funcall val type org-bibtex-types)))
 419                       (funcall val :required (funcall val type org-bibtex-types)))
 420                     (when optional (funcall val :optional (funcall val type org-bibtex-types)))))
 421       (when (consp field) ; or'd pair of fields e.g., (:editor :author)
 422         (let ((present (first (remove
 423                                nil
 424                                (mapcar
 425                                 (lambda (f) (when (org-bibtex-get (funcall name f)) f))
 426                                 field)))))
 427           (setf field (or present (funcall keyword
 428                                            (org-icompleting-read
 429                                             "Field: " (mapcar name field)))))))
 430       (let ((name (funcall name field)))
 431         (unless (org-bibtex-get name)
 432           (let ((prop (org-bibtex-ask field)))
 433             (when prop (org-bibtex-put name prop)))))))
 434   (when (and type (assoc type org-bibtex-types)
 435              (not (org-bibtex-get org-bibtex-key-property)))
 436     (org-bibtex-autokey)))
 437
 438 \f
 439 ;;; Bibtex link functions
 440 (org-add-link-type "bibtex" 'org-bibtex-open)
 441 (add-hook 'org-store-link-functions 'org-bibtex-store-link)
 442
 443 (defun org-bibtex-open (path)
 444   "Visit the bibliography entry on PATH."
 445   (let* ((search (when (string-match "::\\(.+\\)\\'" path)
 446                    (match-string 1 path)))
 447          (path (substring path 0 (match-beginning 0))))
 448     (org-open-file path t nil search)))
 449
 450 (defun org-bibtex-store-link ()
 451   "Store a link to a BibTeX entry."
 452   (when (eq major-mode 'bibtex-mode)
 453     (let* ((search (org-create-file-search-in-bibtex))
 454            (link (concat "file:" (abbreviate-file-name buffer-file-name)
 455                          "::" search))
 456            (entry (mapcar ; repair strings enclosed in "..." or {...}
 457                    (lambda(c)
 458                      (if (string-match
 459                           "^\\(?:{\\|\"\\)\\(.*\\)\\(?:}\\|\"\\)$" (cdr c))
 460                          (cons (car c) (match-string 1 (cdr c))) c))
 461                    (save-excursion
 462                      (bibtex-beginning-of-entry)
 463                      (bibtex-parse-entry)))))
 464       (org-store-link-props
 465        :key (cdr (assoc "=key=" entry))
 466        :author (or (cdr (assoc "author" entry)) "[no author]")
 467        :editor (or (cdr (assoc "editor" entry)) "[no editor]")
 468        :title (or (cdr (assoc "title" entry)) "[no title]")
 469        :booktitle (or (cdr (assoc "booktitle" entry)) "[no booktitle]")
 470        :journal (or (cdr (assoc "journal" entry)) "[no journal]")
 471        :publisher (or (cdr (assoc "publisher" entry)) "[no publisher]")
 472        :pages (or (cdr (assoc "pages" entry)) "[no pages]")
 473        :url (or (cdr (assoc "url" entry)) "[no url]")
 474        :year (or (cdr (assoc "year" entry)) "[no year]")
 475        :month (or (cdr (assoc "month" entry)) "[no month]")
 476        :address (or (cdr (assoc "address" entry)) "[no address]")
 477        :volume (or (cdr (assoc "volume" entry)) "[no volume]")
 478        :number (or (cdr (assoc "number" entry)) "[no number]")
 479        :annote (or (cdr (assoc "annote" entry)) "[no annotation]")
 480        :series (or (cdr (assoc "series" entry)) "[no series]")
 481        :abstract (or (cdr (assoc "abstract" entry)) "[no abstract]")
 482        :btype (or (cdr (assoc "=type=" entry)) "[no type]")
 483        :type "bibtex"
 484        :link link
 485        :description org-bibtex-description))))
 486
 487 (defun org-create-file-search-in-bibtex ()
 488   "Create the search string and description for a BibTeX database entry."
 489   ;; Make a good description for this entry, using names, year and the title
 490   ;; Put it into the `description' variable which is dynamically scoped.
 491   (let ((bibtex-autokey-names 1)
 492         (bibtex-autokey-names-stretch 1)
 493         (bibtex-autokey-name-case-convert-function 'identity)
 494         (bibtex-autokey-name-separator " & ")
 495         (bibtex-autokey-additional-names " et al.")
 496         (bibtex-autokey-year-length 4)
 497         (bibtex-autokey-name-year-separator " ")
 498         (bibtex-autokey-titlewords 3)
 499         (bibtex-autokey-titleword-separator " ")
 500         (bibtex-autokey-titleword-case-convert-function 'identity)
 501         (bibtex-autokey-titleword-length 'infty)
 502         (bibtex-autokey-year-title-separator ": "))
 503     (setq org-bibtex-description (bibtex-generate-autokey)))
 504   ;; Now parse the entry, get the key and return it.
 505   (save-excursion
 506     (bibtex-beginning-of-entry)
 507     (cdr (assoc "=key=" (bibtex-parse-entry)))))
 508
 509 (defun org-execute-file-search-in-bibtex (s)
 510   "Find the link search string S as a key for a database entry."
 511   (when (eq major-mode 'bibtex-mode)
 512     ;; Yes, we want to do the search in this file.
 513     ;; We construct a regexp that searches for "@entrytype{" followed by the key
 514     (goto-char (point-min))
 515     (and (re-search-forward (concat "@[a-zA-Z]+[ \t\n]*{[ \t\n]*"
 516                                     (regexp-quote s) "[ \t\n]*,") nil t)
 517          (goto-char (match-beginning 0)))
 518     (if (and (match-beginning 0) (equal current-prefix-arg '(16)))
 519         ;; Use double prefix to indicate that any web link should be browsed
 520         (let ((b (current-buffer)) (p (point)))
 521           ;; Restore the window configuration because we just use the web link
 522           (set-window-configuration org-window-config-before-follow-link)
 523           (with-current-buffer b
 524             (goto-char p)
 525             (bibtex-url)))
 526       (recenter 0))  ; Move entry start to beginning of window
 527     ;; return t to indicate that the search is done.
 528     t))
 529
 530 ;; Finally add the link search function to the right hook.
 531 (add-hook 'org-execute-file-search-functions 'org-execute-file-search-in-bibtex)
 532
 533 \f
 534 ;;; Bibtex <-> Org-mode headline translation functions
 535 (defun org-bibtex (&optional filename)
 536   "Export each headline in the current file to a bibtex entry.
 537 Headlines are exported using `org-bibtex-export-headline'."
 538   (interactive
 539    (list (read-file-name
 540           "Bibtex file: " nil nil nil
 541           (file-name-nondirectory
 542            (concat (file-name-sans-extension (buffer-file-name)) ".bib")))))
 543   (let ((error-point
 544          (catch 'bib
 545            (let ((bibtex-entries
 546                   (remove nil (org-map-entries
 547                                (lambda ()
 548                                  (condition-case foo
 549                                      (org-bibtex-headline)
 550                                    (error (throw 'bib (point)))))))))
 551              (with-temp-file filename
 552                (insert (mapconcat #'identity bibtex-entries "\n")))
 553              (message "Successfully exported %d BibTeX entries to %s"
 554                       (length bibtex-entries) filename) nil))))
 555     (when error-point
 556       (goto-char error-point)
 557       (message "Bibtex error at %S" (nth 4 (org-heading-components))))))
 558
 559 (defun org-bibtex-check (&optional optional)
 560   "Check the current headline for required fields.
 561 With prefix argument OPTIONAL also prompt for optional fields."
 562   (interactive "P")
 563   (save-restriction
 564     (org-narrow-to-subtree)
 565     (let ((type (let ((name (org-bibtex-get org-bibtex-type-property-name)))
 566                   (when name (intern (concat ":" name))))))
 567       (when type (org-bibtex-fleshout type optional)))))
 568
 569 (defun org-bibtex-check-all (&optional optional)
 570   "Check all headlines in the current file.
 571 With prefix argument OPTIONAL also prompt for optional fields."
 572   (interactive) (org-map-entries (lambda () (org-bibtex-check optional))))
 573
 574 (defun org-bibtex-create (&optional arg nonew)
 575   "Create a new entry at the given level.
 576 With a prefix arg, query for optional fields as well.
 577 If nonew is t, add data to the headline of the entry at point."
 578   (interactive "P")
 579   (let* ((type (org-icompleting-read
 580                 "Type: " (mapcar (lambda (type)
 581                                    (substring (symbol-name (car type)) 1))
 582                                  org-bibtex-types)
 583                 nil nil (when nonew
 584                           (org-bibtex-get org-bibtex-type-property-name))))
 585          (type (if (keywordp type) type (intern (concat ":" type))))
 586          (org-bibtex-treat-headline-as-title (if nonew nil t)))
 587     (unless (assoc type org-bibtex-types)
 588       (error "Type:%s is not known" type))
 589     (if nonew
 590         (org-back-to-heading)
 591       (org-insert-heading)
 592       (let ((title (org-bibtex-ask :title)))
 593         (insert title)
 594         (org-bibtex-put "TITLE" title)))
 595     (org-bibtex-put org-bibtex-type-property-name
 596                     (substring (symbol-name type) 1))
 597     (org-bibtex-fleshout type arg)
 598     (mapc (lambda (tag) (org-toggle-tag tag 'on)) org-bibtex-tags)))
 599
 600 (defun org-bibtex-create-in-current-entry (&optional arg)
 601   "Add bibliographical data to the current entry.
 602 With a prefix arg, query for optional fields."
 603   (interactive "P")
 604   (org-bibtex-create arg t))
 605
 606 (defun org-bibtex-read ()
 607   "Read a bibtex entry and save to `org-bibtex-entries'.
 608 This uses `bibtex-parse-entry'."
 609   (interactive)
 610   (let ((keyword (lambda (str) (intern (concat ":" (downcase str)))))
 611         (clean-space (lambda (str) (replace-regexp-in-string
 612                                     "[[:space:]\n\r]+" " " str)))
 613         (strip-delim
 614          (lambda (str)       ; strip enclosing "..." and {...}
 615            (dolist (pair '((34 . 34) (123 . 125) (123 . 125)))
 616              (when (and (= (aref str 0) (car pair))
 617                         (= (aref str (1- (length str))) (cdr pair)))
 618                (setf str (substring str 1 (1- (length str)))))) str)))
 619     (push (mapcar
 620            (lambda (pair)
 621              (cons (let ((field (funcall keyword (car pair))))
 622                      (case field
 623                        (:=type= :type)
 624                        (:=key= :key)
 625                        (otherwise field)))
 626                    (funcall clean-space (funcall strip-delim (cdr pair)))))
 627            (save-excursion (bibtex-beginning-of-entry) (bibtex-parse-entry)))
 628           org-bibtex-entries)))
 629
 630 (defun org-bibtex-read-buffer (buffer)
 631   "Read all bibtex entries in BUFFER and save to `org-bibtex-entries'.
 632 Return the number of saved entries."
 633   (interactive "bbuffer: ")
 634   (let ((start-length (length org-bibtex-entries)))
 635     (with-current-buffer buffer
 636       (save-excursion
 637         (goto-char (point-max))
 638         (while (not (= (point) (point-min)))
 639           (backward-char 1)
 640           (org-bibtex-read)
 641           (bibtex-beginning-of-entry))))
 642     (let ((added (- (length org-bibtex-entries) start-length)))
 643       (message "parsed %d entries" added)
 644       added)))
 645
 646 (defun org-bibtex-read-file (file)
 647   "Read FILE with `org-bibtex-read-buffer'."
 648   (interactive "ffile: ")
 649   (org-bibtex-read-buffer (find-file-noselect file 'nowarn 'rawfile)))
 650
 651 (defun org-bibtex-write ()
 652   "Insert a heading built from the first element of `org-bibtex-entries'."
 653   (interactive)
 654   (when (= (length org-bibtex-entries) 0)
 655     (error "No entries in `org-bibtex-entries'"))
 656   (let* ((entry (pop org-bibtex-entries))
 657          (org-special-properties nil) ; avoids errors with `org-entry-put'
 658          (val (lambda (field) (cdr (assoc field entry))))
 659          (togtag (lambda (tag) (org-toggle-tag tag 'on))))
 660     (org-insert-heading)
 661     (insert (funcall val :title))
 662     (org-bibtex-put "TITLE" (funcall val :title))
 663     (org-bibtex-put org-bibtex-type-property-name
 664                     (downcase (funcall val :type)))
 665     (dolist (pair entry)
 666       (case (car pair)
 667         (:title    nil)
 668         (:type     nil)
 669         (:key      (org-bibtex-put org-bibtex-key-property (cdr pair)))
 670         (:keywords (if org-bibtex-tags-are-keywords
 671                        (mapc
 672                         (lambda (kw)
 673                           (funcall
 674                            togtag
 675                            (replace-regexp-in-string
 676                             "[^[:alnum:]_@#%]" ""
 677                             (replace-regexp-in-string "[ \t]+" "_" kw))))
 678                         (split-string (cdr pair) ", *"))
 679                      (org-bibtex-put (car pair) (cdr pair))))
 680         (otherwise (org-bibtex-put (car pair)  (cdr pair)))))
 681     (mapc togtag org-bibtex-tags)))
 682
 683 (defun org-bibtex-yank ()
 684   "If kill ring holds a bibtex entry yank it as an Org-mode headline."
 685   (interactive)
 686   (let (entry)
 687     (with-temp-buffer (yank 1) (setf entry (org-bibtex-read)))
 688     (if entry
 689         (org-bibtex-write)
 690       (error "Yanked text does not appear to contain a BibTeX entry"))))
 691
 692 (defun org-bibtex-import-from-file (file)
 693   "Read bibtex entries from FILE and insert as Org-mode headlines after point."
 694   (interactive "ffile: ")
 695   (dotimes (_ (org-bibtex-read-file file))
 696     (save-excursion (org-bibtex-write))
 697     (re-search-forward org-property-end-re)
 698     (open-line 1) (forward-char 1)))
 699
 700 (defun org-bibtex-export-to-kill-ring ()
 701   "Export current headline to kill ring as bibtex entry."
 702   (interactive)
 703   (let ((result (org-bibtex-headline)))
 704     (kill-new result) result))
 705
 706 (defun org-bibtex-search (string)
 707   "Search for bibliographical entries in agenda files.
 708 This function relies `org-search-view' to locate results."
 709   (interactive "sSearch string: ")
 710   (let ((org-agenda-overriding-header "Bib search results:")
 711         (org-agenda-search-view-always-boolean t))
 712     (org-search-view nil
 713                      (format "%s +{:%s%s:}"
 714                              string (or org-bibtex-prefix "")
 715                              org-bibtex-type-property-name))))
 716
 717 (provide 'org-bibtex)
 718
 719 ;;; org-bibtex.el ends here