configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [7])
  45 m4_define([lib_revision], [3])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [4])
  49 m4_define([pacman_version_minor], [0])
  50 m4_define([pacman_version_micro], [3])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58 AC_CONFIG_MACRO_DIR([m4])
  59 AC_CONFIG_AUX_DIR([build-aux])
  60
  61 AC_CANONICAL_HOST
  62 AM_INIT_AUTOMAKE([1.11])
  63 AM_SILENT_RULES([yes])
  64
  65 LT_INIT
  66 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  67 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  68
  69 # Set subsitution values for version stuff in Makefiles and anywhere else,
  70 # and put LIB_VERSION in config.h
  71 AC_SUBST(LIB_VERSION)
  72 AC_SUBST(LIB_VERSION_INFO)
  73 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  74
  75 # Help line for root directory
  76 AC_ARG_WITH(root-dir,
  77         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  78         [ROOTDIR=$withval], [ROOTDIR=/])
  79
  80 # Help line for package extension
  81 AC_ARG_WITH(pkg-ext,
  82         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  83         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  84
  85 # Help line for source package directory
  86 AC_ARG_WITH(src-ext,
  87         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  88         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  89
  90 # Help line for buildscript filename
  91 AC_ARG_WITH(buildscript,
  92         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  93         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  94
  95 # Help line for changing shell used to run install scriptlets
  96 AC_ARG_WITH(scriptlet-shell,
  97         AS_HELP_STRING([--with-scriptlet-shell=shell],
  98                 [set the full path to the shell used to run install scriptlets]),
  99         [SCRIPTLET_SHELL=$withval], [SCRIPTLET_SHELL=/bin/sh])
 100
 101 # Help line for using OpenSSL
 102 AC_ARG_WITH(openssl,
 103         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
 104         [], [with_openssl=check])
 105
 106 # Help line for using gpgme
 107 AC_ARG_WITH(gpgme,
 108         AS_HELP_STRING([--with-gpgme], [use GPGME for PGP signature verification]),
 109         [], [with_gpgme=check])
 110
 111 # Help line for using libcurl
 112 AC_ARG_WITH(curl,
 113         AS_HELP_STRING([--with-libcurl], [use libcurl for the internal downloader]),
 114         [], [with_curl=check])
 115
 116 # Help line for documentation
 117 AC_ARG_ENABLE(doc,
 118         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 119         [wantdoc=$enableval], [wantdoc=yes])
 120
 121 # Help line for doxygen
 122 AC_ARG_ENABLE(doxygen,
 123         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 124         [wantdoxygen=$enableval], [wantdoxygen=no])
 125
 126 # Help line for debug
 127 AC_ARG_ENABLE(debug,
 128         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 129         [debug=$enableval], [debug=no])
 130
 131 # Help line for compiler warning flags
 132 AC_ARG_ENABLE(warningflags,
 133         AS_HELP_STRING([--enable-warningflags], [enable extra compiler warning flags]),
 134         [warningflags=$enableval], [warningflags=no])
 135
 136 # Help line for using git version in pacman version string
 137 AC_ARG_ENABLE(git-version,
 138         AS_HELP_STRING([--enable-git-version],
 139                 [enable use of git version in version string if available]),
 140         [wantgitver=$enableval], [wantgitver=no])
 141
 142 # Enable large file support if available (must be enabled before
 143 # testing compilation against gpgme).
 144 AC_SYS_LARGEFILE
 145
 146 # Checks for programs.
 147 AC_PROG_AWK
 148 AC_PROG_CC_C99
 149 AC_PROG_INSTALL
 150 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 151 AC_PATH_PROGS([BASH_SHELL], [bash bash4], [false])
 152
 153 AS_IF([test "x$BASH_SHELL" = "xfalse"],
 154         AC_MSG_WARN([*** bash >= 4.1.0 is required for pacman scripts]),
 155         [bash_version_major=`$BASH_SHELL -c 'echo "${BASH_VERSINFO[[0]]}"'`
 156         bash_version_minor=`$BASH_SHELL -c 'echo "${BASH_VERSINFO[[1]]}"'`
 157         ok=yes
 158         if test "$bash_version_major" -lt 4; then
 159                 ok=no
 160         fi
 161         if test "$bash_version_major" -eq 4 && test "$bash_version_minor" -lt 1; then
 162                 ok=no
 163         fi
 164         if test "$ok" = "no"; then
 165                 AC_MSG_ERROR([*** bash >= 4.1.0 is required for pacman scripts])
 166         fi
 167         unset bash_version_major bash_version_minor ok])
 168
 169 # find installed gettext
 170 AM_GNU_GETTEXT([external], [need-ngettext])
 171 AM_GNU_GETTEXT_VERSION(0.13.1)
 172
 173 AC_CHECK_LIB([m], [fabs], ,
 174         AC_MSG_ERROR([libm is needed to compile pacman!]))
 175
 176 # Check for libarchive
 177 PKG_CHECK_MODULES(LIBARCHIVE, [libarchive >= 2.8.0], ,
 178         AC_MSG_ERROR([*** libarchive >= 2.8.0 is needed to compile pacman!]))
 179
 180 # Check for OpenSSL
 181 have_openssl=no
 182 if test "x$with_openssl" != "xno"; then
 183         PKG_CHECK_MODULES(LIBSSL, [libcrypto],
 184                 [AC_DEFINE(HAVE_LIBSSL, 1, [Define if libcrypto is available]) have_openssl=yes], have_openssl=no)
 185         if test "x$have_openssl" = xno -a "x$with_openssl" = xyes; then
 186                 AC_MSG_ERROR([*** openssl support requested but libraries not found])
 187         fi
 188 fi
 189 AM_CONDITIONAL(HAVE_LIBSSL, [test "$have_openssl" = "yes"])
 190
 191 # Check for libcurl
 192 have_libcurl=no
 193 if test "x$with_libcurl" != "xno"; then
 194         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.19.4],
 195                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available]) have_libcurl=yes], have_libcurl=no)
 196         if test "x$have_libcurl" = xno -a "x$with_libcurl" = xyes; then
 197                 AC_MSG_ERROR([*** libcurl >= 7.19.4 is required for internal downloader support])
 198         fi
 199 fi
 200 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 201
 202 # Check for gpgme
 203 AC_MSG_CHECKING(whether to link with libgpgme)
 204 AS_IF([test "x$with_gpgme" != "xno"],
 205         [AC_MSG_RESULT([yes])],
 206         [AC_MSG_RESULT([no])])
 207
 208 have_gpgme=no
 209 AS_IF([test "x$with_gpgme" != "xno"],
 210         [AM_PATH_GPGME([1.3.0],
 211                 [LIBS_save="$LIBS"
 212                 CPPFLAGS_save="$CPPFLAGS"
 213                 CFLAGS_save="$CFLAGS"
 214
 215                 LIBS="$LIBS $GPGME_LIBS"
 216                 CPPFLAGS="$CPPFLAGS $GPGME_CPPFLAGS"
 217                 CFLAGS="$CFLAGS $GPGME_CFLAGS"
 218
 219                 AC_MSG_CHECKING([for sane gpgme])
 220                 AC_LINK_IFELSE(
 221                         [AC_LANG_PROGRAM(
 222                                 [[#include <gpgme.h>]],
 223                                 [[return gpgme_check_version("1.3.0");]])],
 224                         [AC_MSG_RESULT([yes])
 225                         have_gpgme=yes
 226                         AC_DEFINE([HAVE_LIBGPGME], [1], [Define if gpgme should be used to provide GPG signature support.])],
 227                         [AC_MSG_RESULT([no])
 228                         have_gpgme=no
 229                         unset GPGME_LIBS
 230                         unset GPGME_CFLAGS]
 231                         AS_IF([test "x$with_gpgme" = "xyes"],
 232                                 [AC_MSG_FAILURE([*** gpgme >= 1.3.0 is needed for GPG signature support])])
 233                         )],
 234                 [with_gpgme=no])]
 235                 [LIBS="$LIBS_save"
 236                 CPPFLAGS="$CPPFLAGS_save"
 237                 CFLAGS="$CFLAGS_save"
 238                 unset CPPFLAGS_save
 239                 unset CFLAGS_save])
 240 AS_IF([test "x$have_gpgme" = xno -a "x$with_gpgme" = xyes],
 241         [AC_MSG_FAILURE([--with-gpgme was given, but gpgme was not found])])
 242 AM_CONDITIONAL([HAVE_LIBGPGME], [test "x$have_gpgme" = "xyes"])
 243
 244 # Checks for header files.
 245 AC_CHECK_HEADERS([fcntl.h float.h glob.h libintl.h limits.h locale.h \
 246                   mntent.h netinet/in.h netinet/tcp.h \
 247                   stddef.h string.h sys/ioctl.h \
 248                   sys/mnttab.h sys/mount.h \
 249                   sys/param.h sys/statvfs.h sys/time.h sys/types.h \
 250                   sys/ucred.h syslog.h termios.h wchar.h])
 251
 252 # Checks for typedefs, structures, and compiler characteristics.
 253 AC_C_INLINE
 254 AC_TYPE_INT64_T
 255 AC_TYPE_MODE_T
 256 AC_TYPE_OFF_T
 257 AC_TYPE_PID_T
 258 AC_TYPE_SIZE_T
 259 AC_TYPE_SSIZE_T
 260 AC_STRUCT_TM
 261 AC_TYPE_UID_T
 262 AC_STRUCT_DIRENT_D_TYPE
 263 PATH_MAX_DEFINED
 264
 265 # Checks for library functions.
 266 AC_FUNC_FORK
 267 AC_FUNC_GETMNTENT
 268 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 269 AC_FUNC_MALLOC
 270 AC_FUNC_MKTIME
 271 AC_FUNC_STRCOLL
 272 AC_CHECK_FUNCS([dup2 getcwd geteuid getmntinfo gettimeofday memmove memset \
 273                 mkdir realpath regcomp rmdir setenv setlocale strcasecmp \
 274                 strchr strcspn strdup strerror strndup strrchr strsep strstr \
 275                 strtol swprintf tcflush wcwidth uname])
 276 AC_CHECK_MEMBERS([struct stat.st_blksize],,,[[#include <sys/stat.h>]])
 277
 278 # For the diskspace code
 279 FS_STATS_TYPE
 280 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 281 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 282                   #include <sys/mount.h>]])
 283
 284 # Check if we can use symbol visibility support in GCC
 285 GCC_VISIBILITY_CC
 286 # Check if we have -fgnu89-inline flag
 287 GCC_GNU89_INLINE_CC
 288
 289 # Host-dependant definitions
 290 SIZECMD="stat -c %s"
 291 SEDINPLACE="sed -i"
 292 STRIP_BINARIES="--strip-all"
 293 STRIP_SHARED="--strip-unneeded"
 294 STRIP_STATIC="--strip-debug"
 295 case "${host_os}" in
 296         *bsd*)
 297                 SIZECMD="stat -f %z"
 298                 SEDINPLACE="sed -i \"\""
 299                 ;;
 300         cygwin*)
 301                 host_os_cygwin=yes
 302                 AC_DEFINE([CYGWIN], [1], [Define if host OS is cygwin])
 303                 ;;
 304         darwin*)
 305                 host_os_darwin=yes
 306                 SIZECMD="/usr/bin/stat -f %z"
 307                 SEDINPLACE="/usr/bin/sed -i ''"
 308                 STRIP_BINARIES=""
 309                 STRIP_SHARED="-S"
 310                 STRIP_STATIC="-S"
 311                 ;;
 312 esac
 313
 314 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 315 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 316 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 317 AC_SUBST(SIZECMD)
 318 AC_SUBST(SEDINPLACE)
 319 AC_SUBST(STRIP_BINARIES)
 320 AC_SUBST(STRIP_SHARED)
 321 AC_SUBST(STRIP_STATIC)
 322
 323 # Variables plugged into makepkg.conf
 324 CARCH="${host%%-*}"
 325 CHOST="${host}"
 326 AC_SUBST(CARCH)
 327 AC_SUBST(CHOST)
 328
 329 # Check for documentation support and status
 330 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 331 AC_MSG_CHECKING([for building documentation])
 332 if test "x$wantdoc" = "xyes" ; then
 333         if test $ASCIIDOC ; then
 334                 AC_MSG_RESULT([yes, enabled by configure])
 335         else
 336                 asciidoc="(warning : asciidoc not installed)"
 337                 AC_MSG_RESULT([yes $asciidoc])
 338         fi
 339         wantdoc=yes
 340 else
 341         AC_MSG_RESULT([no, disabled by configure])
 342         wantdoc=no
 343 fi
 344 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 345
 346 # Check for doxygen support and status
 347 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 348 AC_MSG_CHECKING([for doxygen])
 349 if test "x$wantdoxygen" = "xyes" ; then
 350         if test $DOXYGEN ; then
 351                 AC_MSG_RESULT([yes])
 352                 usedoxygen=yes
 353         else
 354                 AC_MSG_RESULT([no, doxygen missing])
 355                 usedoxygen=no
 356         fi
 357 else
 358         AC_MSG_RESULT([no, disabled by configure])
 359         usedoxygen=no
 360 fi
 361 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 362
 363 # Enable or disable debug code
 364 AC_MSG_CHECKING(for debug mode request)
 365 if test "x$debug" = "xyes" ; then
 366         AC_MSG_RESULT(yes)
 367         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 368         # Check for -fstack-protector availability
 369         GCC_STACK_PROTECT_LIB
 370         GCC_STACK_PROTECT_CC
 371         GCC_FORTIFY_SOURCE_CC
 372         WARNING_CFLAGS="-g -Wall -Werror"
 373 else
 374         AC_MSG_RESULT(no)
 375         WARNING_CFLAGS="-Wall"
 376 fi
 377
 378 # Enable or disable compiler warning flags
 379 AC_MSG_CHECKING(for excessive compiler warning flags)
 380 if test "x$warningflags" = "xyes" ; then
 381         AC_MSG_RESULT(yes)
 382         CFLAGS_ADD([-Wcast-align], [WARNING_CFLAGS])
 383         CFLAGS_ADD([-Wclobbered], [WARNING_CFLAGS])
 384         CFLAGS_ADD([-Wempty-body], [WARNING_CFLAGS])
 385         CFLAGS_ADD([-Wfloat-equal], [WARNING_CFLAGS])
 386         CFLAGS_ADD([-Wformat-nonliteral], [WARNING_CFLAGS])
 387         CFLAGS_ADD([-Wformat-security], [WARNING_CFLAGS])
 388         CFLAGS_ADD([-Wignored-qualifiers], [WARNING_CFLAGS])
 389         CFLAGS_ADD([-Winit-self], [WARNING_CFLAGS])
 390         CFLAGS_ADD([-Wlogical-op], [WARNING_CFLAGS])
 391         CFLAGS_ADD([-Wmissing-declarations], [WARNING_CFLAGS])
 392         CFLAGS_ADD([-Wmissing-field-initializers], [WARNING_CFLAGS])
 393         CFLAGS_ADD([-Wmissing-parameter-type], [WARNING_CFLAGS])
 394         CFLAGS_ADD([-Wmissing-prototypes], [WARNING_CFLAGS])
 395         CFLAGS_ADD([-Wold-style-declaration], [WARNING_CFLAGS])
 396         CFLAGS_ADD([-Woverride-init], [WARNING_CFLAGS])
 397         CFLAGS_ADD([-Wpointer-arith], [WARNING_CFLAGS])
 398         CFLAGS_ADD([-Wredundant-decls], [WARNING_CFLAGS])
 399         CFLAGS_ADD([-Wshadow], [WARNING_CFLAGS])
 400         CFLAGS_ADD([-Wsign-compare], [WARNING_CFLAGS])
 401         CFLAGS_ADD([-Wstrict-aliasing], [WARNING_CFLAGS])
 402         CFLAGS_ADD([-Wstrict-overflow=5], [WARNING_CFLAGS])
 403         CFLAGS_ADD([-Wstrict-prototypes], [WARNING_CFLAGS])
 404         CFLAGS_ADD([-Wtype-limits], [WARNING_CFLAGS])
 405         CFLAGS_ADD([-Wuninitialized], [WARNING_CFLAGS])
 406         CFLAGS_ADD([-Wunused-but-set-parameter], [WARNING_CFLAGS])
 407         CFLAGS_ADD([-Wunused-parameter], [WARNING_CFLAGS])
 408         CFLAGS_ADD([-Wwrite-strings], [WARNING_CFLAGS])
 409 else
 410         AC_MSG_RESULT(no)
 411 fi
 412
 413 # Enable or disable use of git version in pacman version string
 414 AC_MSG_CHECKING(whether to use git version if available)
 415 if test "x$wantgitver" = "xyes" ; then
 416         AC_CHECK_PROGS([GIT], [git])
 417         AC_CHECK_FILE([.git/], hasgitdir=yes)
 418         if test $GIT -a "x$hasgitdir" = "xyes"; then
 419                 AC_MSG_RESULT([yes])
 420                 usegitver=yes
 421                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 422         else
 423                 AC_MSG_RESULT([no, git or .git dir missing])
 424                 usegitver=no
 425         fi
 426 else
 427         AC_MSG_RESULT([no, disabled by configure])
 428         usegitver=no
 429 fi
 430 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 431
 432 # Set root directory
 433 AC_SUBST(ROOTDIR)
 434 AC_DEFINE_UNQUOTED([ROOTDIR], "$ROOTDIR", [The location of the root operating directory])
 435 # Set package file extension
 436 AC_SUBST(PKGEXT)
 437 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 438 # Set source package file extension
 439 AC_SUBST(SRCEXT)
 440 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 441 # Set makepkg build script name
 442 AC_SUBST(BUILDSCRIPT)
 443 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 444 # Set shell used by install scriptlets
 445 AC_SUBST(SCRIPTLET_SHELL)
 446 AC_DEFINE_UNQUOTED([SCRIPTLET_SHELL], "$SCRIPTLET_SHELL", [The full path of the shell used to run install scriptlets])
 447
 448 # Configuration files
 449 AC_CONFIG_FILES([
 450 lib/libalpm/Makefile
 451 lib/libalpm/po/Makefile.in
 452 lib/libalpm/libalpm.pc
 453 src/pacman/Makefile
 454 src/pacman/po/Makefile.in
 455 src/util/Makefile
 456 scripts/Makefile
 457 scripts/po/Makefile.in
 458 doc/Makefile
 459 etc/Makefile
 460 test/pacman/Makefile
 461 test/pacman/tests/Makefile
 462 test/scripts/Makefile
 463 test/util/Makefile
 464 contrib/Makefile
 465 Makefile
 466 ])
 467 AC_OUTPUT
 468
 469 echo "
 470 ${PACKAGE_NAME}:
 471
 472   Build information:
 473     source code location   : ${srcdir}
 474     prefix                 : ${prefix}
 475     sysconfdir             : $(eval echo ${sysconfdir})
 476        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 477     localstatedir          : $(eval echo ${localstatedir})
 478        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 479        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 480
 481     compiler               : ${CC}
 482     preprocessor flags     : ${CPPFLAGS}
 483     compiler flags         : ${WARNING_CFLAGS} ${CFLAGS}
 484     defines                : ${DEFS}
 485     library flags          : ${LIBS} ${LIBSSL_LIBS} ${LIBARCHIVE_LIBS} ${LIBCURL_LIBS} ${GPGME_LIBS}
 486     linker flags           : ${LDFLAGS}
 487
 488     Architecture           : ${CARCH}
 489     Host Type              : ${CHOST}
 490     Filesize command       : ${SIZECMD}
 491     In-place sed command   : ${SEDINPLACE}
 492
 493     libalpm version        : ${LIB_VERSION}
 494     libalpm version info   : ${LIB_VERSION_INFO}
 495     pacman version         : ${PACKAGE_VERSION}
 496     using git version      : ${usegitver}
 497
 498   Directory and file information:
 499     root working directory : ${ROOTDIR}
 500     package extension      : ${PKGEXT}
 501     source pkg extension   : ${SRCEXT}
 502     build script name      : ${BUILDSCRIPT}
 503
 504   Compilation options:
 505     Use libcurl            : ${have_libcurl}
 506     Use GPGME              : ${have_gpgme}
 507     Use OpenSSL            : ${have_openssl}
 508     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 509     Doxygen support        : ${usedoxygen}
 510     debug support          : ${debug}
 511     extra warning flags    : ${warningflags}
 512     use git version        : ${wantgitver}
 513 "
 514
 515 # vim:set ts=2 sw=2 noet: