configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [7])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [4])
  49 m4_define([pacman_version_minor], [0])
  50 m4_define([pacman_version_micro], [1])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE([1.11])
  61 AM_SILENT_RULES([yes])
  62
  63 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  64 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  65
  66 # Set subsitution values for version stuff in Makefiles and anywhere else,
  67 # and put LIB_VERSION in config.h
  68 AC_SUBST(LIB_VERSION)
  69 AC_SUBST(LIB_VERSION_INFO)
  70 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  71
  72 # Help line for root directory
  73 AC_ARG_WITH(root-dir,
  74         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  75         [ROOTDIR=$withval], [ROOTDIR=/])
  76
  77 # Help line for package extension
  78 AC_ARG_WITH(pkg-ext,
  79         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  80         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  81
  82 # Help line for source package directory
  83 AC_ARG_WITH(src-ext,
  84         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  85         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  86
  87 # Help line for buildscript filename
  88 AC_ARG_WITH(buildscript,
  89         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  90         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  91
  92 # Help line for changing shell used to run install scriptlets
  93 AC_ARG_WITH(scriptlet-shell,
  94         AS_HELP_STRING([--with-scriptlet-shell=shell],
  95                 [set the shell used to run install scriptlets]),
  96         [SCRIPTLET_SHELL=$withval], [SCRIPTLET_SHELL=sh])
  97
  98 # Help line for using OpenSSL
  99 AC_ARG_WITH(openssl,
 100         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
 101         [], [with_openssl=check])
 102
 103 # Help line for using gpgme
 104 AC_ARG_WITH(gpgme,
 105         AS_HELP_STRING([--with-gpgme], [use GPGME for PGP signature verification]),
 106         [], [with_gpgme=check])
 107
 108 # Check for useable libcurl
 109 LIBCURL_CHECK_CONFIG([yes], [7.19.4], [with_libcurl=yes], [with_libcurl=no])
 110
 111 # Help line for documentation
 112 AC_ARG_ENABLE(doc,
 113         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 114         [wantdoc=$enableval], [wantdoc=yes])
 115
 116 # Help line for doxygen
 117 AC_ARG_ENABLE(doxygen,
 118         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 119         [wantdoxygen=$enableval], [wantdoxygen=no])
 120
 121 # Help line for debug
 122 AC_ARG_ENABLE(debug,
 123         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 124         [debug=$enableval], [debug=no])
 125
 126 # Help line for using git version in pacman version string
 127 AC_ARG_ENABLE(git-version,
 128         AS_HELP_STRING([--enable-git-version],
 129                 [enable use of git version in version string if available]),
 130         [wantgitver=$enableval], [wantgitver=no])
 131
 132 # Checks for programs.
 133 AC_PROG_AWK
 134 AC_PROG_CC_C99
 135 AC_PROG_CXX
 136 AC_PROG_INSTALL
 137 AC_PROG_LN_S
 138 AC_PROG_MAKE_SET
 139 AC_PROG_LIBTOOL
 140 AC_PROG_RANLIB
 141 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 142 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 143
 144 # find installed gettext
 145 AM_GNU_GETTEXT([external], [need-ngettext])
 146 AM_GNU_GETTEXT_VERSION(0.13.1)
 147
 148 AC_CHECK_LIB([m], [fabs], ,
 149         AC_MSG_ERROR([libm is needed to compile pacman!]))
 150
 151 # Check for libarchive
 152 AC_CHECK_LIB([archive], [archive_read_data], ,
 153         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 154
 155 # Check for OpenSSL
 156 AC_MSG_CHECKING(whether to link with libssl)
 157 AS_IF([test "x$with_openssl" != "xno"],
 158         [AC_MSG_RESULT(yes)
 159         AC_CHECK_LIB([ssl], [MD5_Final], ,
 160         [if test "x$with_openssl" != "xcheck"; then
 161                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 162         fi],
 163         [-lcrypto])
 164         with_openssl=$ac_cv_lib_ssl_MD5_Final],
 165         AC_MSG_RESULT(no))
 166 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$with_openssl" = "xyes"])
 167
 168 # Check for gpgme
 169 AC_MSG_CHECKING(whether to link with libgpgme)
 170 AS_IF([test "x$with_gpgme" != "xno"],
 171         [AC_MSG_RESULT(yes)
 172         AC_CHECK_LIB([gpgme], [gpgme_check_version], ,
 173         [if test "x$with_gpgme" != "xcheck"; then
 174                 AC_MSG_FAILURE([--with-ggpme was given, but -lgpgme was not found])
 175         fi],
 176         [-lgpgme])
 177         with_gpgme=$ac_cv_lib_gpgme_gpgme_check_version],
 178         AC_MSG_RESULT(no))
 179 AM_CONDITIONAL([HAVE_LIBGPGME], [test "x$with_gpgme" = "xyes"])
 180
 181 # Checks for header files.
 182 AC_CHECK_HEADERS([fcntl.h float.h glob.h libintl.h limits.h locale.h \
 183                   mntent.h netinet/in.h netinet/tcp.h \
 184                   stddef.h string.h sys/ioctl.h \
 185                   sys/mnttab.h sys/mount.h \
 186                   sys/param.h sys/statvfs.h sys/time.h sys/types.h \
 187                   sys/ucred.h syslog.h termios.h wchar.h])
 188
 189 # Checks for typedefs, structures, and compiler characteristics.
 190 AC_C_INLINE
 191 AC_TYPE_INT64_T
 192 AC_TYPE_MODE_T
 193 AC_TYPE_OFF_T
 194 AC_TYPE_PID_T
 195 AC_TYPE_SIZE_T
 196 AC_TYPE_SSIZE_T
 197 AC_STRUCT_TM
 198 AC_TYPE_UID_T
 199 AC_STRUCT_DIRENT_D_TYPE
 200 PATH_MAX_DEFINED
 201
 202 # Checks for library functions.
 203 AC_FUNC_FORK
 204 AC_FUNC_GETMNTENT
 205 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 206 AC_FUNC_MALLOC
 207 AC_FUNC_MKTIME
 208 AC_FUNC_STRCOLL
 209 AC_CHECK_FUNCS([dup2 getcwd geteuid getmntinfo gettimeofday memmove memset \
 210                 mkdir realpath regcomp rmdir setenv setlocale strcasecmp \
 211                 strchr strcspn strdup strerror strndup strrchr strsep strstr \
 212                 strtol swprintf tcflush wcwidth uname])
 213 AC_CHECK_MEMBERS([struct stat.st_blksize],,,[[#include <sys/stat.h>]])
 214
 215 # For the diskspace code
 216 FS_STATS_TYPE
 217 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 218 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 219                   #include <sys/mount.h>]])
 220
 221 # Enable large file support if available
 222 AC_SYS_LARGEFILE
 223
 224 # Check if we can use symbol visibility support in GCC
 225 GCC_VISIBILITY_CC
 226 # Check if we have -fgnu89-inline flag
 227 GCC_GNU89_INLINE_CC
 228
 229 # Host-dependant definitions
 230 SIZECMD="stat -L -c %s"
 231 SEDINPLACE="sed -i"
 232 STRIP_BINARIES="--strip-all"
 233 STRIP_SHARED="--strip-unneeded"
 234 STRIP_STATIC="--strip-debug"
 235 case "${host_os}" in
 236         *bsd*)
 237                 SIZECMD="stat -L -f %z"
 238                 SEDINPLACE="sed -i \"\""
 239                 ;;
 240         cygwin*)
 241                 host_os_cygwin=yes
 242                 CFLAGS="$CFLAGS -DCYGWIN"
 243                 ;;
 244         darwin*)
 245                 host_os_darwin=yes
 246                 SIZECMD="/usr/bin/stat -L -f %z"
 247                 SEDINPLACE="/usr/bin/sed -i ''"
 248                 STRIP_BINARIES=""
 249                 STRIP_SHARED="-S"
 250                 STRIP_STATIC="-S"
 251                 ;;
 252 esac
 253
 254 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 255 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 256 AC_SUBST(SIZECMD)
 257 AC_SUBST(SEDINPLACE)
 258 AC_SUBST(STRIP_BINARIES)
 259 AC_SUBST(STRIP_SHARED)
 260 AC_SUBST(STRIP_STATIC)
 261
 262 # Variables plugged into makepkg.conf
 263 CARCH="${host%%-*}"
 264 CHOST="${host}"
 265 AC_SUBST(CARCH)
 266 AC_SUBST(CHOST)
 267
 268 # Check for documentation support and status
 269 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 270 AC_MSG_CHECKING([for building documentation])
 271 if test "x$wantdoc" = "xyes" ; then
 272         if test $ASCIIDOC ; then
 273                 AC_MSG_RESULT([yes, enabled by configure])
 274         else
 275                 asciidoc="(warning : asciidoc not installed)"
 276                 AC_MSG_RESULT([yes $asciidoc])
 277         fi
 278         wantdoc=yes
 279 else
 280         AC_MSG_RESULT([no, disabled by configure])
 281         wantdoc=no
 282 fi
 283 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 284
 285 # Check for doxygen support and status
 286 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 287 AC_MSG_CHECKING([for doxygen])
 288 if test "x$wantdoxygen" = "xyes" ; then
 289         if test $DOXYGEN ; then
 290                 AC_MSG_RESULT([yes])
 291                 usedoxygen=yes
 292         else
 293                 AC_MSG_RESULT([no, doxygen missing])
 294                 usedoxygen=no
 295         fi
 296 else
 297         AC_MSG_RESULT([no, disabled by configure])
 298         usedoxygen=no
 299 fi
 300 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 301
 302 # Enable or disable debug code
 303 AC_MSG_CHECKING(for debug mode request)
 304 if test "x$debug" = "xyes" ; then
 305         AC_MSG_RESULT(yes)
 306         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 307         # Check for -fstack-protector availability
 308         GCC_STACK_PROTECT_LIB
 309         GCC_STACK_PROTECT_CC
 310         GCC_FORTIFY_SOURCE_CC
 311         CFLAGS="$CFLAGS -g -Wall -Werror"
 312 else
 313         AC_MSG_RESULT(no)
 314         CFLAGS="$CFLAGS -Wall"
 315 fi
 316
 317 # Enable or disable use of git version in pacman version string
 318 AC_MSG_CHECKING(whether to use git version if available)
 319 if test "x$wantgitver" = "xyes" ; then
 320         AC_CHECK_PROGS([GIT], [git])
 321         AC_CHECK_FILE([.git/], hasgitdir=yes)
 322         if test $GIT -a "x$hasgitdir" = "xyes"; then
 323                 AC_MSG_RESULT([yes])
 324                 usegitver=yes
 325                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 326         else
 327                 AC_MSG_RESULT([no, git or .git dir missing])
 328                 usegitver=no
 329         fi
 330 else
 331         AC_MSG_RESULT([no, disabled by configure])
 332         usegitver=no
 333 fi
 334 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 335
 336 # Set root directory
 337 AC_SUBST(ROOTDIR)
 338 # Set package file extension
 339 AC_SUBST(PKGEXT)
 340 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 341 # Set source package file extension
 342 AC_SUBST(SRCEXT)
 343 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 344 # Set makepkg build script name
 345 AC_SUBST(BUILDSCRIPT)
 346 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 347 # Set shell used by install scriptlets
 348 AC_SUBST(SCRIPTLET_SHELL)
 349 AC_DEFINE_UNQUOTED([SCRIPTLET_SHELL], "$SCRIPTLET_SHELL", [The shell used to run install scriptlets])
 350
 351 # Configuration files
 352 AC_CONFIG_FILES([
 353 lib/libalpm/Makefile
 354 lib/libalpm/po/Makefile.in
 355 src/pacman/Makefile
 356 src/pacman/po/Makefile.in
 357 src/util/Makefile
 358 scripts/Makefile
 359 scripts/po/Makefile.in
 360 doc/Makefile
 361 etc/Makefile
 362 test/pacman/Makefile
 363 test/pacman/tests/Makefile
 364 test/util/Makefile
 365 contrib/Makefile
 366 Makefile
 367 ])
 368 AC_OUTPUT
 369
 370 echo "
 371 ${PACKAGE_NAME}:
 372
 373   Build information:
 374     source code location   : ${srcdir}
 375     prefix                 : ${prefix}
 376     sysconfdir             : $(eval echo ${sysconfdir})
 377        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 378     localstatedir          : $(eval echo ${localstatedir})
 379        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 380        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 381
 382     compiler               : ${CC}
 383     preprocessor flags     : ${CPPFLAGS}
 384     compiler flags         : ${CFLAGS}
 385     defines                : ${DEFS}
 386     library flags          : ${LIBS}
 387     linker flags           : ${LDFLAGS}
 388
 389     Architecture           : ${CARCH}
 390     Host Type              : ${CHOST}
 391     Filesize command       : ${SIZECMD}
 392     In-place sed command   : ${SEDINPLACE}
 393
 394     libalpm version        : ${LIB_VERSION}
 395     libalpm version info   : ${LIB_VERSION_INFO}
 396     pacman version         : ${PACKAGE_VERSION}
 397     using git version      : ${usegitver}
 398
 399   Directory and file information:
 400     root working directory : ${ROOTDIR}
 401     package extension      : ${PKGEXT}
 402     source pkg extension   : ${SRCEXT}
 403     build script name      : ${BUILDSCRIPT}
 404
 405   Compilation options:
 406     Use libcurl            : ${with_libcurl}
 407     Use GPGME              : ${with_gpgme}
 408     Use OpenSSL            : ${with_openssl}
 409     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 410     Doxygen support        : ${usedoxygen}
 411     debug support          : ${debug}
 412 "
 413
 414 # vim:set ts=2 sw=2 noet: