lisp/ob-ref.el

   1 ;;; ob-ref.el --- org-babel functions for referencing external data
   2
   3 ;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
   4
   5 ;; Authors: Eric Schulte
   6 ;;       Dan Davison
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Functions for referencing data from the header arguments of a
  28 ;; org-babel block.  The syntax of such a reference should be
  29
  30 ;;   #+VAR: variable-name=file:resource-id
  31
  32 ;; - variable-name :: the name of the variable to which the value
  33 ;;                    will be assigned
  34
  35 ;; - file :: path to the file containing the resource, or omitted if
  36 ;;           resource is in the current file
  37
  38 ;; - resource-id :: the id or name of the resource
  39
  40 ;; So an example of a simple src block referencing table data in the
  41 ;; same file would be
  42
  43 ;;  #+NAME: sandbox
  44 ;;  | 1 |         2 | 3 |
  45 ;;  | 4 | org-babel | 6 |
  46 ;;
  47 ;;  #+begin_src emacs-lisp :var table=sandbox
  48 ;;    (message table)
  49 ;;  #+end_src
  50
  51 ;;; Code:
  52 (require 'ob-core)
  53 (eval-when-compile
  54   (require 'cl))
  55
  56 (declare-function org-remove-if-not "org" (predicate seq))
  57 (declare-function org-at-table-p "org" (&optional table-type))
  58 (declare-function org-count "org" (CL-ITEM CL-SEQ))
  59 (declare-function org-at-item-p "org-list" ())
  60 (declare-function org-narrow-to-subtree "org" ())
  61 (declare-function org-id-find-id-in-file "org-id" (id file &optional markerp))
  62 (declare-function org-id-find-id-file "org-id" (id))
  63 (declare-function org-show-context "org" (&optional key))
  64 (declare-function org-pop-to-buffer-same-window
  65                   "org-compat" (&optional buffer-or-name norecord label))
  66
  67 (defvar org-babel-ref-split-regexp
  68   "[ \f\t\n\r\v]*\\(.+?\\)[ \f\t\n\r\v]*=[ \f\t\n\r\v]*\\(.+\\)[ \f\t\n\r\v]*")
  69
  70 (defvar org-babel-update-intermediate nil
  71   "Update the in-buffer results of code blocks executed to resolve references.")
  72
  73 (defun org-babel-ref-parse (assignment)
  74   "Parse a variable ASSIGNMENT in a header argument.
  75 If the right hand side of the assignment has a literal value
  76 return that value, otherwise interpret as a reference to an
  77 external resource and find its value using
  78 `org-babel-ref-resolve'.  Return a list with two elements.  The
  79 first element of the list will be the name of the variable, and
  80 the second will be an emacs-lisp representation of the value of
  81 the variable."
  82   (when (string-match org-babel-ref-split-regexp assignment)
  83     (let ((var (match-string 1 assignment))
  84           (ref (match-string 2 assignment)))
  85       (cons (intern var)
  86             (let ((out (save-excursion
  87                          (when org-babel-current-src-block-location
  88                            (goto-char (if (markerp org-babel-current-src-block-location)
  89                                           (marker-position org-babel-current-src-block-location)
  90                                         org-babel-current-src-block-location)))
  91                          (org-babel-read ref))))
  92               (if (equal out ref)
  93                   (if (string-match "^\".*\"$" ref)
  94                       (read ref)
  95                     (org-babel-ref-resolve ref))
  96                 out))))))
  97
  98 (defun org-babel-ref-goto-headline-id (id)
  99   (goto-char (point-min))
 100   (let ((rx (regexp-quote id)))
 101     (or (re-search-forward
 102          (concat "^[ \t]*:CUSTOM_ID:[ \t]+" rx "[ \t]*$") nil t)
 103         (let* ((file (org-id-find-id-file id))
 104                (m (when file (org-id-find-id-in-file id file 'marker))))
 105           (when (and file m)
 106             (message "file:%S" file)
 107             (org-pop-to-buffer-same-window (marker-buffer m))
 108             (goto-char m)
 109             (move-marker m nil)
 110             (org-show-context)
 111             t)))))
 112
 113 (defun org-babel-ref-headline-body ()
 114   (save-restriction
 115     (org-narrow-to-subtree)
 116     (buffer-substring
 117      (save-excursion (goto-char (point-min))
 118                      (forward-line 1)
 119                      (when (looking-at "[ \t]*:PROPERTIES:")
 120                        (re-search-forward ":END:" nil)
 121                        (forward-char))
 122                      (point))
 123      (point-max))))
 124
 125 (defvar org-babel-library-of-babel)
 126 (defun org-babel-ref-resolve (ref)
 127   "Resolve the reference REF and return its value."
 128   (save-window-excursion
 129     (save-excursion
 130       (let ((case-fold-search t)
 131             type args new-refere new-header-args new-referent result
 132             lob-info split-file split-ref index index-row index-col id)
 133         ;; if ref is indexed grab the indices -- beware nested indices
 134         (when (and (string-match "\\[\\([^\\[]+\\)\\]$" ref)
 135                    (let ((str (substring ref 0 (match-beginning 0))))
 136                      (= (org-count ?( str) (org-count ?) str))))
 137           (setq index (match-string 1 ref))
 138           (setq ref (substring ref 0 (match-beginning 0))))
 139         ;; assign any arguments to pass to source block
 140         (when (string-match
 141                "^\\(.+?\\)\\(\\[\\(.*\\)\\]\\|\\(\\)\\)\(\\(.*\\)\)$" ref)
 142           (setq new-refere      (match-string 1 ref))
 143           (setq new-header-args (match-string 3 ref))
 144           (setq new-referent    (match-string 5 ref))
 145           (when (> (length new-refere) 0)
 146             (when (> (length new-referent) 0)
 147               (setq args (mapcar (lambda (ref) (cons :var ref))
 148                                  (org-babel-ref-split-args new-referent))))
 149             (when (> (length new-header-args) 0)
 150               (setq args (append (org-babel-parse-header-arguments
 151                                   new-header-args) args)))
 152             (setq ref new-refere)))
 153         (when (string-match "^\\(.+\\):\\(.+\\)$" ref)
 154           (setq split-file (match-string 1 ref))
 155           (setq split-ref (match-string 2 ref))
 156           (find-file split-file) (setq ref split-ref))
 157         (save-restriction
 158           (widen)
 159           (goto-char (point-min))
 160           (if (let ((src-rx (org-babel-named-src-block-regexp-for-name ref))
 161                     (res-rx (org-babel-named-data-regexp-for-name ref)))
 162                 ;; goto ref in the current buffer
 163                 (or
 164                  ;; check for code blocks
 165                  (re-search-forward src-rx nil t)
 166                  ;; check for named data
 167                  (re-search-forward res-rx nil t)
 168                  ;; check for local or global headlines by id
 169                  (setq id (org-babel-ref-goto-headline-id ref))
 170                  ;; check the Library of Babel
 171                  (setq lob-info (cdr (assoc (intern ref)
 172                                             org-babel-library-of-babel)))))
 173               (unless (or lob-info id) (goto-char (match-beginning 0)))
 174             ;; ;; TODO: allow searching for names in other buffers
 175             ;; (setq id-loc (org-id-find ref 'marker)
 176             ;;       buffer (marker-buffer id-loc)
 177             ;;       loc (marker-position id-loc))
 178             ;; (move-marker id-loc nil)
 179             (error "Reference '%s' not found in this buffer" ref))
 180           (cond
 181            (lob-info (setq type 'lob))
 182            (id (setq type 'id))
 183            ((and (looking-at org-babel-src-name-regexp)
 184                  (save-excursion
 185                    (forward-line 1)
 186                    (or (looking-at org-babel-src-block-regexp)
 187                        (looking-at org-babel-multi-line-header-regexp))))
 188             (setq type 'source-block))
 189            (t (while (not (setq type (org-babel-ref-at-ref-p)))
 190                 (forward-line 1)
 191                 (beginning-of-line)
 192                 (if (or (= (point) (point-min)) (= (point) (point-max)))
 193                     (error "Reference not found")))))
 194           (let ((params (append args '((:results . "silent")))))
 195             (setq result
 196                   (case type
 197                     (results-line (org-babel-read-result))
 198                     (table        (org-babel-read-table))
 199                     (list         (org-babel-read-list))
 200                     (file         (org-babel-read-link))
 201                     (source-block (org-babel-execute-src-block
 202                                    nil nil (if org-babel-update-intermediate
 203                                                nil params)))
 204                     (lob          (org-babel-execute-src-block
 205                                    nil lob-info params))
 206                     (id           (org-babel-ref-headline-body)))))
 207           (if (symbolp result)
 208               (format "%S" result)
 209             (if (and index (listp result))
 210                 (org-babel-ref-index-list index result)
 211               result)))))))
 212
 213 (defun org-babel-ref-index-list (index lis)
 214   "Return the subset of LIS indexed by INDEX.
 215
 216 Indices are 0 based and negative indices count from the end of
 217 LIS, so 0 references the first element of LIS and -1 references
 218 the last.  If INDEX is separated by \",\"s then each \"portion\"
 219 is assumed to index into the next deepest nesting or dimension.
 220
 221 A valid \"portion\" can consist of either an integer index, two
 222 integers separated by a \":\" in which case the entire range is
 223 returned, or an empty string or \"*\" both of which are
 224 interpreted to mean the entire range and as such are equivalent
 225 to \"0:-1\"."
 226   (if (and (> (length index) 0) (string-match "^\\([^,]*\\),?" index))
 227       (let* ((ind-re "\\(\\([-[:digit:]]+\\):\\([-[:digit:]]+\\)\\|\*\\)")
 228              (lgth (length lis))
 229              (portion (match-string 1 index))
 230              (remainder (substring index (match-end 0)))
 231              (wrap (lambda (num) (if (< num 0) (+ lgth num) num)))
 232              (open (lambda (ls) (if (and (listp ls) (= (length ls) 1)) (car ls) ls))))
 233         (funcall
 234          open
 235          (mapcar
 236           (lambda (sub-lis)
 237             (if (listp sub-lis)
 238                 (org-babel-ref-index-list remainder sub-lis)
 239               sub-lis))
 240           (if (or (= 0 (length portion)) (string-match ind-re portion))
 241               (mapcar
 242                (lambda (n) (nth n lis))
 243                (apply 'org-number-sequence
 244                       (if (and (> (length portion) 0) (match-string 2 portion))
 245                           (list
 246                            (funcall wrap (string-to-number (match-string 2 portion)))
 247                            (funcall wrap (string-to-number (match-string 3 portion))))
 248                         (list (funcall wrap 0) (funcall wrap -1)))))
 249             (list (nth (funcall wrap (string-to-number portion)) lis))))))
 250     lis))
 251
 252 (defun org-babel-ref-split-args (arg-string)
 253   "Split ARG-STRING into top-level arguments of balanced parenthesis."
 254   (mapcar #'org-babel-trim (org-babel-balanced-split arg-string 44)))
 255
 256 (defvar org-bracket-link-regexp)
 257 (defun org-babel-ref-at-ref-p ()
 258   "Return the type of reference located at point.
 259 Return nil if none of the supported reference types are found.
 260 Supported reference types are tables and source blocks."
 261   (cond ((org-at-table-p) 'table)
 262         ((org-at-item-p) 'list)
 263         ((looking-at "^[ \t]*#\\+BEGIN_SRC") 'source-block)
 264         ((looking-at org-bracket-link-regexp) 'file)
 265         ((looking-at org-babel-result-regexp) 'results-line)))
 266
 267 (provide 'ob-ref)
 268
 269
 270
 271 ;;; ob-ref.el ends here