packages/ppp/ppp_2.4.3.bb

   1 SECTION = "console/network"
   2 DESCRIPTION = "Point-to-Point Protocol (PPP) daemon"
   3 HOMEPAGE = "http://samba.org/ppp/"
   4 DEPENDS = "libpcap"
   5 LICENSE = "BSD GPLv2"
   6 PR = "r3"
   7
   8 SRC_URI = "http://ppp.samba.org/ftp/ppp/ppp-${PV}.tar.gz \
   9         file://makefile.patch;patch=1 \
  10         file://cifdefroute.patch;patch=1 \
  11         file://pppd-resolv-varrun.patch;patch=1 \
  12         file://plugins-fix-CC.patch;patch=1 \
  13         file://pppoatm-makefile.patch;patch=1 \
  14         file://enable-ipv6.patch;patch=1 \
  15         file://makefile-remove-hard-usr-reference.patch;patch=1 \
  16         file://pon \
  17         file://poff \
  18         file://init \
  19         file://ip-up \
  20         file://ip-down \
  21         file://08setupdns \
  22         file://92removedns"
  23
  24 SRC_URI_append_nylon = " file://ppp-tdbread.patch;patch=1"
  25
  26 inherit autotools
  27
  28 EXTRA_OEMAKE = "STRIPPROG=${STRIP} MANDIR=${D}${datadir}/man/man8 INCDIR=${D}/usr/include LIBDIR=${D}/usr/lib/pppd/${PV} BINDIR=${D}/usr/sbin"
  29 EXTRA_OECONF = "--disable-strip"
  30
  31 do_stage () {
  32          make INCDIR=${STAGING_INCDIR} install-devel
  33 }
  34
  35 do_install_append () {
  36         make install-etcppp ETCDIR=${D}/${sysconfdir}/ppp
  37         mkdir -p ${D}${bindir}/ ${D}${sysconfdir}/init.d
  38         mkdir -p ${D}${sysconfdir}/ppp/ip-up.d/
  39         mkdir -p ${D}${sysconfdir}/ppp/ip-down.d/
  40         install -m 0755 ${WORKDIR}/pon ${D}${bindir}/pon
  41         install -m 0755 ${WORKDIR}/poff ${D}${bindir}/poff
  42         install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/ppp
  43         install -m 0755 ${WORKDIR}/ip-up ${D}${sysconfdir}/ppp/
  44         install -m 0755 ${WORKDIR}/ip-down ${D}${sysconfdir}/ppp/
  45         install -m 0755 ${WORKDIR}/08setupdns ${D}${sysconfdir}/ppp/ip-up.d/
  46         install -m 0755 ${WORKDIR}/92removedns ${D}${sysconfdir}/ppp/ip-down.d/
  47         rm -rf ${D}/${mandir}/man8/man8
  48 }
  49
  50 CONFFILES_${PN} = "${sysconfdir}/ppp/pap-secrets ${sysconfdir}/ppp/chap-secrets ${sysconfdir}/ppp/options"
  51 PACKAGES += "ppp-oa ppp-oe ppp-radius ppp-winbind ppp-minconn ppp-password ppp-tools"
  52 FILES_${PN}        = "/etc /usr/bin /usr/sbin/chat /usr/sbin/pppd"
  53 FILES_${PN}_nylon  = "/etc /usr/bin /usr/sbin/chat /usr/sbin/pppd /usr/sbin/tdbread"
  54 FILES_${PN}-dbg += "${libdir}/pppd/2.4.3/.debug"
  55 FILES_ppp-oa       = "/usr/lib/pppd/2.4.3/pppoatm.so"
  56 FILES_ppp-oe       = "/usr/sbin/pppoe-discovery /usr/lib/pppd/2.4.3/rp-pppoe.so"
  57 FILES_ppp-radius   = "/usr/lib/pppd/2.4.3/radius.so /usr/lib/pppd/2.4.3/radattr.so /usr/lib/pppd/2.4.3/radrealms.so"
  58 FILES_ppp-winbind  = "/usr/lib/pppd/2.4.3/winbind.so"
  59 FILES_ppp-minconn  = "/usr/lib/pppd/2.4.3/minconn.so"
  60 FILES_ppp-password = "/usr/lib/pppd/2.4.3/pass*.so"
  61 FILES_ppp-tools    = "/usr/sbin/pppstats /usr/sbin/pppdump"
  62 DESCRIPTION_ppp-oa       = "Plugin for PPP needed for PPP-over-ATM"
  63 DESCRIPTION_ppp-oe       = "Plugin for PPP needed for PPP-over-Ethernet"
  64 DESCRIPTION_ppp-radius   = "Plugin for PPP that are related to RADIUS"
  65 DESCRIPTION_ppp-winbind  = "Plugin for PPP to authenticate against Samba or Windows"
  66 DESCRIPTION_ppp-minconn  = "Plugin for PPP to specify a minimum connect time before the idle timeout applies"
  67 DESCRIPTION_ppp-password = "Plugin for PPP to get passwords via a pipe"
  68 DESCRIPTION_ppp-tools    = "The pppdump and pppstats utitilities"
  69 RDEPENDS_ppp_minconn    += "libpcap0.8"
  70
  71 pkg_postinst_${PN}() {
  72 if test "x$D" != "x"; then
  73         exit 1
  74 else
  75         chmod u+s ${sbindir}/pppd
  76 fi
  77 }