configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [7])
  45 m4_define([lib_revision], [0])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [4])
  49 m4_define([pacman_version_minor], [0])
  50 m4_define([pacman_version_micro], [0rc1])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Help line for using gpgme
  97 AC_ARG_WITH(gpgme,
  98         AS_HELP_STRING([--with-gpgme], [use GPGME for PGP signature verification]),
  99         [], [with_gpgme=check])
 100
 101 # Check for useable libcurl
 102 LIBCURL_CHECK_CONFIG([yes], [7.19.4], [with_libcurl=yes], [with_libcurl=no])
 103
 104 # Help line for documentation
 105 AC_ARG_ENABLE(doc,
 106         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 107         [wantdoc=$enableval], [wantdoc=yes])
 108
 109 # Help line for doxygen
 110 AC_ARG_ENABLE(doxygen,
 111         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 112         [wantdoxygen=$enableval], [wantdoxygen=no])
 113
 114 # Help line for debug
 115 AC_ARG_ENABLE(debug,
 116         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 117         [debug=$enableval], [debug=no])
 118
 119 # Help line for using git version in pacman version string
 120 AC_ARG_ENABLE(git-version,
 121         AS_HELP_STRING([--enable-git-version],
 122                 [enable use of git version in version string if available]),
 123         [wantgitver=$enableval], [wantgitver=no])
 124
 125 # Checks for programs.
 126 AC_PROG_AWK
 127 AC_PROG_CC_C99
 128 AC_PROG_CXX
 129 AC_PROG_INSTALL
 130 AC_PROG_LN_S
 131 AC_PROG_MAKE_SET
 132 AC_PROG_LIBTOOL
 133 AC_PROG_RANLIB
 134 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 135 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 136
 137 # find installed gettext
 138 AM_GNU_GETTEXT([external], [need-ngettext])
 139 AM_GNU_GETTEXT_VERSION(0.13.1)
 140
 141 AC_CHECK_LIB([m], [fabs], ,
 142         AC_MSG_ERROR([libm is needed to compile pacman!]))
 143
 144 # Check for libarchive
 145 AC_CHECK_LIB([archive], [archive_read_data], ,
 146         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 147
 148 # Check for OpenSSL
 149 AC_MSG_CHECKING(whether to link with libssl)
 150 AS_IF([test "x$with_openssl" != "xno"],
 151         [AC_MSG_RESULT(yes)
 152         AC_CHECK_LIB([ssl], [MD5_Final], ,
 153         [if test "x$with_openssl" != "xcheck"; then
 154                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 155         fi],
 156         [-lcrypto])
 157         with_openssl=$ac_cv_lib_ssl_MD5_Final],
 158         AC_MSG_RESULT(no))
 159 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$with_openssl" = "xyes"])
 160
 161 # Check for gpgme
 162 AC_MSG_CHECKING(whether to link with libgpgme)
 163 AS_IF([test "x$with_gpgme" != "xno"],
 164         [AC_MSG_RESULT(yes)
 165         AC_CHECK_LIB([gpgme], [gpgme_check_version], ,
 166         [if test "x$with_gpgme" != "xcheck"; then
 167                 AC_MSG_FAILURE([--with-ggpme was given, but -lgpgme was not found])
 168         fi],
 169         [-lgpgme])
 170         with_gpgme=$ac_cv_lib_gpgme_gpgme_check_version],
 171         AC_MSG_RESULT(no))
 172 AM_CONDITIONAL([HAVE_LIBGPGME], [test "x$with_gpgme" = "xyes"])
 173
 174 # Checks for header files.
 175 AC_CHECK_HEADERS([fcntl.h float.h glob.h libintl.h limits.h locale.h \
 176                   mntent.h stddef.h string.h sys/ioctl.h sys/mount.h \
 177                   sys/param.h sys/statvfs.h sys/time.h sys/types.h \
 178                   sys/ucred.h syslog.h termios.h wchar.h])
 179
 180 # Checks for typedefs, structures, and compiler characteristics.
 181 AC_C_INLINE
 182 AC_TYPE_INT64_T
 183 AC_TYPE_MODE_T
 184 AC_TYPE_OFF_T
 185 AC_TYPE_PID_T
 186 AC_TYPE_SIZE_T
 187 AC_TYPE_SSIZE_T
 188 AC_STRUCT_TM
 189 AC_TYPE_UID_T
 190 AC_STRUCT_DIRENT_D_TYPE
 191 PATH_MAX_DEFINED
 192
 193 # Checks for library functions.
 194 AC_FUNC_FORK
 195 AC_FUNC_GETMNTENT
 196 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 197 AC_FUNC_MALLOC
 198 AC_FUNC_MKTIME
 199 AC_FUNC_STRCOLL
 200 AC_CHECK_FUNCS([dup2 getcwd geteuid getmntinfo gettimeofday memmove memset \
 201                 mkdir realpath regcomp rmdir setenv setlocale strcasecmp \
 202                 strchr strcspn strdup strerror strndup strrchr strsep strstr \
 203                 strtol swprintf tcflush wcwidth uname])
 204
 205 # For the diskspace code
 206 FS_STATS_TYPE
 207 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 208 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 209                   #include <sys/mount.h>]])
 210
 211 # Enable large file support if available
 212 AC_SYS_LARGEFILE
 213
 214 # Check if we can use symbol visibility support in GCC
 215 GCC_VISIBILITY_CC
 216 # Check if we have -fgnu89-inline flag
 217 GCC_GNU89_INLINE_CC
 218
 219 # Host-dependant definitions
 220 SIZECMD="stat -L -c %s"
 221 SEDINPLACE="sed -i"
 222 STRIP_BINARIES="--strip-all"
 223 STRIP_SHARED="--strip-unneeded"
 224 STRIP_STATIC="--strip-debug"
 225 case "${host_os}" in
 226         *bsd*)
 227                 SIZECMD="stat -L -f %z"
 228                 SEDINPLACE="sed -i \"\""
 229                 ;;
 230         cygwin*)
 231                 host_os_cygwin=yes
 232                 CFLAGS="$CFLAGS -DCYGWIN"
 233                 ;;
 234         darwin*)
 235                 host_os_darwin=yes
 236                 SIZECMD="/usr/bin/stat -L -f %z"
 237                 SEDINPLACE="/usr/bin/sed -i ''"
 238                 STRIP_BINARIES=""
 239                 STRIP_SHARED="-S"
 240                 STRIP_STATIC="-S"
 241                 ;;
 242 esac
 243
 244 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 245 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 246 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 247 AC_SUBST(SIZECMD)
 248 AC_SUBST(SEDINPLACE)
 249 AC_SUBST(STRIP_BINARIES)
 250 AC_SUBST(STRIP_SHARED)
 251 AC_SUBST(STRIP_STATIC)
 252
 253 # Variables plugged into makepkg.conf
 254 CARCH="${host%%-*}"
 255 CHOST="${host}"
 256 AC_SUBST(CARCH)
 257 AC_SUBST(CHOST)
 258
 259 # Check for documentation support and status
 260 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 261 AC_MSG_CHECKING([for building documentation])
 262 if test "x$wantdoc" = "xyes" ; then
 263         if test $ASCIIDOC ; then
 264                 AC_MSG_RESULT([yes, enabled by configure])
 265         else
 266                 asciidoc="(warning : asciidoc not installed)"
 267                 AC_MSG_RESULT([yes $asciidoc])
 268         fi
 269         wantdoc=yes
 270 else
 271         AC_MSG_RESULT([no, disabled by configure])
 272         wantdoc=no
 273 fi
 274 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 275
 276 # Check for doxygen support and status
 277 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 278 AC_MSG_CHECKING([for doxygen])
 279 if test "x$wantdoxygen" = "xyes" ; then
 280         if test $DOXYGEN ; then
 281                 AC_MSG_RESULT([yes])
 282                 usedoxygen=yes
 283         else
 284                 AC_MSG_RESULT([no, doxygen missing])
 285                 usedoxygen=no
 286         fi
 287 else
 288         AC_MSG_RESULT([no, disabled by configure])
 289         usedoxygen=no
 290 fi
 291 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 292
 293 # Enable or disable debug code
 294 AC_MSG_CHECKING(for debug mode request)
 295 if test "x$debug" = "xyes" ; then
 296         AC_MSG_RESULT(yes)
 297         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 298         # Check for mcheck
 299         AC_CHECK_HEADERS([mcheck.h])
 300         # Check for -fstack-protector availability
 301         GCC_STACK_PROTECT_LIB
 302         GCC_STACK_PROTECT_CC
 303         GCC_FORTIFY_SOURCE_CC
 304         CFLAGS="$CFLAGS -g -Wall -Werror"
 305 else
 306         AC_MSG_RESULT(no)
 307         CFLAGS="$CFLAGS -Wall"
 308 fi
 309
 310 # Enable or disable use of git version in pacman version string
 311 AC_MSG_CHECKING(whether to use git version if available)
 312 if test "x$wantgitver" = "xyes" ; then
 313         AC_CHECK_PROGS([GIT], [git])
 314         AC_CHECK_FILE([.git/], hasgitdir=yes)
 315         if test $GIT -a "x$hasgitdir" = "xyes"; then
 316                 AC_MSG_RESULT([yes])
 317                 usegitver=yes
 318                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 319         else
 320                 AC_MSG_RESULT([no, git or .git dir missing])
 321                 usegitver=no
 322         fi
 323 else
 324         AC_MSG_RESULT([no, disabled by configure])
 325         usegitver=no
 326 fi
 327 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 328
 329 # Set root directory
 330 AC_SUBST(ROOTDIR)
 331 # Set package file extension
 332 AC_SUBST(PKGEXT)
 333 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 334 # Set source package file extension
 335 AC_SUBST(SRCEXT)
 336 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 337 # Set makepkg build script name
 338 AC_SUBST(BUILDSCRIPT)
 339 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 340
 341 # Configuration files
 342 AC_CONFIG_FILES([
 343 lib/libalpm/Makefile
 344 lib/libalpm/po/Makefile.in
 345 src/pacman/Makefile
 346 src/pacman/po/Makefile.in
 347 src/util/Makefile
 348 scripts/Makefile
 349 scripts/po/Makefile.in
 350 doc/Makefile
 351 etc/Makefile
 352 test/pacman/Makefile
 353 test/pacman/tests/Makefile
 354 test/util/Makefile
 355 contrib/Makefile
 356 Makefile
 357 ])
 358 AC_OUTPUT
 359
 360 echo "
 361 ${PACKAGE_NAME}:
 362
 363   Build information:
 364     source code location   : ${srcdir}
 365     prefix                 : ${prefix}
 366     sysconfdir             : $(eval echo ${sysconfdir})
 367        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 368     localstatedir          : $(eval echo ${localstatedir})
 369        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 370        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 371
 372     compiler               : ${CC}
 373     preprocessor flags     : ${CPPFLAGS}
 374     compiler flags         : ${CFLAGS}
 375     defines                : ${DEFS}
 376     library flags          : ${LIBS}
 377     linker flags           : ${LDFLAGS}
 378
 379     Architecture           : ${CARCH}
 380     Host Type              : ${CHOST}
 381     Filesize command       : ${SIZECMD}
 382     In-place sed command   : ${SEDINPLACE}
 383
 384     libalpm version        : ${LIB_VERSION}
 385     libalpm version info   : ${LIB_VERSION_INFO}
 386     pacman version         : ${PACKAGE_VERSION}
 387     using git version      : ${usegitver}
 388
 389   Directory and file information:
 390     root working directory : ${ROOTDIR}
 391     package extension      : ${PKGEXT}
 392     source pkg extension   : ${SRCEXT}
 393     build script name      : ${BUILDSCRIPT}
 394
 395   Compilation options:
 396     Use libcurl            : ${with_libcurl}
 397     Use GPGME              : ${with_gpgme}
 398     Use OpenSSL            : ${with_openssl}
 399     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 400     Doxygen support        : ${usedoxygen}
 401     debug support          : ${debug}
 402 "
 403
 404 # vim:set ts=2 sw=2 noet: