classes/distutils.bbclass

   1 inherit distutils-base
   2
   3 DISTUTILS_STAGE_HEADERS_ARGS ?= "--install-dir=${STAGING_INCDIR}/${PYTHON_DIR}"
   4 DISTUTILS_STAGE_ALL_ARGS ?= "--prefix=${STAGING_DIR_HOST}${layout_prefix} \
   5     --install-data=${STAGING_DATADIR}"
   6 DISTUTILS_INSTALL_ARGS ?= "--prefix=${D}/${prefix} \
   7     --install-data=${D}/${datadir}"
   8
   9 distutils_do_compile() {
  10          BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
  11          ${STAGING_BINDIR_NATIVE}/python setup.py build || \
  12          oefatal "python setup.py build_ext execution failed."
  13 }
  14
  15 distutils_stage_headers() {
  16         install -d ${STAGING_DIR_HOST}${layout_libdir}/${PYTHON_DIR}/site-packages
  17         BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
  18         ${STAGING_BINDIR_NATIVE}/python setup.py install_headers ${DISTUTILS_STAGE_HEADERS_ARGS} || \
  19         oefatal "python setup.py install_headers execution failed."
  20 }
  21
  22 distutils_stage_all() {
  23         install -d ${STAGING_DIR_HOST}${layout_libdir}/${PYTHON_DIR}/site-packages
  24         PYTHONPATH=${STAGING_DIR_HOST}${layout_libdir}/${PYTHON_DIR}/site-packages \
  25         BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
  26         ${STAGING_BINDIR_NATIVE}/python setup.py install ${DISTUTILS_STAGE_ALL_ARGS} || \
  27         oefatal "python setup.py install (stage) execution failed."
  28 }
  29
  30 distutils_do_install() {
  31         install -d ${D}${libdir}/${PYTHON_DIR}/site-packages
  32         PYTHONPATH=${D}/${libdir}/${PYTHON_DIR}/site-packages \
  33         BUILD_SYS=${BUILD_SYS} HOST_SYS=${HOST_SYS} \
  34         ${STAGING_BINDIR_NATIVE}/python setup.py install ${DISTUTILS_INSTALL_ARGS} || \
  35         oefatal "python setup.py install execution failed."
  36
  37         for i in `find ${D} -name "*.py"` ; do \
  38             sed -i -e s:${D}::g $i
  39         done
  40
  41         if test -e ${D}${bindir} ; then
  42             for i in ${D}${bindir}/* ; do \
  43                 sed -i -e s:${STAGING_BINDIR_NATIVE}:${bindir}:g $i
  44             done
  45         fi
  46
  47         if test -e ${D}${sbindir} ; then
  48             for i in ${D}${sbindir}/* ; do \
  49                 sed -i -e s:${STAGING_BINDIR_NATIVE}:${bindir}:g $i
  50             done
  51         fi
  52
  53         rm -f ${D}${libdir}/${PYTHON_DIR}/site-packages/easy-install.pth
  54 }
  55
  56 EXPORT_FUNCTIONS do_compile do_install