configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [7])
  45 m4_define([lib_revision], [1])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [4])
  49 m4_define([pacman_version_minor], [0])
  50 m4_define([pacman_version_micro], [1])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58
  59 AC_CANONICAL_HOST
  60 AM_INIT_AUTOMAKE
  61
  62 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  63 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  64
  65 # Set subsitution values for version stuff in Makefiles and anywhere else,
  66 # and put LIB_VERSION in config.h
  67 AC_SUBST(LIB_VERSION)
  68 AC_SUBST(LIB_VERSION_INFO)
  69 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  70
  71 # Help line for root directory
  72 AC_ARG_WITH(root-dir,
  73         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  74         [ROOTDIR=$withval], [ROOTDIR=/])
  75
  76 # Help line for package extension
  77 AC_ARG_WITH(pkg-ext,
  78         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  79         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  80
  81 # Help line for source package directory
  82 AC_ARG_WITH(src-ext,
  83         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  84         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  85
  86 # Help line for buildscript filename
  87 AC_ARG_WITH(buildscript,
  88         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  89         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  90
  91 # Help line for using OpenSSL
  92 AC_ARG_WITH(openssl,
  93         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
  94         [], [with_openssl=check])
  95
  96 # Help line for using gpgme
  97 AC_ARG_WITH(gpgme,
  98         AS_HELP_STRING([--with-gpgme], [use GPGME for PGP signature verification]),
  99         [], [with_gpgme=check])
 100
 101 # Check for useable libcurl
 102 LIBCURL_CHECK_CONFIG([yes], [7.19.4], [with_libcurl=yes], [with_libcurl=no])
 103
 104 # Help line for documentation
 105 AC_ARG_ENABLE(doc,
 106         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 107         [wantdoc=$enableval], [wantdoc=yes])
 108
 109 # Help line for doxygen
 110 AC_ARG_ENABLE(doxygen,
 111         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 112         [wantdoxygen=$enableval], [wantdoxygen=no])
 113
 114 # Help line for debug
 115 AC_ARG_ENABLE(debug,
 116         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 117         [debug=$enableval], [debug=no])
 118
 119 # Help line for using git version in pacman version string
 120 AC_ARG_ENABLE(git-version,
 121         AS_HELP_STRING([--enable-git-version],
 122                 [enable use of git version in version string if available]),
 123         [wantgitver=$enableval], [wantgitver=no])
 124
 125 # Checks for programs.
 126 AC_PROG_AWK
 127 AC_PROG_CC_C99
 128 AC_PROG_CXX
 129 AC_PROG_INSTALL
 130 AC_PROG_LN_S
 131 AC_PROG_MAKE_SET
 132 AC_PROG_LIBTOOL
 133 AC_PROG_RANLIB
 134 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 135 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 136
 137 # find installed gettext
 138 AM_GNU_GETTEXT([external], [need-ngettext])
 139 AM_GNU_GETTEXT_VERSION(0.13.1)
 140
 141 AC_CHECK_LIB([m], [fabs], ,
 142         AC_MSG_ERROR([libm is needed to compile pacman!]))
 143
 144 # Check for libarchive
 145 AC_CHECK_LIB([archive], [archive_read_data], ,
 146         AC_MSG_ERROR([libarchive is needed to compile pacman!]))
 147
 148 # Check for OpenSSL
 149 AC_MSG_CHECKING(whether to link with libssl)
 150 AS_IF([test "x$with_openssl" != "xno"],
 151         [AC_MSG_RESULT(yes)
 152         AC_CHECK_LIB([ssl], [MD5_Final], ,
 153         [if test "x$with_openssl" != "xcheck"; then
 154                 AC_MSG_FAILURE([--with-openssl was given, but -lssl was not found])
 155         fi],
 156         [-lcrypto])
 157         with_openssl=$ac_cv_lib_ssl_MD5_Final],
 158         AC_MSG_RESULT(no))
 159 AM_CONDITIONAL([HAVE_LIBSSL], [test "x$with_openssl" = "xyes"])
 160
 161 # Check for gpgme
 162 AC_MSG_CHECKING(whether to link with libgpgme)
 163 AS_IF([test "x$with_gpgme" != "xno"],
 164         [AC_MSG_RESULT(yes)
 165         AC_CHECK_LIB([gpgme], [gpgme_check_version], ,
 166         [if test "x$with_gpgme" != "xcheck"; then
 167                 AC_MSG_FAILURE([--with-ggpme was given, but -lgpgme was not found])
 168         fi],
 169         [-lgpgme])
 170         with_gpgme=$ac_cv_lib_gpgme_gpgme_check_version],
 171         AC_MSG_RESULT(no))
 172 AM_CONDITIONAL([HAVE_LIBGPGME], [test "x$with_gpgme" = "xyes"])
 173
 174 # Checks for header files.
 175 AC_CHECK_HEADERS([fcntl.h float.h glob.h libintl.h limits.h locale.h \
 176                   mntent.h netinet/in.h netinet/tcp.h \
 177                   stddef.h string.h sys/ioctl.h \
 178                   sys/mnttab.h sys/mount.h \
 179                   sys/param.h sys/statvfs.h sys/time.h sys/types.h \
 180                   sys/ucred.h syslog.h termios.h wchar.h])
 181
 182 # Checks for typedefs, structures, and compiler characteristics.
 183 AC_C_INLINE
 184 AC_TYPE_INT64_T
 185 AC_TYPE_MODE_T
 186 AC_TYPE_OFF_T
 187 AC_TYPE_PID_T
 188 AC_TYPE_SIZE_T
 189 AC_TYPE_SSIZE_T
 190 AC_STRUCT_TM
 191 AC_TYPE_UID_T
 192 AC_STRUCT_DIRENT_D_TYPE
 193 PATH_MAX_DEFINED
 194
 195 # Checks for library functions.
 196 AC_FUNC_FORK
 197 AC_FUNC_GETMNTENT
 198 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 199 AC_FUNC_MALLOC
 200 AC_FUNC_MKTIME
 201 AC_FUNC_STRCOLL
 202 AC_CHECK_FUNCS([dup2 getcwd geteuid getmntinfo gettimeofday memmove memset \
 203                 mkdir realpath regcomp rmdir setenv setlocale strcasecmp \
 204                 strchr strcspn strdup strerror strndup strrchr strsep strstr \
 205                 strtol swprintf tcflush wcwidth uname])
 206
 207 # For the diskspace code
 208 FS_STATS_TYPE
 209 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 210 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 211                   #include <sys/mount.h>]])
 212
 213 # Enable large file support if available
 214 AC_SYS_LARGEFILE
 215
 216 # Check if we can use symbol visibility support in GCC
 217 GCC_VISIBILITY_CC
 218 # Check if we have -fgnu89-inline flag
 219 GCC_GNU89_INLINE_CC
 220
 221 # Host-dependant definitions
 222 SIZECMD="stat -L -c %s"
 223 SEDINPLACE="sed -i"
 224 STRIP_BINARIES="--strip-all"
 225 STRIP_SHARED="--strip-unneeded"
 226 STRIP_STATIC="--strip-debug"
 227 case "${host_os}" in
 228         *bsd*)
 229                 SIZECMD="stat -L -f %z"
 230                 SEDINPLACE="sed -i \"\""
 231                 ;;
 232         cygwin*)
 233                 host_os_cygwin=yes
 234                 CFLAGS="$CFLAGS -DCYGWIN"
 235                 ;;
 236         darwin*)
 237                 host_os_darwin=yes
 238                 SIZECMD="/usr/bin/stat -L -f %z"
 239                 SEDINPLACE="/usr/bin/sed -i ''"
 240                 STRIP_BINARIES=""
 241                 STRIP_SHARED="-S"
 242                 STRIP_STATIC="-S"
 243                 ;;
 244 esac
 245
 246 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 247 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 248 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 249 AC_SUBST(SIZECMD)
 250 AC_SUBST(SEDINPLACE)
 251 AC_SUBST(STRIP_BINARIES)
 252 AC_SUBST(STRIP_SHARED)
 253 AC_SUBST(STRIP_STATIC)
 254
 255 # Variables plugged into makepkg.conf
 256 CARCH="${host%%-*}"
 257 CHOST="${host}"
 258 AC_SUBST(CARCH)
 259 AC_SUBST(CHOST)
 260
 261 # Check for documentation support and status
 262 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 263 AC_MSG_CHECKING([for building documentation])
 264 if test "x$wantdoc" = "xyes" ; then
 265         if test $ASCIIDOC ; then
 266                 AC_MSG_RESULT([yes, enabled by configure])
 267         else
 268                 asciidoc="(warning : asciidoc not installed)"
 269                 AC_MSG_RESULT([yes $asciidoc])
 270         fi
 271         wantdoc=yes
 272 else
 273         AC_MSG_RESULT([no, disabled by configure])
 274         wantdoc=no
 275 fi
 276 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 277
 278 # Check for doxygen support and status
 279 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 280 AC_MSG_CHECKING([for doxygen])
 281 if test "x$wantdoxygen" = "xyes" ; then
 282         if test $DOXYGEN ; then
 283                 AC_MSG_RESULT([yes])
 284                 usedoxygen=yes
 285         else
 286                 AC_MSG_RESULT([no, doxygen missing])
 287                 usedoxygen=no
 288         fi
 289 else
 290         AC_MSG_RESULT([no, disabled by configure])
 291         usedoxygen=no
 292 fi
 293 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 294
 295 # Enable or disable debug code
 296 AC_MSG_CHECKING(for debug mode request)
 297 if test "x$debug" = "xyes" ; then
 298         AC_MSG_RESULT(yes)
 299         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 300         # Check for mcheck
 301         AC_CHECK_HEADERS([mcheck.h])
 302         # Check for -fstack-protector availability
 303         GCC_STACK_PROTECT_LIB
 304         GCC_STACK_PROTECT_CC
 305         GCC_FORTIFY_SOURCE_CC
 306         CFLAGS="$CFLAGS -g -Wall -Werror"
 307 else
 308         AC_MSG_RESULT(no)
 309         CFLAGS="$CFLAGS -Wall"
 310 fi
 311
 312 # Enable or disable use of git version in pacman version string
 313 AC_MSG_CHECKING(whether to use git version if available)
 314 if test "x$wantgitver" = "xyes" ; then
 315         AC_CHECK_PROGS([GIT], [git])
 316         AC_CHECK_FILE([.git/], hasgitdir=yes)
 317         if test $GIT -a "x$hasgitdir" = "xyes"; then
 318                 AC_MSG_RESULT([yes])
 319                 usegitver=yes
 320                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 321         else
 322                 AC_MSG_RESULT([no, git or .git dir missing])
 323                 usegitver=no
 324         fi
 325 else
 326         AC_MSG_RESULT([no, disabled by configure])
 327         usegitver=no
 328 fi
 329 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 330
 331 # Set root directory
 332 AC_SUBST(ROOTDIR)
 333 # Set package file extension
 334 AC_SUBST(PKGEXT)
 335 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 336 # Set source package file extension
 337 AC_SUBST(SRCEXT)
 338 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 339 # Set makepkg build script name
 340 AC_SUBST(BUILDSCRIPT)
 341 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 342
 343 # Configuration files
 344 AC_CONFIG_FILES([
 345 lib/libalpm/Makefile
 346 lib/libalpm/po/Makefile.in
 347 src/pacman/Makefile
 348 src/pacman/po/Makefile.in
 349 src/util/Makefile
 350 scripts/Makefile
 351 scripts/po/Makefile.in
 352 doc/Makefile
 353 etc/Makefile
 354 test/pacman/Makefile
 355 test/pacman/tests/Makefile
 356 test/util/Makefile
 357 contrib/Makefile
 358 Makefile
 359 ])
 360 AC_OUTPUT
 361
 362 echo "
 363 ${PACKAGE_NAME}:
 364
 365   Build information:
 366     source code location   : ${srcdir}
 367     prefix                 : ${prefix}
 368     sysconfdir             : $(eval echo ${sysconfdir})
 369        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 370     localstatedir          : $(eval echo ${localstatedir})
 371        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 372        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 373
 374     compiler               : ${CC}
 375     preprocessor flags     : ${CPPFLAGS}
 376     compiler flags         : ${CFLAGS}
 377     defines                : ${DEFS}
 378     library flags          : ${LIBS}
 379     linker flags           : ${LDFLAGS}
 380
 381     Architecture           : ${CARCH}
 382     Host Type              : ${CHOST}
 383     Filesize command       : ${SIZECMD}
 384     In-place sed command   : ${SEDINPLACE}
 385
 386     libalpm version        : ${LIB_VERSION}
 387     libalpm version info   : ${LIB_VERSION_INFO}
 388     pacman version         : ${PACKAGE_VERSION}
 389     using git version      : ${usegitver}
 390
 391   Directory and file information:
 392     root working directory : ${ROOTDIR}
 393     package extension      : ${PKGEXT}
 394     source pkg extension   : ${SRCEXT}
 395     build script name      : ${BUILDSCRIPT}
 396
 397   Compilation options:
 398     Use libcurl            : ${with_libcurl}
 399     Use GPGME              : ${with_gpgme}
 400     Use OpenSSL            : ${with_openssl}
 401     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 402     Doxygen support        : ${usedoxygen}
 403     debug support          : ${debug}
 404 "
 405
 406 # vim:set ts=2 sw=2 noet: