configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3 # Minimum version of autoconf required
   4 AC_PREREQ(2.62)
   5
   6 # UPDATING VERSION NUMBERS FOR RELEASES
   7 #
   8 # libalpm:
   9 # current
  10 #   The most recent interface number that this library implements.
  11 # revision
  12 #   The implementation number of the current interface.
  13 # age
  14 #   The difference between the newest and oldest interfaces that this library
  15 #   implements. In other words, the library implements all the interface
  16 #   numbers in the range from number current - age to current.
  17 #
  18 # 1. Start with version information of `0:0:0' for each libtool library.
  19 # 2. Update the version information only immediately before a public release of
  20 #    your software. More frequent updates are unnecessary, and only guarantee
  21 #    that the current interface number gets larger faster.
  22 # 3. If the library source code has changed at all since the last update, then
  23 #    increment revision (`c:r:a' becomes `c:r+1:a').
  24 # 4. If any interfaces have been added, removed, or changed since the last
  25 #    update, increment current, and set revision to 0.
  26 # 5. If any interfaces have been added since the last public release, then
  27 #    increment age.
  28 # 6. If any interfaces have been removed since the last public release, then
  29 #    set age to 0.
  30 #
  31 # pacman:
  32 #   Extreme huge major changes:
  33 #     pacman_version_major += 1
  34 #     pacman_version_minor = 0
  35 #     pacman_version_micro = 0
  36 #
  37 #   Real releases:
  38 #     pacman_version_minor += 1
  39 #     pacman_version_micro = 0
  40 #
  41 #   Bugfix releases:
  42 #     pacman_version_micro += 1
  43
  44 m4_define([lib_current], [7])
  45 m4_define([lib_revision], [3])
  46 m4_define([lib_age], [0])
  47
  48 m4_define([pacman_version_major], [4])
  49 m4_define([pacman_version_minor], [0])
  50 m4_define([pacman_version_micro], [3])
  51 m4_define([pacman_version],
  52           [pacman_version_major.pacman_version_minor.pacman_version_micro])
  53
  54 # Autoconf initialization
  55 AC_INIT([pacman], [pacman_version], [pacman-dev@archlinux.org])
  56 AC_CONFIG_SRCDIR([config.h.in])
  57 AC_CONFIG_HEADERS([config.h])
  58 AC_CONFIG_MACRO_DIR([m4])
  59 AC_CONFIG_AUX_DIR([build-aux])
  60
  61 AC_CANONICAL_HOST
  62 AM_INIT_AUTOMAKE([1.11])
  63 AM_SILENT_RULES([yes])
  64
  65 LT_INIT
  66 LIB_VERSION=`expr lib_current - lib_age`.lib_age.lib_revision
  67 LIB_VERSION_INFO="lib_current:lib_revision:lib_age"
  68
  69 # Set subsitution values for version stuff in Makefiles and anywhere else,
  70 # and put LIB_VERSION in config.h
  71 AC_SUBST(LIB_VERSION)
  72 AC_SUBST(LIB_VERSION_INFO)
  73 AC_DEFINE_UNQUOTED([LIB_VERSION], ["$LIB_VERSION"], [libalpm version number])
  74
  75 # Help line for root directory
  76 AC_ARG_WITH(root-dir,
  77         AS_HELP_STRING([--with-root-dir=path], [set the location of the root operating directory]),
  78         [ROOTDIR=$withval], [ROOTDIR=/])
  79
  80 # Help line for package extension
  81 AC_ARG_WITH(pkg-ext,
  82         AS_HELP_STRING([--with-pkg-ext=ext], [set the file extension used by packages]),
  83         [PKGEXT=$withval], [PKGEXT=.pkg.tar.gz])
  84
  85 # Help line for source package directory
  86 AC_ARG_WITH(src-ext,
  87         AS_HELP_STRING([--with-src-ext=ext], [set the file extension used by source packages]),
  88         [SRCEXT=$withval], [SRCEXT=.src.tar.gz])
  89
  90 # Help line for buildscript filename
  91 AC_ARG_WITH(buildscript,
  92         AS_HELP_STRING([--with-buildscript=name], [set the build script name used by makepkg]),
  93         [BUILDSCRIPT=$withval], [BUILDSCRIPT=PKGBUILD])
  94
  95 # Help line for changing shell used to run install scriptlets
  96 AC_ARG_WITH(scriptlet-shell,
  97         AS_HELP_STRING([--with-scriptlet-shell=shell],
  98                 [set the full path to the shell used to run install scriptlets]),
  99         [SCRIPTLET_SHELL=$withval], [SCRIPTLET_SHELL=/bin/sh])
 100
 101 # Help line for using OpenSSL
 102 AC_ARG_WITH(openssl,
 103         AS_HELP_STRING([--with-openssl], [use OpenSSL crypto implementations instead of internal routines]),
 104         [], [with_openssl=check])
 105
 106 # Help line for using gpgme
 107 AC_ARG_WITH(gpgme,
 108         AS_HELP_STRING([--with-gpgme], [use GPGME for PGP signature verification]),
 109         [], [with_gpgme=check])
 110
 111 # Help line for using libcurl
 112 AC_ARG_WITH(curl,
 113         AS_HELP_STRING([--with-libcurl], [use libcurl for the internal downloader]),
 114         [], [with_curl=check])
 115
 116 # Help line for documentation
 117 AC_ARG_ENABLE(doc,
 118         AS_HELP_STRING([--disable-doc], [prevent make from looking at doc/ dir]),
 119         [wantdoc=$enableval], [wantdoc=yes])
 120
 121 # Help line for doxygen
 122 AC_ARG_ENABLE(doxygen,
 123         AS_HELP_STRING([--enable-doxygen], [build your own API docs via Doxygen]),
 124         [wantdoxygen=$enableval], [wantdoxygen=no])
 125
 126 # Help line for debug
 127 AC_ARG_ENABLE(debug,
 128         AS_HELP_STRING([--enable-debug], [enable debugging support]),
 129         [debug=$enableval], [debug=no])
 130
 131 # Help line for compiler warning flags
 132 AC_ARG_ENABLE(warningflags,
 133         AS_HELP_STRING([--enable-warningflags], [enable extra compiler warning flags]),
 134         [warningflags=$enableval], [warningflags=no])
 135
 136 # Help line for using git version in pacman version string
 137 AC_ARG_ENABLE(git-version,
 138         AS_HELP_STRING([--enable-git-version],
 139                 [enable use of git version in version string if available]),
 140         [wantgitver=$enableval], [wantgitver=no])
 141
 142 # Enable large file support if available (must be enabled before
 143 # testing compilation against gpgme).
 144 AC_SYS_LARGEFILE
 145
 146 # Checks for programs.
 147 AC_PROG_AWK
 148 AC_PROG_CC_C99
 149 AC_PROG_INSTALL
 150 AC_CHECK_PROGS([PYTHON], [python2.7 python2.6 python2.5 python2 python], [false])
 151 AC_PATH_PROGS([BASH_SHELL], [bash bash4 bash3], [false])
 152
 153 # find installed gettext
 154 AM_GNU_GETTEXT([external], [need-ngettext])
 155 AM_GNU_GETTEXT_VERSION(0.13.1)
 156
 157 AC_CHECK_LIB([m], [fabs], ,
 158         AC_MSG_ERROR([libm is needed to compile pacman!]))
 159
 160 # Check for libarchive
 161 PKG_CHECK_MODULES(LIBARCHIVE, [libarchive >= 2.8.0], ,
 162         AC_MSG_ERROR([*** libarchive >= 2.8.0 is needed to compile pacman!]))
 163
 164 # Check for OpenSSL
 165 have_openssl=no
 166 if test "x$with_openssl" != "xno"; then
 167         PKG_CHECK_MODULES(LIBSSL, [libssl libcrypto],
 168                 [AC_DEFINE(HAVE_LIBSSL, 1, [Define if libcrypto is available]) have_openssl=yes], have_openssl=no)
 169         if test "x$have_openssl" = xno -a "x$with_openssl" = xyes; then
 170                 AC_MSG_ERROR([*** openssl support requested but libraries not found])
 171         fi
 172 fi
 173 AM_CONDITIONAL(HAVE_LIBSSL, [test "$have_openssl" = "yes"])
 174
 175 # Check for libcurl
 176 have_libcurl=no
 177 if test "x$with_libcurl" != "xno"; then
 178         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.19.4],
 179                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available]) have_libcurl=yes], have_libcurl=no)
 180         if test "x$have_libcurl" = xno -a "x$with_libcurl" = xyes; then
 181                 AC_MSG_ERROR([*** libcurl >= 7.19.4 is required for internal downloader support])
 182         fi
 183 fi
 184 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 185
 186 # Check for gpgme
 187 AC_MSG_CHECKING(whether to link with libgpgme)
 188 AS_IF([test "x$with_gpgme" != "xno"],
 189         [AC_MSG_RESULT([yes])],
 190         [AC_MSG_RESULT([no])])
 191
 192 have_gpgme=no
 193 AS_IF([test "x$with_gpgme" != "xno"],
 194         [AM_PATH_GPGME([1.3.0],
 195                 [LIBS_save="$LIBS"
 196                 CPPFLAGS_save="$CPPFLAGS"
 197                 CFLAGS_save="$CFLAGS"
 198
 199                 LIBS="$LIBS $GPGME_LIBS"
 200                 CPPFLAGS="$CPPFLAGS $GPGME_CPPFLAGS"
 201                 CFLAGS="$CFLAGS $GPGME_CFLAGS"
 202
 203                 AC_MSG_CHECKING([for sane gpgme])
 204                 AC_LINK_IFELSE(
 205                         [AC_LANG_PROGRAM(
 206                                 [[#include <gpgme.h>]],
 207                                 [[return gpgme_check_version("1.3.0");]])],
 208                         [AC_MSG_RESULT([yes])
 209                         have_gpgme=yes
 210                         AC_DEFINE([HAVE_LIBGPGME], [1], [Define if gpgme should be used to provide GPG signature support.])],
 211                         [AC_MSG_RESULT([no])
 212                         have_gpgme=no
 213                         unset GPGME_LIBS
 214                         unset GPGME_CFLAGS]
 215                         AS_IF([test "x$with_gpgme" = "xyes"],
 216                                 [AC_MSG_FAILURE([*** gpgme >= 1.3.0 is needed for GPG signature support])])
 217                         )],
 218                 [with_gpgme=no])]
 219                 [LIBS="$LIBS_save"
 220                 CPPFLAGS="$CPPFLAGS_save"
 221                 CFLAGS="$CFLAGS_save"
 222                 unset CPPFLAGS_save
 223                 unset CFLAGS_save])
 224 AS_IF([test "x$have_gpgme" = xno -a "x$with_gpgme" = xyes],
 225         [AC_MSG_FAILURE([--with-gpgme was given, but gpgme was not found])])
 226 AM_CONDITIONAL([HAVE_LIBGPGME], [test "x$have_gpgme" = "xyes"])
 227
 228 # Checks for header files.
 229 AC_CHECK_HEADERS([fcntl.h float.h glob.h libintl.h limits.h locale.h \
 230                   mntent.h netinet/in.h netinet/tcp.h \
 231                   stddef.h string.h sys/ioctl.h \
 232                   sys/mnttab.h sys/mount.h \
 233                   sys/param.h sys/statvfs.h sys/time.h sys/types.h \
 234                   sys/ucred.h syslog.h termios.h wchar.h])
 235
 236 # Checks for typedefs, structures, and compiler characteristics.
 237 AC_C_INLINE
 238 AC_TYPE_INT64_T
 239 AC_TYPE_MODE_T
 240 AC_TYPE_OFF_T
 241 AC_TYPE_PID_T
 242 AC_TYPE_SIZE_T
 243 AC_TYPE_SSIZE_T
 244 AC_STRUCT_TM
 245 AC_TYPE_UID_T
 246 AC_STRUCT_DIRENT_D_TYPE
 247 PATH_MAX_DEFINED
 248
 249 # Checks for library functions.
 250 AC_FUNC_FORK
 251 AC_FUNC_GETMNTENT
 252 AC_FUNC_LSTAT_FOLLOWS_SLASHED_SYMLINK
 253 AC_FUNC_MALLOC
 254 AC_FUNC_MKTIME
 255 AC_FUNC_STRCOLL
 256 AC_CHECK_FUNCS([dup2 getcwd geteuid getmntinfo gettimeofday memmove memset \
 257                 mkdir realpath regcomp rmdir setenv setlocale strcasecmp \
 258                 strchr strcspn strdup strerror strndup strrchr strsep strstr \
 259                 strtol swprintf tcflush wcwidth uname])
 260 AC_CHECK_MEMBERS([struct stat.st_blksize],,,[[#include <sys/stat.h>]])
 261
 262 # For the diskspace code
 263 FS_STATS_TYPE
 264 AC_CHECK_MEMBERS([struct statvfs.f_flag],,,[[#include <sys/statvfs.h>]])
 265 AC_CHECK_MEMBERS([struct statfs.f_flags],,,[[#include <sys/param.h>
 266                   #include <sys/mount.h>]])
 267
 268 # Check if we can use symbol visibility support in GCC
 269 GCC_VISIBILITY_CC
 270 # Check if we have -fgnu89-inline flag
 271 GCC_GNU89_INLINE_CC
 272
 273 # Host-dependant definitions
 274 SIZECMD="stat -c %s"
 275 SEDINPLACE="sed -i"
 276 STRIP_BINARIES="--strip-all"
 277 STRIP_SHARED="--strip-unneeded"
 278 STRIP_STATIC="--strip-debug"
 279 case "${host_os}" in
 280         *bsd*)
 281                 SIZECMD="stat -f %z"
 282                 SEDINPLACE="sed -i \"\""
 283                 ;;
 284         cygwin*)
 285                 host_os_cygwin=yes
 286                 AC_DEFINE([CYGWIN], [1], [Define if host OS is cygwin])
 287                 ;;
 288         darwin*)
 289                 host_os_darwin=yes
 290                 SIZECMD="/usr/bin/stat -f %z"
 291                 SEDINPLACE="/usr/bin/sed -i ''"
 292                 STRIP_BINARIES=""
 293                 STRIP_SHARED="-S"
 294                 STRIP_STATIC="-S"
 295                 ;;
 296 esac
 297
 298 AM_CONDITIONAL([CYGWIN], test "x$host_os_cygwin" = "xyes")
 299 AM_CONDITIONAL([DARWIN], test "x$host_os_darwin" = "xyes")
 300 AC_PATH_PROGS([DUPATH], [du], [du], [/usr/bin$PATH_SEPARATOR/bin] )
 301 AC_SUBST(SIZECMD)
 302 AC_SUBST(SEDINPLACE)
 303 AC_SUBST(STRIP_BINARIES)
 304 AC_SUBST(STRIP_SHARED)
 305 AC_SUBST(STRIP_STATIC)
 306
 307 # Variables plugged into makepkg.conf
 308 CARCH="${host%%-*}"
 309 CHOST="${host}"
 310 AC_SUBST(CARCH)
 311 AC_SUBST(CHOST)
 312
 313 # Check for documentation support and status
 314 AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
 315 AC_MSG_CHECKING([for building documentation])
 316 if test "x$wantdoc" = "xyes" ; then
 317         if test $ASCIIDOC ; then
 318                 AC_MSG_RESULT([yes, enabled by configure])
 319         else
 320                 asciidoc="(warning : asciidoc not installed)"
 321                 AC_MSG_RESULT([yes $asciidoc])
 322         fi
 323         wantdoc=yes
 324 else
 325         AC_MSG_RESULT([no, disabled by configure])
 326         wantdoc=no
 327 fi
 328 AM_CONDITIONAL(WANT_DOC, test "x$wantdoc" = "xyes")
 329
 330 # Check for doxygen support and status
 331 AC_CHECK_PROGS([DOXYGEN], [doxygen])
 332 AC_MSG_CHECKING([for doxygen])
 333 if test "x$wantdoxygen" = "xyes" ; then
 334         if test $DOXYGEN ; then
 335                 AC_MSG_RESULT([yes])
 336                 usedoxygen=yes
 337         else
 338                 AC_MSG_RESULT([no, doxygen missing])
 339                 usedoxygen=no
 340         fi
 341 else
 342         AC_MSG_RESULT([no, disabled by configure])
 343         usedoxygen=no
 344 fi
 345 AM_CONDITIONAL(USE_DOXYGEN, test "x$usedoxygen" = "xyes")
 346
 347 # Enable or disable debug code
 348 AC_MSG_CHECKING(for debug mode request)
 349 if test "x$debug" = "xyes" ; then
 350         AC_MSG_RESULT(yes)
 351         AC_DEFINE([PACMAN_DEBUG], , [Enable debug code])
 352         # Check for -fstack-protector availability
 353         GCC_STACK_PROTECT_LIB
 354         GCC_STACK_PROTECT_CC
 355         GCC_FORTIFY_SOURCE_CC
 356         WARNING_CFLAGS="-g -Wall -Werror"
 357 else
 358         AC_MSG_RESULT(no)
 359         WARNING_CFLAGS="-Wall"
 360 fi
 361
 362 # Enable or disable compiler warning flags
 363 AC_MSG_CHECKING(for excessive compiler warning flags)
 364 if test "x$warningflags" = "xyes" ; then
 365         AC_MSG_RESULT(yes)
 366         CFLAGS_ADD([-Wcast-align], [WARNING_CFLAGS])
 367         CFLAGS_ADD([-Wclobbered], [WARNING_CFLAGS])
 368         CFLAGS_ADD([-Wempty-body], [WARNING_CFLAGS])
 369         CFLAGS_ADD([-Wfloat-equal], [WARNING_CFLAGS])
 370         CFLAGS_ADD([-Wformat-nonliteral], [WARNING_CFLAGS])
 371         CFLAGS_ADD([-Wformat-security], [WARNING_CFLAGS])
 372         CFLAGS_ADD([-Wignored-qualifiers], [WARNING_CFLAGS])
 373         CFLAGS_ADD([-Winit-self], [WARNING_CFLAGS])
 374         CFLAGS_ADD([-Wlogical-op], [WARNING_CFLAGS])
 375         CFLAGS_ADD([-Wmissing-declarations], [WARNING_CFLAGS])
 376         CFLAGS_ADD([-Wmissing-parameter-type], [WARNING_CFLAGS])
 377         CFLAGS_ADD([-Wmissing-prototypes], [WARNING_CFLAGS])
 378         CFLAGS_ADD([-Wold-style-declaration], [WARNING_CFLAGS])
 379         CFLAGS_ADD([-Woverride-init], [WARNING_CFLAGS])
 380         CFLAGS_ADD([-Wpointer-arith], [WARNING_CFLAGS])
 381         CFLAGS_ADD([-Wredundant-decls], [WARNING_CFLAGS])
 382         CFLAGS_ADD([-Wshadow], [WARNING_CFLAGS])
 383         CFLAGS_ADD([-Wsign-compare], [WARNING_CFLAGS])
 384         CFLAGS_ADD([-Wstrict-aliasing], [WARNING_CFLAGS])
 385         CFLAGS_ADD([-Wstrict-overflow=5], [WARNING_CFLAGS])
 386         CFLAGS_ADD([-Wstrict-prototypes], [WARNING_CFLAGS])
 387         CFLAGS_ADD([-Wtype-limits], [WARNING_CFLAGS])
 388         CFLAGS_ADD([-Wuninitialized], [WARNING_CFLAGS])
 389         CFLAGS_ADD([-Wunused-but-set-parameter], [WARNING_CFLAGS])
 390         CFLAGS_ADD([-Wunused-parameter], [WARNING_CFLAGS])
 391         CFLAGS_ADD([-Wwrite-strings], [WARNING_CFLAGS])
 392 else
 393         AC_MSG_RESULT(no)
 394 fi
 395
 396 # Enable or disable use of git version in pacman version string
 397 AC_MSG_CHECKING(whether to use git version if available)
 398 if test "x$wantgitver" = "xyes" ; then
 399         AC_CHECK_PROGS([GIT], [git])
 400         AC_CHECK_FILE([.git/], hasgitdir=yes)
 401         if test $GIT -a "x$hasgitdir" = "xyes"; then
 402                 AC_MSG_RESULT([yes])
 403                 usegitver=yes
 404                 AC_DEFINE([USE_GIT_VERSION], , [Use GIT version in version string])
 405         else
 406                 AC_MSG_RESULT([no, git or .git dir missing])
 407                 usegitver=no
 408         fi
 409 else
 410         AC_MSG_RESULT([no, disabled by configure])
 411         usegitver=no
 412 fi
 413 AM_CONDITIONAL(USE_GIT_VERSION, test "x$usegitver" = "xyes")
 414
 415 # Set root directory
 416 AC_SUBST(ROOTDIR)
 417 AC_DEFINE_UNQUOTED([ROOTDIR], "$ROOTDIR", [The location of the root operating directory])
 418 # Set package file extension
 419 AC_SUBST(PKGEXT)
 420 AC_DEFINE_UNQUOTED([PKGEXT], "$PKGEXT", [The file extension used by pacman packages])
 421 # Set source package file extension
 422 AC_SUBST(SRCEXT)
 423 AC_DEFINE_UNQUOTED([SRCEXT], "$SRCEXT", [The file extension used by pacman source packages])
 424 # Set makepkg build script name
 425 AC_SUBST(BUILDSCRIPT)
 426 AC_DEFINE_UNQUOTED([BUILDSCRIPT], "$BUILDSCRIPT", [The build script name used by makepkg])
 427 # Set shell used by install scriptlets
 428 AC_SUBST(SCRIPTLET_SHELL)
 429 AC_DEFINE_UNQUOTED([SCRIPTLET_SHELL], "$SCRIPTLET_SHELL", [The full path of the shell used to run install scriptlets])
 430
 431 # Configuration files
 432 AC_CONFIG_FILES([
 433 lib/libalpm/Makefile
 434 lib/libalpm/po/Makefile.in
 435 src/pacman/Makefile
 436 src/pacman/po/Makefile.in
 437 src/util/Makefile
 438 scripts/Makefile
 439 scripts/po/Makefile.in
 440 doc/Makefile
 441 etc/Makefile
 442 test/pacman/Makefile
 443 test/pacman/tests/Makefile
 444 test/util/Makefile
 445 contrib/Makefile
 446 Makefile
 447 ])
 448 AC_OUTPUT
 449
 450 echo "
 451 ${PACKAGE_NAME}:
 452
 453   Build information:
 454     source code location   : ${srcdir}
 455     prefix                 : ${prefix}
 456     sysconfdir             : $(eval echo ${sysconfdir})
 457        conf file           : $(eval echo ${sysconfdir})/pacman.conf
 458     localstatedir          : $(eval echo ${localstatedir})
 459        database dir        : $(eval echo ${localstatedir})/lib/pacman/
 460        cache dir           : $(eval echo ${localstatedir})/cache/pacman/pkg/
 461
 462     compiler               : ${CC}
 463     preprocessor flags     : ${CPPFLAGS}
 464     compiler flags         : ${WARNING_CFLAGS} ${CFLAGS}
 465     defines                : ${DEFS}
 466     library flags          : ${LIBS} ${LIBSSL_LIBS} ${LIBARCHIVE_LIBS} ${LIBCURL_LIBS} ${GPGME_LIBS}
 467     linker flags           : ${LDFLAGS}
 468
 469     Architecture           : ${CARCH}
 470     Host Type              : ${CHOST}
 471     Filesize command       : ${SIZECMD}
 472     In-place sed command   : ${SEDINPLACE}
 473
 474     libalpm version        : ${LIB_VERSION}
 475     libalpm version info   : ${LIB_VERSION_INFO}
 476     pacman version         : ${PACKAGE_VERSION}
 477     using git version      : ${usegitver}
 478
 479   Directory and file information:
 480     root working directory : ${ROOTDIR}
 481     package extension      : ${PKGEXT}
 482     source pkg extension   : ${SRCEXT}
 483     build script name      : ${BUILDSCRIPT}
 484
 485   Compilation options:
 486     Use libcurl            : ${have_libcurl}
 487     Use GPGME              : ${have_gpgme}
 488     Use OpenSSL            : ${have_openssl}
 489     Run make in doc/ dir   : ${wantdoc} ${asciidoc}
 490     Doxygen support        : ${usedoxygen}
 491     debug support          : ${debug}
 492     extra warning flags    : ${warningflags}
 493     use git version        : ${wantgitver}
 494 "
 495
 496 # vim:set ts=2 sw=2 noet: