lisp/org-irc.el

   1 ;;; org-irc.el --- Store links to IRC sessions
   2 ;;
   3 ;; Copyright (C) 2008-2014 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Philip Jackson <emacs@shellarchive.co.uk>
   6 ;; Keywords: erc, irc, link, org
   7 ;;
   8 ;; This file is part of GNU Emacs.
   9 ;;
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This file implements links to an IRC session from within Org-mode.
  26 ;; Org-mode loads this module by default - if this is not what you want,
  27 ;; configure the variable `org-modules'.
  28 ;;
  29 ;; Please customize the variable `org-modules' to select
  30 ;; extensions you would like to use, and to deselect those which you don't
  31 ;; want.
  32 ;;
  33 ;; Please note that at the moment only ERC is supported.  Other clients
  34 ;; shouldn't be difficult to add though.
  35 ;;
  36 ;; Then set `org-irc-link-to-logs' to non-nil if you would like a
  37 ;; file:/ type link to be created to the current line in the logs or
  38 ;; to t if you would like to create an irc:/ style link.
  39 ;;
  40 ;; Links within an org buffer might look like this:
  41 ;;
  42 ;; [[irc:/irc.freenode.net/#emacs/bob][chat with bob in #emacs on freenode]]
  43 ;; [[irc:/irc.freenode.net/#emacs][#emacs on freenode]]
  44 ;; [[irc:/irc.freenode.net/]]
  45 ;;
  46 ;; If, when the resulting link is visited, there is no connection to a
  47 ;; requested server then one will be created.
  48
  49 ;;; Code:
  50
  51 (require 'org)
  52
  53 ;; Declare the function form ERC that we use.
  54 (declare-function erc-current-logfile "erc-log" (&optional buffer))
  55 (declare-function erc-prompt "erc" ())
  56 (declare-function erc-default-target "erc" ())
  57 (declare-function erc-channel-p "erc" (channel))
  58 (declare-function erc-buffer-filter "erc" (predicate &optional proc))
  59 (declare-function erc-server-buffer "erc" ())
  60 (declare-function erc-get-server-nickname-list "erc" ())
  61 (declare-function erc-cmd-JOIN "erc" (channel &optional key))
  62 (declare-function org-pop-to-buffer-same-window
  63                   "org-compat" (&optional buffer-or-name norecord label))
  64
  65 (defvar org-irc-client 'erc
  66   "The IRC client to act on.")
  67 (defvar org-irc-link-to-logs nil
  68   "Non-nil will store a link to the logs, nil will store an irc: style link.")
  69
  70 (defvar erc-default-port)   ; dynamically scoped from erc.el
  71 (defvar erc-session-port)   ; dynamically scoped form erc-backend.el
  72 (defvar erc-session-server) ; dynamically scoped form erc-backend.el
  73
  74 ;; Generic functions/config (extend these for other clients)
  75
  76 (add-to-list 'org-store-link-functions 'org-irc-store-link)
  77
  78 (org-add-link-type "irc" 'org-irc-visit nil)
  79
  80 (defun org-irc-visit (link)
  81   "Parse LINK and dispatch to the correct function based on the client found."
  82   (let ((link (org-irc-parse-link link)))
  83     (cond
  84      ((eq org-irc-client 'erc)
  85       (org-irc-visit-erc link))
  86      (t
  87       (error "ERC only known client")))))
  88
  89 (defun org-irc-parse-link (link)
  90   "Parse an IRC LINK and return the attributes found.
  91 Parse a LINK that looks like server:port/chan/user (port, chan
  92 and user being optional) and return any of the port, channel or user
  93 attributes that are found."
  94   (let* ((parts (split-string link "/" t))
  95          (len (length parts)))
  96     (when (or (< len 1) (> len 3))
  97       (error "Failed to parse link needed 1-3 parts, got %d" len))
  98     (setcar parts (split-string (car parts) ":" t))
  99     parts))
 100
 101 ;;;###autoload
 102 (defun org-irc-store-link ()
 103   "Dispatch to the appropriate function to store a link to an IRC session."
 104   (cond
 105    ((eq major-mode 'erc-mode)
 106     (org-irc-erc-store-link))))
 107
 108 (defun org-irc-ellipsify-description (string &optional after)
 109   "Remove unnecessary white space from STRING and add ellipses if necessary.
 110 Strip starting and ending white space from STRING and replace any
 111 chars that the value AFTER with '...'"
 112   (let* ((after (number-to-string (or after 30)))
 113          (replace-map (list (cons "^[ \t]*" "")
 114                             (cons "[ \t]*$" "")
 115                             (cons (concat "^\\(.\\{" after
 116                                           "\\}\\).*") "\\1..."))))
 117     (mapc (lambda (x)
 118             (when (string-match (car x) string)
 119               (setq string (replace-match (cdr x) nil nil string))))
 120           replace-map)
 121     string))
 122
 123 ;; ERC specific functions
 124
 125 (defun org-irc-erc-get-line-from-log (erc-line)
 126   "Find the best line to link to from the ERC logs given ERC-LINE as a start.
 127 If the user is on the ERC-prompt then search backward for the
 128 first non-blank line, otherwise return the current line.  The
 129 result is a cons of the filename and search string."
 130   (erc-save-buffer-in-logs)
 131   (require 'erc-log)
 132   (with-current-buffer (find-file-noselect (erc-current-logfile))
 133     (goto-char (point-max))
 134     (list
 135      (abbreviate-file-name buffer-file-name)
 136      ;; can we get a '::' part?
 137      (if (string= erc-line (erc-prompt))
 138          (progn
 139            (goto-char (point-at-bol))
 140            (when (search-backward-regexp "^[^   ]" nil t)
 141              (buffer-substring-no-properties (point-at-bol)
 142                                              (point-at-eol))))
 143        (when (search-backward erc-line nil t)
 144          (buffer-substring-no-properties (point-at-bol)
 145                                          (point-at-eol)))))))
 146
 147 (defun org-irc-erc-store-link ()
 148   "Store a link to the IRC log file or the session itself.
 149 Depending on the variable `org-irc-link-to-logs' store either a
 150 link to the log file for the current session or an irc: link to
 151 the session itself."
 152   (require 'erc-log)
 153   (if org-irc-link-to-logs
 154       (let* ((erc-line (buffer-substring-no-properties
 155                         (point-at-bol) (point-at-eol)))
 156              (parsed-line (org-irc-erc-get-line-from-log erc-line)))
 157         (if (erc-logging-enabled nil)
 158             (progn
 159               (org-store-link-props
 160                :type "file"
 161                :description (concat "'" (org-irc-ellipsify-description
 162                                          (cadr parsed-line) 20)
 163                                     "' from an IRC conversation")
 164                :link (concat "file:" (car parsed-line) "::"
 165                              (cadr parsed-line)))
 166               t)
 167           (error "This ERC session is not being logged")))
 168     (let* ((link-text (org-irc-get-erc-link))
 169            (link (org-irc-parse-link link-text)))
 170       (if link-text
 171           (progn
 172             (org-store-link-props
 173              :type "irc"
 174              :link (concat "irc:/" link-text)
 175              :description (concat "irc session '" link-text "'")
 176              :server (car (car link))
 177              :port (or (string-to-number (cadr (pop link))) erc-default-port)
 178              :nick (pop link))
 179             t)
 180         (error "Failed to create ('irc:/' style) ERC link")))))
 181
 182 (defun org-irc-get-erc-link ()
 183   "Return an org compatible irc:/ link from an ERC buffer."
 184   (let* ((session-port (if (numberp erc-session-port)
 185                            (number-to-string erc-session-port)
 186                          erc-session-port))
 187          (link (concat erc-session-server ":" session-port)))
 188     (concat link "/"
 189             (if (and (erc-default-target)
 190                      (erc-channel-p (erc-default-target))
 191                      (car (get-text-property (point) 'erc-data)))
 192                 ;; we can get a nick
 193                 (let ((nick (car (get-text-property (point) 'erc-data))))
 194                   (concat (erc-default-target) "/" nick))
 195               (erc-default-target)))))
 196
 197 (defun org-irc-get-current-erc-port ()
 198   "Return the current port as a number.
 199 Return the current port number or, if none is set, return the ERC
 200 default."
 201   (cond
 202    ((stringp erc-session-port)
 203     (string-to-number erc-session-port))
 204    ((numberp erc-session-port)
 205     erc-session-port)
 206    (t
 207     erc-default-port)))
 208
 209 (defun org-irc-visit-erc (link)
 210   "Visit an ERC buffer based on criteria found in LINK."
 211   (require 'erc)
 212   (require 'erc-log)
 213   (let* ((server (car (car link)))
 214          (port (or (string-to-number (cadr (pop link))) erc-default-port))
 215          (server-buffer)
 216          (buffer-list
 217           (erc-buffer-filter
 218            (lambda nil
 219              (let ((tmp-server-buf (erc-server-buffer)))
 220                (and tmp-server-buf
 221                     (with-current-buffer tmp-server-buf
 222                       (and
 223                        (eq (org-irc-get-current-erc-port) port)
 224                        (string= erc-session-server server)
 225                        (setq server-buffer tmp-server-buf)))))))))
 226     (if buffer-list
 227         (let ((chan-name (pop link)))
 228           ;; if we got a channel name then switch to it or join it
 229           (if chan-name
 230               (let ((chan-buf (catch 'found
 231                                 (dolist (x buffer-list)
 232                                   (if (string= (buffer-name x) chan-name)
 233                                       (throw 'found x))))))
 234                 (if chan-buf
 235                     (progn
 236                       (org-pop-to-buffer-same-window chan-buf)
 237                       ;; if we got a nick, and they're in the chan,
 238                       ;; then start a chat with them
 239                       (let ((nick (pop link)))
 240                         (when nick
 241                           (if (member nick (erc-get-server-nickname-list))
 242                               (progn
 243                                 (goto-char (point-max))
 244                                 (insert (concat nick ": ")))
 245                             (error "%s not found in %s" nick chan-name)))))
 246                   (progn
 247                     (org-pop-to-buffer-same-window server-buffer)
 248                     (erc-cmd-JOIN chan-name))))
 249             (org-pop-to-buffer-same-window server-buffer)))
 250       ;; no server match, make new connection
 251       (erc-select :server server :port port))))
 252
 253 (provide 'org-irc)
 254
 255 ;; Local variables:
 256 ;; generated-autoload-file: "org-loaddefs.el"
 257 ;; End:
 258
 259 ;;; org-irc.el ends here