lisp/org-bbdb.el

   1 ;;; org-bbdb.el --- Support for links to BBDB entries from within Org-mode
   2
   3 ;; Copyright (C) 2004-2012  Free Software Foundation, Inc.
   4
   5 ;; Authors: Carsten Dominik <carsten at orgmode dot org>
   6 ;;       Thomas Baumann <thomas dot baumann at ch dot tum dot de>
   7 ;; Keywords: outlines, hypermedia, calendar, wp
   8 ;; Homepage: http://orgmode.org
   9 ;;
  10 ;; This file is part of GNU Emacs.
  11 ;;
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  25 ;;
  26 ;;; Commentary:
  27
  28 ;; This file implements links to BBDB database entries from within Org-mode.
  29 ;; Org-mode loads this module by default - if this is not what you want,
  30 ;; configure the variable `org-modules'.
  31
  32 ;; It also implements an interface (based on Ivar Rummelhoff's
  33 ;; bbdb-anniv.el) for those org-mode users, who do not use the diary
  34 ;; but who do want to include the anniversaries stored in the BBDB
  35 ;; into the org-agenda.  If you already include the `diary' into the
  36 ;; agenda, you might want to prefer to include the anniversaries in
  37 ;; the diary using bbdb-anniv.el.
  38 ;;
  39 ;; Put the following in /somewhere/at/home/diary.org and make sure
  40 ;; that this file is in `org-agenda-files`
  41 ;;
  42 ;; %%(org-bbdb-anniversaries)
  43 ;;
  44 ;; For example my diary.org looks like:
  45 ;; * Anniversaries
  46 ;; #+CATEGORY: Anniv
  47 ;; %%(org-bbdb-anniversaries)
  48 ;;
  49 ;;
  50 ;; To add an anniversary to a BBDB record, press `C-o' in the record.
  51 ;; You will be prompted for the field name, in this case it must be
  52 ;; "anniversary".  If this is the first time you are using this field,
  53 ;; you need to confirm that it should be created.
  54 ;;
  55 ;; The format of an anniversary field stored in BBDB is the following
  56 ;; (items in {} are optional):
  57 ;;
  58 ;;     YYYY-MM-DD{ CLASS-OR-FORMAT-STRING}
  59 ;;     {\nYYYY-MM-DD CLASS-OR-FORMAT-STRING}...
  60 ;;
  61 ;; CLASS-OR-FORMAT-STRING is one of two things:
  62 ;;
  63 ;;  - an identifier for a class of anniversaries (eg. birthday or
  64 ;;    wedding) from `org-bbdb-anniversary-format-alist' which then
  65 ;;    defines the format string for this class
  66 ;;  - the (format) string displayed in the diary.
  67 ;;
  68 ;; You can enter multiple anniversaries for a single BBDB record by
  69 ;; separating them with a newline character.  At the BBDB prompt for
  70 ;; the field value, type `C-q C-j' to enter a newline between two
  71 ;; anniversaries.
  72 ;;
  73 ;; If you omit the CLASS-OR-FORMAT-STRING entirely, it defaults to the
  74 ;; value of `org-bbdb-default-anniversary-format' ("birthday" by
  75 ;; default).
  76 ;;
  77 ;; The substitutions in the format string are (in order):
  78 ;;  - the name of the record containing this anniversary
  79 ;;  - the number of years
  80 ;;  - an ordinal suffix (st, nd, rd, th) for the year
  81 ;;
  82 ;; See the documentation of `org-bbdb-anniversary-format-alist' for
  83 ;; further options.
  84 ;;
  85 ;; Example
  86 ;;
  87 ;;       1973-06-22
  88 ;;       20??-??-?? wedding
  89 ;;       1998-03-12 %s created bbdb-anniv.el %d years ago
  90 ;;
  91 ;; From Org's agenda, you can use `C-c C-o' to jump to the BBDB
  92 ;; link from which the entry at point originates.
  93 ;;
  94 ;;; Code:
  95
  96 (require 'org)
  97 (eval-when-compile
  98   (require 'cl))
  99
 100 ;; Declare external functions and variables
 101
 102 (declare-function bbdb "ext:bbdb-com" (string elidep))
 103 (declare-function bbdb-company "ext:bbdb-com" (string elidep))
 104 (declare-function bbdb-current-record "ext:bbdb-com"
 105                   (&optional planning-on-modifying))
 106 (declare-function bbdb-name "ext:bbdb-com" (string elidep))
 107 (declare-function bbdb-completing-read-record "ext:bbdb-com"
 108                   (prompt &optional omit-records))
 109 (declare-function bbdb-record-getprop "ext:bbdb" (record property))
 110 (declare-function bbdb-record-name "ext:bbdb" (record))
 111 (declare-function bbdb-records "ext:bbdb"
 112                   (&optional dont-check-disk already-in-db-buffer))
 113 (declare-function bbdb-split "ext:bbdb" (string separators))
 114 (declare-function bbdb-string-trim "ext:bbdb" (string))
 115 (declare-function bbdb-record-get-field "ext:bbdb" (record field))
 116 (declare-function bbdb-search-name "ext:bbdb-com" (regexp &optional layout))
 117 (declare-function bbdb-search-organization "ext:bbdb-com" (regexp &optional layout))
 118
 119 ;; `bbdb-record-note' is part of BBDB v3.x
 120 (declare-function bbdb-record-note "ext:bbdb" (record label))
 121
 122 (declare-function calendar-leap-year-p "calendar" (year))
 123 (declare-function diary-ordinal-suffix "diary-lib" (n))
 124
 125 (org-no-warnings (defvar date)) ;; unprefixed, from calendar.el
 126
 127 ;; Customization
 128
 129 (defgroup org-bbdb-anniversaries nil
 130   "Customizations for including anniversaries from BBDB into Agenda."
 131   :group 'org-bbdb)
 132
 133 (defcustom org-bbdb-default-anniversary-format "birthday"
 134   "Default anniversary class."
 135   :type  'string
 136   :group 'org-bbdb-anniversaries
 137   :require 'bbdb)
 138
 139 (defcustom org-bbdb-anniversary-format-alist
 140   '(("birthday" .
 141      (lambda (name years suffix)
 142        (concat "Birthday: [[bbdb:" name "][" name " ("
 143                (format "%s" years)        ; handles numbers as well as strings
 144                suffix ")]]")))
 145     ("wedding" .
 146      (lambda (name years suffix)
 147        (concat "[[bbdb:" name "][" name "'s "
 148                (format "%s" years)
 149                suffix " wedding anniversary]]"))))
 150   "How different types of anniversaries should be formatted.
 151 An alist of elements (STRING . FORMAT) where STRING is the name of an
 152 anniversary class and format is either:
 153 1) A format string with the following substitutions (in order):
 154     - the name of the record containing this anniversary
 155     - the number of years
 156     - an ordinal suffix (st, nd, rd, th) for the year
 157
 158 2) A function to be called with three arguments: NAME YEARS SUFFIX
 159    (string int string) returning a string for the diary or nil.
 160
 161 3) An Emacs Lisp form that should evaluate to a string (or nil) in the
 162    scope of variables NAME, YEARS and SUFFIX (among others)."
 163   :type '(alist :key-type   (string   :tag "Class")
 164                 :value-type (function :tag "Function"))
 165   :group 'org-bbdb-anniversaries
 166   :require 'bbdb)
 167
 168 (defcustom org-bbdb-anniversary-field 'anniversary
 169   "The BBDB field which contains anniversaries.
 170 The anniversaries are stored in the following format
 171
 172 YYYY-MM-DD Class-or-Format-String
 173
 174 where class is one of the customized classes for anniversaries;
 175 birthday and wedding are predefined.  Format-String can take three
 176 substitutions 1) the name of the record containing this
 177 anniversary, 2) the number of years, and 3) an ordinal suffix for
 178 the year.
 179
 180 Multiple anniversaries can be separated by \\n."
 181   :type    'symbol
 182   :group   'org-bbdb-anniversaries
 183   :require 'bbdb)
 184
 185 (defcustom org-bbdb-extract-date-fun 'org-bbdb-anniv-extract-date
 186   "How to retrieve `month date year' from the anniversary field.
 187
 188 Customize if you have already filled your BBDB with dates
 189 different from YYYY-MM-DD.  The function must return a list (month
 190 date year)."
 191   :type 'function
 192   :group 'org-bbdb-anniversaries
 193   :require 'bbdb)
 194
 195
 196 ;; Install the link type
 197 (org-add-link-type "bbdb" 'org-bbdb-open 'org-bbdb-export)
 198 (add-hook 'org-store-link-functions 'org-bbdb-store-link)
 199
 200 ;; Implementation
 201 (defun org-bbdb-store-link ()
 202   "Store a link to a BBDB database entry."
 203   (when (eq major-mode 'bbdb-mode)
 204     ;; This is BBDB, we make this link!
 205     (let* ((rec (bbdb-current-record))
 206            (name (bbdb-record-name rec))
 207            (company (if (fboundp 'bbdb-record-getprop)
 208                         (bbdb-record-getprop rec 'company)
 209                       (car (bbdb-record-get-field rec 'organization))))
 210            (link (concat "bbdb:" name)))
 211       (org-store-link-props :type "bbdb" :name name :company company
 212                             :link link :description name)
 213       link)))
 214
 215 (defun org-bbdb-export (path desc format)
 216   "Create the export version of a BBDB link specified by PATH or DESC.
 217 If exporting to either HTML or LaTeX FORMAT the link will be
 218 italicized, in all other cases it is left unchanged."
 219   (when (string= desc (format "bbdb:%s" path))
 220     (setq desc path))
 221   (cond
 222    ((eq format 'html) (format "<i>%s</i>" desc))
 223    ((eq format 'latex) (format "\\textit{%s}" desc))
 224    ((eq format 'odt)
 225     (format "<text:span text:style-name=\"Emphasis\">%s</text:span>" desc))
 226    (t desc)))
 227
 228 (defun org-bbdb-open (name)
 229   "Follow a BBDB link to NAME."
 230   (require 'bbdb-com)
 231   (let ((inhibit-redisplay (not debug-on-error))
 232         (bbdb-electric-p nil))
 233     (if (fboundp 'bbdb-name)
 234         (org-bbdb-open-old name)
 235       (org-bbdb-open-new name))))
 236
 237 (defun org-bbdb-open-old (name)
 238   (catch 'exit
 239     ;; Exact match on name
 240     (bbdb-name (concat "\\`" name "\\'") nil)
 241     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 242     ;; Exact match on name
 243     (bbdb-company (concat "\\`" name "\\'") nil)
 244     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 245     ;; Partial match on name
 246     (bbdb-name name nil)
 247     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 248     ;; Partial match on company
 249     (bbdb-company name nil)
 250     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 251     ;; General match including network address and notes
 252     (bbdb name nil)
 253     (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 254       (delete-window (get-buffer-window "*BBDB*"))
 255       (error "No matching BBDB record"))))
 256
 257 (defun org-bbdb-open-new (name)
 258   (catch 'exit
 259     ;; Exact match on name
 260     (bbdb-search-name (concat "\\`" name "\\'") nil)
 261     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 262     ;; Exact match on name
 263     (bbdb-search-organization (concat "\\`" name "\\'") nil)
 264     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 265     ;; Partial match on name
 266     (bbdb-search-name name nil)
 267     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 268     ;; Partial match on company
 269     (bbdb-search-organization name nil)
 270     (if (< 0 (buffer-size (get-buffer "*BBDB*"))) (throw 'exit nil))
 271     ;; General match including network address and notes
 272     (bbdb name nil)
 273     (when (= 0 (buffer-size (get-buffer "*BBDB*")))
 274       (delete-window (get-buffer-window "*BBDB*"))
 275       (error "No matching BBDB record"))))
 276
 277 (defun org-bbdb-anniv-extract-date (time-str)
 278   "Convert YYYY-MM-DD to (month date year).
 279 Argument TIME-STR is the value retrieved from BBDB.  If YYYY- is omitted
 280 it will be considered unknown."
 281   (multiple-value-bind (a b c) (values-list (org-split-string time-str "-"))
 282     (if (eq c nil)
 283         (list (string-to-number a)
 284               (string-to-number b)
 285               nil)
 286       (list (string-to-number b)
 287             (string-to-number c)
 288             (string-to-number a)))))
 289
 290 (defun org-bbdb-anniv-split (str)
 291   "Split multiple entries in the BBDB anniversary field.
 292 Argument STR is the anniversary field in BBDB."
 293   (let ((pos (string-match "[ \t]" str)))
 294     (if pos (list (substring str 0 pos)
 295                   (bbdb-string-trim (substring str pos)))
 296       (list str nil))))
 297
 298 (defvar org-bbdb-anniv-hash nil
 299   "A hash holding anniversaries extracted from BBDB.
 300 The hash table is created on first use.")
 301
 302 (defvar org-bbdb-updated-p t
 303   "This is non-nil if BBDB has been updated since we last built the hash.")
 304
 305 (defun org-bbdb-make-anniv-hash ()
 306   "Create a hash with anniversaries extracted from BBDB, for fast access.
 307 The anniversaries are assumed to be stored `org-bbdb-anniversary-field'."
 308   (let ((old-bbdb (fboundp 'bbdb-record-getprop))
 309         split tmp annivs)
 310     (clrhash org-bbdb-anniv-hash)
 311     (dolist (rec (bbdb-records))
 312       (when (setq annivs (if old-bbdb
 313                              (bbdb-record-getprop
 314                               rec org-bbdb-anniversary-field)
 315                            (bbdb-record-note
 316                             rec org-bbdb-anniversary-field)))
 317         (setq annivs (if old-bbdb
 318                          (bbdb-split annivs "\n")
 319                        ;; parameter order is reversed in new bbdb
 320                        (bbdb-split "\n" annivs)))
 321         (while annivs
 322           (setq split (org-bbdb-anniv-split (pop annivs)))
 323           (multiple-value-bind (m d y)
 324               (values-list (funcall org-bbdb-extract-date-fun (car split)))
 325             (setq tmp (gethash (list m d) org-bbdb-anniv-hash))
 326             (puthash (list m d) (cons (list y
 327                                             (bbdb-record-name rec)
 328                                             (cadr split))
 329                                       tmp)
 330                      org-bbdb-anniv-hash))))))
 331   (setq org-bbdb-updated-p nil))
 332
 333 (defun org-bbdb-updated (rec)
 334   "Record the fact that BBDB has been updated.
 335 This is used by Org to re-create the anniversary hash table."
 336   (setq org-bbdb-updated-p t))
 337
 338 (add-hook 'bbdb-after-change-hook 'org-bbdb-updated)
 339
 340 ;;;###autoload
 341 (defun org-bbdb-anniversaries()
 342   "Extract anniversaries from BBDB for display in the agenda."
 343   (require 'bbdb)
 344   (require 'diary-lib)
 345   (unless (hash-table-p org-bbdb-anniv-hash)
 346     (setq org-bbdb-anniv-hash
 347           (make-hash-table :test 'equal :size 366)))
 348
 349   (when (or org-bbdb-updated-p
 350             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 351     (org-bbdb-make-anniv-hash))
 352
 353   (let* ((m (car date))    ; month
 354          (d (nth 1 date))  ; day
 355          (y (nth 2 date))  ; year
 356          (annivs (gethash (list m d) org-bbdb-anniv-hash))
 357          (text ())
 358          rec recs)
 359
 360     ;; we don't want to miss people born on Feb. 29th
 361     (when (and (= m 3) (= d 1)
 362                (not (null (gethash (list 2 29) org-bbdb-anniv-hash)))
 363                (not (calendar-leap-year-p y)))
 364       (setq recs (gethash (list 2 29) org-bbdb-anniv-hash))
 365       (while (setq rec (pop recs))
 366         (push rec annivs)))
 367
 368     (when annivs
 369       (while (setq rec (pop annivs))
 370         (when rec
 371           (let* ((class (or (nth 2 rec)
 372                             org-bbdb-default-anniversary-format))
 373                  (form (or (cdr (assoc-string
 374                                  class org-bbdb-anniversary-format-alist t))
 375                            class))      ; (as format string)
 376                  (name (nth 1 rec))
 377                  (years (if (eq (car rec) nil)
 378                             "unknown"
 379                           (- y (car rec))))
 380                  (suffix (if (eq (car rec) nil)
 381                              ""
 382                            (diary-ordinal-suffix years)))
 383                  (tmp (cond
 384                        ((functionp form)
 385                         (funcall form name years suffix))
 386                        ((listp form) (eval form))
 387                        (t (format form name years suffix)))))
 388             (org-add-props tmp nil 'org-bbdb-name name)
 389             (if text
 390                 (setq text (append text (list tmp)))
 391               (setq text (list tmp)))))
 392         ))
 393     text))
 394
 395 (defun org-bbdb-complete-link ()
 396   "Read a bbdb link with name completion."
 397   (require 'bbdb-com)
 398   (concat "bbdb:"
 399           (bbdb-record-name (car (bbdb-completing-read-record "Name: ")))))
 400
 401 (defun org-bbdb-anniv-export-ical ()
 402   "Extract anniversaries from BBDB and convert them to icalendar format."
 403   (require 'bbdb)
 404   (require 'diary-lib)
 405   (unless (hash-table-p org-bbdb-anniv-hash)
 406     (setq org-bbdb-anniv-hash
 407           (make-hash-table :test 'equal :size 366)))
 408   (when (or org-bbdb-updated-p
 409             (= 0 (hash-table-count org-bbdb-anniv-hash)))
 410     (org-bbdb-make-anniv-hash))
 411   (maphash 'org-bbdb-format-vevent org-bbdb-anniv-hash))
 412
 413 (defun org-bbdb-format-vevent (key recs)
 414   (let (rec categ)
 415     (while (setq rec (pop recs))
 416       (setq categ (or (nth 2 rec) org-bbdb-default-anniversary-format))
 417       (princ (format "BEGIN:VEVENT
 418 UID: ANNIV-%4i%02i%02i-%s
 419 DTSTART:%4i%02i%02i
 420 SUMMARY:%s
 421 DESCRIPTION:%s
 422 CATEGORIES:%s
 423 RRULE:FREQ=YEARLY
 424 END:VEVENT\n"
 425                      (nth 0 rec) (nth 0 key) (nth 1 key)
 426                      (mapconcat 'identity
 427                                 (org-split-string (nth 1 rec) "[^a-zA-Z0-90]+")
 428                                 "-")
 429                      (nth 0 rec) (nth 0 key) (nth 1 key)
 430                      (nth 1 rec)
 431                      (concat (capitalize categ) " " (nth 1 rec))
 432                      categ)))))
 433
 434 (provide 'org-bbdb)
 435
 436 ;;; org-bbdb.el ends here