lisp/ob-clojure.el

   1 ;;; ob-clojure.el --- org-babel functions for clojure evaluation
   2
   3 ;; Copyright (C) 2009-2014 Free Software Foundation, Inc.
   4
   5 ;; Author: Joel Boehland, Eric Schulte, Oleh Krehel
   6 ;;
   7 ;; Keywords: literate programming, reproducible research
   8 ;; Homepage: http://orgmode.org
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; Support for evaluating clojure code
  28
  29 ;; Requirements:
  30
  31 ;; - clojure (at least 1.2.0)
  32 ;; - clojure-mode
  33 ;; - either cider or SLIME
  34
  35 ;; For Cider, see https://github.com/clojure-emacs/cider
  36
  37 ;; For SLIME, the best way to install these components is by following
  38 ;; the directions as set out by Phil Hagelberg (Technomancy) on the
  39 ;; web page: http://technomancy.us/126
  40
  41 ;;; Code:
  42 (require 'ob)
  43 (eval-when-compile
  44   (require 'cl))
  45
  46 (declare-function nrepl-send-string-sync "ext:nrepl-client" (input &optional ns session))
  47 (declare-function slime-eval "ext:slime" (sexp &optional package))
  48
  49 (defvar org-babel-tangle-lang-exts)
  50 (add-to-list 'org-babel-tangle-lang-exts '("clojure" . "clj"))
  51
  52 (defvar org-babel-default-header-args:clojure '())
  53 (defvar org-babel-header-args:clojure '((package . :any)))
  54
  55 (defcustom org-babel-clojure-backend
  56   (cond ((featurep 'cider) 'cider)
  57         (t 'slime))
  58   "Backend used to evaluate Clojure code blocks."
  59   :group 'org-babel
  60   :type '(choice
  61           (const :tag "cider" cider)
  62           (const :tag "SLIME" slime)))
  63
  64 (defun org-babel-expand-body:clojure (body params)
  65   "Expand BODY according to PARAMS, return the expanded body."
  66   (let* ((vars (mapcar #'cdr (org-babel-get-header params :var)))
  67          (result-params (cdr (assoc :result-params params)))
  68          (print-level nil) (print-length nil)
  69          (body (org-babel-trim
  70                 (if (> (length vars) 0)
  71                     (concat "(let ["
  72                             (mapconcat
  73                              (lambda (var)
  74                                (format "%S (quote %S)" (car var) (cdr var)))
  75                              vars "\n      ")
  76                             "]\n" body ")")
  77                   body))))
  78     (if (or (member "code" result-params)
  79             (member "pp" result-params))
  80         (format "(clojure.pprint/pprint (do %s))" body)
  81       body)))
  82
  83 (defun org-babel-execute:clojure (body params)
  84   "Execute a block of Clojure code with Babel."
  85   (let ((expanded (org-babel-expand-body:clojure body params))
  86         result)
  87     (case org-babel-clojure-backend
  88       (cider
  89        (require 'cider)
  90        (let ((result-params (cdr (assoc :result-params params))))
  91          (setq result
  92                (plist-get
  93                 (nrepl-send-string-sync expanded)
  94                 (if (or (member "output" result-params)
  95                         (member "pp" result-params))
  96                     :stdout
  97                   :value)))))
  98       (slime
  99        (require 'slime)
 100        (with-temp-buffer
 101          (insert expanded)
 102          (setq result
 103                (slime-eval
 104                 `(swank:eval-and-grab-output
 105                   ,(buffer-substring-no-properties (point-min) (point-max)))
 106                 (cdr (assoc :package params)))))))
 107     (org-babel-result-cond (cdr (assoc :result-params params))
 108       result
 109       (condition-case nil (org-babel-script-escape result)
 110         (error result)))))
 111
 112 (provide 'ob-clojure)
 113
 114 ;;; ob-clojure.el ends here