configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [7])
  45 m4_define([lib_revision], [3])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [4])
  49 m4_define([pacman_version_minor], [0])
  50 m4_define([pacman_version_micro], [3])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58 AC_CONFIG_MACRO_DIR([m4])
  59 AC_CONFIG_AUX_DIR([build-aux])
  60
  61 AC_CANONICAL_HOST
  62 AM_INIT_AUTOMAKE([1.11])
  63 AM_SILENT_RULES([yes])
  64
  65 LT_INIT
  66 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  67 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  68
  69 # Respect empty CFLAGS during compiler tests
  70 if test "x$CFLAGS" != "x"; then
  71   CFLAGS=""
  72 fi
  73
  74 # Set subsitution values for version stuff in Makefiles and anywhere else,
  75 # and put LIB_VERSION in config.h
  76 AC_SUBST(LIB_VERSION)
  77 AC_SUBST(LIB_VERSION_INFO)
  78 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  79
  80 # Help line for root directory
  81 AC_ARG_WITH(root-dir,
  82         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  83         [ROOTDIR=$withval], [ROOTDIR=/])
  84
  85 # Help line for package extension
  86 AC_ARG_WITH(pkg-ext,
  87         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  88         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  89
  90 # Help line for source package directory
  91 AC_ARG_WITH(src-ext,
  92         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  93         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  94
  95 # Help line for buildscript filename
  96 AC_ARG_WITH(buildscript,
  97         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  98         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  99
 100 # Help line for changing shell used to run install scriptlets
 101 AC_ARG_WITH(scriptlet-shell,
 102         AS_HELP_STRING([--with-scriptlet-shell=shell],
 103                 [set the full path to the shell used to run install scriptlets]),
 104         [SCRIPTLET_SHELL=$withval], [SCRIPTLET_SHELL=/bin/sh])
 105
 106 # Help line for using OpenSSL
 107 AC_ARG_WITH(openssl,
 108         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
 109         [], [with_openssl=check])
 110
 111 # Help line for using gpgme
 112 AC_ARG_WITH(gpgme,
 113         AS_HELP_STRING([--with-gpgme], [use GPGME for PGP signature verification]),
 114         [], [with_gpgme=check])
 115
 116 # Help line for using libcurl
 117 AC_ARG_WITH(curl,
 118         AS_HELP_STRING([--with-libcurl], [use libcurl for the internal downloader]),
 119         [], [with_curl=check])
 120
 121 # Help line for documentation
 122 AC_ARG_ENABLE(doc,
 123         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 124         [wantdoc=$enableval], [wantdoc=yes])
 125
 126 # Help line for doxygen
 127 AC_ARG_ENABLE(doxygen,
 128         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 129         [wantdoxygen=$enableval], [wantdoxygen=no])
 130
 131 # Help line for debug
 132 AC_ARG_ENABLE(debug,
 133         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 134         [debug=$enableval], [debug=no])
 135
 136 # Help line for compiler warning flags
 137 AC_ARG_ENABLE(warningflags,
 138         AS_HELP_STRING([--enable-warningflags], [enable extra compiler warning flags]),
 139         [warningflags=$enableval], [warningflags=no])
 140
 141 # Help line for using git version in pacman version string
 142 AC_ARG_ENABLE(git-version,
 143         AS_HELP_STRING([--enable-git-version],
 144                 [enable use of git version in version string if available]),
 145         [wantgitver=$enableval], [wantgitver=no])
 146
 147 # Enable large file support if available (must be enabled before
 148 # testing compilation against gpgme).
 149 AC_SYS_LARGEFILE
 150
 151 # Checks for programs.
 152 AC_PROG_AWK
 153 AC_PROG_CC_C99
 154 AC_PROG_INSTALL
 155 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 156 AC_PATH_PROGS([BASH_SHELL], [bash bash4], [false])
 157
 158 AS_IF([test "x$BASH_SHELL" = "xfalse"],
 159         AC_MSG_WARN([*** bash >= 4.1.0 is required for pacman scripts]),
 160         [bash_version_major=`$BASH_SHELL -c 'echo "${BASH_VERSINFO[[0]]}"'`
 161         bash_version_minor=`$BASH_SHELL -c 'echo "${BASH_VERSINFO[[1]]}"'`
 162         ok=yes
 163         if test "$bash_version_major" -lt 4; then
 164                 ok=no
 165         fi
 166         if test "$bash_version_major" -eq 4 && test "$bash_version_minor" -lt 1; then
 167                 ok=no
 168         fi
 169         if test "$ok" = "no"; then
 170                 AC_MSG_ERROR([*** bash >= 4.1.0 is required for pacman scripts])
 171         fi
 172         unset bash_version_major bash_version_minor ok])
 173
 174 # find installed gettext
 175 AM_GNU_GETTEXT([external], [need-ngettext])
 176 AM_GNU_GETTEXT_VERSION(0.13.1)
 177
 178 AC_CHECK_LIB([m], [fabs], ,
 179         AC_MSG_ERROR([libm is needed to compile pacman!]))
 180
 181 # Check for libarchive
 182 PKG_CHECK_MODULES(LIBARCHIVE, [libarchive >= 2.8.0], ,
 183         AC_MSG_ERROR([*** libarchive >= 2.8.0 is needed to compile pacman!]))
 184
 185 # Check for OpenSSL
 186 have_openssl=no
 187 if test "x$with_openssl" != "xno"; then
 188         PKG_CHECK_MODULES(LIBSSL, [libcrypto],
 189                 [AC_DEFINE(HAVE_LIBSSL, 1, [Define if libcrypto is available]) have_openssl=yes], have_openssl=no)
 190         if test "x$have_openssl" = xno -a "x$with_openssl" = xyes; then
 191                 AC_MSG_ERROR([*** openssl support requested but libraries not found])
 192         fi
 193 fi
 194 AM_CONDITIONAL(HAVE_LIBSSL, [test "$have_openssl" = "yes"])
 195
 196 # Check for libcurl
 197 have_libcurl=no
 198 if test "x$with_libcurl" != "xno"; then
 199         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.19.4],
 200                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available]) have_libcurl=yes], have_libcurl=no)
 201         if test "x$have_libcurl" = xno -a "x$with_libcurl" = xyes; then
 202                 AC_MSG_ERROR([*** libcurl >= 7.19.4 is required for internal downloader support])
 203         fi
 204 fi
 205 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 206
 207 # Check for gpgme
 208 AC_MSG_CHECKING(whether to link with libgpgme)
 209 AS_IF([test "x$with_gpgme" != "xno"],
 210         [AC_MSG_RESULT([yes])],
 211         [AC_MSG_RESULT([no])])
 212
 213 have_gpgme=no
 214 AS_IF([test "x$with_gpgme" != "xno"],
 215         [AM_PATH_GPGME([1.3.0],
 216                 [LIBS_save="$LIBS"
 217                 CPPFLAGS_save="$CPPFLAGS"
 218                 CFLAGS_save="$CFLAGS"
 219
 220                 LIBS="$LIBS $GPGME_LIBS"
 221                 CPPFLAGS="$CPPFLAGS $GPGME_CPPFLAGS"
 222                 CFLAGS="$CFLAGS $GPGME_CFLAGS"
 223
 224                 AC_MSG_CHECKING([for sane gpgme])
 225                 AC_LINK_IFELSE(
 226                         [AC_LANG_PROGRAM(
 227                                 [[#include <gpgme.h>]],
 228                                 [[return gpgme_check_version("1.3.0");]])],
 229                         [AC_MSG_RESULT([yes])
 230                         have_gpgme=yes
 231                         AC_DEFINE([HAVE_LIBGPGME], [1], [Define if gpgme should be used to provide GPG signature support.])],
 232                         [AC_MSG_RESULT([no])
 233                         have_gpgme=no
 234                         unset GPGME_LIBS
 235                         unset GPGME_CFLAGS]
 236                         AS_IF([test "x$with_gpgme" = "xyes"],
 237                                 [AC_MSG_FAILURE([*** gpgme >= 1.3.0 is needed for GPG signature support])])
 238                         )],
 239                 [with_gpgme=no])]
 240                 [LIBS="$LIBS_save"
 241                 CPPFLAGS="$CPPFLAGS_save"
 242                 CFLAGS="$CFLAGS_save"
 243                 unset CPPFLAGS_save
 244                 unset CFLAGS_save])
 245 AS_IF([test "x$have_gpgme" = xno -a "x$with_gpgme" = xyes],
 246         [AC_MSG_FAILURE([--with-gpgme was given, but gpgme was not found])])
 247 AM_CONDITIONAL([HAVE_LIBGPGME], [test "x$have_gpgme" = "xyes"])
 248
 249 # Checks for header files.
 250 AC_CHECK_HEADERS([fcntl.h float.h glob.h libintl.h limits.h locale.h \
 251                   mntent.h netinet/in.h netinet/tcp.h \
 252                   stddef.h string.h sys/ioctl.h \
 253                   sys/mnttab.h sys/mount.h \
 254                   sys/param.h sys/statvfs.h sys/time.h sys/types.h \
 255                   sys/ucred.h syslog.h termios.h wchar.h])
 256
 257 # Checks for typedefs, structures, and compiler characteristics.
 258 AC_C_INLINE
 259 AC_TYPE_INT64_T
 260 AC_TYPE_MODE_T
 261 AC_TYPE_OFF_T
 262 AC_TYPE_PID_T
 263 AC_TYPE_SIZE_T
 264 AC_TYPE_SSIZE_T
 265 AC_STRUCT_TM
 266 AC_TYPE_UID_T
 267 AC_STRUCT_DIRENT_D_TYPE
 268 PATH_MAX_DEFINED
 269
 270 # Checks for library functions.
 271 AC_FUNC_FORK
 272 AC_FUNC_GETMNTENT
 273 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 274 AC_FUNC_MALLOC
 275 AC_FUNC_MKTIME
 276 AC_FUNC_STRCOLL
 277 AC_CHECK_FUNCS([dup2 getcwd geteuid getmntinfo gettimeofday memmove memset \
 278                 mkdir realpath regcomp rmdir setenv setlocale strcasecmp \
 279                 strchr strcspn strdup strerror strndup strrchr strsep strstr \
 280                 strtol swprintf tcflush wcwidth uname])
 281 AC_CHECK_MEMBERS([struct stat.st_blksize],,,[[#include <sys/stat.h>]])
 282
 283 # For the diskspace code
 284 FS_STATS_TYPE
 285 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 286 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 287                   #include <sys/mount.h>]])
 288
 289 # Check if we can use symbol visibility support in GCC
 290 GCC_VISIBILITY_CC
 291 # Check if we have -fgnu89-inline flag
 292 GCC_GNU89_INLINE_CC
 293
 294 # Host-dependant definitions
 295 INODECMD="stat -c '%i %n'"
 296 SIZECMD="stat -c %s"
 297 SEDINPLACE="sed -i"
 298 STRIP_BINARIES="--strip-all"
 299 STRIP_SHARED="--strip-unneeded"
 300 STRIP_STATIC="--strip-debug"
 301 case "${host_os}" in
 302         *bsd*)
 303                 INODECMD="stat -f '%i %n'"
 304                 SIZECMD="stat -f %z"
 305                 SEDINPLACE="sed -i \"\""
 306                 ;;
 307         cygwin*)
 308                 host_os_cygwin=yes
 309                 AC_DEFINE([CYGWIN], [1], [Define if host OS is cygwin])
 310                 ;;
 311         darwin*)
 312                 host_os_darwin=yes
 313                 INODECMD="/usr/bin/stat -f '%i %n'"
 314                 SIZECMD="/usr/bin/stat -f %z"
 315                 SEDINPLACE="/usr/bin/sed -i ''"
 316                 STRIP_BINARIES=""
 317                 STRIP_SHARED="-S"
 318                 STRIP_STATIC="-S"
 319                 ;;
 320 esac
 321
 322 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 323 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 324 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 325 AC_SUBST(INODECMD)
 326 AC_SUBST(SIZECMD)
 327 AC_SUBST(SEDINPLACE)
 328 AC_SUBST(STRIP_BINARIES)
 329 AC_SUBST(STRIP_SHARED)
 330 AC_SUBST(STRIP_STATIC)
 331
 332 # Variables plugged into makepkg.conf
 333 CARCH="${host%%-*}"
 334 CHOST="${host}"
 335 AC_SUBST(CARCH)
 336 AC_SUBST(CHOST)
 337
 338 # Check for documentation support and status
 339 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 340 AC_MSG_CHECKING([for building documentation])
 341 if test "x$wantdoc" = "xyes" ; then
 342         if test $ASCIIDOC ; then
 343                 AC_MSG_RESULT([yes, enabled by configure])
 344         else
 345                 asciidoc="(warning : asciidoc not installed)"
 346                 AC_MSG_RESULT([yes $asciidoc])
 347         fi
 348         wantdoc=yes
 349 else
 350         AC_MSG_RESULT([no, disabled by configure])
 351         wantdoc=no
 352 fi
 353 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 354
 355 # Check for doxygen support and status
 356 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 357 AC_MSG_CHECKING([for doxygen])
 358 if test "x$wantdoxygen" = "xyes" ; then
 359         if test $DOXYGEN ; then
 360                 AC_MSG_RESULT([yes])
 361                 usedoxygen=yes
 362         else
 363                 AC_MSG_RESULT([no, doxygen missing])
 364                 usedoxygen=no
 365         fi
 366 else
 367         AC_MSG_RESULT([no, disabled by configure])
 368         usedoxygen=no
 369 fi
 370 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 371
 372 # Enable or disable debug code
 373 AC_MSG_CHECKING(for debug mode request)
 374 if test "x$debug" = "xyes" ; then
 375         AC_MSG_RESULT(yes)
 376         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 377         # Check for -fstack-protector availability
 378         GCC_STACK_PROTECT_LIB
 379         GCC_STACK_PROTECT_CC
 380         GCC_FORTIFY_SOURCE_CC
 381         WARNING_CFLAGS="-g -Wall -Werror"
 382 else
 383         AC_MSG_RESULT(no)
 384         WARNING_CFLAGS="-Wall"
 385 fi
 386
 387 # Enable or disable compiler warning flags
 388 AC_MSG_CHECKING(for excessive compiler warning flags)
 389 if test "x$warningflags" = "xyes" ; then
 390         AC_MSG_RESULT(yes)
 391         CFLAGS_ADD([-Wcast-align], [WARNING_CFLAGS])
 392         CFLAGS_ADD([-Wclobbered], [WARNING_CFLAGS])
 393         CFLAGS_ADD([-Wempty-body], [WARNING_CFLAGS])
 394         CFLAGS_ADD([-Wfloat-equal], [WARNING_CFLAGS])
 395         CFLAGS_ADD([-Wformat-nonliteral], [WARNING_CFLAGS])
 396         CFLAGS_ADD([-Wformat-security], [WARNING_CFLAGS])
 397         CFLAGS_ADD([-Wignored-qualifiers], [WARNING_CFLAGS])
 398         CFLAGS_ADD([-Winit-self], [WARNING_CFLAGS])
 399         CFLAGS_ADD([-Wlogical-op], [WARNING_CFLAGS])
 400         CFLAGS_ADD([-Wmissing-declarations], [WARNING_CFLAGS])
 401         CFLAGS_ADD([-Wmissing-field-initializers], [WARNING_CFLAGS])
 402         CFLAGS_ADD([-Wmissing-parameter-type], [WARNING_CFLAGS])
 403         CFLAGS_ADD([-Wmissing-prototypes], [WARNING_CFLAGS])
 404         CFLAGS_ADD([-Wold-style-declaration], [WARNING_CFLAGS])
 405         CFLAGS_ADD([-Woverride-init], [WARNING_CFLAGS])
 406         CFLAGS_ADD([-Wpointer-arith], [WARNING_CFLAGS])
 407         CFLAGS_ADD([-Wredundant-decls], [WARNING_CFLAGS])
 408         CFLAGS_ADD([-Wshadow], [WARNING_CFLAGS])
 409         CFLAGS_ADD([-Wsign-compare], [WARNING_CFLAGS])
 410         CFLAGS_ADD([-Wstrict-aliasing], [WARNING_CFLAGS])
 411         CFLAGS_ADD([-Wstrict-overflow=5], [WARNING_CFLAGS])
 412         CFLAGS_ADD([-Wstrict-prototypes], [WARNING_CFLAGS])
 413         CFLAGS_ADD([-Wtype-limits], [WARNING_CFLAGS])
 414         CFLAGS_ADD([-Wuninitialized], [WARNING_CFLAGS])
 415         CFLAGS_ADD([-Wunused-but-set-parameter], [WARNING_CFLAGS])
 416         CFLAGS_ADD([-Wunused-parameter], [WARNING_CFLAGS])
 417         CFLAGS_ADD([-Wwrite-strings], [WARNING_CFLAGS])
 418 else
 419         AC_MSG_RESULT(no)
 420 fi
 421
 422 # Enable or disable use of git version in pacman version string
 423 AC_MSG_CHECKING(whether to use git version if available)
 424 if test "x$wantgitver" = "xyes" ; then
 425         AC_CHECK_PROGS([GIT], [git])
 426         AC_CHECK_FILE([.git/], hasgitdir=yes)
 427         if test $GIT -a "x$hasgitdir" = "xyes"; then
 428                 AC_MSG_RESULT([yes])
 429                 usegitver=yes
 430                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 431         else
 432                 AC_MSG_RESULT([no, git or .git dir missing])
 433                 usegitver=no
 434         fi
 435 else
 436         AC_MSG_RESULT([no, disabled by configure])
 437         usegitver=no
 438 fi
 439 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 440
 441 # Set root directory
 442 AC_SUBST(ROOTDIR)
 443 AC_DEFINE_UNQUOTED([ROOTDIR], "$ROOTDIR", [The location of the root operating directory])
 444 # Set package file extension
 445 AC_SUBST(PKGEXT)
 446 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 447 # Set source package file extension
 448 AC_SUBST(SRCEXT)
 449 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 450 # Set makepkg build script name
 451 AC_SUBST(BUILDSCRIPT)
 452 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 453 # Set shell used by install scriptlets
 454 AC_SUBST(SCRIPTLET_SHELL)
 455 AC_DEFINE_UNQUOTED([SCRIPTLET_SHELL], "$SCRIPTLET_SHELL", [The full path of the shell used to run install scriptlets])
 456
 457 # Configuration files
 458 AC_CONFIG_FILES([
 459 lib/libalpm/Makefile
 460 lib/libalpm/po/Makefile.in
 461 lib/libalpm/libalpm.pc
 462 src/pacman/Makefile
 463 src/pacman/po/Makefile.in
 464 src/util/Makefile
 465 scripts/Makefile
 466 scripts/po/Makefile.in
 467 doc/Makefile
 468 etc/Makefile
 469 test/pacman/Makefile
 470 test/pacman/tests/Makefile
 471 test/scripts/Makefile
 472 test/util/Makefile
 473 contrib/Makefile
 474 Makefile
 475 ])
 476 AC_OUTPUT
 477
 478 echo "
 479 ${PACKAGE_NAME}:
 480
 481   Build information:
 482     source code location   : ${srcdir}
 483     prefix                 : ${prefix}
 484     sysconfdir             : $(eval echo ${sysconfdir})
 485        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 486     localstatedir          : $(eval echo ${localstatedir})
 487        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 488        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 489
 490     compiler               : ${CC}
 491     preprocessor flags     : ${CPPFLAGS}
 492     compiler flags         : ${WARNING_CFLAGS} ${CFLAGS}
 493     defines                : ${DEFS}
 494     library flags          : ${LIBS} ${LIBSSL_LIBS} ${LIBARCHIVE_LIBS} ${LIBCURL_LIBS} ${GPGME_LIBS}
 495     linker flags           : ${LDFLAGS}
 496
 497     Architecture           : ${CARCH}
 498     Host Type              : ${CHOST}
 499     File inode command     : ${INODECMD}
 500     Filesize command       : ${SIZECMD}
 501     In-place sed command   : ${SEDINPLACE}
 502
 503     libalpm version        : ${LIB_VERSION}
 504     libalpm version info   : ${LIB_VERSION_INFO}
 505     pacman version         : ${PACKAGE_VERSION}
 506     using git version      : ${usegitver}
 507
 508   Directory and file information:
 509     root working directory : ${ROOTDIR}
 510     package extension      : ${PKGEXT}
 511     source pkg extension   : ${SRCEXT}
 512     build script name      : ${BUILDSCRIPT}
 513
 514   Compilation options:
 515     Use libcurl            : ${have_libcurl}
 516     Use GPGME              : ${have_gpgme}
 517     Use OpenSSL            : ${have_openssl}
 518     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 519     Doxygen support        : ${usedoxygen}
 520     debug support          : ${debug}
 521     extra warning flags    : ${warningflags}
 522     use git version        : ${wantgitver}
 523 "
 524
 525 # vim:set ts=2 sw=2 noet: