configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [6])
  45 m4_define([lib_revision], [3])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [3])
  49 m4_define([pacman_version_minor], [5])
  50 m4_define([pacman_version_micro], [3])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Help line for using gpgme
  97 AC_ARG_WITH(gpgme,
  98         AS_HELP_STRING([--with-gpgme], [use GPGME for PGP signature verification]),
  99         [], [with_gpgme=check])
 100
 101 # Check for useable libcurl
 102 LIBCURL_CHECK_CONFIG([yes], [7.19.4], [with_libcurl=yes], [with_libcurl=no])
 103
 104 # Help line for documentation
 105 AC_ARG_ENABLE(doc,
 106         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 107         [wantdoc=$enableval], [wantdoc=yes])
 108
 109 # Help line for doxygen
 110 AC_ARG_ENABLE(doxygen,
 111         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 112         [wantdoxygen=$enableval], [wantdoxygen=no])
 113
 114 # Help line for debug
 115 AC_ARG_ENABLE(debug,
 116         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 117         [debug=$enableval], [debug=no])
 118
 119 # Help line for using git version in pacman version string
 120 AC_ARG_ENABLE(git-version,
 121         AS_HELP_STRING([--enable-git-version],
 122                 [enable use of git version in version string if available]),
 123         [wantgitver=$enableval], [wantgitver=no])
 124
 125 # Checks for programs.
 126 AC_PROG_AWK
 127 AC_PROG_CC_C99
 128 AC_PROG_INSTALL
 129 AC_PROG_LN_S
 130 AC_PROG_MAKE_SET
 131 AC_PROG_LIBTOOL
 132 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 133 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 134
 135 # find installed gettext
 136 AM_GNU_GETTEXT([external])
 137 AM_GNU_GETTEXT_VERSION(0.13.1)
 138
 139 AC_CHECK_LIB([m], [fabs], ,
 140         AC_MSG_ERROR([libm is needed to compile pacman!]))
 141
 142 # Check for libarchive
 143 AC_CHECK_LIB([archive], [archive_read_data], ,
 144         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 145
 146 # Check for OpenSSL
 147 AC_MSG_CHECKING(whether to link with libssl)
 148 AS_IF([test "x$with_openssl" != "xno"],
 149         [AC_MSG_RESULT(yes)
 150         AC_CHECK_LIB([ssl], [MD5_Final], ,
 151         [if test "x$with_openssl" != "xcheck"; then
 152                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 153         fi],
 154         [-lcrypto])
 155         with_openssl=$ac_cv_lib_ssl_MD5_Final],
 156         AC_MSG_RESULT(no))
 157 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$with_openssl" = "xyes"])
 158
 159 # Check for gpgme
 160 AC_MSG_CHECKING(whether to link with libgpgme)
 161 AS_IF([test "x$with_gpgme" != "xno"],
 162         [AC_MSG_RESULT(yes)
 163         AC_CHECK_LIB([gpgme], [gpgme_check_version], ,
 164         [if test "x$with_gpgme" != "xcheck"; then
 165                 AC_MSG_FAILURE([--with-ggpme was given, but -lgpgme was not found])
 166         fi],
 167         [-lgpgme])
 168         with_gpgme=$ac_cv_lib_gpgme_gpgme_check_version],
 169         AC_MSG_RESULT(no))
 170 AM_CONDITIONAL([HAVE_LIBGPGME], [test "x$with_gpgme" = "xyes"])
 171
 172 # Checks for header files.
 173 AC_CHECK_HEADERS([fcntl.h glob.h libintl.h locale.h mntent.h string.h \
 174                   sys/ioctl.h sys/mount.h sys/param.h sys/statvfs.h \
 175                   sys/time.h sys/types.h sys/ucred.h syslog.h termios.h \
 176                   wchar.h])
 177
 178 # Checks for typedefs, structures, and compiler characteristics.
 179 AC_C_INLINE
 180 AC_TYPE_MODE_T
 181 AC_TYPE_OFF_T
 182 AC_TYPE_PID_T
 183 AC_TYPE_SIZE_T
 184 AC_STRUCT_TM
 185 AC_TYPE_UID_T
 186 AC_STRUCT_DIRENT_D_TYPE
 187 PATH_MAX_DEFINED
 188
 189 # Checks for library functions.
 190 AC_FUNC_FORK
 191 AC_FUNC_GETMNTENT
 192 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 193 AC_FUNC_MKTIME
 194 AC_CHECK_FUNCS([geteuid getmntinfo realpath regcomp strcasecmp \
 195                 strndup strrchr strsep swprintf tcflush \
 196                 wcwidth uname])
 197 # For the diskspace code
 198 FS_STATS_TYPE
 199 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 200 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 201                   #include <sys/mount.h>]])
 202
 203 # Enable large file support if available
 204 AC_SYS_LARGEFILE
 205
 206 # Check if we can use symbol visibility support in GCC
 207 GCC_VISIBILITY_CC
 208 # Check if we have -fgnu89-inline flag
 209 GCC_GNU89_INLINE_CC
 210
 211 # Host-dependant definitions
 212 SIZECMD="stat -L -c %s"
 213 SEDINPLACE="sed -i"
 214 STRIP_BINARIES="--strip-all"
 215 STRIP_SHARED="--strip-unneeded"
 216 STRIP_STATIC="--strip-debug"
 217 case "${host_os}" in
 218         *bsd*)
 219                 SIZECMD="stat -L -f %z"
 220                 SEDINPLACE="sed -i ''"
 221                 ;;
 222         cygwin*)
 223                 host_os_cygwin=yes
 224                 CFLAGS="$CFLAGS -DCYGWIN"
 225                 ;;
 226         darwin*)
 227                 host_os_darwin=yes
 228                 SIZECMD="/usr/bin/stat -L -f %z"
 229                 SEDINPLACE="/usr/bin/sed -i ''"
 230                 STRIP_BINARIES=""
 231                 STRIP_SHARED="-S"
 232                 STRIP_STATIC="-S"
 233                 ;;
 234 esac
 235
 236 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 237 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 238 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 239 AC_SUBST(SIZECMD)
 240 AC_SUBST(SEDINPLACE)
 241 AC_SUBST(STRIP_BINARIES)
 242 AC_SUBST(STRIP_SHARED)
 243 AC_SUBST(STRIP_STATIC)
 244
 245 # Check for architecture, used in default makepkg.conf
 246 # (Note single space left after CARCHFLAGS)
 247 case "${host}" in
 248         i686-*)
 249                 CARCH="i686"
 250                 CARCHFLAGS="-march=i686 "
 251                 ;;
 252         x86_64-*)
 253                 CARCH="x86_64"
 254                 CARCHFLAGS="-march=x86-64 "
 255                 ;;
 256         ia64-*)
 257                 CARCH="ia64"
 258                 CARCHFLAGS="-march=ia64 "
 259                 ;;
 260         sparc-*)
 261                 CARCH="sparc"
 262                 CARCHFLAGS="-mcpu=v9 "
 263                 ;;
 264         ppc-* | powerpc-*)
 265                 CARCH="ppc"
 266                 CARCHFLAGS="-mcpu=750 "
 267                 ;;
 268         i386-*)
 269                 CARCH="i386"
 270                 CARCHFLAGS="-march=i386 "
 271                 ;;
 272         arm-*)
 273                 CARCH="arm"
 274                 CARCHFLAGS="-march=armv4 "
 275                 ;;
 276         *)
 277                 AC_MSG_WARN([[Your architecture is unknown for makepkg.conf, consider adding it to configure.ac]])
 278                 CARCH="unknown"
 279                 CARCHFLAGS=""
 280                 ;;
 281 esac
 282
 283 # Now do some things common to all architectures
 284 CHOST="${host}"
 285 AC_SUBST(CARCH)
 286 AC_SUBST(CARCHFLAGS)
 287 AC_SUBST(CHOST)
 288
 289 # Check for documentation support and status
 290 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 291 AC_MSG_CHECKING([for building documentation])
 292 if test "x$wantdoc" = "xyes" ; then
 293         if test $ASCIIDOC ; then
 294                 AC_MSG_RESULT([yes, enabled by configure])
 295         else
 296                 asciidoc="(warning : asciidoc not installed)"
 297                 AC_MSG_RESULT([yes $asciidoc])
 298         fi
 299         wantdoc=yes
 300 else
 301         AC_MSG_RESULT([no, disabled by configure])
 302         wantdoc=no
 303 fi
 304 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 305
 306 # Check for doxygen support and status
 307 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 308 AC_MSG_CHECKING([for doxygen])
 309 if test "x$wantdoxygen" = "xyes" ; then
 310         if test $DOXYGEN ; then
 311                 AC_MSG_RESULT([yes])
 312                 usedoxygen=yes
 313         else
 314                 AC_MSG_RESULT([no, doxygen missing])
 315                 usedoxygen=no
 316         fi
 317 else
 318         AC_MSG_RESULT([no, disabled by configure])
 319         usedoxygen=no
 320 fi
 321 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 322
 323 # Enable or disable debug code
 324 AC_MSG_CHECKING(for debug mode request)
 325 if test "x$debug" = "xyes" ; then
 326         AC_MSG_RESULT(yes)
 327         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 328         # Check for mcheck
 329         AC_CHECK_HEADERS([mcheck.h])
 330         # Check for -fstack-protector availability
 331         GCC_STACK_PROTECT_LIB
 332         GCC_STACK_PROTECT_CC
 333         GCC_FORTIFY_SOURCE_CC
 334         CFLAGS="$CFLAGS -g -Wall -Werror"
 335 else
 336         AC_MSG_RESULT(no)
 337         CFLAGS="$CFLAGS -Wall"
 338 fi
 339
 340 # Enable or disable use of git version in pacman version string
 341 AC_MSG_CHECKING(whether to use git version if available)
 342 if test "x$wantgitver" = "xyes" ; then
 343         AC_CHECK_PROGS([GIT], [git])
 344         AC_CHECK_FILE([.git/], hasgitdir=yes)
 345         if test $GIT -a "x$hasgitdir" = "xyes"; then
 346                 AC_MSG_RESULT([yes])
 347                 usegitver=yes
 348                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 349         else
 350                 AC_MSG_RESULT([no, git or .git dir missing])
 351                 usegitver=no
 352         fi
 353 else
 354         AC_MSG_RESULT([no, disabled by configure])
 355         usegitver=no
 356 fi
 357 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 358
 359 # Set root directory
 360 AC_SUBST(ROOTDIR)
 361 # Set package file extension
 362 AC_SUBST(PKGEXT)
 363 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 364 # Set source package file extension
 365 AC_SUBST(SRCEXT)
 366 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 367 # Set makepkg build script name
 368 AC_SUBST(BUILDSCRIPT)
 369 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 370
 371 # Configuration files
 372 AC_CONFIG_FILES([
 373 lib/libalpm/Makefile
 374 lib/libalpm/po/Makefile.in
 375 src/pacman/Makefile
 376 src/util/Makefile
 377 scripts/Makefile
 378 doc/Makefile
 379 etc/Makefile
 380 po/Makefile.in
 381 test/pacman/Makefile
 382 test/pacman/tests/Makefile
 383 test/util/Makefile
 384 contrib/Makefile
 385 Makefile
 386 ])
 387 AC_OUTPUT
 388
 389 echo "
 390 ${PACKAGE_NAME}:
 391
 392   Build information:
 393     source code location   : ${srcdir}
 394     prefix                 : ${prefix}
 395     sysconfdir             : $(eval echo ${sysconfdir})
 396        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 397     localstatedir          : $(eval echo ${localstatedir})
 398        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 399        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 400     compiler               : ${CC}
 401     compiler flags         : ${CFLAGS}
 402     defines                : ${DEFS}
 403
 404     Architecture           : ${CARCH}
 405     Architecture flags     : ${CARCHFLAGS}
 406     Host Type              : ${CHOST}
 407     Filesize command       : ${SIZECMD}
 408     In-place sed command   : ${SEDINPLACE}
 409
 410     libalpm version        : ${LIB_VERSION}
 411     libalpm version info   : ${LIB_VERSION_INFO}
 412     pacman version         : ${PACKAGE_VERSION}
 413     using git version      : ${usegitver}
 414
 415   Directory and file information:
 416     root working directory : ${ROOTDIR}
 417     package extension      : ${PKGEXT}
 418     source pkg extension   : ${SRCEXT}
 419     build script name      : ${BUILDSCRIPT}
 420
 421   Compilation options:
 422     Use libcurl            : ${with_libcurl}
 423     Use GPGME              : ${with_gpgme}
 424     Use OpenSSL            : ${with_openssl}
 425     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 426     Doxygen support        : ${usedoxygen}
 427     debug support          : ${debug}
 428 "
 429
 430 # vim:set ts=2 sw=2 noet: